components/cic/cicParser.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let debug = false
  29 let debug_print s = if debug then prerr_endline (Lazy.force s)
  30
  31 open Printf
  32
  33 (* ZACK TODO element from the DTD still to be handled:
  34    <!ELEMENT CurrentProof (Conjecture*,body)>
  35    <!ELEMENT Sequent %sequent;>
  36    <!ELEMENT Conjecture %sequent;>
  37    <!ELEMENT Decl %term;>
  38    <!ELEMENT Def %term;>
  39    <!ELEMENT Hidden EMPTY>
  40    <!ELEMENT Goal %term;>
  41 *)
  42
  43 exception Getter_failure of string * string
  44 exception Parser_failure of string
  45
  46 type stack_entry =
  47   | Arg of string * Cic.annterm (* relative uri, term *)
  48   (* constants' body and types resides in differne files, thus we can't simple
  49    * keep constants in Cic_obj stack entries *)
  50   | Cic_attributes of Cic.attribute list
  51   | Cic_constant_body of string * string * UriManager.uri list * Cic.annterm
  52       * Cic.attribute list
  53       (* id, for, params, body, object attributes *)
  54   | Cic_constant_type of string * string * UriManager.uri list * Cic.annterm
  55       * Cic.attribute list
  56       (* id, name, params, type, object attributes *)
  57   | Cic_term of Cic.annterm (* term *)
  58   | Cic_obj of Cic.annobj   (* object *)
  59   | Cofix_fun of Cic.id * string * Cic.annterm * Cic.annterm
  60       (* id, name, type, body *)
  61   | Constructor of string * Cic.annterm   (* name, type *)
  62   | Decl of Cic.id * Cic.name * Cic.annterm (* id, binder, source *)
  63   | Def of Cic.id * Cic.name * Cic.annterm  (* id, binder, source *)
  64   | Fix_fun of Cic.id * string * int * Cic.annterm * Cic.annterm
  65       (* id, name, ind. index, type, body *)
  66   | Inductive_type of string * string * bool * Cic.annterm *
  67       (string * Cic.annterm) list (* id, name, inductive, arity, constructors *)
  68   | Meta_subst of Cic.annterm option
  69   | Obj_class of Cic.object_class
  70   | Obj_flavour of Cic.object_flavour
  71   | Obj_field of string (* field name *)
  72   | Obj_generated
  73   | Tag of string * (string * string) list  (* tag name, attributes *)
  74       (* ZACK TODO add file position to tag stack entry so that when attribute
  75        * errors occur, the position of their _start_tag_ could be printed
  76        * instead of the current position (usually the end tag) *)
  77
  78 type ctxt = {
  79   mutable stack: stack_entry list;
  80   mutable xml_parser: XmlPushParser.xml_parser option;
  81   mutable filename: string;
  82   uri: UriManager.uri;
  83 }
  84
  85 let string_of_stack ctxt =
  86   "[" ^ (String.concat "; "
  87     (List.map
  88       (function
  89       | Arg (reluri, _) -> sprintf "Arg %s" reluri
  90       | Cic_attributes _ -> "Cic_attributes"
  91       | Cic_constant_body (id, name, _, _, _) ->
  92           sprintf "Cic_constant_body %s (id=%s)" name id
  93       | Cic_constant_type (id, name, _, _, _) ->
  94           sprintf "Cic_constant_type %s (id=%s)" name id
  95       | Cic_term _ -> "Cic_term"
  96       | Cic_obj _ -> "Cic_obj"
  97       | Constructor (name, _) -> "Constructor " ^ name
  98       | Cofix_fun (id, _, _, _) -> sprintf "Cofix_fun (id=%s)" id
  99       | Decl (id, _, _) -> sprintf "Decl (id=%s)" id
 100       | Def (id, _, _) -> sprintf "Def (id=%s)" id
 101       | Fix_fun (id, _, _, _, _) -> sprintf "Fix_fun (id=%s)" id
 102       | Inductive_type (id, name, _, _, _) ->
 103           sprintf "Inductive_type %s (id=%s)" name id
 104       | Meta_subst _ -> "Meta_subst"
 105       | Obj_class _ -> "Obj_class"
 106       | Obj_flavour _ -> "Obj_flavour"
 107       | Obj_field name -> "Obj_field " ^ name
 108       | Obj_generated -> "Obj_generated"
 109       | Tag (tag, _) -> "Tag " ^ tag)
 110       ctxt.stack)) ^ "]"
 111
 112 let compare_attrs (a1, v1) (a2, v2) = Pervasives.compare a1 a2
 113 let sort_attrs = List.sort compare_attrs
 114
 115 let new_parser_context uri = {
 116   stack = [];
 117   xml_parser = None;
 118   filename = "-";
 119   uri = uri;
 120 }
 121
 122 let get_parser ctxt =
 123   match ctxt.xml_parser with
 124   | Some p -> p
 125   | None -> assert false
 126
 127 (** {2 Error handling} *)
 128
 129 let parse_error ctxt msg =
 130   let (line, col) = XmlPushParser.get_position (get_parser ctxt) in
 131   raise (Parser_failure (sprintf "[%s: line %d, column %d] %s"
 132     ctxt.filename line col msg))
 133
 134 let attribute_error ctxt tag =
 135   parse_error ctxt ("wrong attribute set for " ^ tag)
 136
 137 (** {2 Parsing context management} *)
 138
 139 let pop ctxt =
 140 (*  debug_print (lazy "pop");*)
 141   match ctxt.stack with
 142   | hd :: tl -> (ctxt.stack <- tl)
 143   | _ -> assert false
 144
 145 let push ctxt v =
 146 (*  debug_print (lazy "push");*)
 147   ctxt.stack <- v :: ctxt.stack
 148
 149 let set_top ctxt v =
 150 (*  debug_print (lazy "set_top");*)
 151   match ctxt.stack with
 152   | _ :: tl -> (ctxt.stack <- v :: tl)
 153   | _ -> assert false
 154
 155   (** pop the last tag from the open tags stack returning a pair <tag_name,
 156    * attribute_list> *)
 157 let pop_tag ctxt =
 158   match ctxt.stack with
 159   | Tag (tag, attrs) :: tl ->
 160       ctxt.stack <- tl;
 161       (tag, attrs)
 162   | _ -> parse_error ctxt "unexpected extra content"
 163
 164   (** pop the last tag from the open tags stack returning its attributes.
 165    * Attributes are returned as a list of pair <name, value> _sorted_ by
 166    * attribute name *)
 167 let pop_tag_attrs ctxt = sort_attrs (snd (pop_tag ctxt))
 168
 169 let pop_cics ctxt =
 170   let rec aux acc stack =
 171     match stack with
 172     | Cic_term t :: tl -> aux (t :: acc) tl
 173     | tl -> acc, tl
 174   in
 175   let values, new_stack = aux [] ctxt.stack in
 176   ctxt.stack <- new_stack;
 177   values
 178
 179 let pop_class_modifiers ctxt =
 180   let rec aux acc stack =
 181     match stack with
 182     | (Cic_term (Cic.ASort _) as m) :: tl
 183     | (Obj_field _ as m) :: tl ->
 184         aux (m :: acc) tl
 185     | tl -> acc, tl
 186   in
 187   let values, new_stack = aux [] ctxt.stack in
 188   ctxt.stack <- new_stack;
 189   values
 190
 191 let pop_meta_substs ctxt =
 192   let rec aux acc stack =
 193     match stack with
 194     | Meta_subst t :: tl -> aux (t :: acc) tl
 195     | tl -> acc, tl
 196   in
 197   let values, new_stack = aux [] ctxt.stack in
 198   ctxt.stack <- new_stack;
 199   values
 200
 201 let pop_fix_funs ctxt =
 202   let rec aux acc stack =
 203     match stack with
 204     | Fix_fun (id, name, index, typ, body) :: tl ->
 205         aux ((id, name, index, typ, body) :: acc) tl
 206     | tl -> acc, tl
 207   in
 208   let values, new_stack = aux [] ctxt.stack in
 209   ctxt.stack <- new_stack;
 210   values
 211
 212 let pop_cofix_funs ctxt =
 213   let rec aux acc stack =
 214     match stack with
 215     | Cofix_fun (id, name, typ, body) :: tl ->
 216         aux ((id, name, typ, body) :: acc) tl
 217     | tl -> acc, tl
 218   in
 219   let values, new_stack = aux [] ctxt.stack in
 220   ctxt.stack <- new_stack;
 221   values
 222
 223 let pop_constructors ctxt =
 224   let rec aux acc stack =
 225     match stack with
 226     | Constructor (name, t) :: tl -> aux ((name, t) :: acc) tl
 227     | tl -> acc, tl
 228   in
 229   let values, new_stack = aux [] ctxt.stack in
 230   ctxt.stack <- new_stack;
 231   values
 232
 233 let pop_inductive_types ctxt =
 234   let rec aux acc stack =
 235     match stack with
 236     | Inductive_type (id, name, ind, arity, ctors) :: tl ->
 237         aux ((id, name, ind, arity, ctors) :: acc) tl
 238     | tl -> acc, tl
 239   in
 240   let values, new_stack = aux [] ctxt.stack in
 241   if values = [] then
 242     parse_error ctxt "no \"InductiveType\" element found";
 243   ctxt.stack <- new_stack;
 244   values
 245
 246   (** travels the stack (without popping) for the first term subject of explicit
 247    * named substitution and return its URI *)
 248 let find_base_uri ctxt =
 249   let rec aux = function
 250     | Cic_term (Cic.AConst (_, uri, _)) :: _
 251     | Cic_term (Cic.AMutInd (_, uri, _, _)) :: _
 252     | Cic_term (Cic.AMutConstruct (_, uri, _, _, _)) :: _
 253     | Cic_term (Cic.AVar (_, uri, _)) :: _ ->
 254         uri
 255     | Arg _ :: tl -> aux tl
 256     | _ -> parse_error ctxt "no \"arg\" element found"
 257   in
 258   UriManager.buri_of_uri (aux ctxt.stack)
 259
 260   (** backwardly eats the stack building an explicit named substitution from Arg
 261    * stack entries *)
 262 let pop_subst ctxt base_uri =
 263   let rec aux acc stack =
 264     match stack with
 265     | Arg (rel_uri, term) :: tl ->
 266         let uri = UriManager.uri_of_string (base_uri ^ "/" ^ rel_uri) in
 267         aux ((uri, term) :: acc) tl
 268     | tl -> acc, tl
 269   in
 270   let subst, new_stack = aux [] ctxt.stack in
 271   if subst = [] then
 272     parse_error ctxt "no \"arg\" element found";
 273   ctxt.stack <- new_stack;
 274   subst
 275
 276 let pop_cic ctxt =
 277   match ctxt.stack with
 278   | Cic_term t :: tl ->
 279       ctxt.stack <- tl;
 280       t
 281   | _ -> parse_error ctxt "no cic term found"
 282
 283 let pop_obj_attributes ctxt =
 284   match ctxt.stack with
 285   | Cic_attributes attributes :: tl ->
 286       ctxt.stack <- tl;
 287       attributes
 288   | _ -> []
 289
 290 (** {2 Auxiliary functions} *)
 291
 292 let uri_of_string = UriManager.uri_of_string
 293
 294 let uri_list_of_string =
 295   let space_RE = Str.regexp " " in
 296   fun s ->
 297     List.map uri_of_string (Str.split space_RE s)
 298
 299 let sort_of_string ctxt = function
 300   | "Prop" -> Cic.Prop
 301   | "Set"  -> Cic.Set
 302   | "CProp" -> Cic.CProp
 303   (* THIS CASE IS HERE ONLY TO ALLOW THE PARSING OF COQ LIBRARY
 304    * THIS SHOULD BE REMOVED AS SOON AS univ_maker OR COQ'S EXPORTATION
 305    * IS FIXED *)
 306   | "Type" ->  Cic.Type (CicUniv.fresh ~uri:ctxt.uri ())
 307   | s ->
 308       let len = String.length s in
 309       if not(len > 5) then parse_error ctxt "sort expected";
 310       if not(String.sub s 0 5 = "Type:") then parse_error ctxt "sort expected";
 311       try
 312         Cic.Type
 313           (CicUniv.fresh
 314             ~uri:ctxt.uri
 315             ~id:(int_of_string (String.sub s 5 (len - 5))) ())
 316       with
 317       | Failure "int_of_string"
 318       | Invalid_argument _ -> parse_error ctxt "sort expected"
 319
 320 let patch_subst ctxt subst = function
 321   | Cic.AConst (id, uri, _) -> Cic.AConst (id, uri, subst)
 322   | Cic.AMutInd (id, uri, typeno, _) ->
 323       Cic.AMutInd (id, uri, typeno, subst)
 324   | Cic.AMutConstruct (id, uri, typeno, consno, _) ->
 325       Cic.AMutConstruct (id, uri, typeno, consno, subst)
 326   | Cic.AVar (id, uri, _) -> Cic.AVar (id, uri, subst)
 327   | _ ->
 328       parse_error ctxt
 329         ("only \"CONST\", \"VAR\", \"MUTIND\", and \"MUTCONSTRUCT\" can be" ^
 330         " instantiated")
 331
 332   (** backwardly eats the stack seeking for the first open tag carrying
 333    * "helm:exception" attributes. If found return Some of a pair containing
 334    * exception name and argument. Return None otherwise *)
 335 let find_helm_exception ctxt =
 336   let rec aux = function
 337     | [] -> None
 338     | Tag (_, attrs) :: tl ->
 339         (try
 340           let exn = List.assoc "helm:exception" attrs in
 341           let arg =
 342             try List.assoc "helm:exception_arg" attrs with Not_found -> ""
 343           in
 344           Some (exn, arg)
 345         with Not_found -> aux tl)
 346     | _ :: tl -> aux tl
 347   in
 348   aux ctxt.stack
 349
 350 (** {2 Push parser callbacks}
 351  * each callback needs to be instantiated to a parsing context *)
 352
 353 let start_element ctxt tag attrs =
 354 (*  debug_print (lazy (sprintf "<%s%s>" tag (match attrs with | [] -> "" | _ -> " " ^ String.concat " " (List.map (fun (a,v) -> sprintf "%s=\"%s\"" a v) attrs))));*)
 355   push ctxt (Tag (tag, attrs))
 356
 357 let end_element ctxt tag =
 358 (*  debug_print (lazy (sprintf "</%s>" tag));*)
 359 (*  debug_print (lazy (string_of_stack ctxt));*)
 360   let attribute_error () = attribute_error ctxt tag in
 361   let parse_error = parse_error ctxt in
 362   let sort_of_string = sort_of_string ctxt in
 363   match tag with
 364   | "REL" ->
 365       push ctxt (Cic_term
 366         (match pop_tag_attrs ctxt with
 367         | ["binder", binder; "id", id; "idref", idref; "value", value]
 368         | ["binder", binder; "id", id; "idref", idref; "sort", _;
 369            "value", value] ->
 370             Cic.ARel (id, idref, int_of_string value, binder)
 371         | _ -> attribute_error ()))
 372   | "VAR" ->
 373       push ctxt (Cic_term
 374         (match pop_tag_attrs ctxt with
 375         | ["id", id; "uri", uri]
 376         | ["id", id; "sort", _; "uri", uri] ->
 377             Cic.AVar (id, uri_of_string uri, [])
 378         | _ -> attribute_error ()))
 379   | "CONST" ->
 380       push ctxt (Cic_term
 381         (match pop_tag_attrs ctxt with
 382         | ["id", id; "uri", uri]
 383         | ["id", id; "sort", _; "uri", uri] ->
 384             Cic.AConst (id, uri_of_string uri, [])
 385         | _ -> attribute_error ()))
 386   | "SORT" ->
 387       push ctxt (Cic_term
 388         (match pop_tag_attrs ctxt with
 389         | ["id", id; "value", sort] -> Cic.ASort (id, sort_of_string sort)
 390         | _ -> attribute_error ()))
 391   | "APPLY" ->
 392       let args = pop_cics ctxt in
 393       push ctxt (Cic_term
 394         (match pop_tag_attrs ctxt with
 395         | ["id", id ]
 396         | ["id", id; "sort", _] -> Cic.AAppl (id, args)
 397         | _ -> attribute_error ()))
 398   | "decl" ->
 399       let source = pop_cic ctxt in
 400       push ctxt
 401         (match pop_tag_attrs ctxt with
 402         | ["binder", binder; "id", id ]
 403         | ["binder", binder; "id", id; "type", _] ->
 404             Decl (id, Cic.Name binder, source)
 405         | ["id", id]
 406         | ["id", id; "type", _] -> Decl (id, Cic.Anonymous, source)
 407         | _ -> attribute_error ())
 408   | "def" ->  (* same as "decl" above *)
 409       let source = pop_cic ctxt in
 410       push ctxt
 411         (match pop_tag_attrs ctxt with
 412         | ["binder", binder; "id", id]
 413         | ["binder", binder; "id", id; "sort", _] ->
 414             Def (id, Cic.Name binder, source)
 415         | ["id", id]
 416         | ["id", id; "sort", _] -> Def (id, Cic.Anonymous, source)
 417         | _ -> attribute_error ())
 418   | "arity"           (* transparent elements (i.e. which contain a CIC) *)
 419   | "body"
 420   | "inductiveTerm"
 421   | "pattern"
 422   | "patternsType"
 423   | "target"
 424   | "term"
 425   | "type" ->
 426       let term = pop_cic ctxt in
 427       pop ctxt; (* pops start tag matching current end tag (e.g. <arity>) *)
 428       push ctxt (Cic_term term)
 429   | "substitution" ->   (* optional transparent elements (i.e. which _may_
 430                          * contain a CIC) *)
 431       set_top ctxt  (* replace <substitution> *)
 432         (match ctxt.stack with
 433         | Cic_term term :: tl ->
 434             ctxt.stack <- tl;
 435             (Meta_subst (Some term))
 436         | _ ->  Meta_subst None)
 437   | "PROD" ->
 438       let target = pop_cic ctxt in
 439       let rec add_decl target = function
 440         | Decl (id, binder, source) :: tl ->
 441             add_decl (Cic.AProd (id, binder, source, target)) tl
 442         | tl ->
 443             ctxt.stack <- tl;
 444             target
 445       in
 446       let term = add_decl target ctxt.stack in
 447       (match pop_tag_attrs ctxt with
 448         []
 449       | ["type", _] -> ()
 450       | _ -> attribute_error ());
 451       push ctxt (Cic_term term)
 452   | "LAMBDA" ->
 453       let target = pop_cic ctxt in
 454       let rec add_decl target = function
 455         | Decl (id, binder, source) :: tl ->
 456             add_decl (Cic.ALambda (id, binder, source, target)) tl
 457         | tl ->
 458             ctxt.stack <- tl;
 459             target
 460       in
 461       let term = add_decl target ctxt.stack in
 462       (match pop_tag_attrs ctxt with
 463         []
 464       | ["sort", _] -> ()
 465       | _ -> attribute_error ());
 466       push ctxt (Cic_term term)
 467   | "LETIN" ->
 468       let target = pop_cic ctxt in
 469       let rec add_def target = function
 470         | Def (id, binder, source) :: tl ->
 471             add_def (Cic.ALetIn (id, binder, source, target)) tl
 472         | tl ->
 473             ctxt.stack <- tl;
 474             target
 475       in
 476       let term = add_def target ctxt.stack in
 477       (match pop_tag_attrs ctxt with
 478         []
 479       | ["sort", _] -> ()
 480       | _ -> attribute_error ());
 481       push ctxt (Cic_term term)
 482   | "CAST" ->
 483       let typ = pop_cic ctxt in
 484       let term = pop_cic ctxt in
 485       push ctxt (Cic_term
 486         (match pop_tag_attrs ctxt with
 487           ["id", id]
 488         | ["id", id; "sort", _] -> Cic.ACast (id, term, typ)
 489         | _ -> attribute_error ()));
 490   | "IMPLICIT" ->
 491       push ctxt (Cic_term
 492         (match pop_tag_attrs ctxt with
 493         | ["id", id] -> Cic.AImplicit (id, None)
 494         | ["annotation", annotation; "id", id] ->
 495             let implicit_annotation =
 496               match annotation with
 497               | "closed" -> `Closed
 498               | "hole" -> `Hole
 499               | "type" -> `Type
 500               | _ -> parse_error "invalid value for \"annotation\" attribute"
 501             in
 502             Cic.AImplicit (id, Some implicit_annotation)
 503         | _ -> attribute_error ()))
 504   | "META" ->
 505       let meta_substs = pop_meta_substs ctxt in
 506       push ctxt (Cic_term
 507         (match pop_tag_attrs ctxt with
 508         | ["id", id; "no", no]
 509         | ["id", id; "no", no; "sort", _] ->
 510             Cic.AMeta (id, int_of_string no, meta_substs)
 511         | _ -> attribute_error ()));
 512   | "MUTIND" ->
 513       push ctxt (Cic_term
 514         (match pop_tag_attrs ctxt with
 515         | ["id", id; "noType", noType; "uri", uri] ->
 516             Cic.AMutInd (id, uri_of_string uri, int_of_string noType, [])
 517         | _ -> attribute_error ()));
 518   | "MUTCONSTRUCT" ->
 519       push ctxt (Cic_term
 520         (match pop_tag_attrs ctxt with
 521         | ["id", id; "noConstr", noConstr; "noType", noType; "uri", uri]
 522         | ["id", id; "noConstr", noConstr; "noType", noType; "sort", _;
 523            "uri", uri] ->
 524             Cic.AMutConstruct (id, uri_of_string uri, int_of_string noType,
 525               int_of_string noConstr, [])
 526         | _ -> attribute_error ()));
 527   | "FixFunction" ->
 528       let body = pop_cic ctxt in
 529       let typ = pop_cic ctxt in
 530       push ctxt
 531         (match pop_tag_attrs ctxt with
 532         | ["id", id; "name", name; "recIndex", recIndex] ->
 533             Fix_fun (id, name, int_of_string recIndex, typ, body)
 534         | _ -> attribute_error ())
 535   | "CofixFunction" ->
 536       let body = pop_cic ctxt in
 537       let typ = pop_cic ctxt in
 538       push ctxt
 539         (match pop_tag_attrs ctxt with
 540         | ["id", id; "name", name] ->
 541             Cofix_fun (id, name, typ, body)
 542         | _ -> attribute_error ())
 543   | "FIX" ->
 544       let fix_funs = pop_fix_funs ctxt in
 545       push ctxt (Cic_term
 546         (match pop_tag_attrs ctxt with
 547         | ["id", id; "noFun", noFun]
 548         | ["id", id; "noFun", noFun; "sort", _] ->
 549             Cic.AFix (id, int_of_string noFun, fix_funs)
 550         | _ -> attribute_error ()))
 551   | "COFIX" ->
 552       let cofix_funs = pop_cofix_funs ctxt in
 553       push ctxt (Cic_term
 554         (match pop_tag_attrs ctxt with
 555         | ["id", id; "noFun", noFun]
 556         | ["id", id; "noFun", noFun; "sort", _] ->
 557             Cic.ACoFix (id, int_of_string noFun, cofix_funs)
 558         | _ -> attribute_error ()))
 559   | "MUTCASE" ->
 560       (match pop_cics ctxt with
 561       | patternsType :: inductiveTerm :: patterns ->
 562           push ctxt (Cic_term
 563             (match pop_tag_attrs ctxt with
 564             | ["id", id; "noType", noType; "uriType", uriType]
 565             | ["id", id; "noType", noType; "sort", _; "uriType", uriType] ->
 566                 Cic.AMutCase (id, uri_of_string uriType, int_of_string noType,
 567                   patternsType, inductiveTerm, patterns)
 568             | _ -> attribute_error ()))
 569       | _ -> parse_error "invalid \"MUTCASE\" content")
 570   | "Constructor" ->
 571       let typ = pop_cic ctxt in
 572       push ctxt
 573         (match pop_tag_attrs ctxt with
 574         | ["name", name] -> Constructor (name, typ)
 575         | _ -> attribute_error ())
 576   | "InductiveType" ->
 577       let constructors = pop_constructors ctxt in
 578       let arity = pop_cic ctxt in
 579       push ctxt
 580         (match pop_tag_attrs ctxt with
 581         | ["id", id; "inductive", inductive; "name", name] ->
 582             Inductive_type (id, name, bool_of_string inductive, arity,
 583               constructors)
 584         | _ -> attribute_error ())
 585   | "InductiveDefinition" ->
 586       let inductive_types = pop_inductive_types ctxt in
 587       let obj_attributes = pop_obj_attributes ctxt in
 588       push ctxt (Cic_obj
 589         (match pop_tag_attrs ctxt with
 590         | ["id", id; "noParams", noParams; "params", params] ->
 591             Cic.AInductiveDefinition (id, inductive_types,
 592               uri_list_of_string params, int_of_string noParams, obj_attributes)
 593         | _ -> attribute_error ()))
 594   | "ConstantType" ->
 595       let typ = pop_cic ctxt in
 596       let obj_attributes = pop_obj_attributes ctxt in
 597       push ctxt
 598         (match pop_tag_attrs ctxt with
 599         | ["id", id; "name", name; "params", params] ->
 600             Cic_constant_type (id, name, uri_list_of_string params, typ,
 601               obj_attributes)
 602         | _ -> attribute_error ())
 603   | "ConstantBody" ->
 604       let body = pop_cic ctxt in
 605       let obj_attributes = pop_obj_attributes ctxt in
 606       push ctxt
 607         (match pop_tag_attrs ctxt with
 608         | ["for", for_; "id", id; "params", params] ->
 609             Cic_constant_body (id, for_, uri_list_of_string params, body,
 610               obj_attributes)
 611         | _ -> attribute_error ())
 612   | "Variable" ->
 613       let typ = pop_cic ctxt in
 614       let body =
 615         match pop_cics ctxt with
 616         | [] -> None
 617         | [t] -> Some t
 618         | _ -> parse_error "wrong content for \"Variable\""
 619       in
 620       let obj_attributes = pop_obj_attributes ctxt in
 621       push ctxt (Cic_obj
 622         (match pop_tag_attrs ctxt with
 623         | ["id", id; "name", name; "params", params] ->
 624             Cic.AVariable (id, name, body, typ, uri_list_of_string params,
 625               obj_attributes)
 626         | _ -> attribute_error ()))
 627   | "arg" ->
 628       let term = pop_cic ctxt in
 629       push ctxt
 630         (match pop_tag_attrs ctxt with
 631         | ["relUri", relUri] -> Arg (relUri, term)
 632         | _ -> attribute_error ())
 633   | "instantiate" ->
 634         (* explicit named substitution handling: when the end tag of an element
 635          * subject of exlicit named subst (MUTIND, MUTCONSTRUCT, CONST, VAR) it
 636          * is stored on the stack with no substitutions (i.e. []). When the end
 637          * tag of an "instantiate" element is found we patch the term currently
 638          * on the stack with the substitution built from "instantiate" children
 639          *)
 640         (* XXX inefficiency here: first travels the <arg> elements in order to
 641          * find the baseUri, then in order to build the explicit named subst *)
 642       let base_uri = find_base_uri ctxt in
 643       let subst = pop_subst ctxt base_uri in
 644       let term = pop_cic ctxt in
 645         (* comment from CicParser3.ml:
 646          * CSC: the "id" optional attribute should be parsed and reflected in
 647          *      Cic.annterm and id = string_of_xml_attr (n#attribute "id") *)
 648         (* replace <instantiate> *)
 649       set_top ctxt (Cic_term (patch_subst ctxt subst term))
 650   | "attributes" ->
 651       let rec aux acc = function  (* retrieve object attributes *)
 652         | Obj_class c :: tl -> aux (`Class c :: acc) tl
 653         | Obj_flavour f :: tl -> aux (`Flavour f :: acc) tl
 654         | Obj_generated :: tl -> aux (`Generated :: acc) tl
 655         | tl -> acc, tl
 656       in
 657       let obj_attrs, new_stack = aux [] ctxt.stack in
 658       ctxt.stack <- new_stack;
 659       set_top ctxt (Cic_attributes obj_attrs)
 660   | "generated" -> set_top ctxt Obj_generated
 661   | "field" ->
 662       push ctxt
 663         (match pop_tag_attrs ctxt with
 664         | ["name", name] -> Obj_field name
 665         | _ -> attribute_error ())
 666   | "flavour" ->
 667       push ctxt
 668         (match pop_tag_attrs ctxt with
 669         | [ "value", "definition"] -> Obj_flavour `Definition
 670         | [ "value", "fact"] -> Obj_flavour `Fact
 671         | [ "value", "lemma"] -> Obj_flavour `Lemma
 672         | [ "value", "remark"] -> Obj_flavour `Remark
 673         | [ "value", "theorem"] -> Obj_flavour `Theorem
 674         | [ "value", "variant"] -> Obj_flavour `Variant
 675         | _ -> attribute_error ())
 676   | "class" ->
 677       let class_modifiers = pop_class_modifiers ctxt in
 678       push ctxt
 679         (match pop_tag_attrs ctxt with
 680         | ["value", "coercion"] -> Obj_class `Coercion
 681         | ["value", "elim"] ->
 682             (match class_modifiers with
 683             | [Cic_term (Cic.ASort (_, sort))] -> Obj_class (`Elim sort)
 684             | _ ->
 685                 parse_error
 686                   "unexpected extra content for \"elim\" object class")
 687         | ["value", "record"] ->
 688             let fields =
 689               List.map
 690                 (function
 691                   | Obj_field name ->
 692                       (match Str.split (Str.regexp " ") name with
 693                       | [name] -> name, false
 694                       | [name;"coercion"] -> name,true
 695                       | _ ->
 696                           parse_error
 697                             "wrong \"field\"'s name attribute")
 698                   | _ ->
 699                       parse_error
 700                         "unexpected extra content for \"record\" object class")
 701                 class_modifiers
 702             in
 703             Obj_class (`Record fields)
 704         | ["value", "projection"] -> Obj_class `Projection
 705         | _ -> attribute_error ())
 706   | tag ->
 707       match find_helm_exception ctxt with
 708       | Some (exn, arg) -> raise (Getter_failure (exn, arg))
 709       | None -> parse_error (sprintf "unknown element \"%s\"" tag)
 710
 711 (** {2 Parser internals} *)
 712
 713 let has_gz_suffix fname =
 714   try
 715     let idx = String.rindex fname '.' in
 716     let suffix = String.sub fname idx (String.length fname - idx) in
 717     suffix = ".gz"
 718   with Not_found -> false
 719
 720 let parse uri filename =
 721   let ctxt = new_parser_context uri in
 722   ctxt.filename <- filename;
 723   let module P = XmlPushParser in
 724   let callbacks = {
 725     P.default_callbacks with
 726       P.start_element = Some (start_element ctxt);
 727       P.end_element = Some (end_element ctxt);
 728   } in
 729   let xml_parser = P.create_parser callbacks in
 730   ctxt.xml_parser <- Some xml_parser;
 731   try
 732     (try
 733       let xml_source =
 734         if has_gz_suffix filename then `Gzip_file filename
 735         else `File filename
 736       in
 737       P.parse xml_parser xml_source
 738     with exn ->
 739       ctxt.xml_parser <- None;
 740       (* ZACK: the above "<- None" is vital for garbage collection. Without it
 741        * we keep in memory a circular structure parser -> callbacks -> ctxt ->
 742        * parser. I don't know if the ocaml garbage collector is supposed to
 743        * collect such structures, but for sure the expat bindings will (orribly)
 744        * leak when used in conjunction with such structures *)
 745       raise exn);
 746     ctxt.xml_parser <- None; (* ZACK: same comment as above *)
 747 (*    debug_print (lazy (string_of_stack stack));*)
 748     (* assert (List.length ctxt.stack = 1) *)
 749     List.hd ctxt.stack
 750   with
 751   | Failure "int_of_string" -> parse_error ctxt "integer number expected"
 752   | Invalid_argument "bool_of_string" -> parse_error ctxt "boolean expected"
 753   | P.Parse_error msg -> parse_error ctxt ("parse error: " ^ msg)
 754   | Sys.Break
 755   | Parser_failure _
 756   | Getter_failure _ as exn ->
 757       raise exn
 758   | exn ->
 759       raise (Parser_failure ("uncaught exception: " ^ Printexc.to_string exn))
 760
 761 (** {2 API implementation} *)
 762
 763 let annobj_of_xml uri filename filenamebody =
 764   match filenamebody with
 765   | None ->
 766       (match parse uri filename with
 767       | Cic_constant_type (id, name, params, typ, obj_attributes) ->
 768           Cic.AConstant (id, None, name, None, typ, params, obj_attributes)
 769       | Cic_obj obj -> obj
 770       | _ -> raise (Parser_failure ("no object found in " ^ filename)))
 771   | Some filenamebody ->
 772       (match parse uri filename, parse uri filenamebody with
 773       | Cic_constant_type (type_id, name, params, typ, obj_attributes),
 774         Cic_constant_body (body_id, _, _, body, _) ->
 775           Cic.AConstant (type_id, Some body_id, name, Some body, typ, params,obj_attributes)
 776       | _ ->
 777           raise (Parser_failure (sprintf "no constant found in %s, %s"
 778             filename filenamebody)))
 779
 780 let obj_of_xml uri filename filenamebody =
 781  Deannotate.deannotate_obj (annobj_of_xml uri filename filenamebody)