components/library/cicElim.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 exception Elim_failure of string Lazy.t
  31 exception Can_t_eliminate
  32
  33 let debug_print = fun _ -> ()
  34 (*let debug_print s = prerr_endline (Lazy.force s) *)
  35
  36 let counter = ref ~-1 ;;
  37
  38 let fresh_binder () =  Cic.Name "matita_dummy"
  39 (*
  40  incr counter;
  41  Cic.Name ("e" ^ string_of_int !counter) *)
  42
  43   (** verifies if a given inductive type occurs in a term in target position *)
  44 let rec recursive uri typeno = function
  45   | Cic.Prod (_, _, target) -> recursive uri typeno target
  46   | Cic.MutInd (uri', typeno', [])
  47   | Cic.Appl (Cic.MutInd  (uri', typeno', []) :: _) ->
  48       UriManager.eq uri uri' && typeno = typeno'
  49   | _ -> false
  50
  51   (** given a list of constructor types, return true if at least one of them is
  52   * recursive, false otherwise *)
  53 let recursive_type uri typeno constructors =
  54   let rec aux = function
  55     | Cic.Prod (_, src, tgt) -> recursive uri typeno src || aux tgt
  56     | _ -> false
  57   in
  58   List.exists (fun (_, ty) -> aux ty) constructors
  59
  60 let unfold_appl = function
  61   | Cic.Appl ((Cic.Appl args) :: tl) -> Cic.Appl (args @ tl)
  62   | t -> t
  63
  64 let rec split l n =
  65  match (l,n) with
  66     (l,0) -> ([], l)
  67   | (he::tl, n) -> let (l1,l2) = split tl (n-1) in (he::l1,l2)
  68   | (_,_) -> assert false
  69
  70   (** build elimination principle part related to a single constructor
  71   * @param paramsno number of Prod to ignore in this constructor (i.e. number of
  72   * inductive parameters)
  73   * @param dependent true if we are in the dependent case (i.e. sort <> Prop) *)
  74 let rec delta (uri, typeno) dependent paramsno consno t p args =
  75   match t with
  76   | Cic.MutInd (uri', typeno', []) when
  77     UriManager.eq uri uri' && typeno = typeno' ->
  78       if dependent then
  79         (match args with
  80         | [] -> assert false
  81         | [arg] -> unfold_appl (Cic.Appl [p; arg])
  82         | _ -> unfold_appl (Cic.Appl [p; unfold_appl (Cic.Appl args)]))
  83       else
  84         p
  85   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
  86     UriManager.eq uri uri' && typeno = typeno' ->
  87       let (lparams, rparams) = split tl paramsno in
  88       if dependent then
  89         (match args with
  90         | [] -> assert false
  91         | [arg] -> unfold_appl (Cic.Appl (p :: rparams @ [arg]))
  92         | _ ->
  93             unfold_appl (Cic.Appl (p ::
  94               rparams @ [unfold_appl (Cic.Appl args)])))
  95       else  (* non dependent *)
  96         (match rparams with
  97         | [] -> p
  98         | _ -> Cic.Appl (p :: rparams))
  99   | Cic.Prod (binder, src, tgt) ->
 100       if recursive uri typeno src then
 101         let args = List.map (CicSubstitution.lift 2) args in
 102         let phi =
 103           let src = CicSubstitution.lift 1 src in
 104           delta (uri, typeno) dependent paramsno consno src
 105             (CicSubstitution.lift 1 p) [Cic.Rel 1]
 106         in
 107         let tgt = CicSubstitution.lift 1 tgt in
 108         Cic.Prod (fresh_binder (), src,
 109           Cic.Prod (Cic.Anonymous, phi,
 110             delta (uri, typeno) dependent paramsno consno tgt
 111               (CicSubstitution.lift 2 p) (args @ [Cic.Rel 2])))
 112       else  (* non recursive *)
 113         let args = List.map (CicSubstitution.lift 1) args in
 114         Cic.Prod (fresh_binder (), src,
 115           delta (uri, typeno) dependent paramsno consno tgt
 116             (CicSubstitution.lift 1 p) (args @ [Cic.Rel 1]))
 117   | _ -> assert false
 118
 119 let rec strip_left_params consno leftno = function
 120   | t when leftno = 0 -> t (* no need to lift, the term is (hopefully) closed *)
 121   | Cic.Prod (_, _, tgt) (* when leftno > 0 *) ->
 122       (* after stripping the parameters we lift of consno. consno is 1 based so,
 123       * the first constructor will be lifted by 1 (for P), the second by 2 (1
 124       * for P and 1 for the 1st constructor), and so on *)
 125       if leftno = 1 then
 126         CicSubstitution.lift consno tgt
 127       else
 128         strip_left_params consno (leftno - 1) tgt
 129   | _ -> assert false
 130
 131 let delta (ury, typeno) dependent paramsno consno t p args =
 132   let t = strip_left_params consno paramsno t in
 133   delta (ury, typeno) dependent paramsno consno t p args
 134
 135 let rec add_params binder indno ty eliminator =
 136   if indno = 0 then
 137     eliminator
 138   else
 139     match ty with
 140     | Cic.Prod (name, src, tgt) ->
 141        let name =
 142         match name with
 143            Cic.Name _ -> name
 144          | Cic.Anonymous -> fresh_binder ()
 145        in
 146         binder name src (add_params binder (indno - 1) tgt eliminator)
 147     | _ -> assert false
 148
 149 let rec mk_rels consno = function
 150   | 0 -> []
 151   | n -> Cic.Rel (n+consno) :: mk_rels consno (n-1)
 152
 153 let rec strip_pi = function
 154   | Cic.Prod (_, _, tgt) -> strip_pi tgt
 155   | t -> t
 156
 157 let rec count_pi = function
 158   | Cic.Prod (_, _, tgt) -> count_pi tgt + 1
 159   | t -> 0
 160
 161 let rec type_of_p sort dependent leftno indty = function
 162   | Cic.Prod (n, src, tgt) when leftno = 0 ->
 163       let n =
 164        if dependent then
 165         match n with
 166            Cic.Name _ -> n
 167          | Cic.Anonymous -> fresh_binder ()
 168        else
 169         n
 170       in
 171        Cic.Prod (n, src, type_of_p sort dependent leftno indty tgt)
 172   | Cic.Prod (_, _, tgt) -> type_of_p sort dependent (leftno - 1) indty tgt
 173   | t ->
 174       if dependent then
 175         Cic.Prod (Cic.Anonymous, indty, Cic.Sort sort)
 176       else
 177         Cic.Sort sort
 178
 179 let rec add_right_pi dependent strip liftno liftfrom rightno indty = function
 180   | Cic.Prod (_, src, tgt) when strip = 0 ->
 181       Cic.Prod (fresh_binder (),
 182         CicSubstitution.lift_from liftfrom liftno src,
 183         add_right_pi dependent strip liftno (liftfrom + 1) rightno indty tgt)
 184   | Cic.Prod (_, _, tgt) ->
 185       add_right_pi dependent (strip - 1) liftno liftfrom rightno indty tgt
 186   | t ->
 187       if dependent then
 188         Cic.Prod (fresh_binder (),
 189           CicSubstitution.lift_from (rightno + 1) liftno indty,
 190           Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 0 (rightno + 1)))
 191       else
 192         Cic.Prod (Cic.Anonymous,
 193           CicSubstitution.lift_from (rightno + 1) liftno indty,
 194           if rightno = 0 then
 195             Cic.Rel (1 + liftno + rightno)
 196           else
 197             Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 1 rightno))
 198
 199 let rec add_right_lambda dependent strip liftno liftfrom rightno indty case =
 200 function
 201   | Cic.Prod (_, src, tgt) when strip = 0 ->
 202       Cic.Lambda (fresh_binder (),
 203         CicSubstitution.lift_from liftfrom liftno src,
 204         add_right_lambda dependent strip liftno (liftfrom + 1) rightno indty
 205           case tgt)
 206   | Cic.Prod (_, _, tgt) ->
 207       add_right_lambda true (strip - 1) liftno liftfrom rightno indty
 208         case tgt
 209   | t ->
 210       Cic.Lambda (fresh_binder (),
 211         CicSubstitution.lift_from (rightno + 1) liftno indty, case)
 212
 213 let rec branch (uri, typeno) insource paramsno t fix head args =
 214   match t with
 215   | Cic.MutInd (uri', typeno', []) when
 216     UriManager.eq uri uri' && typeno = typeno' ->
 217       if insource then
 218         (match args with
 219         | [arg] -> Cic.Appl (fix :: args)
 220         | _ -> Cic.Appl (head :: [Cic.Appl args]))
 221       else
 222         (match args with
 223         | [] -> head
 224         | _ -> Cic.Appl (head :: args))
 225   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
 226     UriManager.eq uri uri' && typeno = typeno' ->
 227       if insource then
 228         let (lparams, rparams) = split tl paramsno in
 229         match args with
 230         | [arg] -> Cic.Appl (fix :: rparams @ args)
 231         | _ -> Cic.Appl (fix :: rparams @ [Cic.Appl args])
 232       else
 233         (match args with
 234         | [] -> head
 235         | _ -> Cic.Appl (head :: args))
 236   | Cic.Prod (binder, src, tgt) ->
 237       if recursive uri typeno src then
 238         let args = List.map (CicSubstitution.lift 1) args in
 239         let phi =
 240           let fix = CicSubstitution.lift 1 fix in
 241           let src = CicSubstitution.lift 1 src in
 242           branch (uri, typeno) true paramsno src fix head [Cic.Rel 1]
 243         in
 244         Cic.Lambda (fresh_binder (), src,
 245           branch (uri, typeno) insource paramsno tgt
 246             (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 247             (args @ [Cic.Rel 1; phi]))
 248       else  (* non recursive *)
 249         let args = List.map (CicSubstitution.lift 1) args in
 250         Cic.Lambda (fresh_binder (), src,
 251           branch (uri, typeno) insource paramsno tgt
 252           (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 253             (args @ [Cic.Rel 1]))
 254   | _ -> assert false
 255
 256 let branch (uri, typeno) insource liftno paramsno t fix head args =
 257   let t = strip_left_params liftno paramsno t in
 258   branch (uri, typeno) insource paramsno t fix head args
 259
 260 let elim_of ~sort uri typeno =
 261   counter := ~-1;
 262   let (obj, univ) = (CicEnvironment.get_obj CicUniv.empty_ugraph uri) in
 263   match obj with
 264   | Cic.InductiveDefinition (indTypes, params, leftno, _) ->
 265       let (name, inductive, ty, constructors) =
 266         try
 267           List.nth indTypes typeno
 268         with Failure _ -> assert false
 269       in
 270       let paramsno = count_pi ty in (* number of (left or right) parameters *)
 271       let rightno = paramsno - leftno in
 272       let dependent = (strip_pi ty <> Cic.Sort Cic.Prop) in
 273       let head =
 274        match strip_pi ty with
 275           Cic.Sort s -> s
 276         | _ -> assert false
 277       in
 278       let conslen = List.length constructors in
 279       let consno = ref (conslen + 1) in
 280       if
 281        not
 282         (CicTypeChecker.check_allowed_sort_elimination uri typeno head sort)
 283       then
 284        raise Can_t_eliminate;
 285       let indty =
 286         let indty = Cic.MutInd (uri, typeno, []) in
 287         if paramsno = 0 then
 288           indty
 289         else
 290           Cic.Appl (indty :: mk_rels 0 paramsno)
 291       in
 292       let mk_constructor consno =
 293         let constructor = Cic.MutConstruct (uri, typeno, consno, []) in
 294         if leftno = 0 then
 295           constructor
 296         else
 297           Cic.Appl (constructor :: mk_rels consno leftno)
 298       in
 299       let p_ty = type_of_p sort dependent leftno indty ty in
 300       let final_ty =
 301         add_right_pi dependent leftno (conslen + 1) 1 rightno indty ty
 302       in
 303       let eliminator_type =
 304         let cic =
 305           Cic.Prod (Cic.Name "P", p_ty,
 306             (List.fold_right
 307               (fun (_, constructor) acc ->
 308                 decr consno;
 309                 let p = Cic.Rel !consno in
 310                 Cic.Prod (Cic.Anonymous,
 311                   (delta (uri, typeno) dependent leftno !consno
 312                     constructor p [mk_constructor !consno]),
 313                   acc))
 314               constructors final_ty))
 315         in
 316         add_params (fun b s t -> Cic.Prod (b, s, t)) leftno ty cic
 317       in
 318       let consno = ref (conslen + 1) in
 319       let eliminator_body =
 320         let fix = Cic.Rel (rightno + 2) in
 321         let is_recursive = recursive_type uri typeno constructors in
 322         let recshift = if is_recursive then 1 else 0 in
 323         let (_, branches) =
 324           List.fold_right
 325             (fun (_, ty) (shift, branches) ->
 326               let head = Cic.Rel (rightno + shift + 1 + recshift) in
 327               let b =
 328                 branch (uri, typeno) false
 329                   (rightno + conslen + 2 + recshift) leftno ty fix head []
 330               in
 331               (shift + 1,  b :: branches))
 332             constructors (1, [])
 333         in
 334         let shiftno  = conslen + rightno + 2 + recshift in
 335         let outtype =
 336          if dependent then
 337           Cic.Rel shiftno
 338          else
 339           let head =
 340            if rightno = 0 then
 341             CicSubstitution.lift 1 (Cic.Rel shiftno)
 342            else
 343             Cic.Appl
 344              ((CicSubstitution.lift (rightno + 1) (Cic.Rel shiftno)) ::
 345               mk_rels 1 rightno)
 346           in
 347            add_right_lambda true leftno shiftno 1 rightno indty head ty
 348         in
 349         let mutcase =
 350           Cic.MutCase (uri, typeno, outtype, Cic.Rel 1, branches)
 351         in
 352         let body =
 353           if is_recursive then
 354             let fixfun =
 355               add_right_lambda dependent leftno (conslen + 2) 1 rightno
 356                 indty mutcase ty
 357             in
 358             (* rightno is the decreasing argument, i.e. the argument of
 359              * inductive type *)
 360             Cic.Fix (0, ["f", rightno, final_ty, fixfun])
 361           else
 362             add_right_lambda dependent leftno (conslen + 1) 1 rightno indty
 363               mutcase ty
 364         in
 365         let cic =
 366           Cic.Lambda (Cic.Name "P", p_ty,
 367             (List.fold_right
 368               (fun (_, constructor) acc ->
 369                 decr consno;
 370                 let p = Cic.Rel !consno in
 371                 Cic.Lambda (fresh_binder (),
 372                   (delta (uri, typeno) dependent leftno !consno
 373                     constructor p [mk_constructor !consno]),
 374                   acc))
 375               constructors body))
 376         in
 377         add_params (fun b s t -> Cic.Lambda (b, s, t)) leftno ty cic
 378       in
 379 (*
 380 debug_print (lazy (CicPp.ppterm eliminator_type));
 381 debug_print (lazy (CicPp.ppterm eliminator_body));
 382 *)
 383       let eliminator_type =
 384         FreshNamesGenerator.mk_fresh_names [] [] [] eliminator_type in
 385       let eliminator_body =
 386         FreshNamesGenerator.mk_fresh_names [] [] [] eliminator_body in
 387 (*
 388 debug_print (lazy (CicPp.ppterm eliminator_type));
 389 debug_print (lazy (CicPp.ppterm eliminator_body));
 390 *)
 391       let (computed_type, ugraph) =
 392         try
 393           CicTypeChecker.type_of_aux' [] [] eliminator_body CicUniv.empty_ugraph
 394         with CicTypeChecker.TypeCheckerFailure msg ->
 395           raise (Elim_failure (lazy (sprintf
 396             "type checker failure while type checking:\n%s\nerror:\n%s"
 397             (CicPp.ppterm eliminator_body) (Lazy.force msg))))
 398       in
 399       if not (fst (CicReduction.are_convertible []
 400         eliminator_type computed_type ugraph))
 401       then
 402         raise (Failure (sprintf
 403           "internal error: type mismatch on eliminator type\n%s\n%s"
 404           (CicPp.ppterm eliminator_type) (CicPp.ppterm computed_type)));
 405       let suffix =
 406         match sort with
 407         | Cic.Prop -> "_ind"
 408         | Cic.Set -> "_rec"
 409         | Cic.Type _ -> "_rect"
 410         | _ -> assert false
 411       in
 412       (* let name = UriManager.name_of_uri uri ^ suffix in *)
 413       let name = name ^ suffix in
 414       let buri = UriManager.buri_of_uri uri in
 415       let uri = UriManager.uri_of_string (buri ^ "/" ^ name ^ ".con") in
 416       let obj_attrs = [`Class (`Elim sort); `Generated] in
 417        uri,
 418        Cic.Constant (name, Some eliminator_body, eliminator_type, [], obj_attrs)
 419   | _ ->
 420       failwith (sprintf "not an inductive definition (%s)"
 421         (UriManager.string_of_uri uri))
 422