components/grafite_parser/grafiteDisambiguator.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Ambiguous_input
  31 (* the integer is an offset to be added to each location *)
  32 exception DisambiguationError of
  33  int * (Token.flocation option * string Lazy.t) list list
  34   (** parameters are: option name, error message *)
  35 exception Unbound_identifier of string
  36
  37 type choose_uris_callback =
  38   id:string -> UriManager.uri list -> UriManager.uri list
  39
  40 type choose_interp_callback =
  41   string -> int ->
  42     (Token.flocation list * string * string) list list -> int list
  43
  44 let mono_uris_callback ~id =
  45  if Helm_registry.get_opt_default Helm_registry.get_bool ~default:true
  46       "matita.auto_disambiguation"
  47  then
  48   function l -> l
  49  else
  50   raise Ambiguous_input
  51
  52 let mono_interp_callback _ _ _ = raise Ambiguous_input
  53
  54 let _choose_uris_callback = ref mono_uris_callback
  55 let _choose_interp_callback = ref mono_interp_callback
  56 let set_choose_uris_callback f = _choose_uris_callback := f
  57 let set_choose_interp_callback f = _choose_interp_callback := f
  58
  59 module Callbacks =
  60   struct
  61     let interactive_user_uri_choice ~selection_mode ?ok
  62           ?(enable_button_for_non_vars = true) ~title ~msg ~id uris =
  63               !_choose_uris_callback ~id uris
  64
  65     let interactive_interpretation_choice interp =
  66       !_choose_interp_callback interp
  67
  68     let input_or_locate_uri ~(title:string) ?id () = None
  69       (* Zack: I try to avoid using this callback. I therefore assume that
  70       * the presence of an identifier that can't be resolved via "locate"
  71       * query is a syntax error *)
  72   end
  73
  74 module Disambiguator = Disambiguate.Make (Callbacks)
  75
  76 (* implement module's API *)
  77
  78 let disambiguate_thing ~aliases ~universe
  79   ~(f:?fresh_instances:bool ->
  80       aliases:DisambiguateTypes.environment ->
  81       universe:DisambiguateTypes.multiple_environment option ->
  82       'a -> 'b)
  83   ~(drop_aliases: ?minimize_instances:bool -> 'b -> 'b)
  84   ~(drop_aliases_and_clear_diff: 'b -> 'b)
  85   (thing: 'a)
  86 =
  87   assert (universe <> None);
  88   let library = false, DisambiguateTypes.Environment.empty, None in
  89   let multi_aliases = false, DisambiguateTypes.Environment.empty, universe in
  90   let mono_aliases = true, aliases, Some DisambiguateTypes.Environment.empty in
  91   let passes =  (* <fresh_instances?, aliases, coercions?> *)
  92     [ (false, mono_aliases, false);
  93       (false, multi_aliases, false);
  94       (true, mono_aliases, false);
  95       (true, multi_aliases, false);
  96       (true, mono_aliases, true);
  97       (true, multi_aliases, true);
  98       (true, library, false);
  99         (* for demo to reduce the number of interpretations *)
 100       (true, library, true);
 101     ]
 102   in
 103   let try_pass (fresh_instances, (_, aliases, universe), insert_coercions) =
 104     CicRefine.insert_coercions := insert_coercions;
 105     f ~fresh_instances ~aliases ~universe thing
 106   in
 107   let set_aliases (instances,(use_mono_aliases,_,_),_) (_, user_asked as res) =
 108    if use_mono_aliases && not instances then
 109     drop_aliases res
 110    else if user_asked then
 111     drop_aliases ~minimize_instances:true res (* one shot aliases *)
 112    else
 113     drop_aliases_and_clear_diff res
 114   in
 115   let rec aux errors =
 116     function
 117     | [ pass ] ->
 118         (try
 119           set_aliases pass (try_pass pass)
 120          with Disambiguate.NoWellTypedInterpretation (offset,newerrors) ->
 121           raise (DisambiguationError (offset, errors @ [newerrors])))
 122     | hd :: tl ->
 123         (try
 124           set_aliases hd (try_pass hd)
 125         with Disambiguate.NoWellTypedInterpretation (_offset,newerrors) ->
 126          aux (errors @ [newerrors]) tl)
 127     | [] -> assert false
 128   in
 129   let saved_insert_coercions = !CicRefine.insert_coercions in
 130   try
 131     let res = aux [] passes in
 132     CicRefine.insert_coercions := saved_insert_coercions;
 133     res
 134   with exn ->
 135     CicRefine.insert_coercions := saved_insert_coercions;
 136     raise exn
 137
 138 type disambiguator_thing =
 139  { do_it :
 140     'a 'b.
 141     aliases:DisambiguateTypes.environment ->
 142     universe:DisambiguateTypes.multiple_environment option ->
 143     f:(?fresh_instances:bool ->
 144        aliases:DisambiguateTypes.environment ->
 145        universe:DisambiguateTypes.multiple_environment option ->
 146        'a -> 'b * bool) ->
 147     drop_aliases:(?minimize_instances:bool -> 'b * bool -> 'b * bool) ->
 148     drop_aliases_and_clear_diff:('b * bool -> 'b * bool) -> 'a -> 'b * bool
 149  }
 150
 151 let disambiguate_thing =
 152  let profiler = HExtlib.profile "disambiguate_thing" in
 153   { do_it =
 154      fun ~aliases ~universe ~f ~drop_aliases ~drop_aliases_and_clear_diff thing
 155      -> profiler.HExtlib.profile
 156          (disambiguate_thing ~aliases ~universe ~f ~drop_aliases
 157            ~drop_aliases_and_clear_diff) thing
 158   }
 159
 160 let drop_aliases ?(minimize_instances=false) (choices, user_asked) =
 161  let module D = DisambiguateTypes in
 162  let minimize d =
 163   if not minimize_instances then
 164    d
 165   else
 166    let rec aux =
 167     function
 168        [] -> []
 169      | (D.Symbol (s,n),((descr,_) as ci)) as he::tl when n > 0 ->
 170          if
 171           List.for_all
 172            (function
 173                (D.Symbol (s2,_),(descr2,_)) -> s2 <> s || descr = descr2
 174              | _ -> true
 175            ) d
 176          then
 177           (D.Symbol (s,0),ci)::(aux tl)
 178          else
 179           he::(aux tl)
 180      | (D.Num n,((descr,_) as ci)) as he::tl when n > 0 ->
 181          if
 182           List.for_all
 183            (function (D.Num _,(descr2,_)) -> descr = descr2 | _ -> true) d
 184          then
 185           (D.Num 0,ci)::(aux tl)
 186          else
 187           he::(aux tl)
 188       | he::tl -> he::(aux tl)
 189    in
 190     aux d
 191  in
 192   (List.map (fun (d, a, b, c) -> minimize d, a, b, c) choices),
 193   user_asked
 194
 195 let drop_aliases_and_clear_diff (choices, user_asked) =
 196   (List.map (fun (_, a, b, c) -> [], a, b, c) choices),
 197   user_asked
 198
 199 let disambiguate_term ?fresh_instances ~dbd ~context ~metasenv ?initial_ugraph
 200   ~aliases ~universe term
 201  =
 202   assert (fresh_instances = None);
 203   let f =
 204     Disambiguator.disambiguate_term ~dbd ~context ~metasenv ?initial_ugraph
 205   in
 206   disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
 207    ~drop_aliases_and_clear_diff term
 208
 209 let disambiguate_obj ?fresh_instances ~dbd ~aliases ~universe ~uri obj =
 210   assert (fresh_instances = None);
 211   let f = Disambiguator.disambiguate_obj ~dbd ~uri in
 212   disambiguate_thing.do_it ~aliases ~universe ~f ~drop_aliases
 213    ~drop_aliases_and_clear_diff obj