components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module D    = Deannotate
  29 module S    = CicSubstitution
  30 module TC   = CicTypeChecker
  31 module Un   = CicUniv
  32 module UM   = UriManager
  33 module Obj  = LibraryObjects
  34 module HObj = HelmLibraryObjects
  35 module A    = Cic2acic
  36 module Ut   = CicUtil
  37 module E    = CicEnvironment
  38 module Pp   = CicPp
  39 module PEH  = ProofEngineHelpers
  40 module HEL  = HExtlib
  41 module DTI  = DoubleTypeInference
  42
  43 module Cl   = ProceduralClassify
  44 module T    = ProceduralTypes
  45 module Cn   = ProceduralConversion
  46
  47 type status = {
  48    sorts : (C.id, A.sort_kind) Hashtbl.t;
  49    types : (C.id, A.anntypes) Hashtbl.t;
  50    prefix: string;
  51    max_depth: int option;
  52    depth: int;
  53    context: C.context;
  54    intros: string option list;
  55    clears: string list;
  56    clears_note: string;
  57    case: int list
  58 }
  59
  60 (* helpers ******************************************************************)
  61
  62 let cic = D.deannotate_term
  63
  64 let split2_last l1 l2 =
  65 try
  66    let n = pred (List.length l1) in
  67    let before1, after1 = HEL.split_nth n l1 in
  68    let before2, after2 = HEL.split_nth n l2 in
  69    before1, before2, List.hd after1, List.hd after2
  70 with Invalid_argument _ -> failwith "A2P.split2_last"
  71
  72 let string_of_head = function
  73    | C.ASort _         -> "sort"
  74    | C.AConst _        -> "const"
  75    | C.AMutInd _       -> "mutind"
  76    | C.AMutConstruct _ -> "mutconstruct"
  77    | C.AVar _          -> "var"
  78    | C.ARel _          -> "rel"
  79    | C.AProd _         -> "prod"
  80    | C.ALambda _       -> "lambda"
  81    | C.ALetIn _        -> "letin"
  82    | C.AFix _          -> "fix"
  83    | C.ACoFix _        -> "cofix"
  84    | C.AAppl _         -> "appl"
  85    | C.ACast _         -> "cast"
  86    | C.AMutCase _      -> "mutcase"
  87    | C.AMeta _         -> "meta"
  88    | C.AImplicit _     -> "implict"
  89
  90 let clear st = {st with intros = []}
  91
  92 let next st = {(clear st) with depth = succ st.depth}
  93
  94 let add st entry intro =
  95    {st with context = entry :: st.context; intros = intro :: st.intros}
  96
  97 let push st = {st with case = 1 :: st.case}
  98
  99 let inc st =
 100    {st with case = match st.case with
 101       | []       -> assert false
 102       | hd :: tl -> succ hd :: tl
 103    }
 104
 105 let case st str =
 106    let case = String.concat "." (List.rev_map string_of_int st.case) in
 107    Printf.sprintf "case %s: %s" case str
 108
 109 let test_depth st =
 110 try
 111    let msg = Printf.sprintf "Depth %u: " st.depth in
 112    match st.max_depth with
 113       | None   -> true, ""
 114       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 115 with Invalid_argument _ -> failwith "A2P.test_depth"
 116
 117 let is_rewrite_right = function
 118    | C.AConst (_, uri, []) ->
 119       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 120    | _                     -> false
 121
 122 let is_rewrite_left = function
 123    | C.AConst (_, uri, []) ->
 124       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 125    | _                     -> false
 126
 127 let is_fwd_rewrite_right hd tl =
 128    if is_rewrite_right hd then match List.nth tl 3 with
 129       | C.ARel _ -> true
 130       | _        -> false
 131    else false
 132
 133 let is_fwd_rewrite_left hd tl =
 134    if is_rewrite_left hd then match List.nth tl 3 with
 135       | C.ARel _ -> true
 136       | _        -> false
 137    else false
 138
 139 let get_inner_types st v =
 140 try
 141    let id = Ut.id_of_annterm v in
 142    try match Hashtbl.find st.types id with
 143       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 144       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 145    with Not_found -> None
 146 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 147 (*
 148 let get_inner_sort st v =
 149 try
 150    let id = Ut.id_of_annterm v in
 151    try Hashtbl.find st.sorts id
 152    with Not_found -> `Type (CicUniv.fresh())
 153 with Invalid_argument _ -> failwith "A2P.get_sort"
 154 *)
 155 let get_type msg st bo =
 156 try
 157    let ty, _ = TC.type_of_aux' [] st.context (cic bo) Un.empty_ugraph in
 158    ty
 159 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 160
 161 let get_entry st id =
 162    let rec aux = function
 163       | []                                        -> assert false
 164       | Some (C.Name name, e) :: _ when name = id -> e
 165       | _ :: tl                                   -> aux tl
 166    in
 167    aux st.context
 168
 169 let get_ind_names uri tno =
 170 try
 171    let ts = match E.get_obj Un.empty_ugraph uri with
 172       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 173       | _                                      -> assert false
 174    in
 175    match List.nth ts tno with
 176       | (_, _, _, cs) -> List.map fst cs
 177 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 178
 179 (* proof construction *******************************************************)
 180
 181 let mk_exp_args hd tl classes synth =
 182    let meta id = C.AImplicit (id, None) in
 183    let map v (cl, b) =
 184       if I.overlaps synth cl && b then v else meta ""
 185    in
 186    let rec aux = function
 187       | [] -> []
 188       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 189    in
 190    let args = T.list_rev_map2 map tl classes in
 191    let args = aux args in
 192    if args = [] then hd else C.AAppl ("", hd :: args)
 193
 194 let convert st ?name v =
 195    match get_inner_types st v with
 196       | None            -> []
 197       | Some (sty, ety) ->
 198          let e = Cn.hole "" in
 199          let csty, cety = cic sty, cic ety in
 200          if Ut.alpha_equivalence csty cety then [] else
 201          match name with
 202             | None         -> [T.Change (sty, ety, None, e, "")]
 203             | Some (id, i) ->
 204                begin match get_entry st id with
 205                   | C.Def _  -> [T.ClearBody (id, "")]
 206                   | C.Decl w ->
 207                      let w = S.lift i w in
 208                      if Ut.alpha_equivalence csty w then []
 209                      else
 210                      [T.Note (Pp.ppterm csty); T.Note (Pp.ppterm w);
 211                      T.Change (sty, ety, Some (id, Some id), e, "")]
 212                end
 213
 214 let get_intro = function
 215    | C.Anonymous -> None
 216    | C.Name s    -> Some s
 217
 218 let mk_intros st script =
 219    let intros st script =
 220       if st.intros = [] then script else
 221       let count = List.length st.intros in
 222       T.Intros (Some count, List.rev st.intros, "") :: script
 223    in
 224    let clears st script =
 225       if st.clears = [] then script else T.Clear (st.clears, st.clears_note) :: script
 226    in
 227    intros st (clears st script)
 228
 229 let mk_arg st = function
 230    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 231    | _                              -> []
 232
 233 let mk_fwd_rewrite st dtext name tl direction =
 234    assert (List.length tl = 6);
 235    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 236    let e = Cn.mk_pattern 1 predicate in
 237    match where with
 238       | C.ARel (_, _, _, premise) ->
 239          let script = mk_arg st what in
 240          let where = Some (premise, name) in
 241          let st = {st with context = Cn.clear st.context premise} in
 242          st, T.Rewrite (direction, what, where, e, dtext) :: script
 243       | _                         -> assert false
 244
 245 let mk_rewrite st dtext what qs tl direction =
 246    assert (List.length tl = 5);
 247    let predicate = List.nth tl 2 in
 248    let e = Cn.mk_pattern 1 predicate in
 249    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 250
 251 let rec proc_lambda st name v t =
 252    let dno = DTI.does_not_occur 1 (cic t) in
 253    let dno = dno && match get_inner_types st v with
 254       | None          -> true
 255       | Some (it, et) ->
 256          DTI.does_not_occur 1 (cic it) && DTI.does_not_occur 1 (cic et)
 257    in
 258    let name = if dno then C.Anonymous else name in
 259    let entry = Some (name, C.Decl (cic v)) in
 260    let intro = get_intro name in
 261    proc_proof (add st entry intro) t
 262
 263 and proc_letin st what name v t =
 264    let intro = get_intro name in
 265    let proceed, dtext = test_depth st in
 266    let script = if proceed then
 267       let st, hyp, rqv = match get_inner_types st v with
 268          | Some (ity, _) ->
 269             let st, rqv = match v with
 270                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 271                   mk_fwd_rewrite st dtext intro tl true
 272                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 273                   mk_fwd_rewrite st dtext intro tl false
 274                | v                                                     ->
 275                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 276                   st, [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 277             in
 278             st, C.Decl (cic ity), rqv
 279          | None          ->
 280             st, C.Def (cic v, None), [T.LetIn (intro, v, dtext)]
 281       in
 282       let entry = Some (name, hyp) in
 283       let qt = proc_proof (next (add st entry intro)) t in
 284       List.rev_append rqv qt
 285    else
 286       [T.Apply (what, dtext)]
 287    in
 288    mk_intros st script
 289
 290 and proc_rel st what =
 291    let _, dtext = test_depth st in
 292    let text = "assumption" in
 293    let script = [T.Apply (what, dtext ^ text)] in
 294    mk_intros st script
 295
 296 and proc_mutconstruct st what =
 297    let _, dtext = test_depth st in
 298    let script = [T.Apply (what, dtext)] in
 299    mk_intros st script
 300
 301 and proc_appl st what hd tl =
 302    let proceed, dtext = test_depth st in
 303    let script = if proceed then
 304       let ty = get_type "TC2" st hd in
 305       let classes, rc = Cl.classify st.context ty in
 306       let goal_arity = match get_inner_types st what with
 307          | None          -> 0
 308          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, cic ity))
 309       in
 310       let parsno, argsno = List.length classes, List.length tl in
 311       let decurry = parsno - argsno in
 312       let diff = goal_arity - decurry in
 313       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (cic hd)));
 314       let rec mk_synth a n =
 315          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 316       in
 317       let synth = mk_synth I.S.empty decurry in
 318       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 319       let script = List.rev (mk_arg st hd) @ convert st what in
 320       match rc with
 321          | Some (i, j, uri, tyno) ->
 322             let classes, tl, _, where = split2_last classes tl in
 323             let script = List.rev (mk_arg st where) @ script in
 324             let synth = I.S.add 1 synth in
 325             let names = get_ind_names uri tyno in
 326             let qs = proc_bkd_proofs (next st) synth names classes tl in
 327             if is_rewrite_right hd then
 328                script @ mk_rewrite st dtext where qs tl false
 329             else if is_rewrite_left hd then
 330                script @ mk_rewrite st dtext where qs tl true
 331             else
 332                let predicate = List.nth tl (parsno - i) in
 333                let e = Cn.mk_pattern j predicate in
 334                let using = Some hd in
 335                script @
 336                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 337          | None        ->
 338             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 339             let hd = mk_exp_args hd tl classes synth in
 340             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 341    else
 342       [T.Apply (what, dtext)]
 343    in
 344    mk_intros st script
 345
 346 and proc_other st what =
 347    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 348    let script = [T.Note text] in
 349    mk_intros st script
 350
 351 and proc_proof st t =
 352    let f st =
 353       let xet = match get_inner_types st t with
 354          | Some (_, et) -> Some (cic et)
 355          | None         -> None
 356       in
 357       let context, clears = Cn.get_clears st.context (cic t) xet in
 358       let note = Pp.ppcontext st.context in
 359       {st with context = context; clears = clears; clears_note = note}
 360    in
 361    match t with
 362       | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 363       | C.ALetIn (_, name, v, t) as what -> proc_letin (f st) what name v t
 364       | C.ARel _ as what                 -> proc_rel (f st) what
 365       | C.AMutConstruct _ as what        -> proc_mutconstruct (f st) what
 366       | C.AAppl (_, hd :: tl) as what    -> proc_appl (f st) what hd tl
 367       | what                             -> proc_other (f st) what
 368
 369 and proc_bkd_proofs st synth names classes ts =
 370 try
 371    let get_note =
 372       let names = ref (names, push st) in
 373       fun f ->
 374          match !names with
 375             | [], st       -> fun _ -> f st
 376             | "" :: tl, st -> names := tl, st; fun _ -> f st
 377             | hd :: tl, st ->
 378                let note = case st hd in
 379                names := tl, inc st;
 380                fun b -> if b then T.Note note :: f st else f st
 381    in
 382    let _, dtext = test_depth st in
 383    let aux (inv, _) v =
 384       if I.overlaps synth inv then None else
 385       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 386       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 387    in
 388    let ps = T.list_map2_filter aux classes ts in
 389    let b = List.length ps > 1 in
 390    List.rev_map (fun f -> f b) ps
 391
 392 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 393
 394 (* object costruction *******************************************************)
 395
 396 let is_theorem pars =
 397    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 398    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 399
 400 let proc_obj st = function
 401    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 402       let ast = proc_proof st v in
 403       let count = T.count_steps 0 ast in
 404       let text = Printf.sprintf "tactics: %u" count in
 405       T.Theorem (Some s, t, "") :: ast @ [T.Qed text]
 406    | _                                                               ->
 407       failwith "not a theorem"
 408
 409 (* interface functions ******************************************************)
 410
 411 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 412    let st = {
 413       sorts       = ids_to_inner_sorts;
 414       types       = ids_to_inner_types;
 415       prefix      = prefix;
 416       max_depth   = depth;
 417       depth       = 0;
 418       context     = [];
 419       intros      = [];
 420       clears      = [];
 421       clears_note = "";
 422       case        = []
 423    } in
 424    HLog.debug "Procedural: level 2 transformation";
 425    let steps = proc_obj st aobj in
 426    HLog.debug "Procedural: grafite rendering";
 427    List.rev (T.render_steps [] steps)