components/acic_content/termAcicContent.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31
  32 let debug = false
  33 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  34
  35 type interpretation_id = int
  36
  37 let idref id t = Ast.AttributedTerm (`IdRef id, t)
  38
  39 type term_info =
  40   { sort: (Cic.id, Ast.sort_kind) Hashtbl.t;
  41     uri: (Cic.id, UriManager.uri) Hashtbl.t;
  42   }
  43
  44 let get_types uri =
  45   let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
  46     match o with
  47       | Cic.InductiveDefinition (l,_,_,_) -> l
  48       | _ -> assert false
  49
  50 let name_of_inductive_type uri i =
  51   let types = get_types uri in
  52   let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  53   name
  54
  55   (* returns <name, type> pairs *)
  56 let constructors_of_inductive_type uri i =
  57   let types = get_types uri in
  58   let (_, _, _, constructors) =
  59     try List.nth types i with Not_found -> assert false
  60   in
  61   constructors
  62
  63   (* returns name only *)
  64 let constructor_of_inductive_type uri i j =
  65   (try
  66     fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  67   with Not_found -> assert false)
  68
  69
  70 let ast_of_acic0 term_info acic k =
  71   let k = k term_info in
  72   let id_to_uris = term_info.uri in
  73   let register_uri id uri = Hashtbl.add id_to_uris id uri in
  74   let sort_of_id id =
  75     try
  76       Hashtbl.find term_info.sort id
  77     with Not_found ->
  78       prerr_endline (sprintf "warning: sort of id %s not found, using Type" id);
  79       `Type (CicUniv.fresh ())
  80   in
  81   let aux_substs substs =
  82     Some
  83       (List.map
  84         (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
  85         substs)
  86   in
  87   let aux_context context =
  88     List.map
  89       (function
  90         | None -> None
  91         | Some annterm -> Some (k annterm))
  92       context
  93   in
  94   let aux = function
  95     | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
  96     | Cic.AVar (id,uri,substs) ->
  97         register_uri id uri;
  98         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
  99     | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
 100     | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
 101     | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
 102     | Cic.ASort (id,Cic.Type u) -> idref id (Ast.Sort (`Type u))
 103     | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
 104     | Cic.AImplicit (id, Some `Hole) -> idref id Ast.UserInput
 105     | Cic.AImplicit (id, _) -> idref id Ast.Implicit
 106     | Cic.AProd (id,n,s,t) ->
 107         let binder_kind =
 108           match sort_of_id id with
 109           | `Set | `Type _ -> `Pi
 110           | `Prop | `CProp -> `Forall
 111         in
 112         idref id (Ast.Binder (binder_kind,
 113           (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
 114     | Cic.ACast (id,v,t) -> idref id (Ast.Cast (k v, k t))
 115     | Cic.ALambda (id,n,s,t) ->
 116         idref id (Ast.Binder (`Lambda,
 117           (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
 118     | Cic.ALetIn (id,n,s,t) ->
 119         idref id (Ast.LetIn ((CicNotationUtil.name_of_cic_name n, None),
 120           k s, k t))
 121     | Cic.AAppl (aid,(Cic.AConst _ as he::tl as args))
 122     | Cic.AAppl (aid,(Cic.AMutInd _ as he::tl as args))
 123     | Cic.AAppl (aid,(Cic.AMutConstruct _ as he::tl as args)) ->
 124        let last_n n l =
 125          let rec aux =
 126           function
 127              [] -> assert false
 128            | [_] as l -> l,1
 129            | he::tl ->
 130               let (res,len) as res' = aux tl in
 131                if len < n then
 132                 he::res,len + 1
 133                else
 134                 res'
 135          in
 136           match fst (aux l) with
 137              [] -> assert false
 138            | [t] -> t
 139            | Ast.AttributedTerm (_,(Ast.Appl l))::tl ->
 140                idref aid (Ast.Appl (l@tl))
 141            | l -> idref aid (Ast.Appl l)
 142        in
 143        let deannot_he = Deannotate.deannotate_term he in
 144        if CoercGraph.is_a_coercion deannot_he && !Acic2content.hide_coercions
 145        then
 146          match CoercGraph.is_a_coercion_to_funclass deannot_he with
 147          | None -> idref aid (last_n 1 (List.map k tl))
 148          | Some i -> idref aid (last_n (i+1) (List.map k tl))
 149        else
 150         idref aid (Ast.Appl (List.map k args))
 151     | Cic.AAppl (aid,args) ->
 152         idref aid (Ast.Appl (List.map k args))
 153     | Cic.AConst (id,uri,substs) ->
 154         register_uri id uri;
 155         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 156     | Cic.AMutInd (id,uri,i,substs) ->
 157         let name = name_of_inductive_type uri i in
 158         let uri_str = UriManager.string_of_uri uri in
 159         let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (i+1) in
 160         register_uri id (UriManager.uri_of_string puri_str);
 161         idref id (Ast.Ident (name, aux_substs substs))
 162     | Cic.AMutConstruct (id,uri,i,j,substs) ->
 163         let name = constructor_of_inductive_type uri i j in
 164         let uri_str = UriManager.string_of_uri uri in
 165         let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
 166         register_uri id (UriManager.uri_of_string puri_str);
 167         idref id (Ast.Ident (name, aux_substs substs))
 168     | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
 169         let name = name_of_inductive_type uri typeno in
 170         let uri_str = UriManager.string_of_uri uri in
 171         let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (typeno+1) in
 172         let ctor_puri j =
 173           UriManager.uri_of_string
 174             (sprintf "%s#xpointer(1/%d/%d)" uri_str (typeno+1) j)
 175         in
 176         let case_indty = name, Some (UriManager.uri_of_string puri_str) in
 177         let constructors = constructors_of_inductive_type uri typeno in
 178         let rec eat_branch ty pat =
 179           match (ty, pat) with
 180           | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
 181               let (cv, rhs) = eat_branch t t' in
 182               (CicNotationUtil.name_of_cic_name name, Some (k s)) :: cv, rhs
 183           | _, _ -> [], k pat
 184         in
 185         let j = ref 0 in
 186         let patterns =
 187           try
 188             List.map2
 189               (fun (name, ty) pat ->
 190                 incr j;
 191                 let (capture_variables, rhs) = eat_branch ty pat in
 192                 ((name, Some (ctor_puri !j), capture_variables), rhs))
 193               constructors patterns
 194           with Invalid_argument _ -> assert false
 195         in
 196         idref id (Ast.Case (k te, Some case_indty, Some (k ty), patterns))
 197     | Cic.AFix (id, no, funs) ->
 198         let defs =
 199           List.map
 200             (fun (_, n, decr_idx, ty, bo) ->
 201               ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
 202             funs
 203         in
 204         let name =
 205           try
 206             (match List.nth defs no with
 207             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 208             | _ -> assert false)
 209           with Not_found -> assert false
 210         in
 211         idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
 212     | Cic.ACoFix (id, no, funs) ->
 213         let defs =
 214           List.map
 215             (fun (_, n, ty, bo) ->
 216               ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
 217             funs
 218         in
 219         let name =
 220           try
 221             (match List.nth defs no with
 222             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 223             | _ -> assert false)
 224           with Not_found -> assert false
 225         in
 226         idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
 227   in
 228   aux acic
 229
 230   (* persistent state *)
 231
 232 let level2_patterns32 = Hashtbl.create 211
 233 let interpretations = Hashtbl.create 211  (* symb -> id list ref *)
 234
 235 let compiled32 = ref None
 236 let pattern32_matrix = ref []
 237
 238 let get_compiled32 () =
 239   match !compiled32 with
 240   | None -> assert false
 241   | Some f -> Lazy.force f
 242
 243 let set_compiled32 f = compiled32 := Some f
 244
 245 let add_idrefs =
 246   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 247
 248 let instantiate32 term_info idrefs env symbol args =
 249   let rec instantiate_arg = function
 250     | Ast.IdentArg (n, name) ->
 251         let t = (try List.assoc name env with Not_found -> assert false) in
 252         let rec count_lambda = function
 253           | Ast.AttributedTerm (_, t) -> count_lambda t
 254           | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
 255           | _ -> 0
 256         in
 257         let rec add_lambda t n =
 258           if n > 0 then
 259             let name = CicNotationUtil.fresh_name () in
 260             Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
 261               Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
 262           else
 263             t
 264         in
 265         add_lambda t (n - count_lambda t)
 266   in
 267   let head =
 268     let symbol = Ast.Symbol (symbol, 0) in
 269     add_idrefs idrefs symbol
 270   in
 271   if args = [] then head
 272   else Ast.Appl (head :: List.map instantiate_arg args)
 273
 274 let rec ast_of_acic1 term_info annterm =
 275   let id_to_uris = term_info.uri in
 276   let register_uri id uri = Hashtbl.add id_to_uris id uri in
 277   match (get_compiled32 ()) annterm with
 278   | None -> ast_of_acic0 term_info annterm ast_of_acic1
 279   | Some (env, ctors, pid) ->
 280       let idrefs =
 281         List.map
 282           (fun annterm ->
 283             let idref = CicUtil.id_of_annterm annterm in
 284             (try
 285               register_uri idref
 286                 (CicUtil.uri_of_term (Deannotate.deannotate_term annterm))
 287             with Invalid_argument _ -> ());
 288             idref)
 289           ctors
 290       in
 291       let env' =
 292         List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
 293       in
 294       let _, symbol, args, _ =
 295         try
 296           Hashtbl.find level2_patterns32 pid
 297         with Not_found -> assert false
 298       in
 299       let ast = instantiate32 term_info idrefs env' symbol args in
 300       Ast.AttributedTerm (`IdRef (CicUtil.id_of_annterm annterm), ast)
 301
 302 let load_patterns32 t =
 303   let t =
 304     HExtlib.filter_map (function (true, ap, id) -> Some (ap, id) | _ -> None) t
 305   in
 306   set_compiled32 (lazy (Acic2astMatcher.Matcher32.compiler t))
 307
 308 let ast_of_acic id_to_sort annterm =
 309   debug_print (lazy ("ast_of_acic <- "
 310     ^ CicPp.ppterm (Deannotate.deannotate_term annterm)));
 311   let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
 312   let ast = ast_of_acic1 term_info annterm in
 313   debug_print (lazy ("ast_of_acic -> " ^ CicNotationPp.pp_term ast));
 314   ast, term_info.uri
 315
 316 let fresh_id =
 317   let counter = ref ~-1 in
 318   fun () ->
 319     incr counter;
 320     !counter
 321
 322 let add_interpretation dsc (symbol, args) appl_pattern =
 323   let id = fresh_id () in
 324   Hashtbl.add level2_patterns32 id (dsc, symbol, args, appl_pattern);
 325   pattern32_matrix := (true, appl_pattern, id) :: !pattern32_matrix;
 326   load_patterns32 !pattern32_matrix;
 327   (try
 328     let ids = Hashtbl.find interpretations symbol in
 329     ids := id :: !ids
 330   with Not_found -> Hashtbl.add interpretations symbol (ref [id]));
 331   id
 332
 333 let get_all_interpretations () =
 334   List.map
 335     (function (_, _, id) ->
 336       let (dsc, _, _, _) =
 337         try
 338           Hashtbl.find level2_patterns32 id
 339         with Not_found -> assert false
 340       in
 341       (id, dsc))
 342     !pattern32_matrix
 343
 344 let get_active_interpretations () =
 345   HExtlib.filter_map (function (true, _, id) -> Some id | _ -> None)
 346     !pattern32_matrix
 347
 348 let set_active_interpretations ids =
 349   let pattern32_matrix' =
 350     List.map
 351       (function
 352         | (_, ap, id) when List.mem id ids -> (true, ap, id)
 353         | (_, ap, id) -> (false, ap, id))
 354       !pattern32_matrix
 355   in
 356   pattern32_matrix := pattern32_matrix';
 357   load_patterns32 !pattern32_matrix
 358
 359 exception Interpretation_not_found
 360
 361 let lookup_interpretations symbol =
 362   try
 363    HExtlib.list_uniq
 364     (List.sort Pervasives.compare
 365      (List.map
 366       (fun id ->
 367         let (dsc, _, args, appl_pattern) =
 368           try
 369             Hashtbl.find level2_patterns32 id
 370           with Not_found -> assert false
 371         in
 372         dsc, args, appl_pattern)
 373       !(Hashtbl.find interpretations symbol)))
 374   with Not_found -> raise Interpretation_not_found
 375
 376 let remove_interpretation id =
 377   (try
 378     let _, symbol, _, _ = Hashtbl.find level2_patterns32 id in
 379     let ids = Hashtbl.find interpretations symbol in
 380     ids := List.filter ((<>) id) !ids;
 381     Hashtbl.remove level2_patterns32 id;
 382   with Not_found -> raise Interpretation_not_found);
 383   pattern32_matrix :=
 384     List.filter (fun (_, _, id') -> id <> id') !pattern32_matrix;
 385   load_patterns32 !pattern32_matrix
 386
 387 let _ = load_patterns32 []
 388
 389 let instantiate_appl_pattern env appl_pattern =
 390   let lookup name =
 391     try List.assoc name env
 392     with Not_found ->
 393       prerr_endline (sprintf "Name %s not found" name);
 394       assert false
 395   in
 396   let rec aux = function
 397     | Ast.UriPattern uri -> CicUtil.term_of_uri uri
 398     | Ast.ImplicitPattern -> Cic.Implicit None
 399     | Ast.VarPattern name -> lookup name
 400     | Ast.ApplPattern terms -> Cic.Appl (List.map aux terms)
 401   in
 402   aux appl_pattern
 403