components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     let before = Unix.gettimeofday () in
  56     try
  57      incr calls;
  58      let res = f x in
  59      let after = Unix.gettimeofday () in
  60      let delta = after -. before in
  61       total := !total +. delta;
  62       if delta > !max then max := delta;
  63       res
  64     with
  65      exc ->
  66       let after = Unix.gettimeofday () in
  67       let delta = after -. before in
  68        total := !total +. delta;
  69        if delta > !max then max := delta;
  70        raise exc
  71    in
  72    at_exit
  73     (fun () ->
  74       if !profiling_printings s && !calls <> 0 then
  75        begin
  76         something_profiled := true;
  77         prerr_endline
  78          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  79          s !calls !total !max (!total /. (float_of_int !calls)))
  80        end);
  81    { profile = profile }
  82  else
  83    { profile = fun f x -> f x }
  84
  85 (** {2 Optional values} *)
  86
  87 let map_option f = function None -> None | Some v -> Some (f v)
  88 let iter_option f = function None -> () | Some v -> f v
  89 let unopt = function None -> failwith "unopt: None" | Some v -> v
  90
  91 (** {2 String processing} *)
  92
  93 let split ?(sep = ' ') s =
  94   let pieces = ref [] in
  95   let rec aux idx =
  96     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  97     | Some pos ->
  98         pieces := String.sub s idx (pos - idx) :: !pieces;
  99         aux (pos + 1)
 100     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 101   in
 102   aux 0;
 103   List.rev !pieces
 104
 105 let trim_blanks s =
 106   let rec find_left idx =
 107     match s.[idx] with
 108     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 109     | _ -> idx
 110   in
 111   let rec find_right idx =
 112     match s.[idx] with
 113     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 114     | _ -> idx
 115   in
 116   let s_len = String.length s in
 117   let left, right = find_left 0, find_right (s_len - 1) in
 118   String.sub s left (right - left + 1)
 119
 120 (** {2 Char processing} *)
 121
 122 let is_alpha c =
 123   let code = Char.code c in
 124   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 125
 126 let is_digit c =
 127   let code = Char.code c in
 128   code >= 48 && code <= 57
 129
 130 let is_blank c =
 131   let code = Char.code c in
 132   code = 9 || code = 10 || code = 13 || code = 32
 133
 134 let is_alphanum c = is_alpha c || is_digit c
 135
 136 (** {2 List processing} *)
 137
 138 let flatten_map f l =
 139   List.flatten (List.map f l)
 140 ;;
 141
 142 let rec list_uniq ?(eq=(=)) = function
 143   | [] -> []
 144   | h::[] -> [h]
 145   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 146   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 147
 148 let rec filter_map f =
 149   function
 150   | [] -> []
 151   | hd :: tl ->
 152       (match f hd with
 153       | None -> filter_map f tl
 154       | Some v -> v :: filter_map f tl)
 155
 156 let list_rev_map_filter f l =
 157    let rec aux a = function
 158       | []       -> a
 159       | hd :: tl ->
 160          begin match f hd with
 161             | None   -> aux a tl
 162             | Some b -> aux (b :: a) tl
 163          end
 164    in
 165    aux [] l
 166
 167 let list_concat ?(sep = []) =
 168   let rec aux acc =
 169     function
 170     | [] -> []
 171     | [ last ] -> List.flatten (List.rev (last :: acc))
 172     | hd :: tl -> aux ([sep; hd] @ acc) tl
 173   in
 174   aux []
 175
 176 let rec list_findopt f l =
 177   let rec aux = function
 178     | [] -> None
 179     | x::tl ->
 180         (match f x with
 181         | None -> aux tl
 182         | Some _ as rc -> rc)
 183   in
 184   aux l
 185
 186 let split_nth n l =
 187   let rec aux acc n l =
 188     match n, l with
 189     | 0, _ -> List.rev acc, l
 190     | n, [] -> raise (Failure "HExtlib.split_nth")
 191     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 192   aux [] n l
 193
 194 let list_last l =
 195   let l = List.rev l in
 196   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 197 ;;
 198
 199 (** {2 File predicates} *)
 200
 201 let is_dir fname =
 202   try
 203     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 204   with Unix.Unix_error _ -> false
 205
 206 let is_regular fname =
 207   try
 208     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 209   with Unix.Unix_error _ -> false
 210
 211 let mkdir path =
 212   let components = split ~sep:'/' path in
 213   let rec aux where = function
 214     | [] -> ()
 215     | piece::tl ->
 216         let path =
 217           if where = "" then piece else where ^ "/" ^ piece in
 218         (try
 219           Unix.mkdir path 0o755
 220         with
 221         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 222         | Unix.Unix_error (e,_,_) ->
 223             raise
 224               (Failure
 225                 ("Unix.mkdir " ^ path ^ " 0o755 :" ^ (Unix.error_message e))));
 226         aux path tl
 227   in
 228   let where = if path.[0] = '/' then "/" else "" in
 229   aux where components
 230
 231 (** {2 Filesystem} *)
 232
 233 let input_file fname =
 234   let size = (Unix.stat fname).Unix.st_size in
 235   let buf = Buffer.create size in
 236   let ic = open_in fname in
 237   Buffer.add_channel buf ic size;
 238   close_in ic;
 239   Buffer.contents buf
 240
 241 let input_all ic =
 242   let size = 10240 in
 243   let buf = Buffer.create size in
 244   let s = String.create size in
 245   (try
 246     while true do
 247       let bytes = input ic s 0 size in
 248       if bytes = 0 then raise End_of_file
 249       else Buffer.add_substring buf s 0 bytes
 250     done
 251   with End_of_file -> ());
 252   Buffer.contents buf
 253
 254 let output_file ~filename ~text =
 255   let oc = open_out filename in
 256   output_string oc text;
 257   close_out oc
 258
 259 let blank_split s =
 260   let len = String.length s in
 261   let buf = Buffer.create 0 in
 262   let rec aux acc i =
 263     if i >= len
 264     then begin
 265       if Buffer.length buf > 0
 266       then List.rev (Buffer.contents buf :: acc)
 267       else List.rev acc
 268     end else begin
 269       if is_blank s.[i] then
 270         if Buffer.length buf > 0 then begin
 271           let s = Buffer.contents buf in
 272           Buffer.clear buf;
 273           aux (s :: acc) (i + 1)
 274         end else
 275           aux acc (i + 1)
 276       else begin
 277         Buffer.add_char buf s.[i];
 278         aux acc (i + 1)
 279       end
 280     end
 281   in
 282   aux [] 0
 283
 284   (* Rules: * "~name" -> home dir of "name"
 285    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 286 let tilde_expand s =
 287   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 288   let expand_one s =
 289     let len = String.length s in
 290     if len > 0 && s.[0] = '~' then begin
 291       let login_len = ref 1 in
 292       while !login_len < len && is_alphanum (s.[!login_len]) do
 293         incr login_len
 294       done;
 295       let login = String.sub s 1 (!login_len - 1) in
 296       try
 297         let home =
 298           if login = "" then
 299             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 300           else
 301             get_home login
 302         in
 303         home ^ String.sub s !login_len (len - !login_len)
 304       with Not_found | Invalid_argument _ -> s
 305     end else
 306       s
 307   in
 308   String.concat " " (List.map expand_one (blank_split s))
 309
 310 let find ?(test = fun _ -> true) path =
 311   let rec aux acc todo =
 312     match todo with
 313     | [] -> acc
 314     | path :: tl ->
 315         try
 316           let handle = Unix.opendir path in
 317           let dirs = ref [] in
 318           let matching_files = ref [] in
 319           (try
 320             while true do
 321               match Unix.readdir handle with
 322               | "." | ".." -> ()
 323               | entry ->
 324                   let qentry = path ^ "/" ^ entry in
 325                   (try
 326                     if is_dir qentry then
 327                       dirs := qentry :: !dirs
 328                     else if test qentry then
 329                       matching_files := qentry :: !matching_files;
 330                   with Unix.Unix_error _ -> ())
 331             done
 332           with End_of_file -> Unix.closedir handle);
 333           aux (!matching_files @ acc) (!dirs @ tl)
 334         with Unix.Unix_error _ -> aux acc tl
 335   in
 336   aux [] [path]
 337
 338 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 339
 340 let is_dir_empty d =
 341  try
 342   let od = Unix.opendir d in
 343   let rec aux () =
 344    let name = Unix.readdir od in
 345    if name <> "." && name <> ".." then false else aux () in
 346   let res = try aux () with End_of_file -> true in
 347    Unix.closedir od;
 348    res
 349  with
 350   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 351
 352 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 353
 354 let rec rmdir_descend d =
 355   if is_dir_empty d then
 356     begin
 357       safe_rmdir d;
 358       rmdir_descend (Filename.dirname d)
 359     end
 360
 361
 362 (** {2 Exception handling} *)
 363
 364 let finally at_end f arg =
 365   let res =
 366     try f arg
 367     with exn -> at_end (); raise exn
 368   in
 369   at_end ();
 370   res
 371
 372 (** {2 Localized exceptions } *)
 373
 374 exception Localized of Token.flocation * exn
 375
 376 let loc_of_floc = function
 377   | { Lexing.pos_cnum = loc_begin }, { Lexing.pos_cnum = loc_end } ->
 378       (loc_begin, loc_end)
 379
 380 let floc_of_loc (loc_begin, loc_end) =
 381   let floc_begin =
 382     { Lexing.pos_fname = ""; Lexing.pos_lnum = -1; Lexing.pos_bol = -1;
 383       Lexing.pos_cnum = loc_begin }
 384   in
 385   let floc_end = { floc_begin with Lexing.pos_cnum = loc_end } in
 386   (floc_begin, floc_end)
 387
 388 let dummy_floc = floc_of_loc (-1, -1)
 389
 390 let raise_localized_exception ~offset floc exn =
 391  let (x, y) = loc_of_floc floc in
 392  let x = offset + x in
 393  let y = offset + y in
 394  let flocb,floce = floc in
 395  let floc =
 396    { flocb with Lexing.pos_cnum = x }, { floce with Lexing.pos_cnum = y }
 397  in
 398   raise (Localized (floc, exn))
 399
 400 let estimate_size x =
 401   4 * (String.length (Marshal.to_string x [])) / 1024
 402