components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list;
  58    skip_thm_and_qed : bool;
  59    skip_initial_lambdas : bool;
  60 }
  61
  62 (* helpers ******************************************************************)
  63
  64 let split2_last l1 l2 =
  65 try
  66    let n = pred (List.length l1) in
  67    let before1, after1 = HEL.split_nth n l1 in
  68    let before2, after2 = HEL.split_nth n l2 in
  69    before1, before2, List.hd after1, List.hd after2
  70 with Invalid_argument _ -> failwith "A2P.split2_last"
  71
  72 let string_of_head = function
  73    | C.ASort _         -> "sort"
  74    | C.AConst _        -> "const"
  75    | C.AMutInd _       -> "mutind"
  76    | C.AMutConstruct _ -> "mutconstruct"
  77    | C.AVar _          -> "var"
  78    | C.ARel _          -> "rel"
  79    | C.AProd _         -> "prod"
  80    | C.ALambda _       -> "lambda"
  81    | C.ALetIn _        -> "letin"
  82    | C.AFix _          -> "fix"
  83    | C.ACoFix _        -> "cofix"
  84    | C.AAppl _         -> "appl"
  85    | C.ACast _         -> "cast"
  86    | C.AMutCase _      -> "mutcase"
  87    | C.AMeta _         -> "meta"
  88    | C.AImplicit _     -> "implict"
  89
  90 let clear st = {st with intros = []}
  91
  92 let next st = {(clear st) with depth = succ st.depth}
  93
  94 let add st entry intro =
  95    {st with context = entry :: st.context; intros = intro :: st.intros}
  96
  97 let push st = {st with case = 1 :: st.case}
  98
  99 let inc st =
 100    {st with case = match st.case with
 101       | []       -> assert false
 102       | hd :: tl -> succ hd :: tl
 103    }
 104
 105 let case st str =
 106    let case = String.concat "." (List.rev_map string_of_int st.case) in
 107    Printf.sprintf "case %s: %s" case str
 108
 109 let test_depth st =
 110 try
 111    let msg = Printf.sprintf "Depth %u: " st.depth in
 112    match st.max_depth with
 113       | None   -> true, ""
 114       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 115 with Invalid_argument _ -> failwith "A2P.test_depth"
 116
 117 let is_rewrite_right = function
 118    | C.AConst (_, uri, []) ->
 119       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 120    | _                     -> false
 121
 122 let is_rewrite_left = function
 123    | C.AConst (_, uri, []) ->
 124       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 125    | _                     -> false
 126
 127 let is_fwd_rewrite_right hd tl =
 128    if is_rewrite_right hd then match List.nth tl 3 with
 129       | C.ARel _ -> true
 130       | _        -> false
 131    else false
 132
 133 let is_fwd_rewrite_left hd tl =
 134    if is_rewrite_left hd then match List.nth tl 3 with
 135       | C.ARel _ -> true
 136       | _        -> false
 137    else false
 138
 139 let get_inner_types st v =
 140 try
 141    let id = Ut.id_of_annterm v in
 142    try match Hashtbl.find st.types id with
 143       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 144       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 145    with Not_found -> None
 146 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 147 (*
 148 let get_inner_sort st v =
 149 try
 150    let id = Ut.id_of_annterm v in
 151    try Hashtbl.find st.sorts id
 152    with Not_found -> `Type (CicUniv.fresh())
 153 with Invalid_argument _ -> failwith "A2P.get_sort"
 154 *)
 155 let get_type msg st bo =
 156 try
 157    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.empty_ugraph in
 158    ty
 159 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 160
 161 let get_entry st id =
 162    let rec aux = function
 163       | []                                        -> assert false
 164       | Some (C.Name name, e) :: _ when name = id -> e
 165       | _ :: tl                                   -> aux tl
 166    in
 167    aux st.context
 168
 169 let get_ind_names uri tno =
 170 try
 171    let ts = match E.get_obj Un.empty_ugraph uri with
 172       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 173       | _                                      -> assert false
 174    in
 175    match List.nth ts tno with
 176       | (_, _, _, cs) -> List.map fst cs
 177 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 178
 179 (* proof construction *******************************************************)
 180
 181 let used_premise = C.Name "USED"
 182
 183 let mk_exp_args hd tl classes synth =
 184    let meta id = C.AImplicit (id, None) in
 185    let map v (cl, b) =
 186       if I.overlaps synth cl && b then v else meta ""
 187    in
 188    let rec aux = function
 189       | [] -> []
 190       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 191    in
 192    let args = T.list_rev_map2 map tl classes in
 193    let args = aux args in
 194    if args = [] then hd else C.AAppl ("", hd :: args)
 195
 196 let mk_convert st ?name sty ety note =
 197    let e = Cn.hole "" in
 198    let csty, cety = H.cic sty, H.cic ety in
 199    let _note = Printf.sprintf "%s\nSINTH: %s\nEXP: %s"
 200       note (Pp.ppterm csty) (Pp.ppterm cety)
 201    in
 202    if Ut.alpha_equivalence csty cety then [(* T.Note note *)] else
 203    match name with
 204       | None         -> [T.Change (sty, ety, None, e, ""(*note*))]
 205       | Some (id, i) ->
 206          begin match get_entry st id with
 207             | C.Def _  -> assert false (* [T.ClearBody (id, note)] *)
 208             | C.Decl _ -> [T.Change (ety, sty, Some (id, Some id), e, "" (* note *))]
 209          end
 210
 211 let convert st ?name v =
 212    match get_inner_types st v with
 213       | None            -> [(*T.Note "NORMAL: NO INNER TYPES"*)]
 214       | Some (sty, ety) -> mk_convert st ?name sty ety "NORMAL"
 215
 216 let convert_elim st ?name t v pattern =
 217    match t, get_inner_types st t, get_inner_types st v with
 218       | _, None, _
 219       | _, _, None                                            -> [(* T.Note "ELIM: NO INNER TYPES"*)]
 220       | C.AAppl (_, hd :: tl), Some (tsty, _), Some (vsty, _) ->
 221          let where = List.hd (List.rev tl) in
 222          let cty = Cn.elim_inferred_type
 223              st.context (H.cic vsty) (H.cic where) (H.cic hd) (H.cic pattern)
 224          in
 225          mk_convert st ?name (Cn.fake_annotate "" st.context cty) tsty "ELIM"
 226       | _, Some _, Some _                                     -> assert false
 227
 228 let get_intro = function
 229    | C.Anonymous -> None
 230    | C.Name s    -> Some s
 231
 232 let mk_intros st what script =
 233    let intros st script =
 234       if st.intros = [] then script else
 235       let count = List.length st.intros in
 236       T.Intros (Some count, List.rev st.intros, "") :: script
 237    in
 238    let clears st script =
 239       if true (* st.clears = [] *) then script else T.Clear (st.clears, st.clears_note) :: script
 240    in
 241    intros st (clears st (convert st what @ script))
 242
 243 let mk_arg st = function
 244    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 245    | _                              -> []
 246
 247 let mk_fwd_rewrite st dtext name tl direction t =
 248    assert (List.length tl = 6);
 249    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 250    let e = Cn.mk_pattern 1 predicate in
 251    match where with
 252       | C.ARel (_, _, i, premise) as v ->
 253          let where = Some (premise, name) in
 254 (*         let _script = convert_elim st ~name:(premise, i) t v e in *)
 255          let script = mk_arg st what @ mk_arg st v (* @ script *) in
 256          let st = {st with context = Cn.clear st.context premise} in
 257          st, T.Rewrite (direction, what, where, e, dtext) :: script
 258       | _                         -> assert false
 259
 260 let mk_rewrite st dtext where qs tl direction t =
 261    assert (List.length tl = 5);
 262    let predicate = List.nth tl 2 in
 263    let e = Cn.mk_pattern 1 predicate in
 264    let script = [] (* convert_elim st t t e *) in
 265    script @ [T.Rewrite (direction, where, None, e, dtext); T.Branch (qs, "")]
 266
 267 let rec proc_lambda st name v t =
 268    let dno = DTI.does_not_occur 1 (H.cic t) in
 269    let dno = dno && match get_inner_types st t with
 270       | None          -> true
 271       | Some (it, et) ->
 272          DTI.does_not_occur 1 (H.cic it) && DTI.does_not_occur 1 (H.cic et)
 273    in
 274    let name = match dno, name with
 275       | true, _            -> C.Anonymous
 276       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 277       | false, name        -> name
 278    in
 279    let entry = Some (name, C.Decl (H.cic v)) in
 280    let intro = get_intro name in
 281    proc_proof (add st entry intro) t
 282
 283 and proc_letin st what name v t =
 284    let intro = get_intro name in
 285    let proceed, dtext = test_depth st in
 286    let script = if proceed then
 287       let st, hyp, rqv = match get_inner_types st v with
 288          | Some (ity, _) ->
 289             let st, rqv = match v with
 290                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 291                   mk_fwd_rewrite st dtext intro tl true v
 292                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 293                   mk_fwd_rewrite st dtext intro tl false v
 294                | v                                                     ->
 295                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 296                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 297             in
 298             st, C.Decl (H.cic ity), rqv
 299          | None          ->
 300             st, C.Def (H.cic v, None), [T.LetIn (intro, v, dtext)]
 301       in
 302       let entry = Some (name, hyp) in
 303       let qt = proc_proof (next (add st entry intro)) t in
 304       List.rev_append rqv qt
 305    else
 306       [T.Apply (what, dtext)]
 307    in
 308    mk_intros st what script
 309
 310 and proc_rel st what =
 311    let _, dtext = test_depth st in
 312    let text = "assumption" in
 313    let script = [T.Apply (what, dtext ^ text)] in
 314    mk_intros st what script
 315
 316 and proc_mutconstruct st what =
 317    let _, dtext = test_depth st in
 318    let script = [T.Apply (what, dtext)] in
 319    mk_intros st what script
 320
 321 and proc_appl st what hd tl =
 322    let proceed, dtext = test_depth st in
 323    let script = if proceed then
 324       let ty = get_type "TC2" st hd in
 325       let classes, rc = Cl.classify st.context ty in
 326       let goal_arity = match get_inner_types st what with
 327          | None          -> 0
 328          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, H.cic ity))
 329       in
 330       let parsno, argsno = List.length classes, List.length tl in
 331       let decurry = parsno - argsno in
 332       let diff = goal_arity - decurry in
 333       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 334       let rec mk_synth a n =
 335          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 336       in
 337       let synth = mk_synth I.S.empty decurry in
 338       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 339       let script = List.rev (mk_arg st hd) in
 340       match rc with
 341          | Some (i, j, uri, tyno) ->
 342             let classes, tl, _, where = split2_last classes tl in
 343             let script = List.rev (mk_arg st where) @ script in
 344             let synth = I.S.add 1 synth in
 345             let names = get_ind_names uri tyno in
 346             let qs = proc_bkd_proofs (next st) synth names classes tl in
 347             if is_rewrite_right hd then
 348                script @ mk_rewrite st dtext where qs tl false what
 349             else if is_rewrite_left hd then
 350                script @ mk_rewrite st dtext where qs tl true what
 351             else
 352                let predicate = List.nth tl (parsno - i) in
 353                let e = Cn.mk_pattern j predicate in
 354                let using = Some hd in
 355                (* convert_elim st what what e @ *) script @
 356                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 357          | None        ->
 358             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 359             let hd = mk_exp_args hd tl classes synth in
 360             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 361    else
 362       [T.Apply (what, dtext)]
 363    in
 364    mk_intros st what script
 365
 366 and proc_other st what =
 367    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 368    let script = [T.Note text] in
 369    mk_intros st what script
 370
 371 and proc_proof st t =
 372    let f st =
 373       let xtypes, note = match get_inner_types st t with
 374          | Some (it, et) -> Some (H.cic it, H.cic et),
 375           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 376           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 377          | None          -> None, "\nNo types"
 378       in
 379       let context, clears =
 380         if st.skip_initial_lambdas then
 381           st.context, []
 382         else
 383           Cn.get_clears st.context (H.cic t) xtypes
 384       in
 385       let note = Pp.ppcontext st.context ^ note in
 386       {st with context = context; clears = clears; clears_note = note; }
 387    in
 388    match t with
 389       | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 390       | C.ALetIn (_, name, v, t) as what -> proc_letin (f st) what name v t
 391       | C.ARel _ as what                 -> proc_rel (f st) what
 392       | C.AMutConstruct _ as what        -> proc_mutconstruct (f st) what
 393       | C.AAppl (_, hd :: tl) as what    -> proc_appl (f st) what hd tl
 394       | what                             -> proc_other (f st) what
 395
 396 and proc_bkd_proofs st synth names classes ts =
 397 try
 398    let get_note =
 399       let names = ref (names, push st) in
 400       fun f ->
 401          match !names with
 402             | [], st       -> fun _ -> f st
 403             | "" :: tl, st -> names := tl, st; fun _ -> f st
 404             | hd :: tl, st ->
 405                let note = case st hd in
 406                names := tl, inc st;
 407                fun b -> if b then T.Note note :: f st else f st
 408    in
 409    let _, dtext = test_depth st in
 410    let aux (inv, _) v =
 411       if I.overlaps synth inv then None else
 412       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 413       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 414    in
 415    let ps = T.list_map2_filter aux classes ts in
 416    let b = List.length ps > 1 in
 417    List.rev_map (fun f -> f b) ps
 418
 419 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 420
 421 (* object costruction *******************************************************)
 422
 423 let is_theorem pars =
 424    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 425    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 426
 427 let proc_obj st = function
 428    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 429       let ast = proc_proof st v in
 430       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 431       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 432       let ast =
 433         if st.skip_initial_lambdas then
 434           match ast with
 435             | T.Intros _::tl -> tl
 436             | ast -> ast
 437         else ast
 438       in
 439       if st.skip_thm_and_qed then ast
 440       else T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 441    | _                                                               ->
 442       failwith "not a theorem"
 443
 444 (* interface functions ******************************************************)
 445
 446 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth
 447 ?(skip_thm_and_qed=false) ?(skip_initial_lambdas=false) prefix aobj =
 448    let st = {
 449       sorts       = ids_to_inner_sorts;
 450       types       = ids_to_inner_types;
 451       prefix      = prefix;
 452       max_depth   = depth;
 453       depth       = 0;
 454       context     = [];
 455       intros      = [];
 456       clears      = [];
 457       clears_note = "";
 458       case        = [];
 459       skip_thm_and_qed = skip_thm_and_qed;
 460       skip_initial_lambdas = skip_initial_lambdas;
 461    } in
 462    HLog.debug "Procedural: level 2 transformation";
 463    let steps = proc_obj st aobj in
 464    HLog.debug "Procedural: grafite rendering";
 465    List.rev (T.render_steps [] steps)