components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Drop
  31 exception IncludedFileNotCompiled of string (* file name *)
  32 exception Macro of
  33  GrafiteAst.loc *
  34   (Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro)
  35 exception ReadOnlyUri of string
  36
  37 type options = {
  38   do_heavy_checks: bool ;
  39   clean_baseuri: bool
  40 }
  41
  42 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  43   * names as long as they are available, then it fallbacks to name generation
  44   * using FreshNamesGenerator module *)
  45 let namer_of names =
  46   let len = List.length names in
  47   let count = ref 0 in
  48   fun metasenv context name ~typ ->
  49     if !count < len then begin
  50       let name = Cic.Name (List.nth names !count) in
  51       incr count;
  52       name
  53     end else
  54       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  55
  56 let tactic_of_ast ast =
  57   let module PET = ProofEngineTypes in
  58   match ast with
  59   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  60   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  61   | GrafiteAst.Assumption _ -> Tactics.assumption
  62   | GrafiteAst.Auto (_,depth,width,paramodulation,full) ->
  63       AutoTactic.auto_tac ?depth ?width ?paramodulation ?full
  64         ~dbd:(LibraryDb.instance ()) ()
  65   | GrafiteAst.Change (_, pattern, with_what) ->
  66      Tactics.change ~pattern with_what
  67   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  68   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  69   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  70   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  71   | GrafiteAst.Cut (_, ident, term) ->
  72      let names = match ident with None -> [] | Some id -> [id] in
  73      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  74   | GrafiteAst.Decompose (_, types, what, names) ->
  75       let to_type = function
  76          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  77          | GrafiteAst.Ident _            -> assert false
  78       in
  79       let user_types = List.rev_map to_type types in
  80       let dbd = LibraryDb.instance () in
  81       let mk_fresh_name_callback = namer_of names in
  82       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  83   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  84   | GrafiteAst.Elim (_, what, using, depth, names) ->
  85       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  86         what
  87   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  88       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  89         what
  90   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  91   | GrafiteAst.Exists _ -> Tactics.exists
  92   | GrafiteAst.Fail _ -> Tactics.fail
  93   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
  94       let reduction =
  95         match reduction_kind with
  96         | `Demodulate ->
  97             GrafiteTypes.command_error "demodulation can't be folded"
  98         | `Normalize ->
  99             PET.const_lazy_reduction
 100               (CicReduction.normalize ~delta:false ~subst:[])
 101         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
 102         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 103         | `Unfold None ->
 104             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 105         | `Unfold (Some lazy_term) ->
 106            (fun context metasenv ugraph ->
 107              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 108              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 109         | `Whd ->
 110             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 111       in
 112       Tactics.fold ~reduction ~term ~pattern
 113   | GrafiteAst.Fourier _ -> Tactics.fourier
 114   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 115      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 116       ~dbd:(LibraryDb.instance ()) hyp
 117   | GrafiteAst.Generalize (_,pattern,ident) ->
 118      let names = match ident with None -> [] | Some id -> [id] in
 119      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 120   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 121   | GrafiteAst.IdTac _ -> Tactics.id
 122   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 123   | GrafiteAst.Intros (_, None, names) ->
 124       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 125   | GrafiteAst.Intros (_, Some num, names) ->
 126       PrimitiveTactics.intros_tac ~howmany:num
 127         ~mk_fresh_name_callback:(namer_of names) ()
 128   | GrafiteAst.Inversion (_, term) ->
 129       Tactics.inversion term
 130   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 131       let names = match ident with None -> [] | Some id -> [id] in
 132       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 133         ~to_what what
 134   | GrafiteAst.Left _ -> Tactics.left
 135   | GrafiteAst.LetIn (loc,term,name) ->
 136       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 137   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 138       (match reduction_kind with
 139          | `Demodulate -> Tactics.demodulate ~dbd:(LibraryDb.instance ()) ~pattern
 140          | `Normalize -> Tactics.normalize ~pattern
 141          | `Reduce -> Tactics.reduce ~pattern
 142          | `Simpl -> Tactics.simpl ~pattern
 143          | `Unfold what -> Tactics.unfold ~pattern what
 144          | `Whd -> Tactics.whd ~pattern)
 145   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 146   | GrafiteAst.Replace (_, pattern, with_what) ->
 147      Tactics.replace ~pattern ~with_what
 148   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 149      EqualityTactics.rewrite_tac ~direction ~pattern t
 150   | GrafiteAst.Right _ -> Tactics.right
 151   | GrafiteAst.Ring _ -> Tactics.ring
 152   | GrafiteAst.Split _ -> Tactics.split
 153   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 154   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 155
 156 (* maybe we only need special cases for apply and goal *)
 157 let classify_tactic tactic =
 158   match tactic with
 159   (* tactics that can't close the goal (return a goal we want to "select") *)
 160   | GrafiteAst.Rewrite _
 161   | GrafiteAst.Split _
 162   | GrafiteAst.Replace _
 163   | GrafiteAst.Reduce _
 164   | GrafiteAst.Injection _
 165   | GrafiteAst.IdTac _
 166   | GrafiteAst.Generalize _
 167   | GrafiteAst.Elim _
 168   | GrafiteAst.Cut _
 169   | GrafiteAst.Decompose _ -> true, true
 170   (* tactics we don't want to reorder goals. I think only Goal needs this. *)
 171   | GrafiteAst.Goal _ -> false, true
 172   (* tactics like apply *)
 173   | _ -> true, false
 174
 175 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 176   let module PEH = ProofEngineHelpers in
 177 (*   let print_m name metasenv =
 178     prerr_endline (">>>>> " ^ name);
 179     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 180   in *)
 181   (* phase one calculates:
 182    *   new_goals_from_refine:  goals added by refine
 183    *   head_goal:              the first goal opened by ythe tactic
 184    *   other_goals:            other goals opened by the tactic
 185    *)
 186   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 187   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 188   let head_goal, other_goals, goals =
 189     match goals with
 190     | [] -> None,[],goals
 191     | hd::tl ->
 192         (* assert (List.mem hd new_goals_from_tactic);
 193          * invalidato dalla goal_tac
 194          * *)
 195         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 196         hd) goals
 197   in
 198   let produced_goals =
 199     match head_goal with
 200     | None -> new_goals_from_refine @ other_goals
 201     | Some x -> x :: new_goals_from_refine @ other_goals
 202   in
 203   (* extract the metas generated by refine and tactic *)
 204   let metas_for_tactic_head =
 205     match head_goal with
 206     | None -> []
 207     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 208   let metas_for_tactic_goals =
 209     List.map
 210       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 211     goals
 212   in
 213   let metas_for_refine_goals =
 214     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 215   let produced_metas, goals =
 216     let produced_metas =
 217       if always_opens_a_goal then
 218         metas_for_tactic_head @ metas_for_refine_goals @
 219           metas_for_tactic_goals
 220       else begin
 221 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 222         print_m "metas_for_tactic_head" metas_for_tactic_head;
 223         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 224         metas_for_refine_goals @ metas_for_tactic_head @
 225           metas_for_tactic_goals
 226       end
 227     in
 228     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 229     produced_metas, goals
 230   in
 231   (* residual metas, preserving the original order *)
 232   let before, after =
 233     let rec split e =
 234       function
 235       | [] -> [],[]
 236       | (metano, _, _) :: tl when metano = e ->
 237           [], List.map (fun (x,_,_) -> x) tl
 238       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 239     in
 240     let find n metasenv =
 241       try
 242         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 243       with Not_found -> None
 244     in
 245     let extract l =
 246       List.fold_right
 247         (fun n acc ->
 248           match find n tactic with
 249           | Some x -> x::acc
 250           | None -> acc
 251         ) l [] in
 252     let before_l, after_l = split current_goal start in
 253     let before_l =
 254       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 255     let after_l =
 256       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 257     let before = extract before_l in
 258     let after = extract after_l in
 259       before, after
 260   in
 261 (* |+   DEBUG CODE  +|
 262   print_m "BEGIN" start;
 263   prerr_endline ("goal was: " ^ string_of_int current_goal);
 264   prerr_endline ("and metas from refine are:");
 265   List.iter
 266     (fun t -> prerr_string (" " ^ string_of_int t))
 267   new_goals_from_refine;
 268   prerr_endline "";
 269   print_m "before" before;
 270   print_m "metas_for_tactic_head" metas_for_tactic_head;
 271   print_m "metas_for_refine_goals" metas_for_refine_goals;
 272   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 273   print_m "produced_metas" produced_metas;
 274   print_m "after" after;
 275 |+   FINE DEBUG CODE +| *)
 276   before @ produced_metas @ after, goals
 277
 278 let apply_tactic ~disambiguate_tactic tactic (status, goal) =
 279 (* prerr_endline "apply_tactic"; *)
 280 (* prerr_endline (Continuationals.Stack.pp (GrafiteTypes.get_stack status)); *)
 281  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 282  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 283 (* prerr_endline "disambiguate"; *)
 284  let status, tactic = disambiguate_tactic status goal tactic in
 285  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 286  let proof = GrafiteTypes.get_current_proof status in
 287  let proof_status = proof, goal in
 288  let needs_reordering, always_opens_a_goal = classify_tactic tactic in
 289  let tactic = tactic_of_ast tactic in
 290  (* apply tactic will change the lexicon_status ... *)
 291 (* prerr_endline "apply_tactic bassa"; *)
 292  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 293  let after = ProofEngineTypes.goals_of_proof proof in
 294  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 295 (* prerr_endline("before: " ^ String.concat ", " (List.map string_of_int before));
 296 prerr_endline("after: " ^ String.concat ", " (List.map string_of_int after));
 297 prerr_endline("opened: " ^ String.concat ", " (List.map string_of_int opened)); *)
 298 (* prerr_endline("opened_goals: " ^ String.concat ", " (List.map string_of_int opened_goals));
 299 prerr_endline("closed_goals: " ^ String.concat ", " (List.map string_of_int closed_goals)); *)
 300  let proof, opened_goals =
 301    if needs_reordering then begin
 302      let uri, metasenv_after_tactic, t, ty = proof in
 303 (* prerr_endline ("goal prima del riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof))); *)
 304      let reordered_metasenv, opened_goals =
 305        reorder_metasenv
 306         starting_metasenv
 307         metasenv_after_refinement metasenv_after_tactic
 308         opened goal always_opens_a_goal
 309      in
 310      let proof' = uri, reordered_metasenv, t, ty in
 311 (* prerr_endline ("goal dopo il riordino: " ^ String.concat " " (List.map string_of_int (ProofEngineTypes.goals_of_proof proof'))); *)
 312      proof', opened_goals
 313    end
 314       else
 315         proof, opened_goals
 316  in
 317  let incomplete_proof =
 318    match status.GrafiteTypes.proof_status with
 319    | GrafiteTypes.Incomplete_proof p -> p
 320    | _ -> assert false
 321  in
 322  { status with GrafiteTypes.proof_status =
 323     GrafiteTypes.Incomplete_proof
 324      { incomplete_proof with GrafiteTypes.proof = proof } },
 325  opened_goals, closed_goals
 326
 327 type eval_ast =
 328  {ea_go:
 329   'term 'lazy_term 'reduction 'obj 'ident.
 330   disambiguate_tactic:
 331    (GrafiteTypes.status ->
 332     ProofEngineTypes.goal ->
 333     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 334     GrafiteTypes.status *
 335    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 336
 337   disambiguate_command:
 338    (GrafiteTypes.status ->
 339     'obj GrafiteAst.command ->
 340     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 341
 342   disambiguate_macro:
 343    (GrafiteTypes.status ->
 344     'term GrafiteAst.macro ->
 345     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 346
 347   ?do_heavy_checks:bool ->
 348   ?clean_baseuri:bool ->
 349   GrafiteTypes.status ->
 350   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement ->
 351   GrafiteTypes.status * UriManager.uri list
 352  }
 353
 354 type 'a eval_command =
 355  {ec_go: 'term 'obj.
 356   disambiguate_command:
 357    (GrafiteTypes.status ->
 358     'obj GrafiteAst.command ->
 359     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 360   options -> GrafiteTypes.status -> 'obj GrafiteAst.command ->
 361    GrafiteTypes.status * UriManager.uri list
 362  }
 363
 364 type 'a eval_executable =
 365  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 366   disambiguate_tactic:
 367    (GrafiteTypes.status ->
 368     ProofEngineTypes.goal ->
 369     ('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic ->
 370     GrafiteTypes.status *
 371    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 372
 373   disambiguate_command:
 374    (GrafiteTypes.status ->
 375     'obj GrafiteAst.command ->
 376     GrafiteTypes.status * Cic.obj GrafiteAst.command) ->
 377
 378   disambiguate_macro:
 379    (GrafiteTypes.status ->
 380     'term GrafiteAst.macro ->
 381     Cic.context -> GrafiteTypes.status * Cic.term GrafiteAst.macro) ->
 382
 383   options ->
 384   GrafiteTypes.status ->
 385   ('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code ->
 386   GrafiteTypes.status * UriManager.uri list
 387  }
 388
 389 type 'a eval_from_moo =
 390  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 391
 392 let coercion_moo_statement_of uri =
 393   GrafiteAst.Coercion (HExtlib.dummy_floc, uri, false)
 394
 395 let refinement_toolkit = {
 396   RefinementTool.type_of_aux' =
 397     (fun ?localization_tbl e c t u ->
 398       let saved = !CicRefine.insert_coercions in
 399       CicRefine.insert_coercions:= false;
 400       let rc =
 401         try
 402           let t, ty, metasenv, ugraph =
 403             CicRefine.type_of_aux' ?localization_tbl e c t u in
 404           RefinementTool.Success (t, ty, metasenv, ugraph)
 405         with
 406         | CicRefine.RefineFailure s
 407         | CicRefine.Uncertain s
 408         | CicRefine.AssertFailure s -> RefinementTool.Exception s
 409       in
 410       CicRefine.insert_coercions := saved;
 411       rc);
 412   RefinementTool.ppsubst = CicMetaSubst.ppsubst;
 413   RefinementTool.apply_subst = CicMetaSubst.apply_subst;
 414   RefinementTool.ppmetasenv = CicMetaSubst.ppmetasenv;
 415   RefinementTool.pack_coercion_obj = CicRefine.pack_coercion_obj;
 416  }
 417
 418 let eval_coercion status ~add_composites uri =
 419  let status,compounds =
 420   GrafiteSync.add_coercion ~add_composites refinement_toolkit status uri in
 421  let moo_content = coercion_moo_statement_of uri in
 422  let status = GrafiteTypes.add_moo_content [moo_content] status in
 423   {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 424    compounds
 425
 426 let eval_tactical ~disambiguate_tactic status tac =
 427  let apply_tactic = apply_tactic ~disambiguate_tactic in
 428  let module MatitaStatus =
 429   struct
 430    type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 431
 432    type output_status =
 433      GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 434
 435    type tactic = input_status -> output_status
 436
 437    let id_tactic = apply_tactic (GrafiteAst.IdTac HExtlib.dummy_floc)
 438    let mk_tactic tac = tac
 439    let apply_tactic tac = tac
 440    let goals (_, opened, closed) = opened, closed
 441    let set_goals (opened, closed) (status, _, _) = (status, opened, closed)
 442    let get_stack (status, _) = GrafiteTypes.get_stack status
 443
 444    let set_stack stack (status, opened, closed) =
 445      GrafiteTypes.set_stack stack status, opened, closed
 446
 447    let inject (status, _) = (status, [], [])
 448    let focus goal (status, _, _) = (status, goal)
 449   end
 450  in
 451  let module MatitaTacticals = Tacticals.Make (MatitaStatus) in
 452   let rec tactical_of_ast l tac =
 453     match tac with
 454     | GrafiteAst.Tactic (loc, tactic) ->
 455         MatitaTacticals.tactic (MatitaStatus.mk_tactic (apply_tactic tactic))
 456     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 457        assert (l > 0);
 458        MatitaTacticals.seq ~tactics:(List.map (tactical_of_ast (l+1)) tacticals)
 459     | GrafiteAst.Do (loc, n, tactical) ->
 460         MatitaTacticals.do_tactic ~n ~tactic:(tactical_of_ast (l+1) tactical)
 461     | GrafiteAst.Repeat (loc, tactical) ->
 462         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 463     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 464         assert (l > 0);
 465         MatitaTacticals.thens ~start:(tactical_of_ast (l+1) tactical)
 466           ~continuations:(List.map (tactical_of_ast (l+1)) tacticals)
 467     | GrafiteAst.First (loc, tacticals) ->
 468         MatitaTacticals.first
 469           ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 470     | GrafiteAst.Try (loc, tactical) ->
 471         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast (l+1) tactical)
 472     | GrafiteAst.Solve (loc, tacticals) ->
 473         MatitaTacticals.solve_tactics
 474          ~tactics:(List.map (fun t -> "", tactical_of_ast (l+1) t) tacticals)
 475
 476     | GrafiteAst.Skip loc -> MatitaTacticals.skip
 477     | GrafiteAst.Dot loc -> MatitaTacticals.dot
 478     | GrafiteAst.Semicolon loc -> MatitaTacticals.semicolon
 479     | GrafiteAst.Branch loc -> MatitaTacticals.branch
 480     | GrafiteAst.Shift loc -> MatitaTacticals.shift
 481     | GrafiteAst.Pos (loc, i) -> MatitaTacticals.pos i
 482     | GrafiteAst.Merge loc -> MatitaTacticals.merge
 483     | GrafiteAst.Focus (loc, goals) -> MatitaTacticals.focus goals
 484     | GrafiteAst.Unfocus loc -> MatitaTacticals.unfocus
 485   in
 486   let status, _, _ = tactical_of_ast 0 tac (status, ~-1) in
 487   let status =  (* is proof completed? *)
 488     match status.GrafiteTypes.proof_status with
 489     | GrafiteTypes.Incomplete_proof
 490        { GrafiteTypes.stack = stack; proof = proof }
 491       when Continuationals.Stack.is_empty stack ->
 492         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 493     | _ -> status
 494   in
 495   status
 496
 497 let eval_comment status c = status
 498
 499 (* since the record syntax allows to declare coercions, we have to put this
 500  * information inside the moo *)
 501 let add_coercions_of_record_to_moo obj lemmas status =
 502   let attributes = CicUtil.attributes_of_obj obj in
 503   let is_record = function `Class (`Record att) -> Some att | _-> None in
 504   match HExtlib.list_findopt is_record attributes with
 505   | None -> status,[]
 506   | Some fields ->
 507       let is_a_coercion uri =
 508         try
 509           let obj,_ =
 510             CicEnvironment.get_cooked_obj  CicUniv.empty_ugraph uri in
 511           let attrs = CicUtil.attributes_of_obj obj in
 512           List.mem (`Class `Projection) attrs
 513         with Not_found -> assert false
 514       in
 515       (* looking at the fields we can know the 'wanted' coercions, but not the
 516        * actually generated ones. So, only the intersection between the wanted
 517        * and the actual should be in the moo as coercion, while everithing in
 518        * lemmas should go as aliases *)
 519       let wanted_coercions =
 520         HExtlib.filter_map
 521           (function
 522             | (name,true) ->
 523                Some
 524                  (UriManager.uri_of_string
 525                    (GrafiteTypes.qualify status name ^ ".con"))
 526             | _ -> None)
 527           fields
 528       in
 529       (*
 530       prerr_endline "wanted coercions:";
 531       List.iter
 532         (fun u -> prerr_endline (UriManager.string_of_uri u))
 533         wanted_coercions; *)
 534       let coercions, moo_content =
 535         List.split
 536           (HExtlib.filter_map
 537             (fun uri ->
 538               let is_a_wanted_coercion =
 539                 List.exists (UriManager.eq uri) wanted_coercions in
 540               if is_a_coercion uri && is_a_wanted_coercion then
 541                 Some (uri, coercion_moo_statement_of uri)
 542               else
 543                 None)
 544             lemmas)
 545       in
 546       (* prerr_endline "actual coercions:";
 547       List.iter
 548         (fun u -> prerr_endline (UriManager.string_of_uri u))
 549         coercions; *)
 550       let status = GrafiteTypes.add_moo_content moo_content status in
 551       {status with
 552         GrafiteTypes.coercions = coercions @ status.GrafiteTypes.coercions},
 553       lemmas
 554
 555 let add_obj uri obj status =
 556  let status,lemmas = GrafiteSync.add_obj refinement_toolkit uri obj status in
 557  status, lemmas
 558
 559 let rec eval_command = {ec_go = fun ~disambiguate_command opts status cmd ->
 560  let status,cmd = disambiguate_command status cmd in
 561  let status,uris =
 562   match cmd with
 563   | GrafiteAst.Default (loc, what, uris) as cmd ->
 564      LibraryObjects.set_default what uris;
 565      GrafiteTypes.add_moo_content [cmd] status,[]
 566   | GrafiteAst.Include (loc, baseuri) ->
 567      let moopath_rw, moopath_r =
 568        LibraryMisc.obj_file_of_baseuri
 569          ~must_exist:false ~baseuri ~writable:true,
 570        LibraryMisc.obj_file_of_baseuri
 571          ~must_exist:false ~baseuri ~writable:false
 572      in
 573      let moopath =
 574        if Sys.file_exists moopath_r then moopath_r else
 575          if Sys.file_exists moopath_rw then moopath_rw else
 576            raise (IncludedFileNotCompiled moopath_rw)
 577      in
 578      let status = eval_from_moo.efm_go status moopath in
 579      status,[]
 580   | GrafiteAst.Set (loc, name, value) ->
 581       if name = "baseuri" then begin
 582         let value =
 583           let v = Http_getter_misc.strip_trailing_slash value in
 584           try
 585             ignore (String.index v ' ');
 586             GrafiteTypes.command_error "baseuri can't contain spaces"
 587           with Not_found -> v
 588         in
 589         if Http_getter_storage.is_read_only value then begin
 590           HLog.error (sprintf "uri %s belongs to a read-only repository" value);
 591           raise (ReadOnlyUri value)
 592         end;
 593         if not (Http_getter_storage.is_empty value) &&
 594            opts.clean_baseuri
 595           then begin
 596           HLog.message ("baseuri " ^ value ^ " is not empty");
 597           HLog.message ("cleaning baseuri " ^ value);
 598           LibraryClean.clean_baseuris [value];
 599           assert (Http_getter_storage.is_empty value);
 600         end;
 601         HExtlib.mkdir
 602           (Filename.dirname (Http_getter.filename ~writable:true (value ^
 603             "/foo.con")));
 604       end;
 605       GrafiteTypes.set_option status name value,[]
 606   | GrafiteAst.Drop loc -> raise Drop
 607   | GrafiteAst.Qed loc ->
 608       let uri, metasenv, bo, ty =
 609         match status.GrafiteTypes.proof_status with
 610         | GrafiteTypes.Proof (Some uri, metasenv, body, ty) ->
 611             uri, metasenv, body, ty
 612         | GrafiteTypes.Proof (None, metasenv, body, ty) ->
 613             raise (GrafiteTypes.Command_error
 614               ("Someone allows to start a theorem without giving the "^
 615                "name/uri. This should be fixed!"))
 616         | _->
 617           raise
 618            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 619       in
 620       if metasenv <> [] then
 621         raise
 622          (GrafiteTypes.Command_error
 623            "Proof not completed! metasenv is not empty!");
 624       let name = UriManager.name_of_uri uri in
 625       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 626       let status, lemmas = add_obj uri obj status in
 627        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 628         uri::lemmas
 629   | GrafiteAst.Coercion (loc, uri, add_composites) ->
 630      eval_coercion status ~add_composites uri
 631   | GrafiteAst.Obj (loc,obj) ->
 632      let ext,name =
 633       match obj with
 634          Cic.Constant (name,_,_,_,_)
 635        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 636        | Cic.InductiveDefinition (types,_,_,_) ->
 637           ".ind",
 638           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 639        | _ -> assert false in
 640      let uri =
 641        UriManager.uri_of_string (GrafiteTypes.qualify status name ^ ext) in
 642      let obj = CicRefine.pack_coercion_obj obj in
 643      let metasenv = GrafiteTypes.get_proof_metasenv status in
 644      match obj with
 645      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 646          let name = UriManager.name_of_uri uri in
 647          if not(CicPp.check name ty) then
 648            HLog.error ("Bad name: " ^ name);
 649          if opts.do_heavy_checks then
 650            begin
 651              let dbd = LibraryDb.instance () in
 652              let similar = Whelp.match_term ~dbd ty in
 653              let similar_len = List.length similar in
 654              if similar_len> 30 then
 655                (HLog.message
 656                  ("Duplicate check will compare your theorem with " ^
 657                    string_of_int similar_len ^
 658                    " theorems, this may take a while."));
 659              let convertible =
 660                List.filter (
 661                  fun u ->
 662                    let t = CicUtil.term_of_uri u in
 663                    let ty',g =
 664                      CicTypeChecker.type_of_aux'
 665                        metasenv' [] t CicUniv.empty_ugraph
 666                    in
 667                    fst(CicReduction.are_convertible [] ty' ty g))
 668                similar
 669              in
 670              (match convertible with
 671              | [] -> ()
 672              | x::_ ->
 673                  HLog.warn
 674                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 675                   "\nPlease use a variant."));
 676            end;
 677          let initial_proof = (Some uri, metasenv', bo, ty) in
 678          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 679          { status with GrafiteTypes.proof_status =
 680             GrafiteTypes.Incomplete_proof
 681              { GrafiteTypes.proof = initial_proof; stack = initial_stack } },
 682           []
 683      | _ ->
 684          if metasenv <> [] then
 685           raise (GrafiteTypes.Command_error (
 686             "metasenv not empty while giving a definition with body: " ^
 687             CicMetaSubst.ppmetasenv [] metasenv));
 688          let status, lemmas = add_obj uri obj status in
 689          let status,new_lemmas =
 690           add_coercions_of_record_to_moo obj lemmas status
 691          in
 692           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 693            uri::new_lemmas@lemmas
 694  in
 695   match status.GrafiteTypes.proof_status with
 696      GrafiteTypes.Intermediate _ ->
 697       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 698    | _ -> status,uris
 699
 700 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command ~disambiguate_macro opts status ex ->
 701   match ex with
 702   | GrafiteAst.Tactical (_, tac, None) ->
 703      eval_tactical ~disambiguate_tactic status tac,[]
 704   | GrafiteAst.Tactical (_, tac, Some punct) ->
 705      let status = eval_tactical ~disambiguate_tactic status tac in
 706       eval_tactical ~disambiguate_tactic status punct,[]
 707   | GrafiteAst.Command (_, cmd) ->
 708       eval_command.ec_go ~disambiguate_command opts status cmd
 709   | GrafiteAst.Macro (loc, macro) ->
 710      raise (Macro (loc,disambiguate_macro status macro))
 711
 712 } and eval_from_moo = {efm_go = fun status fname ->
 713   let ast_of_cmd cmd =
 714     GrafiteAst.Executable (HExtlib.dummy_floc,
 715       GrafiteAst.Command (HExtlib.dummy_floc,
 716         cmd))
 717   in
 718   let moo = GrafiteMarshal.load_moo fname in
 719   List.fold_left
 720     (fun status ast ->
 721       let ast = ast_of_cmd ast in
 722       let status,lemmas =
 723        eval_ast.ea_go
 724          ~disambiguate_tactic:(fun status _ tactic -> status,tactic)
 725          ~disambiguate_command:(fun status cmd -> status,cmd)
 726          ~disambiguate_macro:(fun _ _ -> assert false)
 727          status ast
 728       in
 729        assert (lemmas=[]);
 730        status)
 731     status moo
 732 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command ~disambiguate_macro ?(do_heavy_checks=false) ?(clean_baseuri=true) status st
 733 ->
 734   let opts = {
 735     do_heavy_checks = do_heavy_checks ;
 736     clean_baseuri = clean_baseuri }
 737   in
 738   match st with
 739   | GrafiteAst.Executable (_,ex) ->
 740      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 741       ~disambiguate_macro opts status ex
 742   | GrafiteAst.Comment (_,c) -> eval_comment status c,[]
 743 }
 744
 745 let eval_ast = eval_ast.ea_go