components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Drop
  31 exception IncludedFileNotCompiled of string (* file name *)
  32 exception Macro of
  33  GrafiteAst.loc *
  34   (Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro)
  35 exception ReadOnlyUri of string
  36
  37 type 'a disambiguator_input = string * int * 'a
  38
  39 type options = {
  40   do_heavy_checks: bool ;
  41   clean_baseuri: bool
  42 }
  43
  44 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  45   * names as long as they are available, then it fallbacks to name generation
  46   * using FreshNamesGenerator module *)
  47 let namer_of names =
  48   let len = List.length names in
  49   let count = ref 0 in
  50   fun metasenv context name ~typ ->
  51     if !count < len then begin
  52       let name = Cic.Name (List.nth names !count) in
  53       incr count;
  54       name
  55     end else
  56       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  57
  58 let tactic_of_ast ast =
  59   let module PET = ProofEngineTypes in
  60   match ast with
  61   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  62   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  63   | GrafiteAst.Assumption _ -> Tactics.assumption
  64   | GrafiteAst.Auto (_,depth,width,paramodulation,full) ->
  65       AutoTactic.auto_tac ?depth ?width ?paramodulation ?full
  66         ~dbd:(LibraryDb.instance ()) ()
  67   | GrafiteAst.Change (_, pattern, with_what) ->
  68      Tactics.change ~pattern with_what
  69   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  70   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  71   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  72   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  73   | GrafiteAst.Cut (_, ident, term) ->
  74      let names = match ident with None -> [] | Some id -> [id] in
  75      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  76   | GrafiteAst.Decompose (_, types, what, names) ->
  77       let to_type = function
  78          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  79          | GrafiteAst.Ident _            -> assert false
  80       in
  81       let user_types = List.rev_map to_type types in
  82       let dbd = LibraryDb.instance () in
  83       let mk_fresh_name_callback = namer_of names in
  84       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  85   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  86   | GrafiteAst.Elim (_, what, using, depth, names) ->
  87       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  88         what
  89   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  90       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  91         what
  92   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  93   | GrafiteAst.Exists _ -> Tactics.exists
  94   | GrafiteAst.Fail _ -> Tactics.fail
  95   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  96       let reduction =
  97         match reduction_kind with
  98         | `Demodulate ->
  99             GrafiteTypes.command_error "demodulation can't be folded"
 100         | `Normalize ->
 101             PET.const_lazy_reduction
 102               (CicReduction.normalize ~delta:false ~subst:[])
 103         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
 104         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 105         | `Unfold None ->
 106             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 107         | `Unfold (Some lazy_term) ->
 108            (fun context metasenv ugraph ->
 109              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 110              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 111         | `Whd ->
 112             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 113       in
 114       Tactics.fold ~reduction ~term ~pattern
 115   | GrafiteAst.Fourier _ -> Tactics.fourier
 116   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 117      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 118       ~dbd:(LibraryDb.instance ()) hyp
 119   | GrafiteAst.Generalize (_,pattern,ident) ->
 120      let names = match ident with None -> [] | Some id -> [id] in
 121      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 122   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 123   | GrafiteAst.IdTac _ -> Tactics.id
 124   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 125   | GrafiteAst.Intros (_, None, names) ->
 126       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 127   | GrafiteAst.Intros (_, Some num, names) ->
 128       PrimitiveTactics.intros_tac ~howmany:num
 129         ~mk_fresh_name_callback:(namer_of names) ()
 130   | GrafiteAst.Inversion (_, term) ->
 131       Tactics.inversion term
 132   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 133       let names = match ident with None -> [] | Some id -> [id] in
 134       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 135         ~to_what what
 136   | GrafiteAst.Left _ -> Tactics.left
 137   | GrafiteAst.LetIn (loc,term,name) ->
 138       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 139   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 140       (match reduction_kind with
 141          | `Demodulate -> Tactics.demodulate ~dbd:(LibraryDb.instance ()) ~pattern
 142          | `Normalize -> Tactics.normalize ~pattern
 143          | `Reduce -> Tactics.reduce ~pattern
 144          | `Simpl -> Tactics.simpl ~pattern
 145          | `Unfold what -> Tactics.unfold ~pattern what
 146          | `Whd -> Tactics.whd ~pattern)
 147   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 148   | GrafiteAst.Replace (_, pattern, with_what) ->
 149      Tactics.replace ~pattern ~with_what
 150   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 151      EqualityTactics.rewrite_tac ~direction ~pattern t
 152   | GrafiteAst.Right _ -> Tactics.right
 153   | GrafiteAst.Ring _ -> Tactics.ring
 154   | GrafiteAst.Split _ -> Tactics.split
 155   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 156   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 157
 158 (* maybe we only need special cases for apply and goal *)
 159 let classify_tactic tactic =
 160   match tactic with
 161   (* tactics that can't close the goal (return a goal we want to "select") *)
 162   | GrafiteAst.Rewrite _
 163   | GrafiteAst.Split _
 164   | GrafiteAst.Replace _
 165   | GrafiteAst.Reduce _
 166   | GrafiteAst.Injection _
 167   | GrafiteAst.IdTac _
 168   | GrafiteAst.Generalize _
 169   | GrafiteAst.Elim _
 170   | GrafiteAst.Cut _
 171   | GrafiteAst.Decompose _ -> true, true
 172   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 173   | GrafiteAst.Goal _ -> false, true
 174   (* tactics like apply *)
 175   | _ -> true, false
 176
 177 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 178   let module PEH = ProofEngineHelpers in
 179 (*   let print_m name metasenv =
 180     prerr_endline (">>>>> " ^ name);
 181     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 182   in *)
 183   (* phase one calculates:
 184    *   new_goals_from_refine:  goals added by refine
 185    *   head_goal:              the first goal opened by ythe tactic
 186    *   other_goals:            other goals opened by the tactic
 187    *)
 188   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 189   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 190   let head_goal, other_goals, goals =
 191     match goals with
 192     | [] -> None,[],goals
 193     | hd::tl ->
 194         (* assert (List.mem hd new_goals_from_tactic);
 195          * invalidato dalla goal_tac
 196          * *)
 197         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 198         hd) goals
 199   in
 200   let produced_goals =
 201     match head_goal with
 202     | None -> new_goals_from_refine @ other_goals
 203     | Some x -> x :: new_goals_from_refine @ other_goals
 204   in
 205   (* extract the metas generated by refine and tactic *)
 206   let metas_for_tactic_head =
 207     match head_goal with
 208     | None -> []
 209     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 210   let metas_for_tactic_goals =
 211     List.map
 212       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 213     goals
 214   in
 215   let metas_for_refine_goals =
 216     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 217   let produced_metas, goals =
 218     let produced_metas =
 219       if always_opens_a_goal then
 220         metas_for_tactic_head @ metas_for_refine_goals @
 221           metas_for_tactic_goals
 222       else begin
 223 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 224         print_m "metas_for_tactic_head" metas_for_tactic_head;
 225         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 226         metas_for_refine_goals @ metas_for_tactic_head @
 227           metas_for_tactic_goals
 228       end
 229     in
 230     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 231     produced_metas, goals
 232   in
 233   (* residual metas, preserving the original order *)
 234   let before, after =
 235     let rec split e =
 236       function
 237       | [] -> [],[]
 238       | (metano, _, _) :: tl when metano = e ->
 239           [], List.map (fun (x,_,_) -> x) tl
 240       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 241     in
 242     let find n metasenv =
 243       try
 244         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 245       with Not_found -> None
 246     in
 247     let extract l =
 248       List.fold_right
 249         (fun n acc ->
 250           match find n tactic with
 251           | Some x -> x::acc
 252           | None -> acc
 253         ) l [] in
 254     let before_l, after_l = split current_goal start in
 255     let before_l =
 256       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 257     let after_l =
 258       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 259     let before = extract before_l in
 260     let after = extract after_l in
 261       before, after
 262   in
 263 (* |+   DEBUG CODE  +|
 264   print_m "BEGIN" start;
 265   prerr_endline ("goal was: " ^ string_of_int current_goal);
 266   prerr_endline ("and metas from refine are:");
 267   List.iter
 268     (fun t -> prerr_string (" " ^ string_of_int t))
 269   new_goals_from_refine;
 270   prerr_endline "";
 271   print_m "before" before;
 272   print_m "metas_for_tactic_head" metas_for_tactic_head;
 273   print_m "metas_for_refine_goals" metas_for_refine_goals;
 274   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 275   print_m "produced_metas" produced_metas;
 276   print_m "after" after;
 277 |+   FINE DEBUG CODE +| *)
 278   before @ produced_metas @ after, goals
 279
 280 let apply_tactic ~disambiguate_tactic (text,prefix_len,tactic) (status, goal) =
 281 (* prerr_endline "apply_tactic"; *)
 282 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 283  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 284  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 285 (* prerr_endline "disambiguate"; *)
 286  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 287  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 288  let proof = GrafiteTypes.get_current_proof status in
 289  let proof_status = proof, goal in
 290  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 291  let tactic = tactic_of_ast tactic in
 292  (* apply tactic will change the lexicon_status ... *)
 293 (* prerr_endline "apply_tactic bassa"; *)
 294  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 295  let after = ProofEngineTypes.goals_of_proof proof in
 296  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 297 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 298 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 299 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 300 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 301 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 302  let proof, opened_goals =
 303    if needs_reordering then begin
 304      let uri, metasenv_after_tactic, t, ty = proof in
 305 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 306      let reordered_metasenv, opened_goals =
 307        reorder_metasenv
 308         starting_metasenv
 309         metasenv_after_refinement metasenv_after_tactic
 310         opened goal always_opens_a_goal
 311      in
 312      let proof' = uri, reordered_metasenv, t, ty in
 313 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 314      proof', opened_goals
 315    end
 316       else
 317         proof, opened_goals
 318  in
 319  let incomplete_proof =
 320    match status.GrafiteTypes.proof_status with
 321    | GrafiteTypes.Incomplete_proof p -> p
 322    | _ -> assert false
 323  in
 324  { status with GrafiteTypes.proof_status =
 325     GrafiteTypes.Incomplete_proof
 326      { incomplete_proof with GrafiteTypes.proof = proof } },
 327  opened_goals, closed_goals
 328
 329 type eval_ast =
 330  {ea_go:
 331   'term 'lazy_term 'reduction 'obj 'ident.
 332   disambiguate_tactic:
 333    (GrafiteTypes.status ->
 334     ProofEngineTypes.goal ->
 335     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 336     disambiguator_input ->
 337     GrafiteTypes.status *
 338    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 339
 340   disambiguate_command:
 341    (GrafiteTypes.status ->
 342     ('obj GrafiteAst.command) disambiguator_input ->
 343     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 344
 345   disambiguate_macro:
 346    (GrafiteTypes.status ->
 347     ('term GrafiteAst.macro) disambiguator_input ->
 348     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 349
 350   ?do_heavy_checks:bool ->
 351   ?clean_baseuri:bool ->
 352   GrafiteTypes.status ->
 353   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement)
 354   disambiguator_input ->
 355   GrafiteTypes.status * UriManager.uri list
 356  }
 357
 358 type 'a eval_command =
 359  {ec_go: 'term 'obj.
 360   disambiguate_command:
 361    (GrafiteTypes.status -> ('obj GrafiteAst.command) disambiguator_input ->
 362     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 363   options -> GrafiteTypes.status ->
 364     ('obj GrafiteAst.command) disambiguator_input ->
 365    GrafiteTypes.status * UriManager.uri list
 366  }
 367
 368 type 'a eval_executable =
 369  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 370   disambiguate_tactic:
 371    (GrafiteTypes.status ->
 372     ProofEngineTypes.goal ->
 373     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 374     disambiguator_input ->
 375     GrafiteTypes.status *
 376    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 377
 378   disambiguate_command:
 379    (GrafiteTypes.status ->
 380     ('obj GrafiteAst.command) disambiguator_input ->
 381     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 382
 383   disambiguate_macro:
 384    (GrafiteTypes.status ->
 385     ('term GrafiteAst.macro) disambiguator_input ->
 386     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 387
 388   options ->
 389   GrafiteTypes.status ->
 390   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code) disambiguator_input ->
 391   GrafiteTypes.status * UriManager.uri list
 392  }
 393
 394 type 'a eval_from_moo =
 395  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 396
 397 let coercion_moo_statement_of uri =
 398   GrafiteAst.Coercion (HExtlib.dummy_floc, uri, false)
 399
 400 let refinement_toolkit = {
 401   RefinementTool.type_of_aux' =
 402     (fun ?localization_tbl e c t u ->
 403       let saved = !CicRefine.insert_coercions in
 404       CicRefine.insert_coercions:= false;
 405       let rc =
 406         try
 407           let t, ty, metasenv, ugraph =
 408             CicRefine.type_of_aux' ?localization_tbl e c t u in
 409           RefinementTool.Success (t, ty, metasenv, ugraph)
 410         with
 411         | CicRefine.RefineFailure s
 412         | CicRefine.Uncertain s
 413         | CicRefine.AssertFailure s -> RefinementTool.Exception s
 414       in
 415       CicRefine.insert_coercions := saved;
 416       rc);
 417   RefinementTool.ppsubst = CicMetaSubst.ppsubst;
 418   RefinementTool.apply_subst = CicMetaSubst.apply_subst;
 419   RefinementTool.ppmetasenv = CicMetaSubst.ppmetasenv;
 420   RefinementTool.pack_coercion_obj = CicRefine.pack_coercion_obj;
 421  }
 422
 423 let eval_coercion status ~add_composites uri =
 424  let status,compounds =
 425   GrafiteSync.add_coercion ~add_composites refinement_toolkit status uri in
 426  let moo_content = coercion_moo_statement_of uri in
 427  let status = GrafiteTypes.add_moo_content [moo_content] status in
 428   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 429    compounds
 430
 431 let eval_tactical ~disambiguate_tactic status tac =
 432  let apply_tactic = apply_tactic ~disambiguate_tactic in
 433  let module MatitaStatus =
 434   struct
 435    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 436
 437    type output_status =
 438      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 439
 440    type tactic = input_status -> output_status
 441
 442    let id_tactic = apply_tactic ("",0,(GrafiteAst.IdTac HExtlib.dummy_floc))
 443    let mk_tactic tac = tac
 444    let apply_tactic tac = tac
 445    let goals (_, opened, closed) = opened, closed
 446    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 447    let get_stack (status, _) = GrafiteTypes.get_stack status
 448
 449    let set_stack stack (status, opened, closed) =
 450      GrafiteTypes.set_stack stack status, opened, closed
 451
 452    let inject (status, _) = (status, [], [])
 453    let focus goal (status, _, _) = (status, goal)
 454   end
 455  in
 456  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 457   let rec tactical_of_ast l (text,prefix_len,tac) =
 458     let apply_tactic t = apply_tactic (text, prefix_len, t) in
 459     let tactical_of_ast l t = tactical_of_ast l (text,prefix_len,t) in
 460     match tac with
 461     | GrafiteAst.Tactic (loc, tactic) ->
 462         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 463     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 464        assert (l > 0);
 465        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 466     | GrafiteAst.Do (loc, n, tactical) ->
 467         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 468     | GrafiteAst.Repeat (loc, tactical) ->
 469         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 470     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 471         assert (l > 0);
 472         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 473           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 474     | GrafiteAst.First (loc, tacticals) ->
 475         MatitaTacticals.first
 476           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 477     | GrafiteAst.Try (loc, tactical) ->
 478         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 479     | GrafiteAst.Solve (loc, tacticals) ->
 480         MatitaTacticals.solve_tactics
 481          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 482
 483     | GrafiteAst.Skip _loc -> MatitaTacticals.skip
 484     | GrafiteAst.Dot _loc -> MatitaTacticals.dot
 485     | GrafiteAst.Semicolon _loc -> MatitaTacticals.semicolon
 486     | GrafiteAst.Branch _loc -> MatitaTacticals.branch
 487     | GrafiteAst.Shift _loc -> MatitaTacticals.shift
 488     | GrafiteAst.Pos (_loc, i) -> MatitaTacticals.pos i
 489     | GrafiteAst.Merge _loc -> MatitaTacticals.merge
 490     | GrafiteAst.Focus (_loc, goals) -> MatitaTacticals.focus goals
 491     | GrafiteAst.Unfocus _loc -> MatitaTacticals.unfocus
 492     | GrafiteAst.Wildcard _loc -> MatitaTacticals.wildcard
 493   in
 494   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 495   let status =  (* is proof completed? *)
 496     match status.GrafiteTypes.proof_status with
 497     | GrafiteTypes.Incomplete_proof
 498        { GrafiteTypes.stack = stack; proof = proof }
 499       when Continuationals.Stack.is_empty stack ->
 500         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 501     | _ -> status
 502   in
 503   status
 504
 505 let eval_comment status c = status
 506
 507 (* since the record syntax allows to declare coercions, we have to put this
 508  * information inside the moo *)
 509 let add_coercions_of_record_to_moo obj lemmas status =
 510   let attributes = CicUtil.attributes_of_obj obj in
 511   let is_record = function `Class (`Record att) -> Some att | _-> None in
 512   match HExtlib.list_findopt is_record attributes with
 513   | None -> status,[]
 514   | Some fields ->
 515       let is_a_coercion uri =
 516         try
 517           let obj,_ =
 518             CicEnvironment.get_cooked_obj  CicUniv.empty_ugraph uri in
 519           let attrs = CicUtil.attributes_of_obj obj in
 520           List.mem (`Class `Projection) attrs
 521         with Not_found -> assert false
 522       in
 523       (* looking at the fields we can know the 'wanted' coercions, but not the
 524        * actually generated ones. So, only the intersection between the wanted
 525        * and the actual should be in the moo as coercion, while everithing in
 526        * lemmas should go as aliases *)
 527       let wanted_coercions =
 528         HExtlib.filter_map
 529           (function
 530             | (name,true) ->
 531                Some
 532                  (UriManager.uri_of_string
 533                    (GrafiteTypes.qualify status name ^ ".con"))
 534             | _ -> None)
 535           fields
 536       in
 537       (*
 538       prerr_endline "wanted coercions:";
 539       List.iter
 540         (fun u -> prerr_endline (UriManager.string_of_uri u))
 541         wanted_coercions; *)
 542       let coercions, moo_content =
 543         List.split
 544           (HExtlib.filter_map
 545             (fun uri ->
 546               let is_a_wanted_coercion =
 547                 List.exists (UriManager.eq uri) wanted_coercions in
 548               if is_a_coercion uri && is_a_wanted_coercion then
 549                 Some (uri, coercion_moo_statement_of uri)
 550               else
 551                 None)
 552             lemmas)
 553       in
 554       (* prerr_endline "actual coercions:";
 555       List.iter
 556         (fun u -> prerr_endline (UriManager.string_of_uri u))
 557         coercions; *)
 558       let status = GrafiteTypes.add_moo_content moo_content status in
 559       {status with
 560         GrafiteTypes.coercions = coercions @ status.GrafiteTypes.coercions},
 561       lemmas
 562
 563 let add_obj uri obj status =
 564  let status,lemmas = GrafiteSync.add_obj refinement_toolkit uri obj status in
 565  status, lemmas
 566
 567 let rec eval_command = {ec_go = fun ~disambiguate_command opts status
 568 (text,prefix_len,cmd) ->
 569  let status,cmd = disambiguate_command status (text,prefix_len,cmd) in
 570  let status,uris =
 571   match cmd with
 572   | GrafiteAst.Default (loc, what, uris) as cmd ->
 573      LibraryObjects.set_default what uris;
 574      GrafiteTypes.add_moo_content [cmd] status,[]
 575   | GrafiteAst.Include (loc, baseuri) ->
 576      let moopath_rw, moopath_r =
 577        LibraryMisc.obj_file_of_baseuri
 578          ~must_exist:false ~baseuri ~writable:true,
 579        LibraryMisc.obj_file_of_baseuri
 580          ~must_exist:false ~baseuri ~writable:false
 581      in
 582      let moopath =
 583        if Sys.file_exists moopath_r then moopath_r else
 584          if Sys.file_exists moopath_rw then moopath_rw else
 585            raise (IncludedFileNotCompiled moopath_rw)
 586      in
 587      let status = eval_from_moo.efm_go status moopath in
 588      status,[]
 589   | GrafiteAst.Set (loc, name, value) ->
 590       if name = "baseuri" then begin
 591         let value =
 592           let v = Http_getter_misc.strip_trailing_slash value in
 593           try
 594             ignore (String.index v ' ');
 595             GrafiteTypes.command_error "baseuri can't contain spaces"
 596           with Not_found -> v
 597         in
 598         if Http_getter_storage.is_read_only value then begin
 599           HLog.error (sprintf "uri %s belongs to a read-only repository" value);
 600           raise (ReadOnlyUri value)
 601         end;
 602         if not (Http_getter_storage.is_empty value) &&
 603            opts.clean_baseuri
 604           then begin
 605           HLog.message ("baseuri " ^ value ^ " is not empty");
 606           HLog.message ("cleaning baseuri " ^ value);
 607           LibraryClean.clean_baseuris [value];
 608           assert (Http_getter_storage.is_empty value);
 609         end;
 610         HExtlib.mkdir
 611           (Filename.dirname (Http_getter.filename ~writable:true (value ^
 612             "/foo.con")));
 613       end;
 614       GrafiteTypes.set_option status name value,[]
 615   | GrafiteAst.Drop loc -> raise Drop
 616   | GrafiteAst.Qed loc ->
 617       let uri, metasenv, bo, ty =
 618         match status.GrafiteTypes.proof_status with
 619         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 620             uri, metasenv, body, ty
 621         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 622             raise (GrafiteTypes.Command_error
 623               ("Someone allows to start a theorem without giving the "^
 624                "name/uri. This should be fixed!"))
 625         | _->
 626           raise
 627            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 628       in
 629       if metasenv <> [] then
 630         raise
 631          (GrafiteTypes.Command_error
 632            "Proof not completed! metasenv is not empty!");
 633       let name = UriManager.name_of_uri uri in
 634       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 635       let status, lemmas = add_obj uri obj status in
 636        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 637         uri::lemmas
 638   | GrafiteAst.Coercion (loc, uri, add_composites) ->
 639      eval_coercion status ~add_composites uri
 640   | GrafiteAst.Obj (loc,obj) ->
 641      let ext,name =
 642       match obj with
 643          Cic.Constant (name,_,_,_,_)
 644        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 645        | Cic.InductiveDefinition (types,_,_,_) ->
 646           ".ind",
 647           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 648        | _ -> assert false in
 649      let uri =
 650        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext) in
 651      let obj = CicRefine.pack_coercion_obj obj in
 652      let metasenv = GrafiteTypes.get_proof_metasenv status in
 653      match obj with
 654      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 655          let name = UriManager.name_of_uri uri in
 656          if not(CicPp.check name ty) then
 657            HLog.error ("Bad name: " ^ name);
 658          if opts.do_heavy_checks then
 659            begin
 660              let dbd = LibraryDb.instance () in
 661              let similar = Whelp.match_term ~dbd ty in
 662              let similar_len = List.length similar in
 663              if similar_len> 30 then
 664                (HLog.message
 665                  ("Duplicate check will compare your theorem with " ^
 666                    string_of_int similar_len ^
 667                    " theorems, this may take a while."));
 668              let convertible =
 669                List.filter (
 670                  fun u ->
 671                    let t = CicUtil.term_of_uri u in
 672                    let ty',g =
 673                      CicTypeChecker.type_of_aux'
 674                        metasenv' [] t CicUniv.empty_ugraph
 675                    in
 676                    fst(CicReduction.are_convertible [] ty' ty g))
 677                similar
 678              in
 679              (match convertible with
 680              | [] -> ()
 681              | x::_ ->
 682                  HLog.warn
 683                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 684                   "\nPlease use a variant."));
 685            end;
 686          let initial_proof = (Some uri, metasenv', bo, ty) in
 687          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 688          { status with GrafiteTypes.proof_status =
 689             GrafiteTypes.Incomplete_proof
 690              { GrafiteTypes.proof = initial_proof; stack = initial_stack } },
 691           []
 692      | _ ->
 693          if metasenv <> [] then
 694           raise (GrafiteTypes.Command_error (
 695             "metasenv not empty while giving a definition with body: " ^
 696             CicMetaSubst.ppmetasenv [] metasenv));
 697          let status, lemmas = add_obj uri obj status in
 698          let status,new_lemmas =
 699           add_coercions_of_record_to_moo obj lemmas status
 700          in
 701           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 702            uri::new_lemmas@lemmas
 703  in
 704   match status.GrafiteTypes.proof_status with
 705      GrafiteTypes.Intermediate _ ->
 706       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 707    | _ -> status,uris
 708
 709 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command
 710 ~disambiguate_macro opts status (text,prefix_len,ex) ->
 711   match ex with
 712   | GrafiteAst.Tactical (_, tac, None) ->
 713      eval_tactical ~disambiguate_tactic status (text,prefix_len,tac),[]
 714   | GrafiteAst.Tactical (_, tac, Some punct) ->
 715      let status =
 716        eval_tactical ~disambiguate_tactic status (text,prefix_len,tac) in
 717       eval_tactical ~disambiguate_tactic status (text,prefix_len,punct),[]
 718   | GrafiteAst.Command (_, cmd) ->
 719       eval_command.ec_go ~disambiguate_command opts status (text,prefix_len,cmd)
 720   | GrafiteAst.Macro (loc, macro) ->
 721      raise (Macro (loc,disambiguate_macro status (text,prefix_len,macro)))
 722
 723 } and eval_from_moo = {efm_go = fun status fname ->
 724   let ast_of_cmd cmd =
 725     ("",0,GrafiteAst.Executable (HExtlib.dummy_floc,
 726       GrafiteAst.Command (HExtlib.dummy_floc,
 727         cmd)))
 728   in
 729   let moo = GrafiteMarshal.load_moo fname in
 730   List.fold_left
 731     (fun status ast ->
 732       let ast = ast_of_cmd ast in
 733       let status,lemmas =
 734        eval_ast.ea_go
 735          ~disambiguate_tactic:(fun status _ (_,_,tactic) -> status,tactic)
 736          ~disambiguate_command:(fun status (_,_,cmd) -> status,cmd)
 737          ~disambiguate_macro:(fun _ _ -> assert false)
 738          status ast
 739       in
 740        assert (lemmas=[]);
 741        status)
 742     status moo
 743 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
 744 ~disambiguate_macro ?(do_heavy_checks=false) ?(clean_baseuri=true) status
 745 (text,prefix_len,st)
 746 ->
 747   let opts = {
 748     do_heavy_checks = do_heavy_checks ;
 749     clean_baseuri = clean_baseuri }
 750   in
 751   match st with
 752   | GrafiteAst.Executable (_,ex) ->
 753      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 754       ~disambiguate_macro opts status (text,prefix_len,ex)
 755   | GrafiteAst.Comment (_,c) -> eval_comment status (text,prefix_len,c),[]
 756 }
 757
 758 let eval_ast = eval_ast.ea_go