components/acic_procedural/proceduralClassify.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C = Cic
  27 module D = Deannotate
  28 module I = CicInspect
  29
  30 module P = ProceduralPreprocess
  31
  32 type conclusion = (int * int) option
  33
  34 (* debugging ****************************************************************)
  35
  36 let string_of_entry inverse =
  37    if I.S.mem 0 inverse then "C" else
  38    if I.S.is_empty inverse then "I" else "P"
  39
  40 let to_string (classes, rc) =
  41    let linearize = String.concat " " (List.map string_of_entry classes) in
  42    match rc with
  43       | None        -> linearize
  44       | Some (i, j) -> Printf.sprintf "%s %u %u" linearize i j
  45
  46 let out_table b =
  47    let map i (_, inverse) =
  48       let map i tl = Printf.sprintf "%2u" i :: tl in
  49       let iset = String.concat " " (I.S.fold map inverse []) in
  50       Printf.eprintf "%2u|%s\n" i iset
  51    in
  52    Array.iteri map b;
  53    prerr_newline ()
  54
  55 (****************************************************************************)
  56
  57 let id x = x
  58
  59 let classify_conclusion = function
  60    | C.Rel i                -> Some (i, 0)
  61    | C.Appl (C.Rel i :: tl) -> Some (i, List.length tl)
  62    | _                      -> None
  63
  64 let classify c t =
  65 try
  66    let vs, h = P.split c t in
  67    let rc = classify_conclusion (List.hd vs) in
  68    let map (b, h) v = (I.get_rels_from_premise h v, I.S.empty) :: b, succ h in
  69    let l, h = List.fold_left map ([], 0) vs in
  70    let b = Array.of_list (List.rev l) in
  71    let mk_closure b h =
  72       let map j = if j < h then I.S.union (fst b.(j)) else id in
  73       for i = pred h downto 0 do
  74          let direct, unused = b.(i) in
  75          b.(i) <- I.S.fold map direct direct, unused
  76       done; b
  77    in
  78    let b = mk_closure b h in
  79    let rec mk_inverse i direct =
  80       if I.S.is_empty direct then () else
  81       let j = I.S.choose direct in
  82       if j < h then
  83          let unused, inverse = b.(j) in
  84          b.(j) <- unused, I.S.add i inverse
  85        else ();
  86        mk_inverse i (I.S.remove j direct)
  87    in
  88    let map i (direct, _) = mk_inverse i direct in
  89    Array.iteri map b;
  90 (*   out_table b; *)
  91    List.rev_map snd (List.tl (Array.to_list b)), rc
  92 with Invalid_argument _ -> failwith "Classify.classify"