components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     let before = Unix.gettimeofday () in
  56     try
  57      incr calls;
  58      let res = f x in
  59      let after = Unix.gettimeofday () in
  60      let delta = after -. before in
  61       total := !total +. delta;
  62       if delta > !max then max := delta;
  63       res
  64     with
  65      exc ->
  66       let after = Unix.gettimeofday () in
  67       let delta = after -. before in
  68        total := !total +. delta;
  69        if delta > !max then max := delta;
  70        raise exc
  71    in
  72    at_exit
  73     (fun () ->
  74       if !profiling_printings s && !calls <> 0 then
  75        begin
  76         something_profiled := true;
  77         prerr_endline
  78          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  79          s !calls !total !max (!total /. (float_of_int !calls)))
  80        end);
  81    { profile = profile }
  82  else
  83    { profile = fun f x -> f x }
  84
  85 (** {2 Optional values} *)
  86
  87 let map_option f = function None -> None | Some v -> Some (f v)
  88 let iter_option f = function None -> () | Some v -> f v
  89 let unopt = function None -> failwith "unopt: None" | Some v -> v
  90
  91 (** {2 String processing} *)
  92
  93 let split ?(sep = ' ') s =
  94   let pieces = ref [] in
  95   let rec aux idx =
  96     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  97     | Some pos ->
  98         pieces := String.sub s idx (pos - idx) :: !pieces;
  99         aux (pos + 1)
 100     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 101   in
 102   aux 0;
 103   List.rev !pieces
 104
 105 let trim_blanks s =
 106   let rec find_left idx =
 107     match s.[idx] with
 108     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 109     | _ -> idx
 110   in
 111   let rec find_right idx =
 112     match s.[idx] with
 113     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 114     | _ -> idx
 115   in
 116   let s_len = String.length s in
 117   let left, right = find_left 0, find_right (s_len - 1) in
 118   String.sub s left (right - left + 1)
 119
 120 (** {2 Char processing} *)
 121
 122 let is_alpha c =
 123   let code = Char.code c in
 124   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 125
 126 let is_digit c =
 127   let code = Char.code c in
 128   code >= 48 && code <= 57
 129
 130 let is_blank c =
 131   let code = Char.code c in
 132   code = 9 || code = 10 || code = 13 || code = 32
 133
 134 let is_alphanum c = is_alpha c || is_digit c
 135
 136 (** {2 List processing} *)
 137
 138 let flatten_map f l =
 139   List.flatten (List.map f l)
 140 ;;
 141
 142 let rec list_uniq ?(eq=(=)) = function
 143   | [] -> []
 144   | h::[] -> [h]
 145   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 146   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 147
 148 let rec filter_map f =
 149   function
 150   | [] -> []
 151   | hd :: tl ->
 152       (match f hd with
 153       | None -> filter_map f tl
 154       | Some v -> v :: filter_map f tl)
 155
 156 let list_concat ?(sep = []) =
 157   let rec aux acc =
 158     function
 159     | [] -> []
 160     | [ last ] -> List.flatten (List.rev (last :: acc))
 161     | hd :: tl -> aux ([sep; hd] @ acc) tl
 162   in
 163   aux []
 164
 165 let rec list_findopt f l =
 166   let rec aux = function
 167     | [] -> None
 168     | x::tl ->
 169         (match f x with
 170         | None -> aux tl
 171         | Some _ as rc -> rc)
 172   in
 173   aux l
 174
 175 (** {2 File predicates} *)
 176
 177 let is_dir fname =
 178   try
 179     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 180   with Unix.Unix_error _ -> false
 181
 182 let is_regular fname =
 183   try
 184     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 185   with Unix.Unix_error _ -> false
 186
 187 let mkdir path =
 188   let components = split ~sep:'/' path in
 189   let rec aux where = function
 190     | [] -> ()
 191     | piece::tl ->
 192         let path =
 193           if where = "" then piece else where ^ "/" ^ piece in
 194         (try
 195           Unix.mkdir path 0o755
 196         with
 197         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 198         | Unix.Unix_error (e,_,_) ->
 199             raise
 200               (Failure
 201                 ("Unix.mkdir " ^ path ^ " 0o755 :" ^ (Unix.error_message e))));
 202         aux path tl
 203   in
 204   let where = if path.[0] = '/' then "/" else "" in
 205   aux where components
 206
 207 (** {2 Filesystem} *)
 208
 209 let input_file fname =
 210   let size = (Unix.stat fname).Unix.st_size in
 211   let buf = Buffer.create size in
 212   let ic = open_in fname in
 213   Buffer.add_channel buf ic size;
 214   close_in ic;
 215   Buffer.contents buf
 216
 217 let input_all ic =
 218   let size = 10240 in
 219   let buf = Buffer.create size in
 220   let s = String.create size in
 221   (try
 222     while true do
 223       let bytes = input ic s 0 size in
 224       if bytes = 0 then raise End_of_file
 225       else Buffer.add_substring buf s 0 bytes
 226     done
 227   with End_of_file -> ());
 228   Buffer.contents buf
 229
 230 let output_file ~filename ~text =
 231   let oc = open_out filename in
 232   output_string oc text;
 233   close_out oc
 234
 235 let blank_split s =
 236   let len = String.length s in
 237   let buf = Buffer.create 0 in
 238   let rec aux acc i =
 239     if i >= len
 240     then begin
 241       if Buffer.length buf > 0
 242       then List.rev (Buffer.contents buf :: acc)
 243       else List.rev acc
 244     end else begin
 245       if is_blank s.[i] then
 246         if Buffer.length buf > 0 then begin
 247           let s = Buffer.contents buf in
 248           Buffer.clear buf;
 249           aux (s :: acc) (i + 1)
 250         end else
 251           aux acc (i + 1)
 252       else begin
 253         Buffer.add_char buf s.[i];
 254         aux acc (i + 1)
 255       end
 256     end
 257   in
 258   aux [] 0
 259
 260   (* Rules: * "~name" -> home dir of "name"
 261    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 262 let tilde_expand s =
 263   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 264   let expand_one s =
 265     let len = String.length s in
 266     if len > 0 && s.[0] = '~' then begin
 267       let login_len = ref 1 in
 268       while !login_len < len && is_alphanum (s.[!login_len]) do
 269         incr login_len
 270       done;
 271       let login = String.sub s 1 (!login_len - 1) in
 272       try
 273         let home =
 274           if login = "" then
 275             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 276           else
 277             get_home login
 278         in
 279         home ^ String.sub s !login_len (len - !login_len)
 280       with Not_found | Invalid_argument _ -> s
 281     end else
 282       s
 283   in
 284   String.concat " " (List.map expand_one (blank_split s))
 285
 286 let find ?(test = fun _ -> true) path =
 287   let rec aux acc todo =
 288     match todo with
 289     | [] -> acc
 290     | path :: tl ->
 291         try
 292           let handle = Unix.opendir path in
 293           let dirs = ref [] in
 294           let matching_files = ref [] in
 295           (try
 296             while true do
 297               match Unix.readdir handle with
 298               | "." | ".." -> ()
 299               | entry ->
 300                   let qentry = path ^ "/" ^ entry in
 301                   (try
 302                     if is_dir qentry then
 303                       dirs := qentry :: !dirs
 304                     else if test qentry then
 305                       matching_files := qentry :: !matching_files;
 306                   with Unix.Unix_error _ -> ())
 307             done
 308           with End_of_file -> Unix.closedir handle);
 309           aux (!matching_files @ acc) (!dirs @ tl)
 310         with Unix.Unix_error _ -> aux acc tl
 311   in
 312   aux [] [path]
 313
 314 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 315
 316 let is_dir_empty d =
 317  try
 318   let od = Unix.opendir d in
 319   let rec aux () =
 320    let name = Unix.readdir od in
 321    if name <> "." && name <> ".." then false else aux () in
 322   let res = try aux () with End_of_file -> true in
 323    Unix.closedir od;
 324    res
 325  with
 326   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 327
 328 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 329
 330 let rec rmdir_descend d =
 331   if is_dir_empty d then
 332     begin
 333       safe_rmdir d;
 334       rmdir_descend (Filename.dirname d)
 335     end
 336
 337
 338 (** {2 Exception handling} *)
 339
 340 let finally at_end f arg =
 341   let res =
 342     try f arg
 343     with exn -> at_end (); raise exn
 344   in
 345   at_end ();
 346   res
 347
 348 (** {2 Localized exceptions } *)
 349
 350 exception Localized of Token.flocation * exn
 351
 352 let loc_of_floc = function
 353   | { Lexing.pos_cnum = loc_begin }, { Lexing.pos_cnum = loc_end } ->
 354       (loc_begin, loc_end)
 355
 356 let floc_of_loc (loc_begin, loc_end) =
 357   let floc_begin =
 358     { Lexing.pos_fname = ""; Lexing.pos_lnum = -1; Lexing.pos_bol = -1;
 359       Lexing.pos_cnum = loc_begin }
 360   in
 361   let floc_end = { floc_begin with Lexing.pos_cnum = loc_end } in
 362   (floc_begin, floc_end)
 363
 364 let dummy_floc = floc_of_loc (-1, -1)
 365
 366 let raise_localized_exception ~offset floc exn =
 367  let (x, y) = loc_of_floc floc in
 368  let x = offset + x in
 369  let y = offset + y in
 370  let flocb,floce = floc in
 371  let floc =
 372    { flocb with Lexing.pos_cnum = x }, { floce with Lexing.pos_cnum = y }
 373  in
 374   raise (Localized (floc, exn))
 375
 376 let estimate_size x =
 377   4 * (String.length (Marshal.to_string x [])) / 1024
 378