components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module S    = CicSubstitution
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module Pp   = CicPp
  38 module PEH  = ProofEngineHelpers
  39 module HEL  = HExtlib
  40 module DTI  = DoubleTypeInference
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45 module H    = ProceduralHelpers
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list
  58 }
  59
  60 (* helpers ******************************************************************)
  61
  62 let split2_last l1 l2 =
  63 try
  64    let n = pred (List.length l1) in
  65    let before1, after1 = HEL.split_nth n l1 in
  66    let before2, after2 = HEL.split_nth n l2 in
  67    before1, before2, List.hd after1, List.hd after2
  68 with Invalid_argument _ -> failwith "A2P.split2_last"
  69
  70 let string_of_head = function
  71    | C.ASort _         -> "sort"
  72    | C.AConst _        -> "const"
  73    | C.AMutInd _       -> "mutind"
  74    | C.AMutConstruct _ -> "mutconstruct"
  75    | C.AVar _          -> "var"
  76    | C.ARel _          -> "rel"
  77    | C.AProd _         -> "prod"
  78    | C.ALambda _       -> "lambda"
  79    | C.ALetIn _        -> "letin"
  80    | C.AFix _          -> "fix"
  81    | C.ACoFix _        -> "cofix"
  82    | C.AAppl _         -> "appl"
  83    | C.ACast _         -> "cast"
  84    | C.AMutCase _      -> "mutcase"
  85    | C.AMeta _         -> "meta"
  86    | C.AImplicit _     -> "implict"
  87
  88 let clear st = {st with intros = []}
  89
  90 let next st = {(clear st) with depth = succ st.depth}
  91
  92 let add st entry intro =
  93    {st with context = entry :: st.context; intros = intro :: st.intros}
  94
  95 let push st = {st with case = 1 :: st.case}
  96
  97 let inc st =
  98    {st with case = match st.case with
  99       | []       -> assert false
 100       | hd :: tl -> succ hd :: tl
 101    }
 102
 103 let case st str =
 104    let case = String.concat "." (List.rev_map string_of_int st.case) in
 105    Printf.sprintf "case %s: %s" case str
 106
 107 let test_depth st =
 108 try
 109    let msg = Printf.sprintf "Depth %u: " st.depth in
 110    match st.max_depth with
 111       | None   -> true, ""
 112       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 113 with Invalid_argument _ -> failwith "A2P.test_depth"
 114
 115 let is_rewrite_right = function
 116    | C.AConst (_, uri, []) ->
 117       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 118    | _                     -> false
 119
 120 let is_rewrite_left = function
 121    | C.AConst (_, uri, []) ->
 122       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 123    | _                     -> false
 124
 125 let is_fwd_rewrite_right hd tl =
 126    if is_rewrite_right hd then match List.nth tl 3 with
 127       | C.ARel _ -> true
 128       | _        -> false
 129    else false
 130
 131 let is_fwd_rewrite_left hd tl =
 132    if is_rewrite_left hd then match List.nth tl 3 with
 133       | C.ARel _ -> true
 134       | _        -> false
 135    else false
 136
 137 let get_inner_types st v =
 138 try
 139    let id = Ut.id_of_annterm v in
 140    try match Hashtbl.find st.types id with
 141       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 142       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 143    with Not_found -> None
 144 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 145 (*
 146 let get_inner_sort st v =
 147 try
 148    let id = Ut.id_of_annterm v in
 149    try Hashtbl.find st.sorts id
 150    with Not_found -> `Type (CicUniv.fresh())
 151 with Invalid_argument _ -> failwith "A2P.get_sort"
 152 *)
 153 let get_type msg st bo =
 154 try
 155    let ty, _ = TC.type_of_aux' [] st.context (H.cic bo) Un.empty_ugraph in
 156    ty
 157 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 158
 159 let get_entry st id =
 160    let rec aux = function
 161       | []                                        -> assert false
 162       | Some (C.Name name, e) :: _ when name = id -> e
 163       | _ :: tl                                   -> aux tl
 164    in
 165    aux st.context
 166
 167 let get_ind_names uri tno =
 168 try
 169    let ts = match E.get_obj Un.empty_ugraph uri with
 170       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 171       | _                                      -> assert false
 172    in
 173    match List.nth ts tno with
 174       | (_, _, _, cs) -> List.map fst cs
 175 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 176
 177 (* proof construction *******************************************************)
 178
 179 let used_premise = C.Name "USED"
 180
 181 let mk_exp_args hd tl classes synth =
 182    let meta id = C.AImplicit (id, None) in
 183    let map v (cl, b) =
 184       if I.overlaps synth cl && b then v else meta ""
 185    in
 186    let rec aux = function
 187       | [] -> []
 188       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 189    in
 190    let args = T.list_rev_map2 map tl classes in
 191    let args = aux args in
 192    if args = [] then hd else C.AAppl ("", hd :: args)
 193
 194 let convert st ?name v =
 195    match get_inner_types st v with
 196       | None            -> []
 197       | Some (sty, ety) ->
 198          let e = Cn.hole "" in
 199          let csty, cety = H.cic sty, H.cic ety in
 200          if Ut.alpha_equivalence csty cety then [] else
 201          match name with
 202             | None         -> [T.Change (sty, ety, None, e, "")]
 203             | Some (id, i) ->
 204                begin match get_entry st id with
 205                   | C.Def _  -> [T.ClearBody (id, "")]
 206                   | C.Decl w ->
 207                      let w = S.lift i w in
 208                      if Ut.alpha_equivalence csty w then []
 209                      else
 210                      [T.Note (Pp.ppterm csty); T.Note (Pp.ppterm w);
 211                      T.Change (sty, ety, Some (id, Some id), e, "")]
 212                end
 213
 214 let get_intro = function
 215    | C.Anonymous -> None
 216    | C.Name s    -> Some s
 217
 218 let mk_intros st script =
 219    let intros st script =
 220       if st.intros = [] then script else
 221       let count = List.length st.intros in
 222       T.Intros (Some count, List.rev st.intros, "") :: script
 223    in
 224    let clears st script =
 225       if st.clears = [] then script else T.Clear (st.clears, st.clears_note) :: script
 226    in
 227    intros st (clears st script)
 228
 229 let mk_arg st = function
 230    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 231    | _                              -> []
 232
 233 let mk_fwd_rewrite st dtext name tl direction =
 234    assert (List.length tl = 6);
 235    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 236    let e = Cn.mk_pattern 1 predicate in
 237    match where with
 238       | C.ARel (_, _, _, premise) ->
 239          let script = mk_arg st what in
 240          let where = Some (premise, name) in
 241          let st = {st with context = Cn.clear st.context premise} in
 242          st, T.Rewrite (direction, what, where, e, dtext) :: script
 243       | _                         -> assert false
 244
 245 let mk_rewrite st dtext what qs tl direction =
 246    assert (List.length tl = 5);
 247    let predicate = List.nth tl 2 in
 248    let e = Cn.mk_pattern 1 predicate in
 249    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 250
 251 let rec proc_lambda st name v t =
 252    let dno = DTI.does_not_occur 1 (H.cic t) in
 253    let dno = dno && match get_inner_types st t with
 254       | None          -> true
 255       | Some (it, et) ->
 256          DTI.does_not_occur 1 (H.cic it) && DTI.does_not_occur 1 (H.cic et)
 257    in
 258    let name = match dno, name with
 259       | true, _            -> C.Anonymous
 260       | false, C.Anonymous -> H.mk_fresh_name st.context used_premise
 261       | false, name        -> name
 262    in
 263    let entry = Some (name, C.Decl (H.cic v)) in
 264    let intro = get_intro name in
 265    proc_proof (add st entry intro) t
 266
 267 and proc_letin st what name v t =
 268    let intro = get_intro name in
 269    let proceed, dtext = test_depth st in
 270    let script = if proceed then
 271       let st, hyp, rqv = match get_inner_types st v with
 272          | Some (ity, _) ->
 273             let st, rqv = match v with
 274                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 275                   mk_fwd_rewrite st dtext intro tl true
 276                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 277                   mk_fwd_rewrite st dtext intro tl false
 278                | v                                                     ->
 279                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 280                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 281             in
 282             st, C.Decl (H.cic ity), rqv
 283          | None          ->
 284             st, C.Def (H.cic v, None), [T.LetIn (intro, v, dtext)]
 285       in
 286       let entry = Some (name, hyp) in
 287       let qt = proc_proof (next (add st entry intro)) t in
 288       List.rev_append rqv qt
 289    else
 290       [T.Apply (what, dtext)]
 291    in
 292    mk_intros st script
 293
 294 and proc_rel st what =
 295    let _, dtext = test_depth st in
 296    let text = "assumption" in
 297    let script = [T.Apply (what, dtext ^ text)] in
 298    mk_intros st script
 299
 300 and proc_mutconstruct st what =
 301    let _, dtext = test_depth st in
 302    let script = [T.Apply (what, dtext)] in
 303    mk_intros st script
 304
 305 and proc_appl st what hd tl =
 306    let proceed, dtext = test_depth st in
 307    let script = if proceed then
 308       let ty = get_type "TC2" st hd in
 309       let classes, rc = Cl.classify st.context ty in
 310       let goal_arity = match get_inner_types st what with
 311          | None          -> 0
 312          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, H.cic ity))
 313       in
 314       let parsno, argsno = List.length classes, List.length tl in
 315       let decurry = parsno - argsno in
 316       let diff = goal_arity - decurry in
 317       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (H.cic hd)));
 318       let rec mk_synth a n =
 319          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 320       in
 321       let synth = mk_synth I.S.empty decurry in
 322       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 323       let script = List.rev (mk_arg st hd) @ convert st what in
 324       match rc with
 325          | Some (i, j, uri, tyno) ->
 326             let classes, tl, _, where = split2_last classes tl in
 327             let script = List.rev (mk_arg st where) @ script in
 328             let synth = I.S.add 1 synth in
 329             let names = get_ind_names uri tyno in
 330             let qs = proc_bkd_proofs (next st) synth names classes tl in
 331             if is_rewrite_right hd then
 332                script @ mk_rewrite st dtext where qs tl false
 333             else if is_rewrite_left hd then
 334                script @ mk_rewrite st dtext where qs tl true
 335             else
 336                let predicate = List.nth tl (parsno - i) in
 337                let e = Cn.mk_pattern j predicate in
 338                let using = Some hd in
 339                script @
 340                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 341          | None        ->
 342             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 343             let hd = mk_exp_args hd tl classes synth in
 344             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 345    else
 346       [T.Apply (what, dtext)]
 347    in
 348    mk_intros st script
 349
 350 and proc_other st what =
 351    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 352    let script = [T.Note text] in
 353    mk_intros st script
 354
 355 and proc_proof st t =
 356    let f st =
 357       let xtypes, note = match get_inner_types st t with
 358          | Some (it, et) -> Some (H.cic it, H.cic et),
 359           (Printf.sprintf "\nInferred: %s\nExpected: %s"
 360           (Pp.ppterm (H.cic it)) (Pp.ppterm (H.cic et)))
 361          | None          -> None, "\nNo types"
 362       in
 363       let context, clears = Cn.get_clears st.context (H.cic t) xtypes in
 364       let note = Pp.ppcontext st.context ^ note in
 365       {st with context = context; clears = clears; clears_note = note}
 366    in
 367    match t with
 368       | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 369       | C.ALetIn (_, name, v, t) as what -> proc_letin (f st) what name v t
 370       | C.ARel _ as what                 -> proc_rel (f st) what
 371       | C.AMutConstruct _ as what        -> proc_mutconstruct (f st) what
 372       | C.AAppl (_, hd :: tl) as what    -> proc_appl (f st) what hd tl
 373       | what                             -> proc_other (f st) what
 374
 375 and proc_bkd_proofs st synth names classes ts =
 376 try
 377    let get_note =
 378       let names = ref (names, push st) in
 379       fun f ->
 380          match !names with
 381             | [], st       -> fun _ -> f st
 382             | "" :: tl, st -> names := tl, st; fun _ -> f st
 383             | hd :: tl, st ->
 384                let note = case st hd in
 385                names := tl, inc st;
 386                fun b -> if b then T.Note note :: f st else f st
 387    in
 388    let _, dtext = test_depth st in
 389    let aux (inv, _) v =
 390       if I.overlaps synth inv then None else
 391       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 392       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 393    in
 394    let ps = T.list_map2_filter aux classes ts in
 395    let b = List.length ps > 1 in
 396    List.rev_map (fun f -> f b) ps
 397
 398 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 399
 400 (* object costruction *******************************************************)
 401
 402 let is_theorem pars =
 403    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 404    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 405
 406 let proc_obj st = function
 407    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 408       let ast = proc_proof st v in
 409       let steps, nodes = T.count_steps 0 ast, T.count_nodes 0 ast in
 410       let text = Printf.sprintf "tactics: %u\nnodes: %u" steps nodes in
 411       T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 412    | _                                                               ->
 413       failwith "not a theorem"
 414
 415 (* interface functions ******************************************************)
 416
 417 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 418    let st = {
 419       sorts       = ids_to_inner_sorts;
 420       types       = ids_to_inner_types;
 421       prefix      = prefix;
 422       max_depth   = depth;
 423       depth       = 0;
 424       context     = [];
 425       intros      = [];
 426       clears      = [];
 427       clears_note = "";
 428       case        = []
 429    } in
 430    HLog.debug "Procedural: level 2 transformation";
 431    let steps = proc_obj st aobj in
 432    HLog.debug "Procedural: grafite rendering";
 433    List.rev (T.render_steps [] steps)