components/grafite_parser/grafiteDisambiguator.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Ambiguous_input
  31 (* the integer is an offset to be added to each location *)
  32 exception DisambiguationError of
  33  int * (Token.flocation option * string Lazy.t) list list
  34   (** parameters are: option name, error message *)
  35 exception Unbound_identifier of string
  36
  37 type choose_uris_callback =
  38   id:string -> UriManager.uri list -> UriManager.uri list
  39
  40 type choose_interp_callback =
  41   string -> int ->
  42     (Token.flocation list * string * string) list list -> int list
  43
  44 let mono_uris_callback ~id =
  45  if Helm_registry.get_opt_default Helm_registry.get_bool ~default:true
  46       "matita.auto_disambiguation"
  47  then
  48   function l -> l
  49  else
  50   raise Ambiguous_input
  51
  52 let mono_interp_callback _ _ _ = raise Ambiguous_input
  53
  54 let _choose_uris_callback = ref mono_uris_callback
  55 let _choose_interp_callback = ref mono_interp_callback
  56 let set_choose_uris_callback f = _choose_uris_callback := f
  57 let set_choose_interp_callback f = _choose_interp_callback := f
  58
  59 module Callbacks =
  60   struct
  61     let interactive_user_uri_choice ~selection_mode ?ok
  62           ?(enable_button_for_non_vars = true) ~title ~msg ~id uris =
  63               !_choose_uris_callback ~id uris
  64
  65     let interactive_interpretation_choice interp =
  66       !_choose_interp_callback interp
  67
  68     let input_or_locate_uri ~(title:string) ?id () = None
  69       (* Zack: I try to avoid using this callback. I therefore assume that
  70       * the presence of an identifier that can't be resolved via "locate"
  71       * query is a syntax error *)
  72   end
  73
  74 module Disambiguator = Disambiguate.Make (Callbacks)
  75
  76 (* implement module's API *)
  77
  78 let only_one_pass = ref false;;
  79
  80 let disambiguate_thing ~aliases ~universe
  81   ~(f:?fresh_instances:bool ->
  82       aliases:DisambiguateTypes.environment ->
  83       universe:DisambiguateTypes.multiple_environment option ->
  84       'a -> 'b)
  85   ~(drop_aliases: ?minimize_instances:bool -> 'b -> 'b)
  86   ~(drop_aliases_and_clear_diff: 'b -> 'b)
  87   (thing: 'a)
  88 =
  89   assert (universe <> None);
  90   let library = false, DisambiguateTypes.Environment.empty, None in
  91   let multi_aliases = false, DisambiguateTypes.Environment.empty, universe in
  92   let mono_aliases = true, aliases, Some DisambiguateTypes.Environment.empty in
  93   let passes = (* <fresh_instances?, aliases, coercions?> *)
  94    if !only_one_pass then
  95     [ (false, mono_aliases, false) ]
  96    else
  97     [ (false, mono_aliases, false);
  98       (false, multi_aliases, false);
  99       (true, mono_aliases, false);
 100       (true, multi_aliases, false);
 101       (true, mono_aliases, true);
 102       (true, multi_aliases, true);
 103       (true, library, false);
 104         (* for demo to reduce the number of interpretations *)
 105       (true, library, true);
 106     ]
 107   in
 108   let try_pass (fresh_instances, (_, aliases, universe), insert_coercions) =
 109     CicRefine.insert_coercions := insert_coercions;
 110     f ~fresh_instances ~aliases ~universe thing
 111   in
 112   let set_aliases (instances,(use_mono_aliases,_,_),_) (_, user_asked as res) =
 113    if use_mono_aliases && not instances then
 114     drop_aliases res
 115    else if user_asked then
 116     drop_aliases ~minimize_instances:true res (* one shot aliases *)
 117    else
 118     drop_aliases_and_clear_diff res
 119   in
 120   let rec aux errors =
 121     function
 122     | [ pass ] ->
 123         (try
 124           set_aliases pass (try_pass pass)
 125          with Disambiguate.NoWellTypedInterpretation (offset,newerrors) ->
 126           raise (DisambiguationError (offset, errors @ [newerrors])))
 127     | hd :: tl ->
 128         (try
 129           set_aliases hd (try_pass hd)
 130         with Disambiguate.NoWellTypedInterpretation (_offset,newerrors) ->
 131          aux (errors @ [newerrors]) tl)
 132     | [] -> assert false
 133   in
 134   let saved_insert_coercions = !CicRefine.insert_coercions in
 135   try
 136     let res = aux [] passes in
 137     CicRefine.insert_coercions := saved_insert_coercions;
 138     res
 139   with exn ->
 140     CicRefine.insert_coercions := saved_insert_coercions;
 141     raise exn
 142
 143 type disambiguator_thing =
 144  { do_it :
 145     'a 'b.
 146     aliases:DisambiguateTypes.environment ->
 147     universe:DisambiguateTypes.multiple_environment option ->
 148     f:(?fresh_instances:bool ->
 149        aliases:DisambiguateTypes.environment ->
 150        universe:DisambiguateTypes.multiple_environment option ->
 151        'a -> 'b * bool) ->
 152     drop_aliases:(?minimize_instances:bool -> 'b * bool -> 'b * bool) ->
 153     drop_aliases_and_clear_diff:('b * bool -> 'b * bool) -> 'a -> 'b * bool
 154  }
 155
 156 let disambiguate_thing =
 157  let profiler = HExtlib.profile "disambiguate_thing" in
 158   { do_it =
 159      fun ~aliases ~universe ~f ~drop_aliases ~drop_aliases_and_clear_diff thing
 160      -> profiler.HExtlib.profile
 161          (disambiguate_thing ~aliases ~universe ~f ~drop_aliases
 162            ~drop_aliases_and_clear_diff) thing
 163   }
 164
 165 let drop_aliases ?(minimize_instances=false) (choices, user_asked) =
 166  let module D = DisambiguateTypes in
 167  let minimize d =
 168   if not minimize_instances then
 169    d
 170   else
 171    let rec aux =
 172     function
 173        [] -> []
 174      | (D.Symbol (s,n),((descr,_) as ci)) as he::tl when n > 0 ->
 175          if
 176           List.for_all
 177            (function
 178                (D.Symbol (s2,_),(descr2,_)) -> s2 <> s || descr = descr2
 179              | _ -> true
 180            ) d
 181          then
 182           (D.Symbol (s,0),ci)::(aux tl)
 183          else
 184           he::(aux tl)
 185      | (D.Num n,((descr,_) as ci)) as he::tl when n > 0 ->
 186          if
 187           List.for_all
 188            (function (D.Num _,(descr2,_)) -> descr = descr2 | _ -> true) d
 189          then
 190           (D.Num 0,ci)::(aux tl)
 191          else
 192           he::(aux tl)
 193       | he::tl -> he::(aux tl)
 194    in
 195     aux d
 196  in
 197   (List.map (fun (d, a, b, c) -> minimize d, a, b, c) choices),
 198   user_asked
 199
 200 let drop_aliases_and_clear_diff (choices, user_asked) =
 201   (List.map (fun (_, a, b, c) -> [], a, b, c) choices),
 202   user_asked
 203
 204 let disambiguate_term ?fresh_instances ~dbd ~context ~metasenv ?initial_ugraph
 205   ~aliases ~universe term
 206  =
 207   assert (fresh_instances = None);
 208   let f =
 209     Disambiguator.disambiguate_term ~dbd ~context ~metasenv ?initial_ugraph
 210   in
 211   disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
 212    ~drop_aliases_and_clear_diff term
 213
 214 let disambiguate_obj ?fresh_instances ~dbd ~aliases ~universe ~uri obj =
 215   assert (fresh_instances = None);
 216   let f = Disambiguator.disambiguate_obj ~dbd ~uri in
 217   disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
 218    ~drop_aliases_and_clear_diff obj