components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Drop
  31 (* mo file name, ma file name *)
  32 exception IncludedFileNotCompiled of string * string
  33 exception Macro of
  34  GrafiteAst.loc *
  35   (Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro)
  36 exception ReadOnlyUri of string
  37
  38 type 'a disambiguator_input = string * int * 'a
  39
  40 type options = {
  41   do_heavy_checks: bool ;
  42   clean_baseuri: bool
  43 }
  44
  45 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  46   * names as long as they are available, then it fallbacks to name generation
  47   * using FreshNamesGenerator module *)
  48 let namer_of names =
  49   let len = List.length names in
  50   let count = ref 0 in
  51   fun metasenv context name ~typ ->
  52     if !count < len then begin
  53       let name = Cic.Name (List.nth names !count) in
  54       incr count;
  55       name
  56     end else
  57       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  58
  59 let tactic_of_ast ast =
  60   let module PET = ProofEngineTypes in
  61   match ast with
  62   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  63   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  64   | GrafiteAst.ApplyS (_, term) ->
  65      Tactics.applyS ~term ~dbd:(LibraryDb.instance ())
  66   | GrafiteAst.Assumption _ -> Tactics.assumption
  67   | GrafiteAst.Auto (_,params) ->
  68       AutoTactic.auto_tac ~params ~dbd:(LibraryDb.instance ())
  69   | GrafiteAst.Change (_, pattern, with_what) ->
  70      Tactics.change ~pattern with_what
  71   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  72   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  73   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  74   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  75   | GrafiteAst.Cut (_, ident, term) ->
  76      let names = match ident with None -> [] | Some id -> [id] in
  77      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  78   | GrafiteAst.Decompose (_, types, what, names) ->
  79       let to_type = function
  80          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  81          | GrafiteAst.Ident _            -> assert false
  82       in
  83       let user_types = List.rev_map to_type types in
  84       let dbd = LibraryDb.instance () in
  85       let mk_fresh_name_callback = namer_of names in
  86       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types ?what
  87   | GrafiteAst.Demodulate _ -> Tactics.demodulate ~dbd:(LibraryDb.instance ())
  88   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  89   | GrafiteAst.Elim (_, what, using, depth, names) ->
  90       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  91         what
  92   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  93       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  94         what
  95   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  96   | GrafiteAst.Exists _ -> Tactics.exists
  97   | GrafiteAst.Fail _ -> Tactics.fail
  98   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  99       let reduction =
 100         match reduction_kind with
 101         | `Normalize ->
 102             PET.const_lazy_reduction
 103               (CicReduction.normalize ~delta:false ~subst:[])
 104         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
 105         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 106         | `Unfold None ->
 107             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 108         | `Unfold (Some lazy_term) ->
 109            (fun context metasenv ugraph ->
 110              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 111              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 112         | `Whd ->
 113             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 114       in
 115       Tactics.fold ~reduction ~term ~pattern
 116   | GrafiteAst.Fourier _ -> Tactics.fourier
 117   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 118      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 119       ~dbd:(LibraryDb.instance ()) hyp
 120   | GrafiteAst.Generalize (_,pattern,ident) ->
 121      let names = match ident with None -> [] | Some id -> [id] in
 122      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 123   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 124   | GrafiteAst.IdTac _ -> Tactics.id
 125   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 126   | GrafiteAst.Intros (_, None, names) ->
 127       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 128   | GrafiteAst.Intros (_, Some num, names) ->
 129       PrimitiveTactics.intros_tac ~howmany:num
 130         ~mk_fresh_name_callback:(namer_of names) ()
 131   | GrafiteAst.Inversion (_, term) ->
 132       Tactics.inversion term
 133   | GrafiteAst.LApply (_, linear, how_many, to_what, what, ident) ->
 134       let names = match ident with None -> [] | Some id -> [id] in
 135       Tactics.lapply ~mk_fresh_name_callback:(namer_of names)
 136         ~linear ?how_many ~to_what what
 137   | GrafiteAst.Left _ -> Tactics.left
 138   | GrafiteAst.LetIn (loc,term,name) ->
 139       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 140   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 141       (match reduction_kind with
 142          | `Normalize -> Tactics.normalize ~pattern
 143          | `Reduce -> Tactics.reduce ~pattern
 144          | `Simpl -> Tactics.simpl ~pattern
 145          | `Unfold what -> Tactics.unfold ~pattern what
 146          | `Whd -> Tactics.whd ~pattern)
 147   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 148   | GrafiteAst.Replace (_, pattern, with_what) ->
 149      Tactics.replace ~pattern ~with_what
 150   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 151      EqualityTactics.rewrite_tac ~direction ~pattern t
 152   | GrafiteAst.Right _ -> Tactics.right
 153   | GrafiteAst.Ring _ -> Tactics.ring
 154   | GrafiteAst.Split _ -> Tactics.split
 155   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 156   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 157
 158 (* maybe we only need special cases for apply and goal *)
 159 let classify_tactic tactic =
 160   match tactic with
 161   (* tactics that can't close the goal (return a goal we want to "select") *)
 162   | GrafiteAst.Rewrite _
 163   | GrafiteAst.Split _
 164   | GrafiteAst.Replace _
 165   | GrafiteAst.Reduce _
 166   | GrafiteAst.Injection _
 167   | GrafiteAst.IdTac _
 168   | GrafiteAst.Generalize _
 169   | GrafiteAst.Elim _
 170   | GrafiteAst.Cut _
 171   | GrafiteAst.Decompose _ -> true, true
 172   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 173   | GrafiteAst.Goal _ -> false, true
 174   (* tactics like apply *)
 175   | _ -> true, false
 176
 177 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 178   let module PEH = ProofEngineHelpers in
 179 (*   let print_m name metasenv =
 180     prerr_endline (">>>>> " ^ name);
 181     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 182   in *)
 183   (* phase one calculates:
 184    *   new_goals_from_refine:  goals added by refine
 185    *   head_goal:              the first goal opened by ythe tactic
 186    *   other_goals:            other goals opened by the tactic
 187    *)
 188   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 189   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 190   let head_goal, other_goals, goals =
 191     match goals with
 192     | [] -> None,[],goals
 193     | hd::tl ->
 194         (* assert (List.mem hd new_goals_from_tactic);
 195          * invalidato dalla goal_tac
 196          * *)
 197         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 198         hd) goals
 199   in
 200   let produced_goals =
 201     match head_goal with
 202     | None -> new_goals_from_refine @ other_goals
 203     | Some x -> x :: new_goals_from_refine @ other_goals
 204   in
 205   (* extract the metas generated by refine and tactic *)
 206   let metas_for_tactic_head =
 207     match head_goal with
 208     | None -> []
 209     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 210   let metas_for_tactic_goals =
 211     List.map
 212       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 213     goals
 214   in
 215   let metas_for_refine_goals =
 216     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 217   let produced_metas, goals =
 218     let produced_metas =
 219       if always_opens_a_goal then
 220         metas_for_tactic_head @ metas_for_refine_goals @
 221           metas_for_tactic_goals
 222       else begin
 223 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 224         print_m "metas_for_tactic_head" metas_for_tactic_head;
 225         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 226         metas_for_refine_goals @ metas_for_tactic_head @
 227           metas_for_tactic_goals
 228       end
 229     in
 230     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 231     produced_metas, goals
 232   in
 233   (* residual metas, preserving the original order *)
 234   let before, after =
 235     let rec split e =
 236       function
 237       | [] -> [],[]
 238       | (metano, _, _) :: tl when metano = e ->
 239           [], List.map (fun (x,_,_) -> x) tl
 240       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 241     in
 242     let find n metasenv =
 243       try
 244         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 245       with Not_found -> None
 246     in
 247     let extract l =
 248       List.fold_right
 249         (fun n acc ->
 250           match find n tactic with
 251           | Some x -> x::acc
 252           | None -> acc
 253         ) l [] in
 254     let before_l, after_l = split current_goal start in
 255     let before_l =
 256       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 257     let after_l =
 258       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 259     let before = extract before_l in
 260     let after = extract after_l in
 261       before, after
 262   in
 263 (* |+   DEBUG CODE  +|
 264   print_m "BEGIN" start;
 265   prerr_endline ("goal was: " ^ string_of_int current_goal);
 266   prerr_endline ("and metas from refine are:");
 267   List.iter
 268     (fun t -> prerr_string (" " ^ string_of_int t))
 269   new_goals_from_refine;
 270   prerr_endline "";
 271   print_m "before" before;
 272   print_m "metas_for_tactic_head" metas_for_tactic_head;
 273   print_m "metas_for_refine_goals" metas_for_refine_goals;
 274   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 275   print_m "produced_metas" produced_metas;
 276   print_m "after" after;
 277 |+   FINE DEBUG CODE +| *)
 278   before @ produced_metas @ after, goals
 279
 280 let apply_tactic ~disambiguate_tactic (text,prefix_len,tactic) (status, goal) =
 281 (* prerr_endline "apply_tactic"; *)
 282 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 283  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 284  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 285 (* prerr_endline "disambiguate"; *)
 286  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 287  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 288  let proof = GrafiteTypes.get_current_proof status in
 289  let proof_status = proof, goal in
 290  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 291  let tactic = tactic_of_ast tactic in
 292  (* apply tactic will change the lexicon_status ... *)
 293 (* prerr_endline "apply_tactic bassa"; *)
 294  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 295  let after = ProofEngineTypes.goals_of_proof proof in
 296  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 297 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 298 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 299 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 300 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 301 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 302  let proof, opened_goals =
 303    if needs_reordering then begin
 304      let uri, metasenv_after_tactic, t, ty = proof in
 305 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 306      let reordered_metasenv, opened_goals =
 307        reorder_metasenv
 308         starting_metasenv
 309         metasenv_after_refinement metasenv_after_tactic
 310         opened goal always_opens_a_goal
 311      in
 312      let proof' = uri, reordered_metasenv, t, ty in
 313 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 314      proof', opened_goals
 315    end
 316       else
 317         proof, opened_goals
 318  in
 319  let incomplete_proof =
 320    match status.GrafiteTypes.proof_status with
 321    | GrafiteTypes.Incomplete_proof p -> p
 322    | _ -> assert false
 323  in
 324  { status with GrafiteTypes.proof_status =
 325     GrafiteTypes.Incomplete_proof
 326      { incomplete_proof with GrafiteTypes.proof = proof } },
 327  opened_goals, closed_goals
 328
 329 type eval_ast =
 330  {ea_go:
 331   'term 'lazy_term 'reduction 'obj 'ident.
 332   disambiguate_tactic:
 333    (GrafiteTypes.status ->
 334     ProofEngineTypes.goal ->
 335     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 336     disambiguator_input ->
 337     GrafiteTypes.status *
 338    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 339
 340   disambiguate_command:
 341    (GrafiteTypes.status ->
 342     ('obj GrafiteAst.command) disambiguator_input ->
 343     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 344
 345   disambiguate_macro:
 346    (GrafiteTypes.status ->
 347     ('term GrafiteAst.macro) disambiguator_input ->
 348     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 349
 350   ?do_heavy_checks:bool ->
 351   ?clean_baseuri:bool ->
 352   GrafiteTypes.status ->
 353   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement)
 354   disambiguator_input ->
 355   GrafiteTypes.status * UriManager.uri list
 356  }
 357
 358 type 'a eval_command =
 359  {ec_go: 'term 'obj.
 360   disambiguate_command:
 361    (GrafiteTypes.status -> ('obj GrafiteAst.command) disambiguator_input ->
 362     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 363   options -> GrafiteTypes.status ->
 364     ('obj GrafiteAst.command) disambiguator_input ->
 365    GrafiteTypes.status * UriManager.uri list
 366  }
 367
 368 type 'a eval_executable =
 369  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 370   disambiguate_tactic:
 371    (GrafiteTypes.status ->
 372     ProofEngineTypes.goal ->
 373     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 374     disambiguator_input ->
 375     GrafiteTypes.status *
 376    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 377
 378   disambiguate_command:
 379    (GrafiteTypes.status ->
 380     ('obj GrafiteAst.command) disambiguator_input ->
 381     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 382
 383   disambiguate_macro:
 384    (GrafiteTypes.status ->
 385     ('term GrafiteAst.macro) disambiguator_input ->
 386     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 387
 388   options ->
 389   GrafiteTypes.status ->
 390   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code) disambiguator_input ->
 391   GrafiteTypes.status * UriManager.uri list
 392  }
 393
 394 type 'a eval_from_moo =
 395  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 396
 397 let coercion_moo_statement_of uri =
 398   GrafiteAst.Coercion (HExtlib.dummy_floc, uri, false)
 399
 400 let refinement_toolkit = {
 401   RefinementTool.type_of_aux' =
 402     (fun ?localization_tbl e c t u ->
 403       let saved = !CicRefine.insert_coercions in
 404       CicRefine.insert_coercions:= false;
 405       let rc =
 406         try
 407           let t, ty, metasenv, ugraph =
 408             CicRefine.type_of_aux' ?localization_tbl e c t u in
 409           RefinementTool.Success (t, ty, metasenv, ugraph)
 410         with
 411         | CicRefine.RefineFailure s
 412         | CicRefine.Uncertain s
 413         | CicRefine.AssertFailure s -> RefinementTool.Exception s
 414       in
 415       CicRefine.insert_coercions := saved;
 416       rc);
 417   RefinementTool.ppsubst = CicMetaSubst.ppsubst;
 418   RefinementTool.apply_subst = CicMetaSubst.apply_subst;
 419   RefinementTool.ppmetasenv = CicMetaSubst.ppmetasenv;
 420   RefinementTool.pack_coercion_obj = CicRefine.pack_coercion_obj;
 421  }
 422
 423 let eval_coercion status ~add_composites uri =
 424  let status,compounds =
 425   GrafiteSync.add_coercion ~add_composites refinement_toolkit status uri in
 426  let moo_content =
 427    List.map coercion_moo_statement_of (uri::compounds)
 428  in
 429  let status = GrafiteTypes.add_moo_content moo_content status in
 430   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 431    compounds
 432
 433 let eval_tactical ~disambiguate_tactic status tac =
 434  let apply_tactic = apply_tactic ~disambiguate_tactic in
 435  let module MatitaStatus =
 436   struct
 437    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 438
 439    type output_status =
 440      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 441
 442    type tactic = input_status -> output_status
 443
 444    let id_tactic = apply_tactic ("",0,(GrafiteAst.IdTac HExtlib.dummy_floc))
 445    let mk_tactic tac = tac
 446    let apply_tactic tac = tac
 447    let goals (_, opened, closed) = opened, closed
 448    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 449    let get_stack (status, _) = GrafiteTypes.get_stack status
 450
 451    let set_stack stack (status, opened, closed) =
 452      GrafiteTypes.set_stack stack status, opened, closed
 453
 454    let inject (status, _) = (status, [], [])
 455    let focus goal (status, _, _) = (status, goal)
 456   end
 457  in
 458  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 459   let rec tactical_of_ast l (text,prefix_len,tac) =
 460     let apply_tactic t = apply_tactic (text, prefix_len, t) in
 461     let tactical_of_ast l t = tactical_of_ast l (text,prefix_len,t) in
 462     match tac with
 463     | GrafiteAst.Tactic (loc, tactic) ->
 464         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 465     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 466        assert (l > 0);
 467        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 468     | GrafiteAst.Do (loc, n, tactical) ->
 469         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 470     | GrafiteAst.Repeat (loc, tactical) ->
 471         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 472     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 473         assert (l > 0);
 474         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 475           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 476     | GrafiteAst.First (loc, tacticals) ->
 477         MatitaTacticals.first
 478           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 479     | GrafiteAst.Try (loc, tactical) ->
 480         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 481     | GrafiteAst.Solve (loc, tacticals) ->
 482         MatitaTacticals.solve_tactics
 483          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 484
 485     | GrafiteAst.Skip _loc -> MatitaTacticals.skip
 486     | GrafiteAst.Dot _loc -> MatitaTacticals.dot
 487     | GrafiteAst.Semicolon _loc -> MatitaTacticals.semicolon
 488     | GrafiteAst.Branch _loc -> MatitaTacticals.branch
 489     | GrafiteAst.Shift _loc -> MatitaTacticals.shift
 490     | GrafiteAst.Pos (_loc, i) -> MatitaTacticals.pos i
 491     | GrafiteAst.Merge _loc -> MatitaTacticals.merge
 492     | GrafiteAst.Focus (_loc, goals) -> MatitaTacticals.focus goals
 493     | GrafiteAst.Unfocus _loc -> MatitaTacticals.unfocus
 494     | GrafiteAst.Wildcard _loc -> MatitaTacticals.wildcard
 495   in
 496   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 497   let status =  (* is proof completed? *)
 498     match status.GrafiteTypes.proof_status with
 499     | GrafiteTypes.Incomplete_proof
 500        { GrafiteTypes.stack = stack; proof = proof }
 501       when Continuationals.Stack.is_empty stack ->
 502         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 503     | _ -> status
 504   in
 505   status
 506
 507 let eval_comment status c = status
 508
 509 (* since the record syntax allows to declare coercions, we have to put this
 510  * information inside the moo *)
 511 let add_coercions_of_record_to_moo obj lemmas status =
 512   let attributes = CicUtil.attributes_of_obj obj in
 513   let is_record = function `Class (`Record att) -> Some att | _-> None in
 514   match HExtlib.list_findopt is_record attributes with
 515   | None -> status,[]
 516   | Some fields ->
 517       let is_a_coercion uri =
 518         try
 519           let obj,_ =
 520             CicEnvironment.get_cooked_obj  CicUniv.empty_ugraph uri in
 521           let attrs = CicUtil.attributes_of_obj obj in
 522           List.mem (`Class `Coercion) attrs
 523         with Not_found -> assert false
 524       in
 525       (* looking at the fields we can know the 'wanted' coercions, but not the
 526        * actually generated ones. So, only the intersection between the wanted
 527        * and the actual should be in the moo as coercion, while everithing in
 528        * lemmas should go as aliases *)
 529       let wanted_coercions =
 530         HExtlib.filter_map
 531           (function
 532             | (name,true) ->
 533                Some
 534                  (UriManager.uri_of_string
 535                    (GrafiteTypes.qualify status name ^ ".con"))
 536             | _ -> None)
 537           fields
 538       in
 539       (*prerr_endline "wanted coercions:";
 540       List.iter
 541         (fun u -> prerr_endline (UriManager.string_of_uri u))
 542         wanted_coercions; *)
 543       let coercions, moo_content =
 544         List.split
 545           (HExtlib.filter_map
 546             (fun uri ->
 547               let is_a_wanted_coercion =
 548                 List.exists (UriManager.eq uri) wanted_coercions
 549               in
 550               if is_a_coercion uri || is_a_wanted_coercion then
 551                 Some (uri, coercion_moo_statement_of uri)
 552               else
 553                 None)
 554             lemmas)
 555       in
 556       (*prerr_endline "actual coercions:";
 557       List.iter
 558         (fun u -> prerr_endline (UriManager.string_of_uri u))
 559         coercions;
 560       prerr_endline "lemmas was:";
 561       List.iter
 562         (fun u -> prerr_endline (UriManager.string_of_uri u))
 563         lemmas; *)
 564       let status = GrafiteTypes.add_moo_content moo_content status in
 565       {status with
 566         GrafiteTypes.coercions = coercions @ status.GrafiteTypes.coercions},
 567       lemmas
 568
 569 let add_obj uri obj status =
 570  let status,lemmas = GrafiteSync.add_obj refinement_toolkit uri obj status in
 571  status, lemmas
 572
 573 let rec eval_command = {ec_go = fun ~disambiguate_command opts status
 574 (text,prefix_len,cmd) ->
 575  let status,cmd = disambiguate_command status (text,prefix_len,cmd) in
 576  let status,uris =
 577   match cmd with
 578   | GrafiteAst.Default (loc, what, uris) as cmd ->
 579      LibraryObjects.set_default what uris;
 580      GrafiteTypes.add_moo_content [cmd] status,[]
 581   | GrafiteAst.Include (loc, baseuri) ->
 582      let moopath_rw, moopath_r =
 583        LibraryMisc.obj_file_of_baseuri
 584          ~must_exist:false ~baseuri ~writable:true,
 585        LibraryMisc.obj_file_of_baseuri
 586          ~must_exist:false ~baseuri ~writable:false
 587      in
 588      let moopath =
 589        if Sys.file_exists moopath_r then moopath_r else
 590          if Sys.file_exists moopath_rw then moopath_rw else
 591            raise (IncludedFileNotCompiled (moopath_rw,baseuri))
 592      in
 593      let status = eval_from_moo.efm_go status moopath in
 594      status,[]
 595   | GrafiteAst.Set (loc, name, value) ->
 596       if name = "baseuri" then begin
 597         let value =
 598           let v = Http_getter_misc.strip_trailing_slash value in
 599           try
 600             ignore (String.index v ' ');
 601             GrafiteTypes.command_error "baseuri can't contain spaces"
 602           with Not_found -> v
 603         in
 604         if Http_getter_storage.is_read_only value then begin
 605           HLog.error (sprintf "uri %s belongs to a read-only repository" value);
 606           raise (ReadOnlyUri value)
 607         end;
 608         if not (Http_getter_storage.is_empty value) &&
 609            opts.clean_baseuri
 610           then begin
 611           HLog.message ("baseuri " ^ value ^ " is not empty");
 612           HLog.message ("cleaning baseuri " ^ value);
 613           LibraryClean.clean_baseuris [value];
 614           assert (Http_getter_storage.is_empty value);
 615         end;
 616         HExtlib.mkdir
 617           (Filename.dirname (Http_getter.filename ~writable:true (value ^
 618             "/foo.con")));
 619       end;
 620       GrafiteTypes.set_option status name value,[]
 621   | GrafiteAst.Drop loc -> raise Drop
 622   | GrafiteAst.Qed loc ->
 623       let uri, metasenv, bo, ty =
 624         match status.GrafiteTypes.proof_status with
 625         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 626             uri, metasenv, body, ty
 627         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 628             raise (GrafiteTypes.Command_error
 629               ("Someone allows to start a theorem without giving the "^
 630                "name/uri. This should be fixed!"))
 631         | _->
 632           raise
 633            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 634       in
 635       if metasenv <> [] then
 636         raise
 637          (GrafiteTypes.Command_error
 638            "Proof not completed! metasenv is not empty!");
 639       let name = UriManager.name_of_uri uri in
 640       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 641       let status, lemmas = add_obj uri obj status in
 642        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 643         uri::lemmas
 644   | GrafiteAst.Coercion (loc, uri, add_composites) ->
 645      eval_coercion status ~add_composites uri
 646   | GrafiteAst.Obj (loc,obj) ->
 647      let ext,name =
 648       match obj with
 649          Cic.Constant (name,_,_,_,_)
 650        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 651        | Cic.InductiveDefinition (types,_,_,_) ->
 652           ".ind",
 653           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 654        | _ -> assert false in
 655      let uri =
 656        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext) in
 657      let obj = CicRefine.pack_coercion_obj obj in
 658      let metasenv = GrafiteTypes.get_proof_metasenv status in
 659      match obj with
 660      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 661          let name = UriManager.name_of_uri uri in
 662          if not(CicPp.check name ty) then
 663            HLog.error ("Bad name: " ^ name);
 664          if opts.do_heavy_checks then
 665            begin
 666              let dbd = LibraryDb.instance () in
 667              let similar = Whelp.match_term ~dbd ty in
 668              let similar_len = List.length similar in
 669              if similar_len> 30 then
 670                (HLog.message
 671                  ("Duplicate check will compare your theorem with " ^
 672                    string_of_int similar_len ^
 673                    " theorems, this may take a while."));
 674              let convertible =
 675                List.filter (
 676                  fun u ->
 677                    let t = CicUtil.term_of_uri u in
 678                    let ty',g =
 679                      CicTypeChecker.type_of_aux'
 680                        metasenv' [] t CicUniv.empty_ugraph
 681                    in
 682                    fst(CicReduction.are_convertible [] ty' ty g))
 683                similar
 684              in
 685              (match convertible with
 686              | [] -> ()
 687              | x::_ ->
 688                  HLog.warn
 689                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 690                   "\nPlease use a variant."));
 691            end;
 692          let initial_proof = (Some uri, metasenv', bo, ty) in
 693          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 694          { status with GrafiteTypes.proof_status =
 695             GrafiteTypes.Incomplete_proof
 696              { GrafiteTypes.proof = initial_proof; stack = initial_stack } },
 697           []
 698      | _ ->
 699          if metasenv <> [] then
 700           raise (GrafiteTypes.Command_error (
 701             "metasenv not empty while giving a definition with body: " ^
 702             CicMetaSubst.ppmetasenv [] metasenv));
 703          let status, lemmas = add_obj uri obj status in
 704          let status,new_lemmas =
 705           add_coercions_of_record_to_moo obj lemmas status
 706          in
 707           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 708            uri::new_lemmas@lemmas
 709  in
 710   match status.GrafiteTypes.proof_status with
 711      GrafiteTypes.Intermediate _ ->
 712       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 713    | _ -> status,uris
 714
 715 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command
 716 ~disambiguate_macro opts status (text,prefix_len,ex) ->
 717   match ex with
 718   | GrafiteAst.Tactical (_, tac, None) ->
 719      eval_tactical ~disambiguate_tactic status (text,prefix_len,tac),[]
 720   | GrafiteAst.Tactical (_, tac, Some punct) ->
 721      let status =
 722        eval_tactical ~disambiguate_tactic status (text,prefix_len,tac) in
 723       eval_tactical ~disambiguate_tactic status (text,prefix_len,punct),[]
 724   | GrafiteAst.Command (_, cmd) ->
 725       eval_command.ec_go ~disambiguate_command opts status (text,prefix_len,cmd)
 726   | GrafiteAst.Macro (loc, macro) ->
 727      raise (Macro (loc,disambiguate_macro status (text,prefix_len,macro)))
 728
 729 } and eval_from_moo = {efm_go = fun status fname ->
 730   let ast_of_cmd cmd =
 731     ("",0,GrafiteAst.Executable (HExtlib.dummy_floc,
 732       GrafiteAst.Command (HExtlib.dummy_floc,
 733         cmd)))
 734   in
 735   let moo = GrafiteMarshal.load_moo fname in
 736   List.fold_left
 737     (fun status ast ->
 738       let ast = ast_of_cmd ast in
 739       let status,lemmas =
 740        eval_ast.ea_go
 741          ~disambiguate_tactic:(fun status _ (_,_,tactic) -> status,tactic)
 742          ~disambiguate_command:(fun status (_,_,cmd) -> status,cmd)
 743          ~disambiguate_macro:(fun _ _ -> assert false)
 744          status ast
 745       in
 746        assert (lemmas=[]);
 747        status)
 748     status moo
 749 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
 750 ~disambiguate_macro ?(do_heavy_checks=false) ?(clean_baseuri=true) status
 751 (text,prefix_len,st)
 752 ->
 753   let opts = {
 754     do_heavy_checks = do_heavy_checks ;
 755     clean_baseuri = clean_baseuri }
 756   in
 757   match st with
 758   | GrafiteAst.Executable (_,ex) ->
 759      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 760       ~disambiguate_macro opts status (text,prefix_len,ex)
 761   | GrafiteAst.Comment (_,c) -> eval_comment status (text,prefix_len,c),[]
 762 }
 763
 764 let eval_ast = eval_ast.ea_go