components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Drop
  31 (* mo file name, ma file name *)
  32 exception IncludedFileNotCompiled of string * string
  33 exception Macro of
  34  GrafiteAst.loc *
  35   (Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro)
  36 exception ReadOnlyUri of string
  37
  38 type 'a disambiguator_input = string * int * 'a
  39
  40 type options = {
  41   do_heavy_checks: bool ;
  42   clean_baseuri: bool
  43 }
  44
  45 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  46   * names as long as they are available, then it fallbacks to name generation
  47   * using FreshNamesGenerator module *)
  48 let namer_of names =
  49   let len = List.length names in
  50   let count = ref 0 in
  51   fun metasenv context name ~typ ->
  52     if !count < len then begin
  53       let name = Cic.Name (List.nth names !count) in
  54       incr count;
  55       name
  56     end else
  57       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  58
  59 let tactic_of_ast ast =
  60   let module PET = ProofEngineTypes in
  61   match ast with
  62   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  63   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  64   | GrafiteAst.ApplyS (_, term) ->
  65      Tactics.applyS ~term ~dbd:(LibraryDb.instance ())
  66   | GrafiteAst.Assumption _ -> Tactics.assumption
  67   | GrafiteAst.Auto (_,params) ->
  68       AutoTactic.auto_tac ~params ~dbd:(LibraryDb.instance ())
  69   | GrafiteAst.Change (_, pattern, with_what) ->
  70      Tactics.change ~pattern with_what
  71   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  72   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  73   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  74   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  75   | GrafiteAst.Cut (_, ident, term) ->
  76      let names = match ident with None -> [] | Some id -> [id] in
  77      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  78   | GrafiteAst.Decompose (_, types, what, names) ->
  79       let to_type = function
  80          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  81          | GrafiteAst.Ident _            -> assert false
  82       in
  83       let user_types = List.rev_map to_type types in
  84       let dbd = LibraryDb.instance () in
  85       let mk_fresh_name_callback = namer_of names in
  86       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types ?what
  87   | GrafiteAst.Demodulate _ -> Tactics.demodulate ~dbd:(LibraryDb.instance ())
  88   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  89   | GrafiteAst.Elim (_, what, using, depth, names) ->
  90       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  91         what
  92   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  93       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  94         what
  95   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  96   | GrafiteAst.Exists _ -> Tactics.exists
  97   | GrafiteAst.Fail _ -> Tactics.fail
  98   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  99       let reduction =
 100         match reduction_kind with
 101         | `Normalize ->
 102             PET.const_lazy_reduction
 103               (CicReduction.normalize ~delta:false ~subst:[])
 104         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
 105         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 106         | `Unfold None ->
 107             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 108         | `Unfold (Some lazy_term) ->
 109            (fun context metasenv ugraph ->
 110              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 111              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 112         | `Whd ->
 113             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 114       in
 115       Tactics.fold ~reduction ~term ~pattern
 116   | GrafiteAst.Fourier _ -> Tactics.fourier
 117   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 118      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 119       ~dbd:(LibraryDb.instance ()) hyp
 120   | GrafiteAst.Generalize (_,pattern,ident) ->
 121      let names = match ident with None -> [] | Some id -> [id] in
 122      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 123   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 124   | GrafiteAst.IdTac _ -> Tactics.id
 125   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 126   | GrafiteAst.Intros (_, None, names) ->
 127       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 128   | GrafiteAst.Intros (_, Some num, names) ->
 129       PrimitiveTactics.intros_tac ~howmany:num
 130         ~mk_fresh_name_callback:(namer_of names) ()
 131   | GrafiteAst.Inversion (_, term) ->
 132       Tactics.inversion term
 133   | GrafiteAst.LApply (_, linear, how_many, to_what, what, ident) ->
 134       let names = match ident with None -> [] | Some id -> [id] in
 135       Tactics.lapply ~mk_fresh_name_callback:(namer_of names)
 136         ~linear ?how_many ~to_what what
 137   | GrafiteAst.Left _ -> Tactics.left
 138   | GrafiteAst.LetIn (loc,term,name) ->
 139       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 140   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 141       (match reduction_kind with
 142          | `Normalize -> Tactics.normalize ~pattern
 143          | `Reduce -> Tactics.reduce ~pattern
 144          | `Simpl -> Tactics.simpl ~pattern
 145          | `Unfold what -> Tactics.unfold ~pattern what
 146          | `Whd -> Tactics.whd ~pattern)
 147   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 148   | GrafiteAst.Replace (_, pattern, with_what) ->
 149      Tactics.replace ~pattern ~with_what
 150   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 151      EqualityTactics.rewrite_tac ~direction ~pattern t
 152   | GrafiteAst.Right _ -> Tactics.right
 153   | GrafiteAst.Ring _ -> Tactics.ring
 154   | GrafiteAst.Split _ -> Tactics.split
 155   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 156   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 157   (* Implementazioni Aggiunte *)
 158   | GrafiteAst.Assume (_, id, t) -> Declarative.assume id t
 159   | GrafiteAst.Suppose (_, t, id) -> Declarative.suppose t id
 160   | GrafiteAst.By_term_we_proved (_, t, ty, id) ->
 161      Declarative.by_term_we_proved t ty id
 162   | GrafiteAst.We_need_to_prove (_, t, id) -> Declarative.we_need_to_prove t id
 163   | GrafiteAst.Bydone (_, t) -> Declarative.bydone t
 164
 165 (* maybe we only need special cases for apply and goal *)
 166 let classify_tactic tactic =
 167   match tactic with
 168   (* tactics that can't close the goal (return a goal we want to "select") *)
 169   | GrafiteAst.Rewrite _
 170   | GrafiteAst.Split _
 171   | GrafiteAst.Replace _
 172   | GrafiteAst.Reduce _
 173   | GrafiteAst.Injection _
 174   | GrafiteAst.IdTac _
 175   | GrafiteAst.Generalize _
 176   | GrafiteAst.Elim _
 177   | GrafiteAst.Cut _
 178   | GrafiteAst.Decompose _ -> true, true
 179   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 180   | GrafiteAst.Goal _ -> false, true
 181   (* tactics like apply *)
 182   | _ -> true, false
 183
 184 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 185   let module PEH = ProofEngineHelpers in
 186 (*   let print_m name metasenv =
 187     prerr_endline (">>>>> " ^ name);
 188     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 189   in *)
 190   (* phase one calculates:
 191    *   new_goals_from_refine:  goals added by refine
 192    *   head_goal:              the first goal opened by ythe tactic
 193    *   other_goals:            other goals opened by the tactic
 194    *)
 195   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 196   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 197   let head_goal, other_goals, goals =
 198     match goals with
 199     | [] -> None,[],goals
 200     | hd::tl ->
 201         (* assert (List.mem hd new_goals_from_tactic);
 202          * invalidato dalla goal_tac
 203          * *)
 204         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 205         hd) goals
 206   in
 207   let produced_goals =
 208     match head_goal with
 209     | None -> new_goals_from_refine @ other_goals
 210     | Some x -> x :: new_goals_from_refine @ other_goals
 211   in
 212   (* extract the metas generated by refine and tactic *)
 213   let metas_for_tactic_head =
 214     match head_goal with
 215     | None -> []
 216     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 217   let metas_for_tactic_goals =
 218     List.map
 219       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 220     goals
 221   in
 222   let metas_for_refine_goals =
 223     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 224   let produced_metas, goals =
 225     let produced_metas =
 226       if always_opens_a_goal then
 227         metas_for_tactic_head @ metas_for_refine_goals @
 228           metas_for_tactic_goals
 229       else begin
 230 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 231         print_m "metas_for_tactic_head" metas_for_tactic_head;
 232         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 233         metas_for_refine_goals @ metas_for_tactic_head @
 234           metas_for_tactic_goals
 235       end
 236     in
 237     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 238     produced_metas, goals
 239   in
 240   (* residual metas, preserving the original order *)
 241   let before, after =
 242     let rec split e =
 243       function
 244       | [] -> [],[]
 245       | (metano, _, _) :: tl when metano = e ->
 246           [], List.map (fun (x,_,_) -> x) tl
 247       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 248     in
 249     let find n metasenv =
 250       try
 251         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 252       with Not_found -> None
 253     in
 254     let extract l =
 255       List.fold_right
 256         (fun n acc ->
 257           match find n tactic with
 258           | Some x -> x::acc
 259           | None -> acc
 260         ) l [] in
 261     let before_l, after_l = split current_goal start in
 262     let before_l =
 263       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 264     let after_l =
 265       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 266     let before = extract before_l in
 267     let after = extract after_l in
 268       before, after
 269   in
 270 (* |+   DEBUG CODE  +|
 271   print_m "BEGIN" start;
 272   prerr_endline ("goal was: " ^ string_of_int current_goal);
 273   prerr_endline ("and metas from refine are:");
 274   List.iter
 275     (fun t -> prerr_string (" " ^ string_of_int t))
 276   new_goals_from_refine;
 277   prerr_endline "";
 278   print_m "before" before;
 279   print_m "metas_for_tactic_head" metas_for_tactic_head;
 280   print_m "metas_for_refine_goals" metas_for_refine_goals;
 281   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 282   print_m "produced_metas" produced_metas;
 283   print_m "after" after;
 284 |+   FINE DEBUG CODE +| *)
 285   before @ produced_metas @ after, goals
 286
 287 let apply_tactic ~disambiguate_tactic (text,prefix_len,tactic) (status, goal) =
 288 (* prerr_endline "apply_tactic"; *)
 289 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 290  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 291  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 292 (* prerr_endline "disambiguate"; *)
 293  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 294  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 295  let proof = GrafiteTypes.get_current_proof status in
 296  let proof_status = proof, goal in
 297  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 298  let tactic = tactic_of_ast tactic in
 299  (* apply tactic will change the lexicon_status ... *)
 300 (* prerr_endline "apply_tactic bassa"; *)
 301  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 302  let after = ProofEngineTypes.goals_of_proof proof in
 303  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 304 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 305 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 306 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 307 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 308 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 309  let proof, opened_goals =
 310    if needs_reordering then begin
 311      let uri, metasenv_after_tactic, t, ty = proof in
 312 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 313      let reordered_metasenv, opened_goals =
 314        reorder_metasenv
 315         starting_metasenv
 316         metasenv_after_refinement metasenv_after_tactic
 317         opened goal always_opens_a_goal
 318      in
 319      let proof' = uri, reordered_metasenv, t, ty in
 320 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 321      proof', opened_goals
 322    end
 323       else
 324         proof, opened_goals
 325  in
 326  let incomplete_proof =
 327    match status.GrafiteTypes.proof_status with
 328    | GrafiteTypes.Incomplete_proof p -> p
 329    | _ -> assert false
 330  in
 331  { status with GrafiteTypes.proof_status =
 332     GrafiteTypes.Incomplete_proof
 333      { incomplete_proof with GrafiteTypes.proof = proof } },
 334  opened_goals, closed_goals
 335
 336 type eval_ast =
 337  {ea_go:
 338   'term 'lazy_term 'reduction 'obj 'ident.
 339   disambiguate_tactic:
 340    (GrafiteTypes.status ->
 341     ProofEngineTypes.goal ->
 342     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 343     disambiguator_input ->
 344     GrafiteTypes.status *
 345    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 346
 347   disambiguate_command:
 348    (GrafiteTypes.status ->
 349     ('obj GrafiteAst.command) disambiguator_input ->
 350     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 351
 352   disambiguate_macro:
 353    (GrafiteTypes.status ->
 354     ('term GrafiteAst.macro) disambiguator_input ->
 355     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 356
 357   ?do_heavy_checks:bool ->
 358   ?clean_baseuri:bool ->
 359   GrafiteTypes.status ->
 360   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement)
 361   disambiguator_input ->
 362   GrafiteTypes.status * UriManager.uri list
 363  }
 364
 365 type 'a eval_command =
 366  {ec_go: 'term 'obj.
 367   disambiguate_command:
 368    (GrafiteTypes.status -> ('obj GrafiteAst.command) disambiguator_input ->
 369     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 370   options -> GrafiteTypes.status ->
 371     ('obj GrafiteAst.command) disambiguator_input ->
 372    GrafiteTypes.status * UriManager.uri list
 373  }
 374
 375 type 'a eval_executable =
 376  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 377   disambiguate_tactic:
 378    (GrafiteTypes.status ->
 379     ProofEngineTypes.goal ->
 380     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 381     disambiguator_input ->
 382     GrafiteTypes.status *
 383    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 384
 385   disambiguate_command:
 386    (GrafiteTypes.status ->
 387     ('obj GrafiteAst.command) disambiguator_input ->
 388     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 389
 390   disambiguate_macro:
 391    (GrafiteTypes.status ->
 392     ('term GrafiteAst.macro) disambiguator_input ->
 393     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 394
 395   options ->
 396   GrafiteTypes.status ->
 397   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code) disambiguator_input ->
 398   GrafiteTypes.status * UriManager.uri list
 399  }
 400
 401 type 'a eval_from_moo =
 402  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 403
 404 let coercion_moo_statement_of uri =
 405   GrafiteAst.Coercion (HExtlib.dummy_floc, uri, false)
 406
 407 let refinement_toolkit = {
 408   RefinementTool.type_of_aux' =
 409     (fun ?localization_tbl e c t u ->
 410       let saved = !CicRefine.insert_coercions in
 411       CicRefine.insert_coercions:= false;
 412       let rc =
 413         try
 414           let t, ty, metasenv, ugraph =
 415             CicRefine.type_of_aux' ?localization_tbl e c t u in
 416           RefinementTool.Success (t, ty, metasenv, ugraph)
 417         with
 418         | CicRefine.RefineFailure s
 419         | CicRefine.Uncertain s
 420         | CicRefine.AssertFailure s -> RefinementTool.Exception s
 421       in
 422       CicRefine.insert_coercions := saved;
 423       rc);
 424   RefinementTool.ppsubst = CicMetaSubst.ppsubst;
 425   RefinementTool.apply_subst = CicMetaSubst.apply_subst;
 426   RefinementTool.ppmetasenv = CicMetaSubst.ppmetasenv;
 427   RefinementTool.pack_coercion_obj = CicRefine.pack_coercion_obj;
 428  }
 429
 430 let eval_coercion status ~add_composites uri =
 431  let status,compounds =
 432   GrafiteSync.add_coercion ~add_composites refinement_toolkit status uri in
 433  let moo_content =
 434    List.map coercion_moo_statement_of (uri::compounds)
 435  in
 436  let status = GrafiteTypes.add_moo_content moo_content status in
 437   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 438    compounds
 439
 440 let eval_tactical ~disambiguate_tactic status tac =
 441  let apply_tactic = apply_tactic ~disambiguate_tactic in
 442  let module MatitaStatus =
 443   struct
 444    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 445
 446    type output_status =
 447      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 448
 449    type tactic = input_status -> output_status
 450
 451    let id_tactic = apply_tactic ("",0,(GrafiteAst.IdTac HExtlib.dummy_floc))
 452    let mk_tactic tac = tac
 453    let apply_tactic tac = tac
 454    let goals (_, opened, closed) = opened, closed
 455    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 456    let get_stack (status, _) = GrafiteTypes.get_stack status
 457
 458    let set_stack stack (status, opened, closed) =
 459      GrafiteTypes.set_stack stack status, opened, closed
 460
 461    let inject (status, _) = (status, [], [])
 462    let focus goal (status, _, _) = (status, goal)
 463   end
 464  in
 465  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 466   let rec tactical_of_ast l (text,prefix_len,tac) =
 467     let apply_tactic t = apply_tactic (text, prefix_len, t) in
 468     let tactical_of_ast l t = tactical_of_ast l (text,prefix_len,t) in
 469     match tac with
 470     | GrafiteAst.Tactic (loc, tactic) ->
 471         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 472     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 473        assert (l > 0);
 474        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 475     | GrafiteAst.Do (loc, n, tactical) ->
 476         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 477     | GrafiteAst.Repeat (loc, tactical) ->
 478         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 479     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 480         assert (l > 0);
 481         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 482           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 483     | GrafiteAst.First (loc, tacticals) ->
 484         MatitaTacticals.first
 485           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 486     | GrafiteAst.Try (loc, tactical) ->
 487         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 488     | GrafiteAst.Solve (loc, tacticals) ->
 489         MatitaTacticals.solve_tactics
 490          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 491
 492     | GrafiteAst.Skip _loc -> MatitaTacticals.skip
 493     | GrafiteAst.Dot _loc -> MatitaTacticals.dot
 494     | GrafiteAst.Semicolon _loc -> MatitaTacticals.semicolon
 495     | GrafiteAst.Branch _loc -> MatitaTacticals.branch
 496     | GrafiteAst.Shift _loc -> MatitaTacticals.shift
 497     | GrafiteAst.Pos (_loc, i) -> MatitaTacticals.pos i
 498     | GrafiteAst.Merge _loc -> MatitaTacticals.merge
 499     | GrafiteAst.Focus (_loc, goals) -> MatitaTacticals.focus goals
 500     | GrafiteAst.Unfocus _loc -> MatitaTacticals.unfocus
 501     | GrafiteAst.Wildcard _loc -> MatitaTacticals.wildcard
 502   in
 503   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 504   let status =  (* is proof completed? *)
 505     match status.GrafiteTypes.proof_status with
 506     | GrafiteTypes.Incomplete_proof
 507        { GrafiteTypes.stack = stack; proof = proof }
 508       when Continuationals.Stack.is_empty stack ->
 509         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 510     | _ -> status
 511   in
 512   status
 513
 514 let eval_comment status c = status
 515
 516 (* since the record syntax allows to declare coercions, we have to put this
 517  * information inside the moo *)
 518 let add_coercions_of_record_to_moo obj lemmas status =
 519   let attributes = CicUtil.attributes_of_obj obj in
 520   let is_record = function `Class (`Record att) -> Some att | _-> None in
 521   match HExtlib.list_findopt is_record attributes with
 522   | None -> status,[]
 523   | Some fields ->
 524       let is_a_coercion uri =
 525         try
 526           let obj,_ =
 527             CicEnvironment.get_cooked_obj  CicUniv.empty_ugraph uri in
 528           let attrs = CicUtil.attributes_of_obj obj in
 529           List.mem (`Class `Coercion) attrs
 530         with Not_found -> assert false
 531       in
 532       (* looking at the fields we can know the 'wanted' coercions, but not the
 533        * actually generated ones. So, only the intersection between the wanted
 534        * and the actual should be in the moo as coercion, while everithing in
 535        * lemmas should go as aliases *)
 536       let wanted_coercions =
 537         HExtlib.filter_map
 538           (function
 539             | (name,true) ->
 540                Some
 541                  (UriManager.uri_of_string
 542                    (GrafiteTypes.qualify status name ^ ".con"))
 543             | _ -> None)
 544           fields
 545       in
 546       (*prerr_endline "wanted coercions:";
 547       List.iter
 548         (fun u -> prerr_endline (UriManager.string_of_uri u))
 549         wanted_coercions; *)
 550       let coercions, moo_content =
 551         List.split
 552           (HExtlib.filter_map
 553             (fun uri ->
 554               let is_a_wanted_coercion =
 555                 List.exists (UriManager.eq uri) wanted_coercions
 556               in
 557               if is_a_coercion uri || is_a_wanted_coercion then
 558                 Some (uri, coercion_moo_statement_of uri)
 559               else
 560                 None)
 561             lemmas)
 562       in
 563       (*prerr_endline "actual coercions:";
 564       List.iter
 565         (fun u -> prerr_endline (UriManager.string_of_uri u))
 566         coercions;
 567       prerr_endline "lemmas was:";
 568       List.iter
 569         (fun u -> prerr_endline (UriManager.string_of_uri u))
 570         lemmas; *)
 571       let status = GrafiteTypes.add_moo_content moo_content status in
 572       {status with
 573         GrafiteTypes.coercions = coercions @ status.GrafiteTypes.coercions},
 574       lemmas
 575
 576 let add_obj uri obj status =
 577  let status,lemmas = GrafiteSync.add_obj refinement_toolkit uri obj status in
 578  status, lemmas
 579
 580 let rec eval_command = {ec_go = fun ~disambiguate_command opts status
 581 (text,prefix_len,cmd) ->
 582  let status,cmd = disambiguate_command status (text,prefix_len,cmd) in
 583  let status,uris =
 584   match cmd with
 585   | GrafiteAst.Default (loc, what, uris) as cmd ->
 586      LibraryObjects.set_default what uris;
 587      GrafiteTypes.add_moo_content [cmd] status,[]
 588   | GrafiteAst.Include (loc, baseuri) ->
 589      let moopath_rw, moopath_r =
 590        LibraryMisc.obj_file_of_baseuri
 591          ~must_exist:false ~baseuri ~writable:true,
 592        LibraryMisc.obj_file_of_baseuri
 593          ~must_exist:false ~baseuri ~writable:false
 594      in
 595      let moopath =
 596        if Sys.file_exists moopath_r then moopath_r else
 597          if Sys.file_exists moopath_rw then moopath_rw else
 598            raise (IncludedFileNotCompiled (moopath_rw,baseuri))
 599      in
 600      let status = eval_from_moo.efm_go status moopath in
 601      status,[]
 602   | GrafiteAst.Set (loc, name, value) ->
 603       if name = "baseuri" then begin
 604         let value =
 605           let v = Http_getter_misc.strip_trailing_slash value in
 606           try
 607             ignore (String.index v ' ');
 608             GrafiteTypes.command_error "baseuri can't contain spaces"
 609           with Not_found -> v
 610         in
 611         if Http_getter_storage.is_read_only value then begin
 612           HLog.error (sprintf "uri %s belongs to a read-only repository" value);
 613           raise (ReadOnlyUri value)
 614         end;
 615         if not (Http_getter_storage.is_empty value) &&
 616            opts.clean_baseuri
 617           then begin
 618           HLog.message ("baseuri " ^ value ^ " is not empty");
 619           HLog.message ("cleaning baseuri " ^ value);
 620           LibraryClean.clean_baseuris [value];
 621           assert (Http_getter_storage.is_empty value);
 622         end;
 623         HExtlib.mkdir
 624           (Filename.dirname (Http_getter.filename ~writable:true (value ^
 625             "/foo.con")));
 626       end;
 627       GrafiteTypes.set_option status name value,[]
 628   | GrafiteAst.Drop loc -> raise Drop
 629   | GrafiteAst.Qed loc ->
 630       let uri, metasenv, bo, ty =
 631         match status.GrafiteTypes.proof_status with
 632         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 633             uri, metasenv, body, ty
 634         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 635             raise (GrafiteTypes.Command_error
 636               ("Someone allows to start a theorem without giving the "^
 637                "name/uri. This should be fixed!"))
 638         | _->
 639           raise
 640            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 641       in
 642       if metasenv <> [] then
 643         raise
 644          (GrafiteTypes.Command_error
 645            "Proof not completed! metasenv is not empty!");
 646       let name = UriManager.name_of_uri uri in
 647       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 648       let status, lemmas = add_obj uri obj status in
 649        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 650         uri::lemmas
 651   | GrafiteAst.Coercion (loc, uri, add_composites) ->
 652      eval_coercion status ~add_composites uri
 653   | GrafiteAst.Obj (loc,obj) ->
 654      let ext,name =
 655       match obj with
 656          Cic.Constant (name,_,_,_,_)
 657        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 658        | Cic.InductiveDefinition (types,_,_,_) ->
 659           ".ind",
 660           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 661        | _ -> assert false in
 662      let uri =
 663        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext) in
 664      let obj = CicRefine.pack_coercion_obj obj in
 665      let metasenv = GrafiteTypes.get_proof_metasenv status in
 666      match obj with
 667      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 668          let name = UriManager.name_of_uri uri in
 669          if not(CicPp.check name ty) then
 670            HLog.error ("Bad name: " ^ name);
 671          if opts.do_heavy_checks then
 672            begin
 673              let dbd = LibraryDb.instance () in
 674              let similar = Whelp.match_term ~dbd ty in
 675              let similar_len = List.length similar in
 676              if similar_len> 30 then
 677                (HLog.message
 678                  ("Duplicate check will compare your theorem with " ^
 679                    string_of_int similar_len ^
 680                    " theorems, this may take a while."));
 681              let convertible =
 682                List.filter (
 683                  fun u ->
 684                    let t = CicUtil.term_of_uri u in
 685                    let ty',g =
 686                      CicTypeChecker.type_of_aux'
 687                        metasenv' [] t CicUniv.empty_ugraph
 688                    in
 689                    fst(CicReduction.are_convertible [] ty' ty g))
 690                similar
 691              in
 692              (match convertible with
 693              | [] -> ()
 694              | x::_ ->
 695                  HLog.warn
 696                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 697                   "\nPlease use a variant."));
 698            end;
 699          let initial_proof = (Some uri, metasenv', bo, ty) in
 700          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 701          { status with GrafiteTypes.proof_status =
 702             GrafiteTypes.Incomplete_proof
 703              { GrafiteTypes.proof = initial_proof; stack = initial_stack } },
 704           []
 705      | _ ->
 706          if metasenv <> [] then
 707           raise (GrafiteTypes.Command_error (
 708             "metasenv not empty while giving a definition with body: " ^
 709             CicMetaSubst.ppmetasenv [] metasenv));
 710          let status, lemmas = add_obj uri obj status in
 711          let status,new_lemmas =
 712           add_coercions_of_record_to_moo obj lemmas status
 713          in
 714           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 715            uri::new_lemmas@lemmas
 716  in
 717   match status.GrafiteTypes.proof_status with
 718      GrafiteTypes.Intermediate _ ->
 719       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 720    | _ -> status,uris
 721
 722 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command
 723 ~disambiguate_macro opts status (text,prefix_len,ex) ->
 724   match ex with
 725   | GrafiteAst.Tactical (_, tac, None) ->
 726      eval_tactical ~disambiguate_tactic status (text,prefix_len,tac),[]
 727   | GrafiteAst.Tactical (_, tac, Some punct) ->
 728      let status =
 729        eval_tactical ~disambiguate_tactic status (text,prefix_len,tac) in
 730       eval_tactical ~disambiguate_tactic status (text,prefix_len,punct),[]
 731   | GrafiteAst.Command (_, cmd) ->
 732       eval_command.ec_go ~disambiguate_command opts status (text,prefix_len,cmd)
 733   | GrafiteAst.Macro (loc, macro) ->
 734      raise (Macro (loc,disambiguate_macro status (text,prefix_len,macro)))
 735
 736 } and eval_from_moo = {efm_go = fun status fname ->
 737   let ast_of_cmd cmd =
 738     ("",0,GrafiteAst.Executable (HExtlib.dummy_floc,
 739       GrafiteAst.Command (HExtlib.dummy_floc,
 740         cmd)))
 741   in
 742   let moo = GrafiteMarshal.load_moo fname in
 743   List.fold_left
 744     (fun status ast ->
 745       let ast = ast_of_cmd ast in
 746       let status,lemmas =
 747        eval_ast.ea_go
 748          ~disambiguate_tactic:(fun status _ (_,_,tactic) -> status,tactic)
 749          ~disambiguate_command:(fun status (_,_,cmd) -> status,cmd)
 750          ~disambiguate_macro:(fun _ _ -> assert false)
 751          status ast
 752       in
 753        assert (lemmas=[]);
 754        status)
 755     status moo
 756 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
 757 ~disambiguate_macro ?(do_heavy_checks=false) ?(clean_baseuri=true) status
 758 (text,prefix_len,st)
 759 ->
 760   let opts = {
 761     do_heavy_checks = do_heavy_checks ;
 762     clean_baseuri = clean_baseuri }
 763   in
 764   match st with
 765   | GrafiteAst.Executable (_,ex) ->
 766      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 767       ~disambiguate_macro opts status (text,prefix_len,ex)
 768   | GrafiteAst.Comment (_,c) -> eval_comment status (text,prefix_len,c),[]
 769 }
 770
 771 let eval_ast = eval_ast.ea_go