components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module D    = Deannotate
  29 module DTI  = DoubleTypeInference
  30 module TC   = CicTypeChecker
  31 module Un   = CicUniv
  32 module UM   = UriManager
  33 module Obj  = LibraryObjects
  34 module HObj = HelmLibraryObjects
  35 module A    = Cic2acic
  36 module Ut   = CicUtil
  37 module E    = CicEnvironment
  38 module PER  = ProofEngineReduction
  39
  40 module P    = ProceduralPreprocess
  41 module Cl   = ProceduralClassify
  42 module M    = ProceduralMode
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45
  46 type status = {
  47    sorts : (C.id, A.sort_kind) Hashtbl.t;
  48    types : (C.id, A.anntypes) Hashtbl.t;
  49    prefix: string;
  50    max_depth: int option;
  51    depth: int;
  52    context: C.context;
  53    intros: string list
  54 }
  55
  56 (* helpers ******************************************************************)
  57
  58 let identity x = x
  59
  60 let comp f g x = f (g x)
  61
  62 let cic = D.deannotate_term
  63
  64 let split2_last l1 l2 =
  65 try
  66    let n = pred (List.length l1) in
  67    let before1, after1 = T.list_split n l1 in
  68    let before2, after2 = T.list_split n l2 in
  69    before1, before2, List.hd after1, List.hd after2
  70 with Invalid_argument _ -> failwith "A2P.split2_last"
  71
  72 let string_of_head = function
  73    | C.ASort _         -> "sort"
  74    | C.AConst _        -> "const"
  75    | C.AMutInd _       -> "mutind"
  76    | C.AMutConstruct _ -> "mutconstruct"
  77    | C.AVar _          -> "var"
  78    | C.ARel _          -> "rel"
  79    | C.AProd _         -> "prod"
  80    | C.ALambda _       -> "lambda"
  81    | C.ALetIn _        -> "letin"
  82    | C.AFix _          -> "fix"
  83    | C.ACoFix _        -> "cofix"
  84    | C.AAppl _         -> "appl"
  85    | C.ACast _         -> "cast"
  86    | C.AMutCase _      -> "mutcase"
  87    | C.AMeta _         -> "meta"
  88    | C.AImplicit _     -> "implict"
  89
  90 let clear st = {st with intros = []}
  91
  92 let next st = {(clear st) with depth = succ st.depth}
  93
  94 let add st entry intro =
  95    {st with context = entry :: st.context; intros = intro :: st.intros}
  96
  97 let test_depth st =
  98 try
  99    let msg = Printf.sprintf "Depth %u: " st.depth in
 100    match st.max_depth with
 101       | None   -> true, ""
 102       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 103 with Invalid_argument _ -> failwith "A2P.test_depth"
 104
 105 let is_rewrite_right = function
 106    | C.AConst (_, uri, []) ->
 107       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 108    | _                     -> false
 109
 110 let is_rewrite_left = function
 111    | C.AConst (_, uri, []) ->
 112       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 113    | _                     -> false
 114
 115 let is_fwd_rewrite_right hd tl =
 116    if is_rewrite_right hd then match List.nth tl 3 with
 117       | C.ARel _ -> true
 118       | _        -> false
 119    else false
 120
 121 let is_fwd_rewrite_left hd tl =
 122    if is_rewrite_left hd then match List.nth tl 3 with
 123       | C.ARel _ -> true
 124       | _        -> false
 125    else false
 126 (*
 127 let get_ind_name uri tno xcno =
 128 try
 129    let ts = match E.get_obj Un.empty_ugraph uri with
 130       | C.InductiveDefinition (ts, _, _,_), _ -> ts
 131       | _                                     -> assert false
 132    in
 133    let tname, cs = match List.nth ts tno with
 134       | (name, _, _, cs) -> name, cs
 135    in
 136    match xcno with
 137       | None     -> tname
 138       | Some cno -> fst (List.nth cs (pred cno))
 139 with Invalid_argument _ -> failwith "A2P.get_ind_name"
 140 *)
 141 let get_inner_types st v =
 142 try
 143    let id = Ut.id_of_annterm v in
 144    try match Hashtbl.find st.types id with
 145       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 146       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 147    with Not_found -> None
 148 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 149
 150 let get_inner_sort st v =
 151 try
 152    let id = Ut.id_of_annterm v in
 153    try Hashtbl.find st.sorts id
 154    with Not_found -> `Type (CicUniv.fresh())
 155 with Invalid_argument _ -> failwith "A2P.get_sort"
 156
 157 (* proof construction *******************************************************)
 158
 159 let unused_premise = "UNUSED"
 160
 161 let defined_premise = "DEFINED"
 162
 163 let expanded_premise = "EXPANDED"
 164
 165 let convert st ?name v =
 166    match get_inner_types st v with
 167       | None          -> []
 168       | Some (st, et) ->
 169          let cst, cet = cic st, cic et in
 170          if PER.alpha_equivalence cst cet then [] else
 171          let e = Cn.mk_pattern [] (T.mk_arel 1 "") in
 172          match name with
 173             | None    -> [T.Change (st, et, None, e, "")]
 174             | Some id -> [T.Change (st, et, Some (id, id), e, ""); T.ClearBody (id, "")]
 175
 176 let eta_expand n t =
 177    let id = Ut.id_of_annterm t in
 178    let ty = C.AImplicit ("", None) in
 179    let name i = Printf.sprintf "%s%u" expanded_premise i in
 180    let lambda i t = C.ALambda (id, C.Name (name i), ty, t) in
 181    let arg i n = T.mk_arel (n - i) (name (n - i - 1)) in
 182    let rec aux i f a =
 183       if i >= n then f, a else aux (succ i) (comp f (lambda i)) (arg i n :: a)
 184    in
 185    let absts, args = aux 0 identity [] in
 186    match Cn.lift 1 n t with
 187       | C.AAppl (id, ts) -> absts (C.AAppl (id, ts @ args))
 188       | t                -> absts (C.AAppl ("", t :: args))
 189
 190 let appl_expand n = function
 191    | C.AAppl (id, ts) ->
 192       let before, after = T.list_split (List.length ts + n) ts in
 193       C.AAppl (id, C.AAppl ("", before) :: after)
 194    | _                -> assert false
 195
 196 let get_intro name t =
 197 try
 198 match name with
 199    | C.Anonymous -> unused_premise
 200    | C.Name s    ->
 201       if DTI.does_not_occur 1 (cic t) then unused_premise else s
 202 with Invalid_argument _ -> failwith "A2P.get_intro"
 203
 204 let mk_intros st script =
 205 try
 206    if st.intros = [] then script else
 207    let count = List.length st.intros in
 208    T.Intros (Some count, List.rev st.intros, "") :: script
 209 with Invalid_argument _ -> failwith "A2P.mk_intros"
 210
 211 let rec mk_atomic st dtext what =
 212    if T.is_atomic what then
 213       match what with
 214       | C.ARel (_, _, _, name) -> convert st ~name what, what
 215       | _                      -> [], what
 216    else
 217       let name = defined_premise in
 218       let script = convert st ~name what in
 219       script @ mk_fwd_proof st dtext name what, T.mk_arel 0 name
 220
 221 and mk_fwd_rewrite st dtext name tl direction =
 222    assert (List.length tl = 6);
 223    let what, where = List.nth tl 5, List.nth tl 3 in
 224    let rps, predicate = [List.nth tl 4], List.nth tl 2 in
 225    let e = Cn.mk_pattern rps predicate in
 226    match where with
 227       | C.ARel (_, _, _, premise) ->
 228          let script, what = mk_atomic st dtext what in
 229          T.Rewrite (direction, what, Some (premise, name), e, dtext) :: script
 230       | _                         -> assert false
 231
 232 and mk_rewrite st dtext script t what qs tl direction =
 233    assert (List.length tl = 5);
 234    let rps, predicate = [List.nth tl 4], List.nth tl 2 in
 235    let e = Cn.mk_pattern rps predicate in
 236    List.rev script @ convert st t @
 237    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 238
 239 and mk_fwd_proof st dtext name = function
 240    | C.ALetIn (_, n, v, t)                           ->
 241       let entry = Some (n, C.Def (cic v, None)) in
 242       let intro = get_intro n t in
 243       let qt = mk_fwd_proof (add st entry intro) dtext name t in
 244       let qv = mk_fwd_proof st "" intro v in
 245       List.append qt qv
 246    | C.AAppl (_, hd :: tl) as v                         ->
 247       if is_fwd_rewrite_right hd tl then mk_fwd_rewrite st dtext name tl true else
 248       if is_fwd_rewrite_left hd tl then mk_fwd_rewrite st dtext name tl false else
 249       let ty, _ = TC.type_of_aux' [] st.context (cic hd) Un.empty_ugraph in
 250       begin match get_inner_types st v with
 251          | Some (ity, _) when M.bkd st.context ty ->
 252             let qs = [[T.Id ""]; mk_proof (next st) v] in
 253             [T.Branch (qs, ""); T.Cut (name, ity, dtext)]
 254          | _                                      ->
 255             let (classes, rc) as h = Cl.classify st.context ty in
 256             let text = Printf.sprintf "%u %s" (List.length classes) (Cl.to_string h) in
 257             [T.LetIn (name, v, dtext ^ text)]
 258       end
 259 (*   | C.AMutCase (id, uri, tyno, outty, arg, cases) as v ->
 260       begin match Cn.mk_ind st.context id uri tyno outty arg cases with
 261          | None   -> [T.LetIn (name, v, dtext)]
 262          | Some v -> mk_fwd_proof st dtext name v
 263       end
 264 *)   | C.ACast (_, v, _)                                  ->
 265       mk_fwd_proof st dtext name v
 266    | v                                                  ->
 267       match get_inner_types st v with
 268          | Some (ity, _) ->
 269             let qs = [[T.Id ""]; mk_proof (next st) v] in
 270             [T.Branch (qs, ""); T.Cut (name, ity, dtext)]
 271          | _             ->
 272             [T.LetIn (name, v, dtext)]
 273
 274 and mk_proof st = function
 275    | C.ALambda (_, name, v, t)                     ->
 276       let entry = Some (name, C.Decl (cic v)) in
 277       let intro = get_intro name t in
 278       mk_proof (add st entry intro) t
 279    | C.ALetIn (_, name, v, t) as what              ->
 280       let proceed, dtext = test_depth st in
 281       let script = if proceed then
 282          let entry = Some (name, C.Def (cic v, None)) in
 283          let intro = get_intro name t in
 284          let q = mk_proof (next (add st entry intro)) t in
 285          List.rev_append (mk_fwd_proof st dtext intro v) q
 286       else
 287          [T.Apply (what, dtext)]
 288       in
 289       mk_intros st script
 290    | C.ARel _ as what                              ->
 291       let _, dtext = test_depth st in
 292       let text = "assumption" in
 293       let script = [T.Apply (what, dtext ^ text)] in
 294       mk_intros st script
 295    | C.AMutConstruct _ as what                     ->
 296       let _, dtext = test_depth st in
 297       let script = [T.Apply (what, dtext)] in
 298       mk_intros st script
 299    | C.AAppl (_, hd :: tl) as t                    ->
 300       let proceed, dtext = test_depth st in
 301       let script = if proceed then
 302          let ty, _ = TC.type_of_aux' [] st.context (cic hd) Un.empty_ugraph in
 303          let (classes, rc) as h = Cl.classify st.context ty in
 304          let premises, _ = P.split st.context ty in
 305          let decurry = List.length classes - List.length tl in
 306          if decurry < 0 then mk_proof (clear st) (appl_expand decurry t) else
 307          if decurry > 0 then mk_proof (clear st) (eta_expand decurry t) else
 308          let synth = I.S.singleton 0 in
 309          let text = Printf.sprintf "%u %s" (List.length classes) (Cl.to_string h) in
 310          match rc with
 311             | Some (i, j) when i > 1 && i <= List.length classes && M.is_eliminator premises ->
 312                let classes, tl, _, what = split2_last classes tl in
 313                let script, what = mk_atomic st dtext what in
 314                let synth = I.S.add 1 synth in
 315                let qs = mk_bkd_proofs (next st) synth classes tl in
 316                if is_rewrite_right hd then
 317                   mk_rewrite st dtext script t what qs tl false
 318                else if is_rewrite_left hd then
 319                   mk_rewrite st dtext script t what qs tl true
 320                else
 321                   let using = Some hd in
 322                   List.rev script @ convert st t @
 323                   [T.Elim (what, using, dtext ^ text); T.Branch (qs, "")]
 324             | _                                                  ->
 325                let qs = mk_bkd_proofs (next st) synth classes tl in
 326                let script, hd = mk_atomic st dtext hd in
 327                List.rev script @ convert st t @
 328                [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 329       else
 330          [T.Apply (t, dtext)]
 331       in
 332       mk_intros st script
 333    | C.AMutCase (id, uri, tyno, outty, arg, cases) ->
 334       begin match Cn.mk_ind st.context id uri tyno outty arg cases with
 335          | _ (* None *)  ->
 336             let text = Printf.sprintf "%s" "UNEXPANDED: mutcase" in
 337             let script = [T.Note text] in
 338             mk_intros st script
 339 (*         | Some t -> mk_proof st t *)
 340       end
 341    | C.ACast (_, t, _)                             ->
 342       mk_proof st t
 343    | t                                             ->
 344       let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head t) in
 345       let script = [T.Note text] in
 346       mk_intros st script
 347
 348 and mk_bkd_proofs st synth classes ts =
 349 try
 350    let _, dtext = test_depth st in
 351    let aux inv v =
 352       if I.overlaps synth inv then None else
 353       if I.S.is_empty inv then Some (mk_proof st v) else
 354       Some [T.Apply (v, dtext ^ "dependent")]
 355    in
 356    T.list_map2_filter aux classes ts
 357 with Invalid_argument _ -> failwith "A2P.mk_bkd_proofs"
 358
 359 (* object costruction *******************************************************)
 360
 361 let is_theorem pars =
 362    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 363    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 364
 365 let mk_obj st = function
 366    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 367       let ast = mk_proof st v in
 368       let count = T.count_steps 0 ast in
 369       let text = Printf.sprintf "tactics: %u" count in
 370       T.Theorem (s, t, text) :: ast @ [T.Qed ""]
 371    | _                                                               ->
 372       failwith "not a theorem"
 373
 374 (* interface functions ******************************************************)
 375
 376 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 377    let st = {
 378       sorts     = ids_to_inner_sorts;
 379       types     = ids_to_inner_types;
 380       prefix    = prefix;
 381       max_depth = depth;
 382       depth     = 0;
 383       context   = [];
 384       intros    = []
 385    } in
 386    HLog.debug "Level 2 transformation";
 387    let steps = mk_obj st aobj in
 388    HLog.debug "grafite rendering";
 389    List.rev (T.render_steps [] steps)