components/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 open GrafiteAst
  31
  32 let tactical_terminator = ""
  33 let tactic_terminator = tactical_terminator
  34 let command_terminator = tactical_terminator
  35
  36 let pp_idents idents = "[" ^ String.concat "; " idents ^ "]"
  37
  38 let pp_reduction_kind ~term_pp = function
  39   | `Demodulate -> "demodulate"
  40   | `Normalize -> "normalize"
  41   | `Reduce -> "reduce"
  42   | `Simpl -> "simplify"
  43   | `Unfold (Some t) -> "unfold " ^ term_pp t
  44   | `Unfold None -> "unfold"
  45   | `Whd -> "whd"
  46
  47 let pp_tactic_pattern ~term_pp ~lazy_term_pp (what, hyp, goal) =
  48   let what_text =
  49     match what with
  50     | None -> ""
  51     | Some t -> sprintf "in match (%s) " (lazy_term_pp t) in
  52   let hyp_text =
  53     String.concat " "
  54       (List.map (fun (name, p) -> sprintf "%s:(%s)" name (term_pp p)) hyp) in
  55   let goal_text =
  56     match goal with
  57     | None -> ""
  58     | Some t -> sprintf "\\vdash (%s)" (term_pp t) in
  59   sprintf "%sin %s%s" what_text hyp_text goal_text
  60
  61 let pp_intros_specs = function
  62    | None, []         -> ""
  63    | Some num, []     -> Printf.sprintf " names %i" num
  64    | None, idents     -> Printf.sprintf " names %s" (pp_idents idents)
  65    | Some num, idents -> Printf.sprintf " names %i %s" num (pp_idents idents)
  66
  67 let terms_pp ~term_pp terms = String.concat ", " (List.map term_pp terms)
  68
  69 let rec pp_tactic ~term_pp ~lazy_term_pp =
  70   let pp_reduction_kind = pp_reduction_kind ~term_pp in
  71   let pp_tactic_pattern = pp_tactic_pattern ~lazy_term_pp ~term_pp in
  72   function
  73   | Absurd (_, term) -> "absurd" ^ term_pp term
  74   | Apply (_, term) -> "apply " ^ term_pp term
  75   | Auto (_,_,_,Some kind,_) -> "auto " ^ kind
  76   | Auto _ -> "auto"
  77   | Assumption _ -> "assumption"
  78   | Change (_, where, with_what) ->
  79       sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
  80   | Clear (_,id) -> sprintf "clear %s" id
  81   | ClearBody (_,id) -> sprintf "clearbody %s" id
  82   | Constructor (_,n) -> "constructor " ^ string_of_int n
  83   | Contradiction _ -> "contradiction"
  84   | Cut (_, ident, term) ->
  85      "cut " ^ term_pp term ^
  86       (match ident with None -> "" | Some id -> " as " ^ id)
  87   | Decompose (_, [], what, names) ->
  88       sprintf "decompose %s%s" what (pp_intros_specs (None, names))
  89   | Decompose (_, types, what, names) ->
  90       let to_ident = function
  91          | Ident id -> id
  92          | Type _   -> assert false
  93       in
  94       let types = List.rev_map to_ident types in
  95       sprintf "decompose %s %s%s" (pp_idents types) what (pp_intros_specs (None, names))
  96   | Discriminate (_, term) -> "discriminate " ^ term_pp term
  97   | Elim (_, term, using, num, idents) ->
  98       sprintf "elim " ^ term_pp term ^
  99       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 100       ^ pp_intros_specs (num, idents)
 101   | ElimType (_, term, using, num, idents) ->
 102       sprintf "elim type " ^ term_pp term ^
 103       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 104       ^ pp_intros_specs (num, idents)
 105   | Exact (_, term) -> "exact " ^ term_pp term
 106   | Exists _ -> "exists"
 107   | Fold (_, kind, term, pattern) ->
 108       sprintf "fold %s %s %s" (pp_reduction_kind kind)
 109        (lazy_term_pp term) (pp_tactic_pattern pattern)
 110   | FwdSimpl (_, hyp, idents) ->
 111       sprintf "fwd %s%s" hyp
 112         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 113   | Generalize (_, pattern, ident) ->
 114      sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 115       (match ident with None -> "" | Some id -> " as " ^ id)
 116   | Goal (_, n) -> "goal " ^ string_of_int n
 117   | Fail _ -> "fail"
 118   | Fourier _ -> "fourier"
 119   | IdTac _ -> "id"
 120   | Injection (_, term) -> "injection " ^ term_pp term
 121   | Intros (_, None, []) -> "intros"
 122   | Inversion (_, term) -> "inversion " ^ term_pp term
 123   | Intros (_, num, idents) ->
 124       sprintf "intros%s%s"
 125         (match num with None -> "" | Some num -> " " ^ string_of_int num)
 126         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 127   | LApply (_, level_opt, terms, term, ident_opt) ->
 128       sprintf "lapply %s%s%s%s"
 129         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 130         (term_pp term)
 131         (match terms with [] -> "" | _ -> " to " ^ terms_pp ~term_pp terms)
 132         (match ident_opt with None -> "" | Some ident -> " as " ^ ident)
 133   | Left _ -> "left"
 134   | LetIn (_, term, ident) -> sprintf "let %s in %s" (term_pp term) ident
 135   | Reduce (_, kind, pat) ->
 136       sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 137   | Reflexivity _ -> "reflexivity"
 138   | Replace (_, pattern, t) ->
 139       sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 140   | Rewrite (_, pos, t, pattern) ->
 141       sprintf "rewrite %s %s %s"
 142         (if pos = `LeftToRight then ">" else "<")
 143         (term_pp t)
 144         (pp_tactic_pattern pattern)
 145   | Right _ -> "right"
 146   | Ring _ -> "ring"
 147   | Split _ -> "split"
 148   | Symmetry _ -> "symmetry"
 149   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 150
 151 let pp_search_kind = function
 152   | `Locate -> "locate"
 153   | `Hint -> "hint"
 154   | `Match -> "match"
 155   | `Elim -> "elim"
 156   | `Instance -> "instance"
 157
 158 let pp_arg ~term_pp arg =
 159   let s = term_pp arg in
 160    if s = "" || (s.[0] = '(' && s.[String.length s - 1] = ')') then
 161      (* _nice_ heuristic *)
 162      s
 163    else
 164      "(" ^ s ^ ")"
 165
 166 let pp_macro ~term_pp =
 167   let term_pp = pp_arg ~term_pp in
 168   function
 169   (* Whelp *)
 170   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 171   | WHint (_, t) -> "whelp hint " ^ term_pp t
 172   | WLocate (_, s) -> "whelp locate \"" ^ s ^ "\""
 173   | WElim (_, t) -> "whelp elim " ^ term_pp t
 174   | WMatch (_, term) -> "whelp match " ^ term_pp term
 175   (* real macros *)
 176   | Check (_, term) -> sprintf "Check %s" (term_pp term)
 177   | Hint _ -> "hint"
 178   | Search_pat (_, kind, pat) ->
 179       sprintf "search %s \"%s\"" (pp_search_kind kind) pat
 180   | Search_term (_, kind, term) ->
 181       sprintf "search %s %s" (pp_search_kind kind) (term_pp term)
 182   | Print (_, name) -> sprintf "Print \"%s\"" name
 183   | Quit _ -> "Quit"
 184
 185 let pp_associativity = function
 186   | Gramext.LeftA -> "left associative"
 187   | Gramext.RightA -> "right associative"
 188   | Gramext.NonA -> "non associative"
 189
 190 let pp_precedence i = sprintf "with precedence %d" i
 191
 192 let pp_dir_opt = function
 193   | None -> ""
 194   | Some `LeftToRight -> "> "
 195   | Some `RightToLeft -> "< "
 196
 197 let pp_default what uris =
 198   sprintf "default \"%s\" %s" what
 199     (String.concat " " (List.map UriManager.string_of_uri uris))
 200
 201 let pp_coercion uri do_composites =
 202    sprintf "coercion %s (* %s *)" (UriManager.string_of_uri uri)
 203      (if do_composites then "compounds" else "no compounds")
 204
 205 let pp_command ~obj_pp = function
 206   | Include (_,path) -> "include \"" ^ path ^ "\""
 207   | Qed _ -> "qed"
 208   | Drop _ -> "drop"
 209   | Set (_, name, value) -> sprintf "set \"%s\" \"%s\"" name value
 210   | Coercion (_, uri, do_composites) -> pp_coercion uri do_composites
 211   | Obj (_,obj) -> obj_pp obj
 212   | Default (_,what,uris) ->
 213       pp_default what uris
 214
 215 let rec pp_tactical ~term_pp ~lazy_term_pp =
 216   let pp_tactic = pp_tactic ~lazy_term_pp ~term_pp in
 217   let pp_tacticals = pp_tacticals ~lazy_term_pp ~term_pp in
 218   function
 219   | Tactic (_, tac) -> pp_tactic tac
 220   | Do (_, count, tac) ->
 221       sprintf "do %d %s" count (pp_tactical ~term_pp ~lazy_term_pp tac)
 222   | Repeat (_, tac) -> "repeat " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 223   | Seq (_, tacs) -> pp_tacticals ~sep:"; " tacs
 224   | Then (_, tac, tacs) ->
 225       sprintf "%s; [%s]" (pp_tactical ~term_pp ~lazy_term_pp tac)
 226         (pp_tacticals ~sep:" | " tacs)
 227   | First (_, tacs) -> sprintf "tries [%s]" (pp_tacticals ~sep:" | " tacs)
 228   | Try (_, tac) -> "try " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 229   | Solve (_, tac) -> sprintf "solve [%s]" (pp_tacticals ~sep:" | " tac)
 230
 231   | Dot _ -> "."
 232   | Semicolon _ -> ";"
 233   | Branch _ -> "["
 234   | Shift _ -> "|"
 235   | Pos (_, i) -> sprintf "%s:" (String.concat "," (List.map string_of_int i))
 236   | Wildcard _ -> "*:"
 237   | Merge _ -> "]"
 238   | Focus (_, goals) ->
 239       sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 240   | Unfocus _ -> "unfocus"
 241   | Skip _ -> "skip"
 242
 243 and pp_tacticals ~term_pp ~lazy_term_pp ~sep tacs =
 244   String.concat sep (List.map (pp_tactical~lazy_term_pp ~term_pp) tacs)
 245
 246 let pp_executable ~term_pp ~lazy_term_pp ~obj_pp =
 247   function
 248   | Macro (_, macro) -> pp_macro ~term_pp macro ^ "."
 249   | Tactical (_, tac, Some punct) ->
 250       pp_tactical ~lazy_term_pp ~term_pp tac
 251       ^ pp_tactical ~lazy_term_pp ~term_pp punct
 252   | Tactical (_, tac, None) -> pp_tactical ~lazy_term_pp ~term_pp tac
 253   | Command (_, cmd) -> pp_command ~obj_pp cmd ^ "."
 254
 255 let pp_comment ~term_pp ~lazy_term_pp ~obj_pp =
 256   function
 257   | Note (_,str) -> sprintf "(* %s *)" str
 258   | Code (_,code) ->
 259       sprintf "(** %s. **)" (pp_executable ~term_pp ~lazy_term_pp ~obj_pp code)
 260
 261 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 262   function
 263   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 264   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c