components/acic_procedural/proceduralConversion.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module C    = Cic
  27 module E    = CicEnvironment
  28 module Un   = CicUniv
  29 module TC   = CicTypeChecker
  30 module D    = Deannotate
  31 module UM   = UriManager
  32
  33 module T    = ProceduralTypes
  34 module Cl   = ProceduralClassify
  35
  36 (* helpers ******************************************************************)
  37
  38 let cic = D.deannotate_term
  39
  40 let get_ind_type uri tyno =
  41    match E.get_obj Un.empty_ugraph uri with
  42       | C.InductiveDefinition (tys, _, lpsno, _), _ -> lpsno, List.nth tys tyno
  43       | _                                           -> assert false
  44
  45 let get_default_eliminator context uri tyno ty =
  46    let _, (name, _, _, _) = get_ind_type uri tyno in
  47    let sort, _ = TC.type_of_aux' [] context ty Un.empty_ugraph in
  48    let ext = match sort with
  49       | C.Sort C.Prop     -> "_ind"
  50       | C.Sort C.Set      -> "_rec"
  51       | C.Sort C.CProp    -> "_rec"
  52       | C.Sort (C.Type _) -> "_rect"
  53       | C.Meta (_,_)      -> assert false
  54       | _                 -> assert false
  55    in
  56    let buri = UM.buri_of_uri uri in
  57    let uri = UM.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con") in
  58    C.Const (uri, [])
  59
  60 let rec list_sub start length = function
  61    | _  :: tl when start  > 0 -> list_sub (pred start) length tl
  62    | hd :: tl when length > 0 -> hd :: list_sub start (pred length) tl
  63    | _                        -> []
  64
  65
  66 (* proof construction *******************************************************)
  67
  68 let lift k n =
  69    let rec lift_xns k (uri, t) = uri, lift_term k t
  70    and lift_ms k = function
  71       | None   -> None
  72       | Some t -> Some (lift_term k t)
  73    and lift_fix len k (id, name, i, ty, bo) =
  74       id, name, i, lift_term k ty, lift_term (k + len) bo
  75    and lift_cofix len k (id, name, ty, bo) =
  76       id, name, lift_term k ty, lift_term (k + len) bo
  77    and lift_term k = function
  78       | C.ASort _ as t -> t
  79       | C.AImplicit _ as t -> t
  80       | C.ARel (id, rid, m, b) as t -> if m < k then t else C.ARel (id, rid, m + n, b)
  81       | C.AConst (id, uri, xnss) -> C.AConst (id, uri, List.map (lift_xns k) xnss)
  82       | C.AVar (id, uri, xnss) -> C.AVar (id, uri, List.map (lift_xns k) xnss)
  83       | C.AMutInd (id, uri, tyno, xnss) -> C.AMutInd (id, uri, tyno, List.map (lift_xns k) xnss)
  84       | C.AMutConstruct (id, uri, tyno, consno, xnss) -> C.AMutConstruct (id, uri,tyno,consno, List.map (lift_xns k) xnss)
  85       | C.AMeta (id, i, mss) -> C.AMeta(id, i, List.map (lift_ms k) mss)
  86       | C.AAppl (id, ts) -> C.AAppl (id, List.map (lift_term k) ts)
  87       | C.ACast (id, te, ty) -> C.ACast (id, lift_term k te, lift_term k ty)
  88       | C.AMutCase (id, sp, i, outty, t, pl) -> C.AMutCase (id, sp, i, lift_term k outty, lift_term k t, List.map (lift_term k) pl)
  89       | C.AProd (id, n, s, t) -> C.AProd (id, n, lift_term k s, lift_term (succ k) t)
  90       | C.ALambda (id, n, s, t) -> C.ALambda (id, n, lift_term k s, lift_term (succ k) t)
  91       | C.ALetIn (id, n, s, t) -> C.ALetIn (id, n, lift_term k s, lift_term (succ k) t)
  92       | C.AFix (id, i, fl) -> C.AFix (id, i, List.map (lift_fix (List.length fl) k) fl)
  93       | C.ACoFix (id, i, fl) -> C.ACoFix (id, i, List.map (lift_cofix (List.length fl) k) fl)
  94    in
  95    lift_term k
  96
  97 let fake_annotate c =
  98    let get_binder c m =
  99       try match List.nth c (pred m) with
 100          | Some (C.Name s, _) -> s
 101          | _                  -> assert false
 102       with
 103          | Invalid_argument _ -> assert false
 104    in
 105    let mk_decl n v = Some (n, C.Decl v) in
 106    let mk_def n v = Some (n, C.Def (v, None)) in
 107    let mk_fix (name, _, _, bo) = mk_def (C.Name name) bo in
 108    let mk_cofix (name, _, bo) = mk_def (C.Name name) bo in
 109    let rec ann_xns c (uri, t) = uri, ann_term c t
 110    and ann_ms c = function
 111       | None   -> None
 112       | Some t -> Some (ann_term c t)
 113    and ann_fix newc c (name, i, ty, bo) =
 114       "", name, i, ann_term c ty, ann_term (List.rev_append newc c) bo
 115    and ann_cofix newc c (name, ty, bo) =
 116       "", name, ann_term c ty, ann_term (List.rev_append newc c) bo
 117    and ann_term c = function
 118       | C.Sort sort -> C.ASort ("", sort)
 119       | C.Implicit ann -> C.AImplicit ("", ann)
 120       | C.Rel m -> C.ARel ("", "", m, get_binder c m)
 121       | C.Const (uri, xnss) -> C.AConst ("", uri, List.map (ann_xns c) xnss)
 122       | C.Var (uri, xnss) -> C.AVar ("", uri, List.map (ann_xns c) xnss)
 123       | C.MutInd (uri, tyno, xnss) -> C.AMutInd ("", uri, tyno, List.map (ann_xns c) xnss)
 124       | C.MutConstruct (uri, tyno, consno, xnss) -> C.AMutConstruct ("", uri,tyno,consno, List.map (ann_xns c) xnss)
 125       | C.Meta (i, mss) -> C.AMeta("", i, List.map (ann_ms c) mss)
 126       | C.Appl ts -> C.AAppl ("", List.map (ann_term c) ts)
 127       | C.Cast (te, ty) -> C.ACast ("", ann_term c te, ann_term c ty)
 128       | C.MutCase (sp, i, outty, t, pl) -> C.AMutCase ("", sp, i, ann_term c outty, ann_term c t, List.map (ann_term c) pl)
 129       | C.Prod (n, s, t) -> C.AProd ("", n, ann_term c s, ann_term (mk_decl n s :: c) t)
 130       | C.Lambda (n, s, t) -> C.ALambda ("", n, ann_term c s, ann_term (mk_decl n s :: c) t)
 131       | C.LetIn (n, s, t) -> C.ALetIn ("", n, ann_term c s, ann_term (mk_def n s :: c) t)
 132       | C.Fix (i, fl) -> C.AFix ("", i, List.map (ann_fix (List.rev_map mk_fix fl) c) fl)
 133       | C.CoFix (i, fl) -> C.ACoFix ("", i, List.map (ann_cofix (List.rev_map mk_cofix fl) c) fl)
 134    in
 135    ann_term c
 136
 137 let rec add_abst n t =
 138    if n <= 0 then t else
 139    let t = C.ALambda ("", C.Name "foo", C.AImplicit ("", None), lift 0 1 t) in
 140    add_abst (pred n) t
 141
 142 let mk_ind context id uri tyno outty arg cases =
 143 try
 144    let is_recursive = function
 145       | C.MutInd (u, no, _) -> UM.eq u uri && no = tyno
 146       | _                   -> false
 147    in
 148    let lpsno, (_, _, _, constructors) = get_ind_type uri tyno in
 149    let inty, _ = TC.type_of_aux' [] context (cic arg) Un.empty_ugraph in
 150    let ps = match inty with
 151       | C.MutInd _                  -> []
 152       | C.Appl (C.MutInd _ :: args) -> List.map (fake_annotate context) args
 153       | _                           -> assert false
 154    in
 155    let lps, rps = T.list_split lpsno ps in
 156    let eliminator = get_default_eliminator context uri tyno inty in
 157    let eliminator = fake_annotate context eliminator in
 158    let arg_ref = T.mk_arel 0 "foo" in
 159    let body = C.AMutCase (id, uri, tyno, outty, arg_ref, cases) in
 160    let predicate = add_abst (succ (List.length rps)) body in
 161    let map2 case (_, cty) =
 162       let map (h, case, k) premise =
 163          if h > 0 then pred h, lift k 1 case, k else
 164          if is_recursive premise then 0, lift (succ k) 1 case, succ k else
 165          0, case, succ k
 166       in
 167       let premises, _ = Cl.split context cty in
 168       let _, lifted_case, _ =
 169          List.fold_left map (lpsno, case, 1) (List.rev (List.tl premises))
 170       in
 171       lifted_case
 172    in
 173    let lifted_cases = List.map2 map2 cases constructors in
 174    let args = eliminator :: lps @ predicate :: lifted_cases @ rps @ [arg] in
 175    Some (C.AAppl (id, args))
 176 with Invalid_argument _ -> failwith "PCn.mk_ind"