components/acic_procedural/acic2Procedural.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module I    = CicInspect
  28 module D    = Deannotate
  29 module S    = CicSubstitution
  30 module TC   = CicTypeChecker
  31 module Un   = CicUniv
  32 module UM   = UriManager
  33 module Obj  = LibraryObjects
  34 module HObj = HelmLibraryObjects
  35 module A    = Cic2acic
  36 module Ut   = CicUtil
  37 module E    = CicEnvironment
  38 module Pp   = CicPp
  39 module PEH  = ProofEngineHelpers
  40 module HEL  = HExtlib
  41
  42 module Cl   = ProceduralClassify
  43 module T    = ProceduralTypes
  44 module Cn   = ProceduralConversion
  45
  46 type status = {
  47    sorts : (C.id, A.sort_kind) Hashtbl.t;
  48    types : (C.id, A.anntypes) Hashtbl.t;
  49    prefix: string;
  50    max_depth: int option;
  51    depth: int;
  52    context: C.context;
  53    intros: string list;
  54    case: int list
  55 }
  56
  57 (* helpers ******************************************************************)
  58
  59 let cic = D.deannotate_term
  60
  61 let split2_last l1 l2 =
  62 try
  63    let n = pred (List.length l1) in
  64    let before1, after1 = HEL.split_nth n l1 in
  65    let before2, after2 = HEL.split_nth n l2 in
  66    before1, before2, List.hd after1, List.hd after2
  67 with Invalid_argument _ -> failwith "A2P.split2_last"
  68
  69 let string_of_head = function
  70    | C.ASort _         -> "sort"
  71    | C.AConst _        -> "const"
  72    | C.AMutInd _       -> "mutind"
  73    | C.AMutConstruct _ -> "mutconstruct"
  74    | C.AVar _          -> "var"
  75    | C.ARel _          -> "rel"
  76    | C.AProd _         -> "prod"
  77    | C.ALambda _       -> "lambda"
  78    | C.ALetIn _        -> "letin"
  79    | C.AFix _          -> "fix"
  80    | C.ACoFix _        -> "cofix"
  81    | C.AAppl _         -> "appl"
  82    | C.ACast _         -> "cast"
  83    | C.AMutCase _      -> "mutcase"
  84    | C.AMeta _         -> "meta"
  85    | C.AImplicit _     -> "implict"
  86
  87 let clear st = {st with intros = []}
  88
  89 let next st = {(clear st) with depth = succ st.depth}
  90
  91 let add st entry intro =
  92    {st with context = entry :: st.context; intros = intro :: st.intros}
  93
  94 let push st = {st with case = 1 :: st.case}
  95
  96 let inc st =
  97    {st with case = match st.case with
  98       | []       -> assert false
  99       | hd :: tl -> succ hd :: tl
 100    }
 101
 102 let case st str =
 103    let case = String.concat "." (List.rev_map string_of_int st.case) in
 104    Printf.sprintf "case %s: %s" case str
 105
 106 let test_depth st =
 107 try
 108    let msg = Printf.sprintf "Depth %u: " st.depth in
 109    match st.max_depth with
 110       | None   -> true, ""
 111       | Some d -> if st.depth < d then true, msg else false, "DEPTH EXCEDED: "
 112 with Invalid_argument _ -> failwith "A2P.test_depth"
 113
 114 let is_rewrite_right = function
 115    | C.AConst (_, uri, []) ->
 116       UM.eq uri HObj.Logic.eq_ind_r_URI || Obj.is_eq_ind_r_URI uri
 117    | _                     -> false
 118
 119 let is_rewrite_left = function
 120    | C.AConst (_, uri, []) ->
 121       UM.eq uri HObj.Logic.eq_ind_URI || Obj.is_eq_ind_URI uri
 122    | _                     -> false
 123
 124 let is_fwd_rewrite_right hd tl =
 125    if is_rewrite_right hd then match List.nth tl 3 with
 126       | C.ARel _ -> true
 127       | _        -> false
 128    else false
 129
 130 let is_fwd_rewrite_left hd tl =
 131    if is_rewrite_left hd then match List.nth tl 3 with
 132       | C.ARel _ -> true
 133       | _        -> false
 134    else false
 135
 136 let get_inner_types st v =
 137 try
 138    let id = Ut.id_of_annterm v in
 139    try match Hashtbl.find st.types id with
 140       | {A.annsynthesized = st; A.annexpected = Some et} -> Some (st, et)
 141       | {A.annsynthesized = st; A.annexpected = None}    -> Some (st, st)
 142    with Not_found -> None
 143 with Invalid_argument _ -> failwith "A2P.get_inner_types"
 144 (*
 145 let get_inner_sort st v =
 146 try
 147    let id = Ut.id_of_annterm v in
 148    try Hashtbl.find st.sorts id
 149    with Not_found -> `Type (CicUniv.fresh())
 150 with Invalid_argument _ -> failwith "A2P.get_sort"
 151 *)
 152 let get_type msg st bo =
 153 try
 154    let ty, _ = TC.type_of_aux' [] st.context (cic bo) Un.empty_ugraph in
 155    ty
 156 with e -> failwith (msg ^ ": " ^ Printexc.to_string e)
 157
 158 let get_entry st id =
 159    let rec aux = function
 160       | []                                        -> assert false
 161       | Some (C.Name name, e) :: _ when name = id -> e
 162       | _ :: tl                                   -> aux tl
 163    in
 164    aux st.context
 165
 166 let get_ind_names uri tno =
 167 try
 168    let ts = match E.get_obj Un.empty_ugraph uri with
 169       | C.InductiveDefinition (ts, _, _, _), _ -> ts
 170       | _                                      -> assert false
 171    in
 172    match List.nth ts tno with
 173       | (_, _, _, cs) -> List.map fst cs
 174 with Invalid_argument _ -> failwith "A2P.get_ind_names"
 175
 176 (* proof construction *******************************************************)
 177
 178 let unused_premise = "UNUSED"
 179
 180 let mk_exp_args hd tl classes synth =
 181    let meta id = C.AImplicit (id, None) in
 182    let map v (cl, b) =
 183       if I.overlaps synth cl && b then v else meta ""
 184    in
 185    let rec aux = function
 186       | [] -> []
 187       | hd :: tl -> if hd = meta "" then aux tl else List.rev (hd :: tl)
 188    in
 189    let args = T.list_rev_map2 map tl classes in
 190    let args = aux args in
 191    if args = [] then hd else C.AAppl ("", hd :: args)
 192
 193 let convert st ?name v =
 194    match get_inner_types st v with
 195       | None            -> []
 196       | Some (sty, ety) ->
 197          let e = Cn.hole "" in
 198          let csty, cety = cic sty, cic ety in
 199          if Ut.alpha_equivalence csty cety then [] else
 200          match name with
 201             | None         -> [T.Change (sty, ety, None, e, "")]
 202             | Some (id, i) ->
 203                begin match get_entry st id with
 204                   | C.Def _  -> [T.ClearBody (id, "")]
 205                   | C.Decl w ->
 206                      let w = S.lift i w in
 207                      if Ut.alpha_equivalence csty w then []
 208                      else
 209                      [T.Note (Pp.ppterm csty); T.Note (Pp.ppterm w);
 210                      T.Change (sty, ety, Some (id, id), e, "")]
 211                end
 212
 213 let get_intro = function
 214    | C.Anonymous -> unused_premise
 215    | C.Name s    -> s
 216
 217 let mk_intros st script =
 218    if st.intros = [] then script else
 219    let count = List.length st.intros in
 220    T.Intros (Some count, List.rev st.intros, "") :: script
 221
 222 let mk_arg st = function
 223    | C.ARel (_, _, i, name) as what -> convert st ~name:(name, i) what
 224    | _                              -> []
 225
 226 let mk_fwd_rewrite st dtext name tl direction =
 227    assert (List.length tl = 6);
 228    let what, where, predicate = List.nth tl 5, List.nth tl 3, List.nth tl 2 in
 229    let e = Cn.mk_pattern 1 predicate in
 230    match where with
 231       | C.ARel (_, _, _, premise) ->
 232          let script = mk_arg st what in
 233          let where = Some (premise, name) in
 234          T.Rewrite (direction, what, where, e, dtext) :: script
 235       | _                         -> assert false
 236
 237 let mk_rewrite st dtext what qs tl direction =
 238    assert (List.length tl = 5);
 239    let predicate = List.nth tl 2 in
 240    let e = Cn.mk_pattern 1 predicate in
 241    [T.Rewrite (direction, what, None, e, dtext); T.Branch (qs, "")]
 242
 243 let rec proc_lambda st name v t =
 244    let entry = Some (name, C.Decl (cic v)) in
 245    let intro = get_intro name in
 246    proc_proof (add st entry intro) t
 247
 248 and proc_letin st what name v t =
 249    let intro = get_intro name in
 250    let proceed, dtext = test_depth st in
 251    let script = if proceed then
 252       let hyp, rqv = match get_inner_types st v with
 253          | Some (ity, _) ->
 254             let rqv = match v with
 255                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_right hd tl ->
 256                   mk_fwd_rewrite st dtext intro tl true
 257                | C.AAppl (_, hd :: tl) when is_fwd_rewrite_left hd tl  ->
 258                   mk_fwd_rewrite st dtext intro tl false
 259                | v                                                     ->
 260                   let qs = [proc_proof (next st) v; [T.Id ""]] in
 261                   [T.Branch (qs, ""); T.Cut (intro, ity, dtext)]
 262             in
 263             C.Decl (cic ity), rqv
 264          | None          ->
 265             C.Def (cic v, None), [T.LetIn (intro, v, dtext)]
 266       in
 267       let entry = Some (name, hyp) in
 268       let qt = proc_proof (next (add st entry intro)) t in
 269       List.rev_append rqv qt
 270    else
 271       [T.Apply (what, dtext)]
 272    in
 273    mk_intros st script
 274
 275 and proc_rel st what =
 276    let _, dtext = test_depth st in
 277    let text = "assumption" in
 278    let script = [T.Apply (what, dtext ^ text)] in
 279    mk_intros st script
 280
 281 and proc_mutconstruct st what =
 282    let _, dtext = test_depth st in
 283    let script = [T.Apply (what, dtext)] in
 284    mk_intros st script
 285
 286 and proc_appl st what hd tl =
 287    let proceed, dtext = test_depth st in
 288    let script = if proceed then
 289       let ty = get_type "TC2" st hd in
 290       let classes, rc = Cl.classify st.context ty in
 291       let goal_arity = match get_inner_types st what with
 292          | None          -> 0
 293          | Some (ity, _) -> snd (PEH.split_with_whd (st.context, cic ity))
 294       in
 295       let parsno, argsno = List.length classes, List.length tl in
 296       let decurry = parsno - argsno in
 297       let diff = goal_arity - decurry in
 298       if diff < 0 then failwith (Printf.sprintf "NOT TOTAL: %i %s |--- %s" diff (Pp.ppcontext st.context) (Pp.ppterm (cic hd)));
 299       let rec mk_synth a n =
 300          if n < 0 then a else mk_synth (I.S.add n a) (pred n)
 301       in
 302       let synth = mk_synth I.S.empty decurry in
 303       let text = "" (* Printf.sprintf "%u %s" parsno (Cl.to_string h) *) in
 304       let script = List.rev (mk_arg st hd) @ convert st what in
 305       match rc with
 306          | Some (i, j, uri, tyno) ->
 307             let classes, tl, _, where = split2_last classes tl in
 308             let script = List.rev (mk_arg st where) @ script in
 309             let synth = I.S.add 1 synth in
 310             let names = get_ind_names uri tyno in
 311             let qs = proc_bkd_proofs (next st) synth names classes tl in
 312             if is_rewrite_right hd then
 313                script @ mk_rewrite st dtext where qs tl false
 314             else if is_rewrite_left hd then
 315                script @ mk_rewrite st dtext where qs tl true
 316             else
 317                let predicate = List.nth tl (parsno - i) in
 318                let e = Cn.mk_pattern j predicate in
 319                let using = Some hd in
 320                script @
 321                [T.Elim (where, using, e, dtext ^ text); T.Branch (qs, "")]
 322          | None        ->
 323             let qs = proc_bkd_proofs (next st) synth [] classes tl in
 324             let hd = mk_exp_args hd tl classes synth in
 325             script @ [T.Apply (hd, dtext ^ text); T.Branch (qs, "")]
 326    else
 327       [T.Apply (what, dtext)]
 328    in
 329    mk_intros st script
 330
 331 and proc_other st what =
 332    let text = Printf.sprintf "%s: %s" "UNEXPANDED" (string_of_head what) in
 333    let script = [T.Note text] in
 334    mk_intros st script
 335
 336 and proc_proof st = function
 337    | C.ALambda (_, name, w, t)        -> proc_lambda st name w t
 338    | C.ALetIn (_, name, v, t) as what -> proc_letin st what name v t
 339    | C.ARel _ as what                 -> proc_rel st what
 340    | C.AMutConstruct _ as what        -> proc_mutconstruct st what
 341    | C.AAppl (_, hd :: tl) as what    -> proc_appl st what hd tl
 342    | what                             -> proc_other st what
 343
 344 and proc_bkd_proofs st synth names classes ts =
 345 try
 346    let get_note =
 347       let names = ref (names, push st) in
 348       fun f ->
 349          match !names with
 350             | [], st       -> fun _ -> f st
 351             | "" :: tl, st -> names := tl, st; fun _ -> f st
 352             | hd :: tl, st ->
 353                let note = case st hd in
 354                names := tl, inc st;
 355                fun b -> if b then T.Note note :: f st else f st
 356    in
 357    let _, dtext = test_depth st in
 358    let aux (inv, _) v =
 359       if I.overlaps synth inv then None else
 360       if I.S.is_empty inv then Some (get_note (fun st -> proc_proof st v)) else
 361       Some (fun _ -> [T.Apply (v, dtext ^ "dependent")])
 362    in
 363    let ps = T.list_map2_filter aux classes ts in
 364    let b = List.length ps > 1 in
 365    List.rev_map (fun f -> f b) ps
 366
 367 with Invalid_argument s -> failwith ("A2P.proc_bkd_proofs: " ^ s)
 368
 369 (* object costruction *******************************************************)
 370
 371 let is_theorem pars =
 372    List.mem (`Flavour `Theorem) pars || List.mem (`Flavour `Fact) pars ||
 373    List.mem (`Flavour `Remark) pars || List.mem (`Flavour `Lemma) pars
 374
 375 let proc_obj st = function
 376    | C.AConstant (_, _, s, Some v, t, [], pars) when is_theorem pars ->
 377       let ast = proc_proof st v in
 378       let count = T.count_steps 0 ast in
 379       let text = Printf.sprintf "tactics: %u" count in
 380       T.Theorem (s, t, "") :: ast @ [T.Qed text]
 381    | _                                                               ->
 382       failwith "not a theorem"
 383
 384 (* interface functions ******************************************************)
 385
 386 let acic2procedural ~ids_to_inner_sorts ~ids_to_inner_types ?depth prefix aobj =
 387    let st = {
 388       sorts     = ids_to_inner_sorts;
 389       types     = ids_to_inner_types;
 390       prefix    = prefix;
 391       max_depth = depth;
 392       depth     = 0;
 393       context   = [];
 394       intros    = [];
 395       case      = []
 396    } in
 397    HLog.debug "Procedural: level 2 transformation";
 398    let steps = proc_obj st aobj in
 399    HLog.debug "Procedural: grafite rendering";
 400    List.rev (T.render_steps [] steps)