components/content_pres/proceduralTypes.ml

   1 (* Copyright (C) 2003-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 module H = HExtlib
  27 module C = Cic
  28 module G = GrafiteAst
  29 module N = CicNotationPt
  30
  31 (* functions to be moved ****************************************************)
  32
  33 let list_map2_filter map l1 l2 =
  34    let rec filter l = function
  35       | []           -> l
  36       | None :: tl   -> filter l tl
  37       | Some a :: tl -> filter (a :: l) tl
  38   in
  39   filter [] (List.rev_map2 map l1 l2)
  40
  41 let rec list_split n l =
  42    if n = 0 then [], l else
  43    let l1, l2 = list_split (pred n) (List.tl l) in
  44    List.hd l :: l1, l2
  45
  46 let cont sep a = match sep with
  47    | None     -> a
  48    | Some sep -> sep :: a
  49
  50 let list_rev_map_concat map sep a l =
  51    let rec aux a = function
  52       | []          -> a
  53       | [x]         -> map a x
  54       | x :: y :: l -> aux (sep :: map a x) (y :: l)
  55    in
  56    aux a l
  57
  58 (****************************************************************************)
  59
  60 type name  = string
  61 type what  = Cic.annterm
  62 type how   = bool
  63 type using = Cic.annterm
  64 type count = int
  65 type note  = string
  66 type where = (name * name) option
  67
  68 type step = Note of note
  69           | Theorem of name * what * note
  70           | Qed of note
  71           | Id of note
  72           | Intros of count option * name list * note
  73           | Cut of name * what * note
  74           | LetIn of name * what * note
  75           | Rewrite of how * what * where * note
  76           | Elim of what * using option * note
  77           | Apply of what * note
  78           | Branch of step list list * note
  79
  80 (* annterm constructors *****************************************************)
  81
  82 let mk_arel i b = Cic.ARel ("", "", i, b)
  83
  84 (* grafite ast constructors *************************************************)
  85
  86 let floc = H.dummy_floc
  87
  88 let mk_note str = G.Comment (floc, G.Note (floc, str))
  89
  90 let mk_theorem name t =
  91    let obj = N.Theorem (`Theorem, name, t, None) in
  92    G.Executable (floc, G.Command (floc, G.Obj (floc, obj)))
  93
  94 let mk_qed =
  95    G.Executable (floc, G.Command (floc, G.Qed floc))
  96
  97 let mk_tactic tactic =
  98    G.Executable (floc, G.Tactical (floc, G.Tactic (floc, tactic), None))
  99
 100 let mk_id =
 101    let tactic = G.IdTac floc in
 102    mk_tactic tactic
 103
 104 let mk_intros xi ids =
 105    let tactic = G.Intros (floc, xi, ids) in
 106    mk_tactic tactic
 107
 108 let mk_cut name what =
 109    let tactic = G.Cut (floc, Some name, what) in
 110    mk_tactic tactic
 111
 112 let mk_letin name what =
 113    let tactic = G.LetIn (floc, what, name) in
 114    mk_tactic tactic
 115
 116 let mk_rewrite direction what where =
 117    let hole = C.AImplicit ("", Some `Hole) in
 118    let direction = if direction then `RightToLeft else `LeftToRight in
 119    let pattern, rename = match where with
 120       | None                 -> (None, [], Some hole), []
 121       | Some (premise, name) -> (None, [premise, hole], None), [name]
 122    in
 123    let tactic = G.Rewrite (floc, direction, what, pattern, rename) in
 124    mk_tactic tactic
 125
 126 let mk_elim what using =
 127    let tactic = G.Elim (floc, what, using, Some 0, []) in
 128    mk_tactic tactic
 129
 130 let mk_apply t =
 131    let tactic = G.Apply (floc, t) in
 132    mk_tactic tactic
 133
 134 let mk_dot = G.Executable (floc, G.Tactical (floc, G.Dot floc, None))
 135
 136 let mk_sc = G.Executable (floc, G.Tactical (floc, G.Semicolon floc, None))
 137
 138 let mk_ob = G.Executable (floc, G.Tactical (floc, G.Branch floc, None))
 139
 140 let mk_cb = G.Executable (floc, G.Tactical (floc, G.Merge floc, None))
 141
 142 let mk_vb = G.Executable (floc, G.Tactical (floc, G.Shift floc, None))
 143
 144 (* rendering ****************************************************************)
 145
 146 let rec render_step sep a = function
 147    | Note s               -> mk_note s :: a
 148    | Theorem (n, t, s)    -> mk_note s :: mk_theorem n t :: a
 149    | Qed s                -> mk_note s :: mk_qed :: a
 150    | Id s                 -> mk_note s :: cont sep (mk_id :: a)
 151    | Intros (c, ns, s)    -> mk_note s :: cont sep (mk_intros c ns :: a)
 152    | Cut (n, t, s)        -> mk_note s :: cont sep (mk_cut n t :: a)
 153    | LetIn (n, t, s)      -> mk_note s :: cont sep (mk_letin n t :: a)
 154    | Rewrite (b, t, w, s) -> mk_note s :: cont sep (mk_rewrite b t w :: a)
 155    | Elim (t, xu, s)      -> mk_note s :: cont sep (mk_elim t xu :: a)
 156    | Apply (t, s)         -> mk_note s :: cont sep (mk_apply t :: a)
 157    | Branch ([], s)       -> a
 158    | Branch ([ps], s)     -> render_steps a ps
 159    | Branch (pss, s)      ->
 160       let a =  mk_ob :: a in
 161       let body = mk_cb :: list_rev_map_concat render_steps mk_vb a pss in
 162       mk_note s :: cont sep body
 163
 164 and render_steps a = function
 165    | []                                          -> a
 166    | [p]                                         -> render_step None a p
 167    | (Note _ | Theorem _ | Qed _ as p) :: ps     ->
 168       render_steps (render_step None a p) ps
 169    | p :: ((Branch ([], _) :: _) as ps) ->
 170       render_steps (render_step None a p) ps
 171    | p :: ((Branch (_ :: _ :: _, _) :: _) as ps) ->
 172       render_steps (render_step (Some mk_sc) a p) ps
 173    | p :: ps                                     ->
 174       render_steps (render_step (Some mk_dot) a p) ps
 175
 176 (* counting *****************************************************************)
 177
 178 let rec count_step a = function
 179    | Note _
 180    | Theorem _
 181    | Qed _           -> a
 182    | Branch (pps, _) -> List.fold_left count_steps a pps
 183    | _               -> succ a
 184
 185 and count_steps a = List.fold_left count_step a