components/cic_unification/coercGraph.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf;;
  29
  30 type coercion_search_result =
  31      (* metasenv, last coercion argument, fully saturated coercion *)
  32      (* to apply the coercion it is sufficient to unify the last coercion
  33         argument (that is a Meta) with the term to be coerced *)
  34   | SomeCoercion of (Cic.metasenv * Cic.term * Cic.term) list
  35   | SomeCoercionToTgt of (Cic.metasenv * Cic.term * Cic.term) list
  36   | NoCoercion
  37   | NotMetaClosed
  38   | NotHandled of string Lazy.t
  39
  40 let debug = false
  41 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  42
  43 let saturate_coercion ul metasenv subst context =
  44   let cl = List.map CicUtil.term_of_uri ul in
  45   let funclass_arityl =
  46     let _,tgtcarl = List.split (List.map CoercDb.get_carr ul) in
  47     List.map (function CoercDb.Fun i -> i | _ -> 0) tgtcarl
  48   in
  49   let freshmeta = CicMkImplicit.new_meta metasenv subst in
  50    List.map2
  51     (fun arity c ->
  52       let ty,_ =
  53        CicTypeChecker.type_of_aux' ~subst metasenv context c
  54         CicUniv.empty_ugraph in
  55       let _,metasenv,args,lastmeta =
  56        TermUtil.saturate_term freshmeta metasenv context ty arity in
  57       let irl =
  58        CicMkImplicit.identity_relocation_list_for_metavariable context
  59       in
  60        metasenv, Cic.Meta (lastmeta-1,irl),
  61         match args with
  62            [] -> c
  63          | _ -> Cic.Appl (c::args)
  64     ) funclass_arityl cl
  65 ;;
  66
  67 (* searches a coercion fron src to tgt in the !coercions list *)
  68 let look_for_coercion' metasenv subst context src tgt =
  69   let pp_l s l =
  70    match l with
  71    | [] ->
  72        debug_print
  73          (lazy
  74          (sprintf ":-( coercion non trovata[%s] da %s a %s" s
  75              (CoercDb.name_of_carr src)
  76              (CoercDb.name_of_carr tgt)));
  77    | _::_ ->
  78        debug_print (lazy (
  79                sprintf ":-) TROVATE[%s] %d coercion(s) da %s a %s" s
  80            (List.length l)
  81            (CoercDb.name_of_carr src)
  82            (CoercDb.name_of_carr tgt)));
  83   in
  84   try
  85     let l =
  86       CoercDb.find_coercion
  87         (fun (s,t) -> CoercDb.eq_carr s src && CoercDb.eq_carr t tgt)
  88     in
  89     pp_l "precise" l;
  90      (match l with
  91      | [] ->
  92          let l =
  93            CoercDb.find_coercion
  94              (fun (_,t) -> CoercDb.eq_carr t tgt)
  95          in
  96          pp_l "approx" l;
  97          (match l with
  98          | [] -> NoCoercion
  99          | ul -> SomeCoercionToTgt (saturate_coercion ul metasenv subst context))
 100      | ul -> SomeCoercion (saturate_coercion ul metasenv subst context))
 101   with
 102     | CoercDb.EqCarrNotImplemented s -> NotHandled s
 103     | CoercDb.EqCarrOnNonMetaClosed -> NotMetaClosed
 104 ;;
 105
 106 let look_for_coercion metasenv subst context src tgt =
 107   let src_uri = CoercDb.coerc_carr_of_term src in
 108   let tgt_uri = CoercDb.coerc_carr_of_term tgt in
 109   look_for_coercion' metasenv subst context src_uri tgt_uri
 110
 111 let source_of t =
 112   try
 113     let uri = CicUtil.uri_of_term t in
 114     CoercDb.term_of_carr (fst (CoercDb.get_carr uri))
 115   with Invalid_argument _ -> assert false (* t must be a coercion *)
 116
 117 let generate_dot_file () =
 118   let module Pp = GraphvizPp.Dot in
 119   let buf = Buffer.create 10240 in
 120   let fmt = Format.formatter_of_buffer buf in
 121   Pp.header ~node_attrs:["fontsize", "9"; "width", ".4"; "height", ".4"]
 122     ~edge_attrs:["fontsize", "10"] fmt;
 123   let l = CoercDb.to_list () in
 124   let pp_description carr =
 125     match CoercDb.uri_of_carr carr with
 126     | None -> ()
 127     | Some uri ->
 128         Pp.node (CoercDb.name_of_carr carr)
 129           ~attrs:["href", UriManager.string_of_uri uri] fmt in
 130   List.iter
 131     (fun (src, tgt, cl) ->
 132       let src_name = CoercDb.name_of_carr src in
 133       let tgt_name = CoercDb.name_of_carr tgt in
 134       pp_description src;
 135       pp_description tgt;
 136       List.iter
 137         (fun c ->
 138           Pp.edge src_name tgt_name
 139             ~attrs:[ "label", UriManager.name_of_uri c;
 140               "href", UriManager.string_of_uri c ]
 141             fmt)
 142         cl)
 143     l;
 144   Pp.trailer fmt;
 145   Buffer.contents buf
 146 ;;
 147
 148 let is_composite t =
 149   try
 150     let uri =
 151       match t with
 152       | Cic.Appl (he::_) -> CicUtil.uri_of_term he
 153       | _ -> CicUtil.uri_of_term t
 154     in
 155     match CicEnvironment.get_obj CicUniv.empty_ugraph uri with
 156     | Cic.Constant (_,_, _, _, attrs),_  ->
 157         List.exists (function `Class (`Coercion _) -> true | _ -> false) attrs
 158     | _ -> false
 159   with Invalid_argument _ -> false
 160 ;;
 161
 162 let coerced_arg l =
 163   match l with
 164   | [] | [_] -> assert false
 165   | c::_ when not (CoercDb.is_a_coercion' c) -> assert false
 166   | c::tl ->
 167      let arity =
 168        match CoercDb.is_a_coercion_to_funclass c with None -> 0 | Some a -> a
 169     in
 170     (* decide a decent structure for coercion carriers so that all this stuff is
 171      * useless *)
 172     let pi =
 173       (* this calculation is not complete, since we have strange carriers *)
 174       let rec count_pi = function
 175         | Cic.Prod(_,_,t) -> 1+ (count_pi t)
 176         | _ -> 0
 177       in
 178       let uri = CicUtil.uri_of_term c in
 179       match fst(CicEnvironment.get_obj CicUniv.empty_ugraph uri) with
 180       | Cic.Constant (_, _, ty, _, _) -> count_pi ty
 181       | _ -> assert false
 182     in
 183     try Some (List.nth tl (pi - arity)) with Invalid_argument _ -> None
 184 ;;
 185
 186 (************************* meet calculation stuff ********************)
 187 let eq_uri_opt u1 u2 =
 188   match u1,u2 with
 189   | Some u1, Some u2 -> UriManager.eq u1 u2
 190   | None,Some _ | Some _, None -> false
 191   | None, None -> true
 192 ;;
 193
 194 let eq_carr_uri (c1,u1) (c2,u2) = CoercDb.eq_carr c1 c2 && eq_uri_opt u1 u2;;
 195
 196 let eq_carr_uri_uri (c1,u1,u11) (c2,u2,u22) =
 197   CoercDb.eq_carr c1 c2 && eq_uri_opt u1 u2 && eq_uri_opt u11 u22
 198 ;;
 199
 200 let uniq = HExtlib.list_uniq ~eq:eq_carr_uri;;
 201
 202 let uniq2 = HExtlib.list_uniq ~eq:eq_carr_uri_uri;;
 203
 204 let splat e l = List.map (fun x -> e, Some x) l;;
 205
 206 (* : carr -> (carr * uri option) where the option is always Some *)
 207 let get_coercions_to carr =
 208   let l = CoercDb.to_list () in
 209   let splat_coercion_to carr (src,tgt,cl) =
 210     if CoercDb.eq_carr tgt carr then Some (splat src cl) else None
 211   in
 212   let l = List.flatten (HExtlib.filter_map (splat_coercion_to carr) l) in
 213   l
 214 ;;
 215
 216 (* : carr -> (carr * uri option) where the option is always Some *)
 217 let get_coercions_from carr =
 218   let l = CoercDb.to_list () in
 219   let splat_coercion_from carr (src,tgt,cl) =
 220     if CoercDb.eq_carr src carr then Some (splat tgt cl) else None
 221   in
 222   List.flatten (HExtlib.filter_map (splat_coercion_from carr) l)
 223 ;;
 224
 225 (* intersect { (s1,u1) | u1:s1->t1 } { (s2,u2) | u2:s2->t2 }
 226  * gives the set { (s,u1,u2) | u1:s->t1 /\ u2:s->t2 } *)
 227 let intersect l1 l2 =
 228   let is_in_l1 (x,u2) =
 229     HExtlib.filter_map
 230       (fun (src,u1) ->
 231          if CoercDb.eq_carr x src then Some (src,u1,u2) else None)
 232     l1
 233   in
 234   uniq2 (List.flatten (List.map is_in_l1 l2))
 235 ;;
 236
 237 (* grow tgt gives all the (src,u) such that u:tgt->src *)
 238 let grow tgt =
 239   uniq ((tgt,None)::(get_coercions_to tgt))
 240 ;;
 241
 242 let lb (c,_,_) =
 243   let l = get_coercions_from c in
 244   fun (x,_,_) -> List.exists (fun (y,_) -> CoercDb.eq_carr x y) l
 245 ;;
 246
 247 (* given the set { (s,u1,u2) | u1:s->t1 /\ u2:s->t2 } removes the elements
 248  * (s,_,_) such that (s',_,_) is in the set and there exists a coercion s->s' *)
 249 let rec min acc = function
 250   | c::tl ->
 251     if List.exists (lb c) (tl@acc) then min acc tl else min (c::acc) tl
 252   | [] -> acc
 253 ;;
 254
 255 let meets metasenv subst context left right =
 256   let saturate metasenv uo =
 257     match uo with
 258     | None -> metasenv, None
 259     | Some u ->
 260         match saturate_coercion [u] metasenv subst context with
 261         | [metasenv, sat, last] -> metasenv, Some (sat, last)
 262         | _ -> assert false
 263   in
 264   List.map
 265     (fun (c,uo1,uo2) ->
 266       let metasenv, uo1 = saturate metasenv uo1 in
 267       let metasenv, uo2 = saturate metasenv uo2 in
 268       c,metasenv, uo1, uo2)
 269     (min [] (intersect (grow left) (grow right)))
 270 ;;
 271
 272 (* EOF *)