components/acic_procedural/proceduralConversion.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module E    = CicEnvironment
  28 module Un   = CicUniv
  29 module TC   = CicTypeChecker
  30 module D    = Deannotate
  31 module UM   = UriManager
  32
  33 module T    = ProceduralTypes
  34 module Cl   = ProceduralClassify
  35
  36 (* helpers ******************************************************************)
  37
  38 let cic = D.deannotate_term
  39
  40 let get_ind_type uri tyno =
  41    match E.get_obj Un.empty_ugraph uri with
  42       | C.InductiveDefinition (tys, _, lpsno, _), _ -> lpsno, List.nth tys tyno
  43       | _                                           -> assert false
  44
  45 let get_default_eliminator context uri tyno ty =
  46    let _, (name, _, _, _) = get_ind_type uri tyno in
  47    let sort, _ = TC.type_of_aux' [] context ty Un.empty_ugraph in
  48    let ext = match sort with
  49       | C.Sort C.Prop     -> "_ind"
  50       | C.Sort C.Set      -> "_rec"
  51       | C.Sort C.CProp    -> "_rec"
  52       | C.Sort (C.Type _) -> "_rect"
  53       | C.Meta (_,_)      -> assert false
  54       | _                 -> assert false
  55    in
  56    let buri = UM.buri_of_uri uri in
  57    let uri = UM.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con") in
  58    C.Const (uri, [])
  59
  60 let rec list_sub start length = function
  61    | _  :: tl when start  > 0 -> list_sub (pred start) length tl
  62    | hd :: tl when length > 0 -> hd :: list_sub start (pred length) tl
  63    | _                        -> []
  64
  65
  66 (* proof construction *******************************************************)
  67
  68 let rec need_whd i = function
  69    | C.ACast (_, t, _)               -> need_whd i t
  70    | C.AProd (_, _, _, t) when i > 0 -> need_whd (pred i) t
  71    | _                    when i > 0 -> true
  72    | _                               -> false
  73
  74 let lift k n =
  75    let rec lift_xns k (uri, t) = uri, lift_term k t
  76    and lift_ms k = function
  77       | None   -> None
  78       | Some t -> Some (lift_term k t)
  79    and lift_fix len k (id, name, i, ty, bo) =
  80       id, name, i, lift_term k ty, lift_term (k + len) bo
  81    and lift_cofix len k (id, name, ty, bo) =
  82       id, name, lift_term k ty, lift_term (k + len) bo
  83    and lift_term k = function
  84       | C.ASort _ as t -> t
  85       | C.AImplicit _ as t -> t
  86       | C.ARel (id, rid, m, b) as t -> if m < k then t else C.ARel (id, rid, m + n, b)
  87       | C.AConst (id, uri, xnss) -> C.AConst (id, uri, List.map (lift_xns k) xnss)
  88       | C.AVar (id, uri, xnss) -> C.AVar (id, uri, List.map (lift_xns k) xnss)
  89       | C.AMutInd (id, uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (lift_xns k) xnss)
  90       | C.AMutConstruct (id, uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (lift_xns k) xnss)
  91       | C.AMeta (id, i, mss) -> C.AMeta(id, i, List.map (lift_ms k) mss)
  92       | C.AAppl (id, ts) -> C.AAppl (id, List.map (lift_term k) ts)
  93       | C.ACast (id, te, ty) -> C.ACast (id, lift_term k te, lift_term k ty)
  94       | C.AMutCase (id, sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, lift_term k outty, lift_term k t, List.map (lift_term k) pl)
  95       | C.AProd (id, n, s, t) -> C.AProd (id, n, lift_term k s, lift_term (succ k) t)
  96       | C.ALambda (id, n, s, t) -> C.ALambda (id, n, lift_term k s, lift_term (succ k) t)
  97       | C.ALetIn (id, n, s, t) -> C.ALetIn (id, n, lift_term k s, lift_term (succ k) t)
  98       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (lift_fix (List.length fl) k) fl)
  99       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (lift_cofix (List.length fl) k) fl)
 100    in
 101    lift_term k
 102
 103 let fake_annotate c =
 104    let get_binder c m =
 105       try match List.nth c (pred m) with
 106          | Some (C.Name s, _) -> s
 107          | _                  -> assert false
 108       with
 109          | Invalid_argument _ -> assert false
 110    in
 111    let mk_decl n v = Some (n, C.Decl v) in
 112    let mk_def n v = Some (n, C.Def (v, None)) in
 113    let mk_fix (name, _, _, bo) = mk_def (C.Name name) bo in
 114    let mk_cofix (name, _, bo) = mk_def (C.Name name) bo in
 115    let rec ann_xns c (uri, t) = uri, ann_term c t
 116    and ann_ms c = function
 117       | None   -> None
 118       | Some t -> Some (ann_term c t)
 119    and ann_fix newc c (name, i, ty, bo) =
 120       "", name, i, ann_term c ty, ann_term (List.rev_append newc c) bo
 121    and ann_cofix newc c (name, ty, bo) =
 122       "", name, ann_term c ty, ann_term (List.rev_append newc c) bo
 123    and ann_term c = function
 124       | C.Sort sort -> C.ASort ("", sort)
 125       | C.Implicit ann -> C.AImplicit ("", ann)
 126       | C.Rel m -> C.ARel ("", "", m, get_binder c m)
 127       | C.Const (uri, xnss) -> C.AConst ("", uri, List.map (ann_xns c) xnss)
 128       | C.Var (uri, xnss) -> C.AVar ("", uri, List.map (ann_xns c) xnss)
 129       | C.MutInd (uri, tyno, xnss) -> C.AMutInd ("", uri, tyno, List.map (ann_xns c) xnss)
 130       | C.MutConstruct (uri, tyno, consno, xnss) -> C.AMutConstruct ("", uri,tyno,consno, List.map (ann_xns c) xnss)
 131       | C.Meta (i, mss) -> C.AMeta("", i, List.map (ann_ms c) mss)
 132       | C.Appl ts -> C.AAppl ("", List.map (ann_term c) ts)
 133       | C.Cast (te, ty) -> C.ACast ("", ann_term c te, ann_term c ty)
 134       | C.MutCase (sp, i, outty, t, pl) -> C.AMutCase ("", sp, i, ann_term c outty, ann_term c t, List.map (ann_term c) pl)
 135       | C.Prod (n, s, t) -> C.AProd ("", n, ann_term c s, ann_term (mk_decl n s :: c) t)
 136       | C.Lambda (n, s, t) -> C.ALambda ("", n, ann_term c s, ann_term (mk_decl n s :: c) t)
 137       | C.LetIn (n, s, t) -> C.ALetIn ("", n, ann_term c s, ann_term (mk_def n s :: c) t)
 138       | C.Fix (i, fl) -> C.AFix ("", i, List.map (ann_fix (List.rev_map mk_fix fl) c) fl)
 139       | C.CoFix (i, fl) -> C.ACoFix ("", i, List.map (ann_cofix (List.rev_map mk_cofix fl) c) fl)
 140    in
 141    ann_term c
 142
 143 let rec add_abst n t =
 144    if n <= 0 then t else
 145    let t = C.ALambda ("", C.Name "foo", C.AImplicit ("", None), lift 0 1 t) in
 146    add_abst (pred n) t
 147
 148 let mk_ind context id uri tyno outty arg cases =
 149 try
 150    let is_recursive = function
 151       | C.MutInd (u, no, _) -> UM.eq u uri && no = tyno
 152       | _                   -> false
 153    in
 154    let lpsno, (_, _, _, constructors) = get_ind_type uri tyno in
 155    let inty, _ = TC.type_of_aux' [] context (cic arg) Un.empty_ugraph in
 156    let ps = match inty with
 157       | C.MutInd _                  -> []
 158       | C.Appl (C.MutInd _ :: args) -> List.map (fake_annotate context) args
 159       | _                           -> assert false
 160    in
 161    let lps, rps = T.list_split lpsno ps in
 162    let eliminator = get_default_eliminator context uri tyno inty in
 163    let eliminator = fake_annotate context eliminator in
 164    let arg_ref = T.mk_arel 0 "foo" in
 165    let body = C.AMutCase (id, uri, tyno, outty, arg_ref, cases) in
 166    let predicate = add_abst (succ (List.length rps)) body in
 167    let map2 case (_, cty) =
 168       let map (h, case, k) premise =
 169          if h > 0 then pred h, lift k 1 case, k else
 170          if is_recursive premise then 0, lift (succ k) 1 case, succ k else
 171          0, case, succ k
 172       in
 173       let premises, _ = Cl.split context cty in
 174       let _, lifted_case, _ =
 175          List.fold_left map (lpsno, case, 1) (List.rev (List.tl premises))
 176       in
 177       lifted_case
 178    in
 179    let lifted_cases = List.map2 map2 cases constructors in
 180    let args = eliminator :: lps @ predicate :: lifted_cases @ rps @ [arg] in
 181    Some (C.AAppl (id, args))
 182 with Invalid_argument _ -> failwith "PCn.mk_ind"