components/grafite_parser/grafiteParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31
  32 type 'a localized_option =
  33    LSome of 'a
  34  | LNone of GrafiteAst.loc
  35
  36 type ast_statement =
  37   (CicNotationPt.term, CicNotationPt.term,
  38    CicNotationPt.term GrafiteAst.reduction, CicNotationPt.obj, string)
  39     GrafiteAst.statement
  40
  41 type statement =
  42   include_paths:string list ->
  43   LexiconEngine.status ->
  44     LexiconEngine.status * ast_statement localized_option
  45
  46 let grammar = CicNotationParser.level2_ast_grammar
  47
  48 let term = CicNotationParser.term
  49 let statement = Grammar.Entry.create grammar "statement"
  50
  51 let add_raw_attribute ~text t = Ast.AttributedTerm (`Raw text, t)
  52
  53 let default_precedence = 50
  54 let default_associativity = Gramext.NonA
  55
  56 EXTEND
  57   GLOBAL: term statement;
  58   arg: [
  59    [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
  60       SYMBOL ":"; ty = term; RPAREN -> names,ty
  61    | name = IDENT -> [name],Ast.Implicit
  62    ]
  63   ];
  64   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
  65   tactic_term: [ [ t = term LEVEL "90N" -> t ] ];
  66   ident_list0: [ [ LPAREN; idents = LIST0 IDENT; RPAREN -> idents ] ];
  67   tactic_term_list1: [
  68     [ tactic_terms = LIST1 tactic_term SEP SYMBOL "," -> tactic_terms ]
  69   ];
  70   reduction_kind: [
  71     [ IDENT "normalize" -> `Normalize
  72     | IDENT "reduce" -> `Reduce
  73     | IDENT "simplify" -> `Simpl
  74     | IDENT "unfold"; t = OPT tactic_term -> `Unfold t
  75     | IDENT "whd" -> `Whd ]
  76   ];
  77   sequent_pattern_spec: [
  78    [ hyp_paths =
  79       LIST0
  80        [ id = IDENT ;
  81          path = OPT [SYMBOL ":" ; path = tactic_term -> path ] ->
  82          (id,match path with Some p -> p | None -> Ast.UserInput) ];
  83      goal_path = OPT [ SYMBOL <:unicode<vdash>>; term = tactic_term -> term ] ->
  84       let goal_path =
  85        match goal_path, hyp_paths with
  86           None, [] -> Some Ast.UserInput
  87         | None, _::_ -> None
  88         | Some goal_path, _ -> Some goal_path
  89       in
  90        hyp_paths,goal_path
  91    ]
  92   ];
  93   pattern_spec: [
  94     [ res = OPT [
  95        "in";
  96        wanted_and_sps =
  97         [ "match" ; wanted = tactic_term ;
  98           sps = OPT [ "in"; sps = sequent_pattern_spec -> sps ] ->
  99            Some wanted,sps
 100         | sps = sequent_pattern_spec ->
 101            None,Some sps
 102         ] ->
 103          let wanted,hyp_paths,goal_path =
 104           match wanted_and_sps with
 105              wanted,None -> wanted, [], Some Ast.UserInput
 106            | wanted,Some (hyp_paths,goal_path) -> wanted,hyp_paths,goal_path
 107          in
 108           wanted, hyp_paths, goal_path ] ->
 109       match res with
 110          None -> None,[],Some Ast.UserInput
 111        | Some ps -> ps]
 112   ];
 113   direction: [
 114     [ SYMBOL ">" -> `LeftToRight
 115     | SYMBOL "<" -> `RightToLeft ]
 116   ];
 117   int: [ [ num = NUMBER -> int_of_string num ] ];
 118   intros_spec: [
 119     [ num = OPT [ num = int -> num ]; idents = OPT ident_list0 ->
 120         let idents = match idents with None -> [] | Some idents -> idents in
 121         num, idents
 122     ]
 123   ];
 124   using: [ [ using = OPT [ IDENT "using"; t = tactic_term -> t ] -> using ] ];
 125   tactic: [
 126     [ IDENT "absurd"; t = tactic_term ->
 127         GrafiteAst.Absurd (loc, t)
 128     | IDENT "apply"; t = tactic_term ->
 129         GrafiteAst.Apply (loc, t)
 130     | IDENT "applyS"; t = tactic_term ->
 131         GrafiteAst.ApplyS (loc, t)
 132     | IDENT "assumption" ->
 133         GrafiteAst.Assumption loc
 134     | IDENT "auto"; params =
 135         LIST0 [ i = IDENT -> i,"" | i = IDENT ; SYMBOL "="; v = [ v = int ->
 136           string_of_int v | v = IDENT -> v ] -> i,v ] ->
 137         GrafiteAst.Auto (loc,params)
 138     | IDENT "clear"; ids = LIST1 IDENT ->
 139         GrafiteAst.Clear (loc, ids)
 140     | IDENT "clearbody"; id = IDENT ->
 141         GrafiteAst.ClearBody (loc,id)
 142     | IDENT "change"; what = pattern_spec; "with"; t = tactic_term ->
 143         GrafiteAst.Change (loc, what, t)
 144     | IDENT "constructor"; n = int ->
 145         GrafiteAst.Constructor (loc, n)
 146     | IDENT "contradiction" ->
 147         GrafiteAst.Contradiction loc
 148     | IDENT "cut"; t = tactic_term; ident = OPT [ "as"; id = IDENT -> id] ->
 149         GrafiteAst.Cut (loc, ident, t)
 150     | IDENT "decompose"; types = OPT ident_list0; what = OPT IDENT;
 151         idents = OPT [ "as"; idents = LIST1 IDENT -> idents ] ->
 152         let types = match types with None -> [] | Some types -> types in
 153         let idents = match idents with None -> [] | Some idents -> idents in
 154         let to_spec id = GrafiteAst.Ident id in
 155         GrafiteAst.Decompose (loc, List.rev_map to_spec types, what, idents)
 156     | IDENT "demodulate" -> GrafiteAst.Demodulate loc
 157     | IDENT "discriminate"; t = tactic_term ->
 158         GrafiteAst.Discriminate (loc, t)
 159     | IDENT "elim"; what = tactic_term; using = using;
 160       (num, idents) = intros_spec ->
 161         GrafiteAst.Elim (loc, what, using, num, idents)
 162     | IDENT "elimType"; what = tactic_term; using = using;
 163       (num, idents) = intros_spec ->
 164         GrafiteAst.ElimType (loc, what, using, num, idents)
 165     | IDENT "exact"; t = tactic_term ->
 166         GrafiteAst.Exact (loc, t)
 167     | IDENT "exists" ->
 168         GrafiteAst.Exists loc
 169     | IDENT "fail" -> GrafiteAst.Fail loc
 170     | IDENT "fold"; kind = reduction_kind; t = tactic_term; p = pattern_spec ->
 171         let (pt,_,_) = p in
 172           if pt <> None then
 173             raise (HExtlib.Localized (loc, CicNotationParser.Parse_error
 174               ("the pattern cannot specify the term to replace, only its"
 175               ^ " paths in the hypotheses and in the conclusion")))
 176         else
 177          GrafiteAst.Fold (loc, kind, t, p)
 178     | IDENT "fourier" ->
 179         GrafiteAst.Fourier loc
 180     | IDENT "fwd"; hyp = IDENT; idents = OPT [ "as"; idents = LIST1 IDENT -> idents ] ->
 181         let idents = match idents with None -> [] | Some idents -> idents in
 182         GrafiteAst.FwdSimpl (loc, hyp, idents)
 183     | IDENT "generalize"; p=pattern_spec; id = OPT ["as" ; id = IDENT -> id] ->
 184        GrafiteAst.Generalize (loc,p,id)
 185     | IDENT "goal"; n = int ->
 186         GrafiteAst.Goal (loc, n)
 187     | IDENT "id" -> GrafiteAst.IdTac loc
 188     | IDENT "injection"; t = tactic_term ->
 189         GrafiteAst.Injection (loc, t)
 190     | IDENT "intro"; ident = OPT IDENT ->
 191         let idents = match ident with None -> [] | Some id -> [id] in
 192         GrafiteAst.Intros (loc, Some 1, idents)
 193     | IDENT "intros"; (num, idents) = intros_spec ->
 194         GrafiteAst.Intros (loc, num, idents)
 195     | IDENT "inversion"; t = tactic_term ->
 196         GrafiteAst.Inversion (loc, t)
 197     | IDENT "lapply";
 198       linear = OPT [ IDENT "linear" ];
 199       depth = OPT [ IDENT "depth"; SYMBOL "="; i = int -> i ];
 200       what = tactic_term;
 201       to_what = OPT [ "to" ; t = tactic_term_list1 -> t ];
 202       ident = OPT [ "as" ; ident = IDENT -> ident ] ->
 203         let linear = match linear with None -> false | Some _ -> true in
 204         let to_what = match to_what with None -> [] | Some to_what -> to_what in
 205         GrafiteAst.LApply (loc, linear, depth, to_what, what, ident)
 206     | IDENT "left" -> GrafiteAst.Left loc
 207     | IDENT "letin"; where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 208         GrafiteAst.LetIn (loc, t, where)
 209     | kind = reduction_kind; p = pattern_spec ->
 210         GrafiteAst.Reduce (loc, kind, p)
 211     | IDENT "reflexivity" ->
 212         GrafiteAst.Reflexivity loc
 213     | IDENT "replace"; p = pattern_spec; "with"; t = tactic_term ->
 214         GrafiteAst.Replace (loc, p, t)
 215     | IDENT "rewrite" ; d = direction; t = tactic_term ; p = pattern_spec ->
 216        let (pt,_,_) = p in
 217         if pt <> None then
 218          raise
 219           (HExtlib.Localized (loc,
 220            (CicNotationParser.Parse_error
 221             "the pattern cannot specify the term to rewrite, only its paths in the hypotheses and in the conclusion")))
 222         else
 223          GrafiteAst.Rewrite (loc, d, t, p)
 224     | IDENT "right" ->
 225         GrafiteAst.Right loc
 226     | IDENT "ring" ->
 227         GrafiteAst.Ring loc
 228     | IDENT "split" ->
 229         GrafiteAst.Split loc
 230     | IDENT "symmetry" ->
 231         GrafiteAst.Symmetry loc
 232     | IDENT "transitivity"; t = tactic_term ->
 233         GrafiteAst.Transitivity (loc, t)
 234      (* Produzioni Aggiunte *)
 235     | IDENT "assume" ; id = IDENT ; SYMBOL ":" ; t = tactic_term ->
 236         GrafiteAst.Assume (loc, id, t)
 237     | IDENT "suppose" ; t = tactic_term ; LPAREN ; id = IDENT ; RPAREN ; t1 = OPT [IDENT "that" ; IDENT "is" ; IDENT "equivalent" ; "to " ; t' = tactic_term -> t']->
 238         GrafiteAst.Suppose (loc, t, id, t1)
 239     | IDENT "by" ; t = [t' = tactic_term -> Some t' | SYMBOL "_" -> None];
 240       cont=by_continuation ->
 241        (match cont with
 242            None -> GrafiteAst.Bydone (loc, t)
 243          | Some (ty,id,t1) ->
 244             GrafiteAst.By_term_we_proved(loc, t, ty, id, t1))
 245     | IDENT "we" ; IDENT "need" ; "to" ; IDENT "prove" ; t = tactic_term ; LPAREN ; id = IDENT ; RPAREN ; t1 = OPT [IDENT "or" ; IDENT "equivalently"; t' = tactic_term -> t']->
 246         GrafiteAst.We_need_to_prove (loc, t, id, t1)
 247     | IDENT "we" ; IDENT "proceed" ; IDENT "by" ; IDENT "induction" ; "on" ; t=tactic_term ; "to" ; IDENT "prove" ; t1=tactic_term ->
 248         GrafiteAst.We_proceed_by_induction_on (loc, t, t1)
 249     | IDENT "by" ; IDENT "induction" ; IDENT "hypothesis" ; IDENT "we" ; IDENT "know" ; t=tactic_term ; LPAREN ; id = IDENT ; RPAREN ->
 250         GrafiteAst.Byinduction(loc, t, id)
 251     | IDENT "the" ; IDENT "thesis" ; IDENT "becomes" ; t=tactic_term ->
 252         GrafiteAst.Thesisbecomes(loc, t)
 253     | IDENT "case" ; id = IDENT ; params=LIST0[LPAREN ; i=IDENT ;
 254         SYMBOL":" ; t=tactic_term ; RPAREN -> i,t] ->
 255          GrafiteAst.Case(loc,id,params)
 256     | IDENT "let" ; id = IDENT ; SYMBOL ":" ; t = tactic_term ; IDENT "such" ; IDENT "that" ; t1=tactic_term ->
 257         GrafiteAst.Let1 (loc, id, t, t1)
 258     | IDENT "by" ; t=[t'=tactic_term->Some t'|SYMBOL "_"-> None] ; IDENT "we" ; IDENT "have" ; t1=tactic_term ; LPAREN ; id=IDENT ; RPAREN ; IDENT "and" ; t2=tactic_term ; LPAREN ; id1=IDENT ; RPAREN ->
 259        GrafiteAst.Bywehave (loc, t, t1, id, t2, id1)
 260     | IDENT "obtain" ; termine=tactic_term ; SYMBOL "=" ; t1=tactic_term ; IDENT "by" ; t2=[ t=tactic_term -> Some t | SYMBOL "_" -> None  ] ->
 261      GrafiteAst.RewritingStep(loc, Some termine, t1, t2)
 262     | SYMBOL "=" ; t1=tactic_term ; IDENT "by" ; t2=[ t=tactic_term -> Some t | SYMBOL "_" -> None  ] ->
 263      GrafiteAst.RewritingStep(loc, None, t1, t2)
 264   ]
 265 ];
 266   by_continuation: [
 267     [ IDENT "we" ; IDENT "proved" ; ty = tactic_term ; LPAREN ; id = IDENT ; RPAREN ; t1 = OPT [IDENT "that" ; IDENT "is" ; IDENT "equivalent" ; "to" ; t2 = tactic_term -> t2] -> Some (ty,id,t1)
 268     | IDENT "done" -> None
 269     ]
 270 ];
 271   atomic_tactical:
 272     [ "sequence" LEFTA
 273       [ t1 = SELF; SYMBOL ";"; t2 = SELF ->
 274           let ts =
 275             match t1 with
 276             | GrafiteAst.Seq (_, l) -> l @ [ t2 ]
 277             | _ -> [ t1; t2 ]
 278           in
 279           GrafiteAst.Seq (loc, ts)
 280       ]
 281     | "then" NONA
 282       [ tac = SELF; SYMBOL ";";
 283         SYMBOL "["; tacs = LIST0 SELF SEP SYMBOL "|"; SYMBOL "]"->
 284           (GrafiteAst.Then (loc, tac, tacs))
 285       ]
 286     | "loops" RIGHTA
 287       [ IDENT "do"; count = int; tac = SELF; IDENT "end" ->
 288           GrafiteAst.Do (loc, count, tac)
 289       | IDENT "repeat"; tac = SELF; IDENT "end" -> GrafiteAst.Repeat (loc, tac)
 290       ]
 291     | "simple" NONA
 292       [ IDENT "first";
 293         SYMBOL "["; tacs = LIST0 SELF SEP SYMBOL "|"; SYMBOL "]"->
 294           GrafiteAst.First (loc, tacs)
 295       | IDENT "try"; tac = SELF -> GrafiteAst.Try (loc, tac)
 296       | IDENT "solve";
 297         SYMBOL "["; tacs = LIST0 SELF SEP SYMBOL "|"; SYMBOL "]"->
 298           GrafiteAst.Solve (loc, tacs)
 299       | LPAREN; tac = SELF; RPAREN -> tac
 300       | tac = tactic -> GrafiteAst.Tactic (loc, tac)
 301       ]
 302     ];
 303   punctuation_tactical:
 304     [
 305       [ SYMBOL "[" -> GrafiteAst.Branch loc
 306       | SYMBOL "|" -> GrafiteAst.Shift loc
 307       | i = LIST1 int SEP SYMBOL ","; SYMBOL ":" -> GrafiteAst.Pos (loc, i)
 308       | SYMBOL "*"; SYMBOL ":" -> GrafiteAst.Wildcard loc
 309       | SYMBOL "]" -> GrafiteAst.Merge loc
 310       | SYMBOL ";" -> GrafiteAst.Semicolon loc
 311       | SYMBOL "." -> GrafiteAst.Dot loc
 312       ]
 313     ];
 314   tactical:
 315     [ "simple" NONA
 316       [ IDENT "focus"; goals = LIST1 int -> GrafiteAst.Focus (loc, goals)
 317       | IDENT "unfocus" -> GrafiteAst.Unfocus loc
 318       | IDENT "skip" -> GrafiteAst.Skip loc
 319       | tac = atomic_tactical LEVEL "loops" -> tac
 320       ]
 321     ];
 322   theorem_flavour: [
 323     [ [ IDENT "definition"  ] -> `Definition
 324     | [ IDENT "fact"        ] -> `Fact
 325     | [ IDENT "lemma"       ] -> `Lemma
 326     | [ IDENT "remark"      ] -> `Remark
 327     | [ IDENT "theorem"     ] -> `Theorem
 328     ]
 329   ];
 330   inductive_spec: [ [
 331     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 332     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 333     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 334     tl = OPT [ "with";
 335       types = LIST1 [
 336         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 337        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 338           (name, true, typ, constructors) ] SEP "with" -> types
 339     ] ->
 340       let params =
 341         List.fold_right
 342           (fun (names, typ) acc ->
 343             (List.map (fun name -> (name, typ)) names) @ acc)
 344           params []
 345       in
 346       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 347       let tl_ind_types = match tl with None -> [] | Some types -> types in
 348       let ind_types = fst_ind_type :: tl_ind_types in
 349       (params, ind_types)
 350   ] ];
 351
 352   record_spec: [ [
 353     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 354      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; SYMBOL "{" ;
 355      fields = LIST0 [
 356        name = IDENT ;
 357        coercion = [ SYMBOL ":" -> false | SYMBOL ":"; SYMBOL ">" -> true ] ;
 358        ty = term -> (name,ty,coercion)
 359      ] SEP SYMBOL ";"; SYMBOL "}" ->
 360       let params =
 361         List.fold_right
 362           (fun (names, typ) acc ->
 363             (List.map (fun name -> (name, typ)) names) @ acc)
 364           params []
 365       in
 366       (params,name,typ,fields)
 367   ] ];
 368
 369   macro: [
 370     [ [ IDENT "check"   ]; t = term ->
 371         GrafiteAst.Check (loc, t)
 372     | [ IDENT "hint" ] -> GrafiteAst.Hint loc
 373     | [ IDENT "whelp"; "match" ] ; t = term ->
 374         GrafiteAst.WMatch (loc,t)
 375     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 376         GrafiteAst.WInstance (loc,t)
 377     | [ IDENT "whelp"; IDENT "locate" ] ; id = QSTRING ->
 378         GrafiteAst.WLocate (loc,id)
 379     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 380         GrafiteAst.WElim (loc, t)
 381     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 382         GrafiteAst.WHint (loc,t)
 383     ]
 384   ];
 385   alias_spec: [
 386     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 387       let alpha = "[a-zA-Z]" in
 388       let num = "[0-9]+" in
 389       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 390       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 391       let rex = Str.regexp ("^"^ident^"$") in
 392       if Str.string_match rex id 0 then
 393         if (try ignore (UriManager.uri_of_string uri); true
 394             with UriManager.IllFormedUri _ -> false)
 395         then
 396           LexiconAst.Ident_alias (id, uri)
 397         else
 398           raise
 399            (HExtlib.Localized (loc, CicNotationParser.Parse_error (sprintf "Not a valid uri: %s" uri)))
 400       else
 401         raise (HExtlib.Localized (loc, CicNotationParser.Parse_error (
 402           sprintf "Not a valid identifier: %s" id)))
 403     | IDENT "symbol"; symbol = QSTRING;
 404       instance = OPT [ LPAREN; IDENT "instance"; n = int; RPAREN -> n ];
 405       SYMBOL "="; dsc = QSTRING ->
 406         let instance =
 407           match instance with Some i -> i | None -> 0
 408         in
 409         LexiconAst.Symbol_alias (symbol, instance, dsc)
 410     | IDENT "num";
 411       instance = OPT [ LPAREN; IDENT "instance"; n = int; RPAREN -> n ];
 412       SYMBOL "="; dsc = QSTRING ->
 413         let instance =
 414           match instance with Some i -> i | None -> 0
 415         in
 416         LexiconAst.Number_alias (instance, dsc)
 417     ]
 418   ];
 419   argument: [
 420     [ l = LIST0 [ SYMBOL <:unicode<eta>> (* η *); SYMBOL "." -> () ];
 421       id = IDENT ->
 422         Ast.IdentArg (List.length l, id)
 423     ]
 424   ];
 425   associativity: [
 426     [ IDENT "left";  IDENT "associative" -> Gramext.LeftA
 427     | IDENT "right"; IDENT "associative" -> Gramext.RightA
 428     | IDENT "non"; IDENT "associative" -> Gramext.NonA
 429     ]
 430   ];
 431   precedence: [
 432     [ "with"; IDENT "precedence"; n = NUMBER -> int_of_string n ]
 433   ];
 434   notation: [
 435     [ dir = OPT direction; s = QSTRING;
 436       assoc = OPT associativity; prec = OPT precedence;
 437       IDENT "for";
 438       p2 =
 439         [ blob = UNPARSED_AST ->
 440             add_raw_attribute ~text:(sprintf "@{%s}" blob)
 441               (CicNotationParser.parse_level2_ast
 442                 (Ulexing.from_utf8_string blob))
 443         | blob = UNPARSED_META ->
 444             add_raw_attribute ~text:(sprintf "${%s}" blob)
 445               (CicNotationParser.parse_level2_meta
 446                 (Ulexing.from_utf8_string blob))
 447         ] ->
 448           let assoc =
 449             match assoc with
 450             | None -> default_associativity
 451             | Some assoc -> assoc
 452           in
 453           let prec =
 454             match prec with
 455             | None -> default_precedence
 456             | Some prec -> prec
 457           in
 458           let p1 =
 459             add_raw_attribute ~text:s
 460               (CicNotationParser.parse_level1_pattern
 461                 (Ulexing.from_utf8_string s))
 462           in
 463           (dir, p1, assoc, prec, p2)
 464     ]
 465   ];
 466   level3_term: [
 467     [ u = URI -> Ast.UriPattern (UriManager.uri_of_string u)
 468     | id = IDENT -> Ast.VarPattern id
 469     | SYMBOL "_" -> Ast.ImplicitPattern
 470     | LPAREN; terms = LIST1 SELF; RPAREN ->
 471         (match terms with
 472         | [] -> assert false
 473         | [term] -> term
 474         | terms -> Ast.ApplPattern terms)
 475     ]
 476   ];
 477   interpretation: [
 478     [ s = CSYMBOL; args = LIST0 argument; SYMBOL "="; t = level3_term ->
 479         (s, args, t)
 480     ]
 481   ];
 482
 483   include_command: [ [
 484       IDENT "include" ; path = QSTRING ->
 485         loc,path,LexiconAst.WithPreferences
 486     | IDENT "include'" ; path = QSTRING ->
 487         loc,path,LexiconAst.WithoutPreferences
 488    ]];
 489
 490   grafite_command: [ [
 491       IDENT "set"; n = QSTRING; v = QSTRING ->
 492         GrafiteAst.Set (loc, n, v)
 493     | IDENT "drop" -> GrafiteAst.Drop loc
 494     | IDENT "print"; s = IDENT -> GrafiteAst.Print (loc,s)
 495     | IDENT "qed" -> GrafiteAst.Qed loc
 496     | IDENT "variant" ; name = IDENT; SYMBOL ":";
 497       typ = term; SYMBOL <:unicode<def>> ; newname = IDENT ->
 498         GrafiteAst.Obj (loc,
 499           Ast.Theorem
 500             (`Variant,name,typ,Some (Ast.Ident (newname, None))))
 501     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 502       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 503         GrafiteAst.Obj (loc, Ast.Theorem (flavour, name, typ, body))
 504     | flavour = theorem_flavour; name = IDENT; SYMBOL <:unicode<def>> (* ≝ *);
 505       body = term ->
 506         GrafiteAst.Obj (loc,
 507           Ast.Theorem (flavour, name, Ast.Implicit, Some body))
 508     | IDENT "axiom"; name = IDENT; SYMBOL ":"; typ = term ->
 509         GrafiteAst.Obj (loc, Ast.Theorem (`Axiom, name, typ, None))
 510     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 511         defs = CicNotationParser.let_defs ->
 512           let name,ty =
 513             match defs with
 514             | ((Ast.Ident (name, None), Some ty),_,_) :: _ -> name,ty
 515             | ((Ast.Ident (name, None), None),_,_) :: _ ->
 516                 name, Ast.Implicit
 517             | _ -> assert false
 518           in
 519           let body = Ast.Ident (name,None) in
 520           GrafiteAst.Obj (loc, Ast.Theorem(`Definition, name, ty,
 521             Some (Ast.LetRec (ind_kind, defs, body))))
 522     | IDENT "inductive"; spec = inductive_spec ->
 523         let (params, ind_types) = spec in
 524         GrafiteAst.Obj (loc, Ast.Inductive (params, ind_types))
 525     | IDENT "coinductive"; spec = inductive_spec ->
 526         let (params, ind_types) = spec in
 527         let ind_types = (* set inductive flags to false (coinductive) *)
 528           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 529             ind_types
 530         in
 531         GrafiteAst.Obj (loc, Ast.Inductive (params, ind_types))
 532     | IDENT "coercion" ; suri = URI ->
 533         GrafiteAst.Coercion (loc, UriManager.uri_of_string suri, true)
 534     | IDENT "record" ; (params,name,ty,fields) = record_spec ->
 535         GrafiteAst.Obj (loc, Ast.Record (params,name,ty,fields))
 536     | IDENT "default" ; what = QSTRING ; uris = LIST1 URI ->
 537        let uris = List.map UriManager.uri_of_string uris in
 538         GrafiteAst.Default (loc,what,uris)
 539   ]];
 540   lexicon_command: [ [
 541       IDENT "alias" ; spec = alias_spec ->
 542         LexiconAst.Alias (loc, spec)
 543     | IDENT "notation"; (dir, l1, assoc, prec, l2) = notation ->
 544         LexiconAst.Notation (loc, dir, l1, assoc, prec, l2)
 545     | IDENT "interpretation"; id = QSTRING;
 546       (symbol, args, l3) = interpretation ->
 547         LexiconAst.Interpretation (loc, id, (symbol, args), l3)
 548   ]];
 549   executable: [
 550     [ cmd = grafite_command; SYMBOL "." -> GrafiteAst.Command (loc, cmd)
 551     | tac = tactical; punct = punctuation_tactical ->
 552         GrafiteAst.Tactical (loc, tac, Some punct)
 553     | punct = punctuation_tactical -> GrafiteAst.Tactical (loc, punct, None)
 554     | mac = macro; SYMBOL "." -> GrafiteAst.Macro (loc, mac)
 555     ]
 556   ];
 557   comment: [
 558     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 559        GrafiteAst.Code (loc, ex)
 560     | str = NOTE ->
 561        GrafiteAst.Note (loc, str)
 562     ]
 563   ];
 564   statement: [
 565     [ ex = executable ->
 566        fun ~include_paths status -> status,LSome(GrafiteAst.Executable (loc,ex))
 567     | com = comment ->
 568        fun ~include_paths status -> status,LSome (GrafiteAst.Comment (loc, com))
 569     | (iloc,fname,mode) = include_command ; SYMBOL "."  ->
 570        fun ~include_paths status ->
 571         let buri, fullpath =
 572           DependenciesParser.baseuri_of_script ~include_paths fname
 573         in
 574         let status =
 575          LexiconEngine.eval_command status
 576            (LexiconAst.Include (iloc,buri,mode,fullpath))
 577         in
 578          status,
 579           LSome
 580           (GrafiteAst.Executable
 581            (loc,GrafiteAst.Command
 582             (loc,GrafiteAst.Include (iloc,buri))))
 583     | scom = lexicon_command ; SYMBOL "." ->
 584        fun ~include_paths status ->
 585         let status = LexiconEngine.eval_command status scom in
 586          status,LNone loc
 587     | EOI -> raise End_of_file
 588     ]
 589   ];
 590 END
 591
 592 let exc_located_wrapper f =
 593   try
 594     f ()
 595   with
 596   | Stdpp.Exc_located (_, End_of_file) -> raise End_of_file
 597   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 598       raise (HExtlib.Localized (floc,CicNotationParser.Parse_error msg))
 599   | Stdpp.Exc_located (floc, exn) ->
 600       raise
 601        (HExtlib.Localized (floc,CicNotationParser.Parse_error (Printexc.to_string exn)))
 602
 603 let parse_statement lexbuf =
 604   exc_located_wrapper
 605     (fun () -> (Grammar.Entry.parse statement (Obj.magic lexbuf)))