components/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 open GrafiteAst
  31
  32 let tactical_terminator = ""
  33 let tactic_terminator = tactical_terminator
  34 let command_terminator = tactical_terminator
  35
  36 let pp_idents idents = "[" ^ String.concat "; " idents ^ "]"
  37
  38 let pp_reduction_kind ~term_pp = function
  39   | `Demodulate -> "demodulate"
  40   | `Normalize -> "normalize"
  41   | `Reduce -> "reduce"
  42   | `Simpl -> "simplify"
  43   | `Unfold (Some t) -> "unfold " ^ term_pp t
  44   | `Unfold None -> "unfold"
  45   | `Whd -> "whd"
  46
  47 let pp_tactic_pattern ~term_pp ~lazy_term_pp (what, hyp, goal) =
  48   let what_text =
  49     match what with
  50     | None -> ""
  51     | Some t -> sprintf "in match (%s) " (lazy_term_pp t) in
  52   let hyp_text =
  53     String.concat " "
  54       (List.map (fun (name, p) -> sprintf "%s:(%s)" name (term_pp p)) hyp) in
  55   let goal_text =
  56     match goal with
  57     | None -> ""
  58     | Some t -> sprintf "\\vdash (%s)" (term_pp t) in
  59   sprintf "%sin %s%s" what_text hyp_text goal_text
  60
  61 let pp_intros_specs = function
  62    | None, []         -> ""
  63    | Some num, []     -> Printf.sprintf " names %i" num
  64    | None, idents     -> Printf.sprintf " names %s" (pp_idents idents)
  65    | Some num, idents -> Printf.sprintf " names %i %s" num (pp_idents idents)
  66
  67 let terms_pp ~term_pp terms = String.concat ", " (List.map term_pp terms)
  68
  69 let rec pp_tactic ~term_pp ~lazy_term_pp =
  70   let pp_reduction_kind = pp_reduction_kind ~term_pp in
  71   let pp_tactic_pattern = pp_tactic_pattern ~lazy_term_pp ~term_pp in
  72   function
  73   | Absurd (_, term) -> "absurd" ^ term_pp term
  74   | Apply (_, term) -> "apply " ^ term_pp term
  75   | Auto _ -> "auto"
  76   | Assumption _ -> "assumption"
  77   | Change (_, where, with_what) ->
  78       sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
  79   | Clear (_,id) -> sprintf "clear %s" id
  80   | ClearBody (_,id) -> sprintf "clearbody %s" id
  81   | Constructor (_,n) -> "constructor " ^ string_of_int n
  82   | Contradiction _ -> "contradiction"
  83   | Cut (_, ident, term) ->
  84      "cut " ^ term_pp term ^
  85       (match ident with None -> "" | Some id -> " as " ^ id)
  86   | Decompose (_, [], what, names) ->
  87       sprintf "decompose %s%s" what (pp_intros_specs (None, names))
  88   | Decompose (_, types, what, names) ->
  89       let to_ident = function
  90          | Ident id -> id
  91          | Type _   -> assert false
  92       in
  93       let types = List.rev_map to_ident types in
  94       sprintf "decompose %s %s%s" (pp_idents types) what (pp_intros_specs (None, names))
  95   | Discriminate (_, term) -> "discriminate " ^ term_pp term
  96   | Elim (_, term, using, num, idents) ->
  97       sprintf "elim " ^ term_pp term ^
  98       (match using with None -> "" | Some term -> " using " ^ term_pp term)
  99       ^ pp_intros_specs (num, idents)
 100   | ElimType (_, term, using, num, idents) ->
 101       sprintf "elim type " ^ term_pp term ^
 102       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 103       ^ pp_intros_specs (num, idents)
 104   | Exact (_, term) -> "exact " ^ term_pp term
 105   | Exists _ -> "exists"
 106   | Fold (_, kind, term, pattern) ->
 107       sprintf "fold %s %s %s" (pp_reduction_kind kind)
 108        (lazy_term_pp term) (pp_tactic_pattern pattern)
 109   | FwdSimpl (_, hyp, idents) ->
 110       sprintf "fwd %s%s" hyp
 111         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 112   | Generalize (_, pattern, ident) ->
 113      sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 114       (match ident with None -> "" | Some id -> " as " ^ id)
 115   | Goal (_, n) -> "goal " ^ string_of_int n
 116   | Fail _ -> "fail"
 117   | Fourier _ -> "fourier"
 118   | IdTac _ -> "id"
 119   | Injection (_, term) -> "injection " ^ term_pp term
 120   | Intros (_, None, []) -> "intro"
 121   | Inversion (_, term) -> "inversion " ^ term_pp term
 122   | Intros (_, num, idents) ->
 123       sprintf "intros%s%s"
 124         (match num with None -> "" | Some num -> " " ^ string_of_int num)
 125         (match idents with [] -> "" | idents -> " " ^ pp_idents idents)
 126   | LApply (_, level_opt, terms, term, ident_opt) ->
 127       sprintf "lapply %s%s%s%s"
 128         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 129         (term_pp term)
 130         (match terms with [] -> "" | _ -> " to " ^ terms_pp ~term_pp terms)
 131         (match ident_opt with None -> "" | Some ident -> " using " ^ ident)
 132   | Left _ -> "left"
 133   | LetIn (_, term, ident) -> sprintf "let %s in %s" (term_pp term) ident
 134   | Reduce (_, kind, pat) ->
 135       sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 136   | Reflexivity _ -> "reflexivity"
 137   | Replace (_, pattern, t) ->
 138       sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 139   | Rewrite (_, pos, t, pattern) ->
 140       sprintf "rewrite %s %s %s"
 141         (if pos = `LeftToRight then ">" else "<")
 142         (term_pp t)
 143         (pp_tactic_pattern pattern)
 144   | Right _ -> "right"
 145   | Ring _ -> "ring"
 146   | Split _ -> "split"
 147   | Symmetry _ -> "symmetry"
 148   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 149
 150 let pp_search_kind = function
 151   | `Locate -> "locate"
 152   | `Hint -> "hint"
 153   | `Match -> "match"
 154   | `Elim -> "elim"
 155   | `Instance -> "instance"
 156
 157 let pp_macro ~term_pp = function
 158   (* Whelp *)
 159   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 160   | WHint (_, t) -> "whelp hint " ^ term_pp t
 161   | WLocate (_, s) -> "whelp locate " ^ s
 162   | WElim (_, t) -> "whelp elim " ^ term_pp t
 163   | WMatch (_, term) -> "whelp match " ^ term_pp term
 164   (* real macros *)
 165   | Check (_, term) -> sprintf "Check %s" (term_pp term)
 166   | Hint _ -> "hint"
 167   | Search_pat (_, kind, pat) ->
 168       sprintf "search %s \"%s\"" (pp_search_kind kind) pat
 169   | Search_term (_, kind, term) ->
 170       sprintf "search %s %s" (pp_search_kind kind) (term_pp term)
 171   | Print (_, name) -> sprintf "Print \"%s\"" name
 172   | Quit _ -> "Quit"
 173
 174 let pp_associativity = function
 175   | Gramext.LeftA -> "left associative"
 176   | Gramext.RightA -> "right associative"
 177   | Gramext.NonA -> "non associative"
 178
 179 let pp_precedence i = sprintf "with precedence %d" i
 180
 181 let pp_dir_opt = function
 182   | None -> ""
 183   | Some `LeftToRight -> "> "
 184   | Some `RightToLeft -> "< "
 185
 186 let pp_default what uris =
 187   sprintf "default \"%s\" %s" what
 188     (String.concat " " (List.map UriManager.string_of_uri uris))
 189
 190 let pp_coercion uri do_composites =
 191    sprintf "coercion %s (* %s *)" (UriManager.string_of_uri uri)
 192      (if do_composites then "compounds" else "no compounds")
 193
 194 let pp_command ~obj_pp = function
 195   | Include (_,path) -> "include " ^ path
 196   | Qed _ -> "qed"
 197   | Drop _ -> "drop"
 198   | Set (_, name, value) -> sprintf "set \"%s\" \"%s\"" name value
 199   | Coercion (_, uri, do_composites) -> pp_coercion uri do_composites
 200   | Obj (_,obj) -> obj_pp obj
 201   | Default (_,what,uris) ->
 202       pp_default what uris
 203
 204 let rec pp_tactical ~term_pp ~lazy_term_pp =
 205   let pp_tactic = pp_tactic ~lazy_term_pp ~term_pp in
 206   let pp_tacticals = pp_tacticals ~lazy_term_pp ~term_pp in
 207   function
 208   | Tactic (_, tac) -> pp_tactic tac
 209   | Do (_, count, tac) ->
 210       sprintf "do %d %s" count (pp_tactical ~term_pp ~lazy_term_pp tac)
 211   | Repeat (_, tac) -> "repeat " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 212   | Seq (_, tacs) -> pp_tacticals ~sep:"; " tacs
 213   | Then (_, tac, tacs) ->
 214       sprintf "%s; [%s]" (pp_tactical ~term_pp ~lazy_term_pp tac)
 215         (pp_tacticals ~sep:" | " tacs)
 216   | First (_, tacs) -> sprintf "tries [%s]" (pp_tacticals ~sep:" | " tacs)
 217   | Try (_, tac) -> "try " ^ pp_tactical ~term_pp ~lazy_term_pp tac
 218   | Solve (_, tac) -> sprintf "solve [%s]" (pp_tacticals ~sep:" | " tac)
 219
 220   | Dot _ -> "."
 221   | Semicolon _ -> ";"
 222   | Branch _ -> "["
 223   | Shift _ -> "|"
 224   | Pos (_, i) -> sprintf "%d:" i
 225   | Merge _ -> "]"
 226   | Focus (_, goals) ->
 227       sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 228   | Unfocus _ -> "unfocus"
 229   | Skip _ -> "skip"
 230
 231 and pp_tacticals ~term_pp ~lazy_term_pp ~sep tacs =
 232   String.concat sep (List.map (pp_tactical~lazy_term_pp ~term_pp) tacs)
 233
 234 let pp_executable ~term_pp ~lazy_term_pp ~obj_pp =
 235   function
 236   | Macro (_, macro) -> pp_macro ~term_pp macro
 237   | Tactical (_, tac, Some punct) ->
 238       pp_tactical ~lazy_term_pp ~term_pp tac
 239       ^ pp_tactical ~lazy_term_pp ~term_pp punct
 240   | Tactical (_, tac, None) -> pp_tactical ~lazy_term_pp ~term_pp tac
 241   | Command (_, cmd) -> pp_command ~obj_pp cmd
 242
 243 let pp_comment ~term_pp ~lazy_term_pp ~obj_pp =
 244   function
 245   | Note (_,str) -> sprintf "(* %s *)" str
 246   | Code (_,code) ->
 247       sprintf "(** %s. **)" (pp_executable ~term_pp ~lazy_term_pp ~obj_pp code)
 248
 249 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 250   function
 251   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 252   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c