arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/constructors/successor_1.ma".
  16 include "ground_2/notation/functions/predecessor_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'Successor m = (S m).
  23
  24 interpretation "nat predecessor" 'Predecessor m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ⫯(x+y) = (⫯x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ⫯(n1∨n2) = (⫯n1 ∨ ⫯n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ⫯n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  61 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  62 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  63 qed-.
  64
  65 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  66 /2 width=1 by plus_minus_minus_be/ qed-.
  67
  68 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  69 // qed.
  70
  71 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  72 /2 by plus_minus/ qed-.
  73
  74 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  75 /2 by plus_minus/ qed-.
  76
  77 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  78 // qed.
  79
  80 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  81 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  82 qed-.
  83
  84 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  85 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  86 qed-.
  87
  88 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  89 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  90
  91 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  92                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  93 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  94 qed-.
  95
  96 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  97 /2 width=1 by plus_minus/ qed-.
  98
  99 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
 100                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
 101 /2 width=1 by arith_b1/ qed-.
 102
 103 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 104 #n normalize >le_to_leb_true //
 105 qed.
 106
 107 lemma associative_max: associative … max.
 108 #x #y #z normalize
 109 @(leb_elim x y) normalize #Hxy
 110 @(leb_elim y z) normalize #Hyz //
 111 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 112 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 113   >not_le_to_leb_false //
 114 ]
 115 qed.
 116
 117 (* Properties ***************************************************************)
 118
 119 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 120 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 121 [1,4: @or_intror #H destruct
 122 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 123 | /2 width=1 by or_introl/
 124 ]
 125 qed-.
 126
 127 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 128 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 129 #H elim H -m /2 width=1 by or3_intro1/
 130 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 131 qed-.
 132
 133 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 134 // qed-.
 135
 136 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 137 // qed-.
 138
 139 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 140 /3 width=1 by monotonic_le_minus_l/ qed.
 141
 142 (* Note: this might interfere with nat.ma *)
 143 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 144 #m #n #Hmn #Hm whd >(S_pred … Hm)
 145 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 146 qed.
 147
 148 lemma lt_S_S: ∀x,y. x < y → ⫯x < ⫯y.
 149 /2 width=1 by le_S_S/ qed.
 150
 151 lemma lt_S: ∀n,m. n < m → n < ⫯m.
 152 /2 width=1 by le_S/ qed.
 153
 154 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (⫯n1 ∨ n2) ≤ ⫯n.
 155 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 156
 157 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ⫯n2) ≤ ⫯n.
 158 /2 width=1 by max_S1_le_S/ qed-.
 159
 160 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 161 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 162
 163 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 164 #z #x #y #n #Hzx #Hxny
 165 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 166 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 167 /2 width=1 by monotonic_le_minus_l2/
 168 qed.
 169
 170 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 171 #z #x #y #n #Hzx #Hyxn
 172 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 173 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 174 /2 width=1 by monotonic_le_minus_l2/
 175 qed.
 176
 177 (* Inversion & forward lemmas ***********************************************)
 178
 179 lemma lt_refl_false: ∀n. n < n → ⊥.
 180 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 181 qed-.
 182
 183 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 184 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 185 qed-.
 186
 187 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 188 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 189
 190 lemma succ_inv_refl_sn: ∀x. ⫯x = x → ⊥.
 191 #x #H @(lt_le_false x (⫯x)) //
 192 qed-.
 193
 194 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 195 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 196 qed-.
 197
 198 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 199 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 200 #H elim (le_plus_xSy_O_false … H)
 201 qed-.
 202
 203 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 204 /2 width=4 by le_plus_xySz_x_false/ qed-.
 205
 206 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 207 /2 width=4 by plus_xySz_x_false/ qed-.
 208
 209 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 210 * // normalize #m #H elim (lt_refl_false m) //
 211 qed-.
 212
 213 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 214 // qed-.
 215
 216 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 217 /2 width=2 by le_plus_minus_comm/ qed-.
 218
 219 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 220 /2 width=1 by monotonic_pred/ qed-.
 221
 222 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 223 #m1 #m2 #n1 #n2 #H #Hm
 224 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 225 /2 width=2 by le_plus_to_le/
 226 qed-.
 227
 228 lemma lt_S_S_to_lt: ∀x,y. ⫯x < ⫯y → x < y.
 229 /2 width=1 by le_S_S_to_le/ qed-.
 230
 231 (* Note this should go in nat.ma *)
 232 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 233 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 234 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 235 #y #_ >minus_plus_plus_l
 236 #H lapply (discr_plus_xy_minus_xz … H) -H
 237 #H destruct
 238 qed-.
 239
 240 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ⫯m = n.
 241 * /2 width=2 by ex_intro/
 242 #H cases (lt_le_false … H) -H //
 243 qed-.
 244
 245 lemma lt_inv_S1: ∀m,n. ⫯m < n → ∃∃p. m < p & ⫯p = n.
 246 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 247 #H cases (lt_le_false … H) -H //
 248 qed-.
 249
 250 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ⫯z = y.
 251 * /3 width=3 by le_S_S_to_le, ex2_intro/
 252 #x #H elim (lt_le_false … H) -H //
 253 qed-.
 254
 255 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 256 /2 width=1 by plus_le_0/ qed-.
 257
 258 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 259 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 260 qed-.
 261
 262 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 263 * /2 width=1 by conj/ #x #y normalize #H destruct
 264 qed-.
 265
 266 lemma nat_split: ∀x. x = 0 ∨ ∃y. ⫯y = x.
 267 * /3 width=2 by ex_intro, or_introl, or_intror/
 268 qed-.
 269
 270 lemma lt_elim: ∀R:relation nat.
 271                (∀n2. R O (⫯n2)) →
 272                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 273                ∀n2,n1. n1 < n2 → R n1 n2.
 274 #R #IH1 #IH2 #n2 elim n2 -n2
 275 [ #n1 #H elim (lt_le_false … H) -H //
 276 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 277 ]
 278 qed-.
 279
 280 lemma le_elim: ∀R:relation nat.
 281                (∀n2. R O (n2)) →
 282                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 283                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 284 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 285 /4 width=1 by monotonic_pred/ -IH1 -IH2
 286 #n1 #H elim (lt_le_false … H) -H //
 287 qed-.
 288
 289 (* Iterators ****************************************************************)
 290
 291 (* Note: see also: lib/arithemetics/bigops.ma *)
 292 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 293   match n with
 294    [ O   ⇒ nil
 295    | S k ⇒ op (iter k B op nil)
 296    ].
 297
 298 interpretation "iterated function" 'exp op n = (iter n ? op).
 299
 300 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 301 // qed.
 302
 303 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 304 // qed.
 305
 306 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 307 #B #f #b #l >commutative_plus //
 308 qed.
 309
 310 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 311 #B #f #b #l elim l -l normalize //
 312 qed.
 313
 314 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 315 #B #f #b #l1 elim l1 -l1 normalize //
 316 qed.
 317
 318 (* Trichotomy operator ******************************************************)
 319
 320 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 321 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 322   match n1 with
 323   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 324   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 325   ].
 326
 327 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 328 #A #a1 #a2 #a3 #n2 elim n2 -n2
 329 [ #n1 #H elim (lt_zero_false … H)
 330 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 331 ]
 332 qed.
 333
 334 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 335 #A #a1 #a2 #a3 #n elim n -n normalize //
 336 qed.
 337
 338 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 339 #A #a1 #a2 #a3 #n1 elim n1 -n1
 340 [ #n2 #H elim (lt_zero_false … H)
 341 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 342 ]
 343 qed.