components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module D    = Deannotate
  29 module S    = CicSubstitution
  30 module TC   = CicTypeChecker
  31 module Un   = CicUniv
  32 module UM   = UriManager
  33 module Obj  = LibraryObjects
  34 module HObj = HelmLibraryObjects
  35 module A    = Cic2acic
  36 module Ut   = CicUtil
  37 module E    = CicEnvironment
  38 module Pp   = CicPp
  39 module PEH  = ProofEngineHelpers
  40 module HEL  = HExtlib
  41 module DTI  = DoubleTypeInference
  42
  43 module Cl   = ProceduralClassify
  44 module T    = ProceduralTypes
  45 module Cn   = ProceduralConversion
  46 module H    = ProceduralHelpers
  47
  48 type status = {
  49    sorts : (C.id, A.sort_kind) Hashtbl.t;
  50    types : (C.id, A.anntypes) Hashtbl.t;
  51    prefix: string;
  52    max_depth: int option;
  53    depth: int;
  54    context: C.context;
  55    intros: string option list;
  56    clears: string list;
  57    clears_note: string;
  58    case: int list
  59 }
  60
  61 (* helpers ******************************************************************)
  62
  63 let cic = D.deannotate_term
  64
  65 let split2_last l1 l2 =
  66 try
  67    let n = pred (List.length l1) in
  68    let before1, after1 = HEL.split_nth n l1 in
  69    let before2, after2 = HEL.split_nth n l2 in
  70    before1, before2, List.hd after1, List.hd after2
  71 with Invalid_argument _ -> failwith "A2P.split2_last"
  72
  73 let string_of_head = function
  74    | C.ASort _         -> "sort"
  75    | C.AConst _        -> "const"
  76    | C.AMutInd _       -> "mutind"
  77    | C.AMutConstruct _ -> "mutconstruct"
  78    | C.AVar _          -> "var"
  79    | C.ARel _          -> "rel"
  80    | C.AProd _         -> "prod"
  81    | C.ALambda _       -> "lambda"
  82    | C.ALetIn _        -> "letin"
  83    | C.AFix _          -> "fix"
  84    | C.ACoFix _        -> "cofix"
  85    | C.AAppl _         -> "appl"
  86    | C.ACast _         -> "cast"
  87    | C.AMutCase _      -> "mutcase"
  88    | C.AMeta _         -> "meta"
  89    | C.AImplicit _     -> "implict"
  90
  91 let clear st = {st with intros = []}
  92
  93 let next st = {(clear st) with depth = succ st.depth}
  94
  95 let add st entry intro =
  96    {st with context = entry :: st.context; intros = intro :: st.intros}
  97
  98 let push st = {st with case = 1 :: st.case}
  99
 100 let inc st =
 101    {st with case = match st.case with
 102       | []       -> assert false
 103       | hd :: tl -> succ hd :: tl
 104    }
 105
 106 let case st str =
 107    let case = String.concat "." (List.rev_map string_of_int st.case) in
 108    Printf.sprintf "case %s: %s" case str
 109
 110 let test_depth st =
 111 try
 112    let msg = Printf.sprintf "Depth %u: " st.depth in
 113    match st.max_depth with
 114       | None   -> true, ""
 115       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 116 with Invalid_argument _ -> failwith "A2P.test_depth"
 117
 118 let is_rewrite_right = function
 119    | C.AConst (_, uri, []) ->
 120       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 121    | _                     -> false
 122
 123 let is_rewrite_left = function
 124    | C.AConst (_, uri, []) ->
 125       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 126    | _                     -> false
 127
 128 let is_fwd_rewrite_right hd tl =
 129    if is_rewrite_right hd then match List.nth tl 3 with
 130       | C.ARel _ -> true
 131       | _        -> false
 132    else false
 133
 134 let is_fwd_rewrite_left hd tl =
 135    if is_rewrite_left hd then match List.nth tl 3 with
 136       | C.ARel _ -> true
 137       | _        -> false
 138    else false
 139
 140 let get_inner_types st v =
 141 try
 142    let id = Ut.id_of_annterm v in
 143    try match Hashtbl.find st.types id with
 144       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 145       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 146    with Not_found -> None
 147 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 148 (*
 149 let get_inner_sort st v =
 150 try
 151    let id = Ut.id_of_annterm v in
 152    try Hashtbl.find st.sorts id
 153    with Not_found -> `Type (CicUniv.fresh())
 154 with Invalid_argument _ -> failwith "A2P.get_sort"
 155 *)
 156 let get_type msg st bo =
 157 try
 158    let ty, _ = TC.type_of_aux' [] st.context (cic bo) Un.empty_ugraph in
 159    ty
 160 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 161
 162 let get_entry st id =
 163    let rec aux = function
 164       | []                                        -> assert false
 165       | Some (C.Name name, e) :: _ when name = id -> e
 166       | _ :: tl                                   -> aux tl
 167    in
 168    aux st.context
 169
 170 let get_ind_names uri tno =
 171 try
 172    let ts = match E.get_obj Un.empty_ugraph uri with
 173       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 174       | _                                      -> assert false
 175    in
 176    match List.nth ts tno with
 177       | (_, _, _, cs) -> List.map fst cs
 178 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 179
 180 (* proof construction *******************************************************)
 181
 182 let used_premise = C.Name "USED"
 183
 184 let mk_exp_args hd tl classes synth =
 185    let meta id = C.AImplicit (id, None) in
 186    let map v (cl, b) =
 187       if I.overlaps synth cl && b then v else meta ""
 188    in
 189    let rec aux = function
 190       | [] -> []
 191       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 192    in
 193    let args = T.list_rev_map2 map tl classes in
 194    let args = aux args in
 195    if args = [] then hd else C.AAppl ("", hd :: args)
 196
 197 let convert st ?name v =
 198    match get_inner_types st v with
 199       | None            -> []
 200       | Some (sty, ety) ->
 201          let e = Cn.hole "" in
 202          let csty, cety = cic sty, cic ety in
 203          if Ut.alpha_equivalence csty cety then [] else
 204          match name with
 205             | None         -> [T.Change (sty, ety, None, e, "")]
 206             | Some (id, i) ->
 207                begin match get_entry st id with
 208                   | C.Def _  -> [T.ClearBody (id, "")]
 209                   | C.Decl w ->
 210                      let w = S.lift i w in
 211                      if Ut.alpha_equivalence csty w then []
 212                      else
 213                      [T.Note (Pp.ppterm csty); T.Note (Pp.ppterm w);
 214                      T.Change (sty, ety, Some (id, Some id), e, "")]
 215                end
 216
 217 let get_intro = function
 218    | C.Anonymous -> None
 219    | C.Name s    -> Some s
 220
 221 let mk_intros st script =
 222    let intros st script =
 223       if st.intros = [] then script else
 224       let count = List.length st.intros in
 225       T.Intros (Some count, List.rev st.intros, "") :: script
 226    in
 227    let clears st script =
 228       if st.clears = [] then script else T.Clear (st.clears, st.clears_note) :: script
 229    in
 230    intros st (clears st script)
 231
 232 let mk_arg st = function
 233    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 234    | _                              -> []
 235
 236 let mk_fwd_rewrite st dtext name tl direction =
 237    assert (List.length tl = 6);
 238    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 239    let e = Cn.mk_pattern 1 predicate in
 240    match where with
 241       | C.ARel (_, _, _, premise) ->
 242          let script = mk_arg st what in
 243          let where = Some (premise, name) in
 244          let st = {st with context = Cn.clear st.context premise} in
 245          st, T.Rewrite (direction, what, where, e, dtext) :: script
 246       | _                         -> assert false
 247
 248 let mk_rewrite st dtext what qs tl direction =
 249    assert (List.length tl = 5);
 250    let predicate = List.nth tl 2 in
 251    let e = Cn.mk_pattern 1 predicate in
 252    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 253
 254 let rec proc_lambda st name v t =
 255    let dno = DTI.does_not_occur 1 (cic t) in
 256    let dno = dno && match get_inner_types st t with
 257       | None          -> true
 258       | Some (it, et) ->
 259          DTI.does_not_occur 1 (cic it) && DTI.does_not_occur 1 (cic et)
 260    in
 261    let name = match dno, name with
 262       | true, _            -> C.Anonymous
 263       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 264       | false, name        -> name
 265    in
 266    let entry = Some (name, C.Decl (cic v)) in
 267    let intro = get_intro name in
 268    proc_proof (add st entry intro) t
 269
 270 and proc_letin st what name v t =
 271    let intro = get_intro name in
 272    let proceed, dtext = test_depth st in
 273    let script = if proceed then
 274       let st, hyp, rqv = match get_inner_types st v with
 275          | Some (ity, _) ->
 276             let st, rqv = match v with
 277                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 278                   mk_fwd_rewrite st dtext intro tl true
 279                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 280                   mk_fwd_rewrite st dtext intro tl false
 281                | v                                                     ->
 282                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 283                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 284             in
 285             st, C.Decl (cic ity), rqv
 286          | None          ->
 287             st, C.Def (cic v, None), [T.LetIn (intro, v, dtext)]
 288       in
 289       let entry = Some (name, hyp) in
 290       let qt = proc_proof (next (add st entry intro)) t in
 291       List.rev_append rqv qt
 292    else
 293       [T.Apply (what, dtext)]
 294    in
 295    mk_intros st script
 296
 297 and proc_rel st what =
 298    let _, dtext = test_depth st in
 299    let text = "assumption" in
 300    let script = [T.Apply (what, dtext ^ text)] in
 301    mk_intros st script
 302
 303 and proc_mutconstruct st what =
 304    let _, dtext = test_depth st in
 305    let script = [T.Apply (what, dtext)] in
 306    mk_intros st script
 307
 308 and proc_appl st what hd tl =
 309    let proceed, dtext = test_depth st in
 310    let script = if proceed then
 311       let ty = get_type "TC2" st hd in
 312       let classes, rc = Cl.classify st.context ty in
 313       let goal_arity = match get_inner_types st what with
 314          | None          -> 0
 315          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, cic ity))
 316       in
 317       let parsno, argsno = List.length classes, List.length tl in
 318       let decurry = parsno - argsno in
 319       let diff = goal_arity - decurry in
 320       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (cic hd)));
 321       let rec mk_synth a n =
 322          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 323       in
 324       let synth = mk_synth I.S.empty decurry in
 325       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 326       let script = List.rev (mk_arg st hd) @ convert st what in
 327       match rc with
 328          | Some (i, j, uri, tyno) ->
 329             let classes, tl, _, where = split2_last classes tl in
 330             let script = List.rev (mk_arg st where) @ script in
 331             let synth = I.S.add 1 synth in
 332             let names = get_ind_names uri tyno in
 333             let qs = proc_bkd_proofs (next st) synth names classes tl in
 334             if is_rewrite_right hd then
 335                script @ mk_rewrite st dtext where qs tl false
 336             else if is_rewrite_left hd then
 337                script @ mk_rewrite st dtext where qs tl true
 338             else
 339                let predicate = List.nth tl (parsno - i) in
 340                let e = Cn.mk_pattern j predicate in
 341                let using = Some hd in
 342                script @
 343                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 344          | None        ->
 345             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 346             let hd = mk_exp_args hd tl classes synth in
 347             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 348    else
 349       [T.Apply (what, dtext)]
 350    in
 351    mk_intros st script
 352
 353 and proc_other st what =
 354    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 355    let script = [T.Note text] in
 356    mk_intros st script
 357
 358 and proc_proof st t =
 359    let f st =
 360       let xtypes, note = match get_inner_types st t with
 361          | Some (it, et) -> Some (cic it, cic et),
 362           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 363           (Pp.ppterm (cic it)) (Pp.ppterm (cic et)))
 364          | None          -> None, "\nNo types"
 365       in
 366       let context, clears = Cn.get_clears st.context (cic t) xtypes in
 367       let note = Pp.ppcontext st.context ^ note in
 368       {st with context = context; clears = clears; clears_note = note}
 369    in
 370    match t with
 371       | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 372       | C.ALetIn (_, name, v, t) as what -> proc_letin (f st) what name v t
 373       | C.ARel _ as what                 -> proc_rel (f st) what
 374       | C.AMutConstruct _ as what        -> proc_mutconstruct (f st) what
 375       | C.AAppl (_, hd :: tl) as what    -> proc_appl (f st) what hd tl
 376       | what                             -> proc_other (f st) what
 377
 378 and proc_bkd_proofs st synth names classes ts =
 379 try
 380    let get_note =
 381       let names = ref (names, push st) in
 382       fun f ->
 383          match !names with
 384             | [], st       -> fun _ -> f st
 385             | "" :: tl, st -> names := tl, st; fun _ -> f st
 386             | hd :: tl, st ->
 387                let note = case st hd in
 388                names := tl, inc st;
 389                fun b -> if b then T.Note note :: f st else f st
 390    in
 391    let _, dtext = test_depth st in
 392    let aux (inv, _) v =
 393       if I.overlaps synth inv then None else
 394       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 395       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 396    in
 397    let ps = T.list_map2_filter aux classes ts in
 398    let b = List.length ps > 1 in
 399    List.rev_map (fun f -> f b) ps
 400
 401 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 402
 403 (* object costruction *******************************************************)
 404
 405 let is_theorem pars =
 406    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 407    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 408
 409 let proc_obj st = function
 410    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 411       let ast = proc_proof st v in
 412       let count = T.count_steps 0 ast in
 413       let text = Printf.sprintf "tactics: %u" count in
 414       T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 415    | _                                                               ->
 416       failwith "not a theorem"
 417
 418 (* interface functions ******************************************************)
 419
 420 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 421    let st = {
 422       sorts       = ids_to_inner_sorts;
 423       types       = ids_to_inner_types;
 424       prefix      = prefix;
 425       max_depth   = depth;
 426       depth       = 0;
 427       context     = [];
 428       intros      = [];
 429       clears      = [];
 430       clears_note = "";
 431       case        = []
 432    } in
 433    HLog.debug "Procedural: level 2 transformation";
 434    let steps = proc_obj st aobj in
 435    HLog.debug "Procedural: grafite rendering";
 436    List.rev (T.render_steps [] steps)