components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module D    = Deannotate
  29 module TC   = CicTypeChecker
  30 module Un   = CicUniv
  31 module UM   = UriManager
  32 module Obj  = LibraryObjects
  33 module HObj = HelmLibraryObjects
  34 module A    = Cic2acic
  35 module Ut   = CicUtil
  36 module E    = CicEnvironment
  37 module PEH  = ProofEngineHelpers
  38 module Pp   = CicPp
  39
  40 module Cl   = ProceduralClassify
  41 module T    = ProceduralTypes
  42 module Cn   = ProceduralConversion
  43
  44 type status = {
  45    sorts : (C.id, A.sort_kind) Hashtbl.t;
  46    types : (C.id, A.anntypes) Hashtbl.t;
  47    prefix: string;
  48    max_depth: int option;
  49    depth: int;
  50    context: C.context;
  51    intros: string list
  52 }
  53
  54 (* helpers ******************************************************************)
  55
  56 let cic = D.deannotate_term
  57
  58 let split2_last l1 l2 =
  59 try
  60    let n = pred (List.length l1) in
  61    let before1, after1 = T.list_split n l1 in
  62    let before2, after2 = T.list_split n l2 in
  63    before1, before2, List.hd after1, List.hd after2
  64 with Invalid_argument _ -> failwith "A2P.split2_last"
  65
  66 let string_of_head = function
  67    | C.ASort _         -> "sort"
  68    | C.AConst _        -> "const"
  69    | C.AMutInd _       -> "mutind"
  70    | C.AMutConstruct _ -> "mutconstruct"
  71    | C.AVar _          -> "var"
  72    | C.ARel _          -> "rel"
  73    | C.AProd _         -> "prod"
  74    | C.ALambda _       -> "lambda"
  75    | C.ALetIn _        -> "letin"
  76    | C.AFix _          -> "fix"
  77    | C.ACoFix _        -> "cofix"
  78    | C.AAppl _         -> "appl"
  79    | C.ACast _         -> "cast"
  80    | C.AMutCase _      -> "mutcase"
  81    | C.AMeta _         -> "meta"
  82    | C.AImplicit _     -> "implict"
  83
  84 let clear st = {st with intros = []}
  85
  86 let next st = {(clear st) with depth = succ st.depth}
  87
  88 let add st entry intro =
  89    {st with context = entry :: st.context; intros = intro :: st.intros}
  90
  91 let test_depth st =
  92 try
  93    let msg = Printf.sprintf "Depth %u: " st.depth in
  94    match st.max_depth with
  95       | None   -> true, ""
  96       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
  97 with Invalid_argument _ -> failwith "A2P.test_depth"
  98
  99 let is_rewrite_right = function
 100    | C.AConst (_, uri, []) ->
 101       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 102    | _                     -> false
 103
 104 let is_rewrite_left = function
 105    | C.AConst (_, uri, []) ->
 106       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 107    | _                     -> false
 108
 109 let is_fwd_rewrite_right hd tl =
 110    if is_rewrite_right hd then match List.nth tl 3 with
 111       | C.ARel _ -> true
 112       | _        -> false
 113    else false
 114
 115 let is_fwd_rewrite_left hd tl =
 116    if is_rewrite_left hd then match List.nth tl 3 with
 117       | C.ARel _ -> true
 118       | _        -> false
 119    else false
 120 (*
 121 let get_ind_name uri tno xcno =
 122 try
 123    let ts = match E.get_obj Un.empty_ugraph uri with
 124       | C.InductiveDefinition (ts, _, _,_), _ -> ts
 125       | _                                     -> assert false
 126    in
 127    let tname, cs = match List.nth ts tno with
 128       | (name, _, _, cs) -> name, cs
 129    in
 130    match xcno with
 131       | None     -> tname
 132       | Some cno -> fst (List.nth cs (pred cno))
 133 with Invalid_argument _ -> failwith "A2P.get_ind_name"
 134 *)
 135 let get_inner_types st v =
 136 try
 137    let id = Ut.id_of_annterm v in
 138    try match Hashtbl.find st.types id with
 139       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 140       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 141    with Not_found -> None
 142 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 143 (*
 144 let get_inner_sort st v =
 145 try
 146    let id = Ut.id_of_annterm v in
 147    try Hashtbl.find st.sorts id
 148    with Not_found -> `Type (CicUniv.fresh())
 149 with Invalid_argument _ -> failwith "A2P.get_sort"
 150 *)
 151 let get_type msg st bo =
 152 try
 153    let ty, _ = TC.type_of_aux' [] st.context (cic bo) Un.empty_ugraph in
 154    ty
 155 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 156
 157 let get_entry st id =
 158    let rec aux = function
 159       | []                                        -> assert false
 160       | Some (C.Name name, e) :: _ when name = id -> e
 161       | _ :: tl                                   -> aux tl
 162    in
 163    aux st.context
 164
 165 (* proof construction *******************************************************)
 166
 167 let unused_premise = "UNUSED"
 168
 169 let mk_exp_args hd tl classes =
 170    let meta id = C.AImplicit (id, None) in
 171    let map v (cl, b) =
 172       if I.S.mem 0 cl && b then v else meta ""
 173    in
 174    let rec aux = function
 175       | [] -> []
 176       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 177    in
 178    let args = List.rev_map2 map tl classes in
 179    let args = aux args in
 180    if args = [] then hd else C.AAppl ("", hd :: args)
 181
 182 let convert st ?name v =
 183    match get_inner_types st v with
 184       | None            -> []
 185       | Some (sty, ety) ->
 186          let csty, cety = cic sty, cic ety in
 187          if Ut.alpha_equivalence csty cety then [] else
 188          let e = Cn.mk_pattern 0 (T.mk_arel 1 "") in
 189          match name with
 190             | None    -> [T.Change (sty, ety, None, e, "")]
 191             | Some id ->
 192                begin match get_entry st id with
 193                   | C.Def _  -> [T.ClearBody (id, "")]
 194                   | C.Decl w ->
 195                      if Ut.alpha_equivalence csty w then []
 196                      else [T.Change (sty, ety, Some (id, id), e, "")]
 197                end
 198
 199 let get_intro = function
 200    | C.Anonymous -> unused_premise
 201    | C.Name s    -> s
 202
 203 let mk_intros st script =
 204    if st.intros = [] then script else
 205    let count = List.length st.intros in
 206    T.Intros (Some count, List.rev st.intros, "") :: script
 207
 208 let mk_arg st = function
 209    | C.ARel (_, _, _, name) as what -> convert st ~name what
 210    | _                              -> []
 211
 212 let mk_fwd_rewrite st dtext name tl direction =
 213    assert (List.length tl = 6);
 214    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 215    let e = Cn.mk_pattern 1 predicate in
 216    match where with
 217       | C.ARel (_, _, _, premise) ->
 218          let script = mk_arg st what in
 219          let where = Some (premise, name) in
 220          T.Rewrite (direction, what, where, e, dtext) :: script
 221       | _                         -> assert false
 222
 223 let mk_rewrite st dtext what qs tl direction =
 224    assert (List.length tl = 5);
 225    let predicate = List.nth tl 2 in
 226    let e = Cn.mk_pattern 1 predicate in
 227    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 228
 229 let rec proc_lambda st name v t =
 230    let entry = Some (name, C.Decl (cic v)) in
 231    let intro = get_intro name in
 232    proc_proof (add st entry intro) t
 233
 234 and proc_letin st what name v t =
 235    let intro = get_intro name in
 236    let proceed, dtext = test_depth st in
 237    let script = if proceed then
 238       let hyp, rqv = match get_inner_types st v with
 239          | Some (ity, _) ->
 240             let rqv = match v with
 241                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 242                   mk_fwd_rewrite st dtext intro tl true
 243                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 244                   mk_fwd_rewrite st dtext intro tl false
 245                | v                                                     ->
 246                   let qs = [[T.Id ""]; proc_proof (next st) v] in
 247                   [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 248             in
 249             C.Decl (cic ity), rqv
 250          | None          ->
 251             C.Def (cic v, None), [T.LetIn (intro, v, dtext)]
 252       in
 253       let entry = Some (name, hyp) in
 254       let qt = proc_proof (next (add st entry intro)) t in
 255       List.rev_append rqv qt
 256    else
 257       [T.Apply (what, dtext)]
 258    in
 259    mk_intros st script
 260
 261 and proc_rel st what =
 262    let _, dtext = test_depth st in
 263    let text = "assumption" in
 264    let script = [T.Apply (what, dtext ^ text)] in
 265    mk_intros st script
 266
 267 and proc_mutconstruct st what =
 268    let _, dtext = test_depth st in
 269    let script = [T.Apply (what, dtext)] in
 270    mk_intros st script
 271
 272 and proc_appl st what hd tl =
 273    let proceed, dtext = test_depth st in
 274    let script = if proceed then
 275       let ty = get_type "TC2" st hd in
 276       let (classes, rc) as h = Cl.classify st.context ty in
 277       let argsno = List.length classes in
 278       let diff = argsno - List.length tl in
 279       if diff <> 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (cic hd)));
 280       let synth = I.S.singleton 0 in
 281       let text = Printf.sprintf "%u %s" argsno (Cl.to_string h) in
 282       let script = List.rev (mk_arg st hd) @ convert st what in
 283       match rc with
 284          | Some (i, j) ->
 285             let classes, tl, _, where = split2_last classes tl in
 286             let script = List.rev (mk_arg st where) @ script in
 287             let synth = I.S.add 1 synth in
 288             let qs = proc_bkd_proofs (next st) synth classes tl in
 289             if is_rewrite_right hd then
 290                script @ mk_rewrite st dtext where qs tl false
 291             else if is_rewrite_left hd then
 292                script @ mk_rewrite st dtext where qs tl true
 293             else
 294                let predicate = List.nth tl (argsno - i) in
 295                let e = Cn.mk_pattern 0 (T.mk_arel 1 "") (* j predicate *) in
 296                let using = Some hd in
 297                script @
 298                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 299          | None        ->
 300             let qs = proc_bkd_proofs (next st) synth classes tl in
 301             let hd = mk_exp_args hd tl classes in
 302             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 303    else
 304       [T.Apply (what, dtext)]
 305    in
 306    mk_intros st script
 307
 308 and proc_other st what =
 309    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 310    let script = [T.Note text] in
 311    mk_intros st script
 312
 313
 314 and proc_proof st = function
 315    | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 316    | C.ALetIn (_, name, v, t) as what -> proc_letin st what name v t
 317    | C.ARel _ as what                 -> proc_rel st what
 318    | C.AMutConstruct _ as what        -> proc_mutconstruct st what
 319    | C.AAppl (_, hd :: tl) as what    -> proc_appl st what hd tl
 320    | what                             -> proc_other st what
 321
 322 and proc_bkd_proofs st synth classes ts =
 323 try
 324    let _, dtext = test_depth st in
 325    let aux (inv, _) v =
 326       if I.overlaps synth inv then None else
 327       if I.S.is_empty inv then Some (proc_proof st v) else
 328       Some [T.Apply (v, dtext ^ "dependent")]
 329    in
 330    T.list_map2_filter aux classes ts
 331 with Invalid_argument _ -> failwith "A2P.proc_bkd_proofs"
 332
 333 (* object costruction *******************************************************)
 334
 335 let is_theorem pars =
 336    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 337    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 338
 339 let proc_obj st = function
 340    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 341       let ast = proc_proof st v in
 342       let count = T.count_steps 0 ast in
 343       let text = Printf.sprintf "tactics: %u" count in
 344       T.Theorem (s, t, text) :: ast @ [T.Qed ""]
 345    | _                                                               ->
 346       failwith "not a theorem"
 347
 348 (* interface functions ******************************************************)
 349
 350 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 351    let st = {
 352       sorts     = ids_to_inner_sorts;
 353       types     = ids_to_inner_types;
 354       prefix    = prefix;
 355       max_depth = depth;
 356       depth     = 0;
 357       context   = [];
 358       intros    = []
 359    } in
 360    HLog.debug "Procedural: level 2 transformation";
 361    let steps = proc_obj st aobj in
 362    HLog.debug "Procedural: grafite rendering";
 363    List.rev (T.render_steps [] steps)