components/tactics/equalityTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let rec rewrite_tac ~direction ~(pattern: ProofEngineTypes.lazy_pattern) equality =
  29  let _rewrite_tac ~direction ~pattern:(wanted,hyps_pat,concl_pat) equality status
  30  =
  31   let module C = Cic in
  32   let module U = UriManager in
  33   let module PET = ProofEngineTypes in
  34   let module PER = ProofEngineReduction in
  35   let module PEH = ProofEngineHelpers in
  36   let module PT = PrimitiveTactics in
  37   assert (wanted = None);   (* this should be checked syntactically *)
  38   let proof,goal = status in
  39   let curi, metasenv, pbo, pty = proof in
  40   let (metano,context,gty) = CicUtil.lookup_meta goal metasenv in
  41   match hyps_pat with
  42      he::(_::_ as tl) ->
  43        PET.apply_tactic
  44         (Tacticals.then_
  45           (rewrite_tac ~direction
  46            ~pattern:(None,[he],None) equality)
  47           (rewrite_tac ~direction ~pattern:(None,tl,concl_pat) equality)
  48         ) status
  49    | [_] as hyps_pat when concl_pat <> None ->
  50        PET.apply_tactic
  51         (Tacticals.then_
  52           (rewrite_tac ~direction
  53            ~pattern:(None,hyps_pat,None) equality)
  54           (rewrite_tac ~direction ~pattern:(None,[],concl_pat) equality)
  55         ) status
  56    | _ ->
  57   let arg,dir2,tac,concl_pat,gty =
  58    match hyps_pat with
  59       [] -> None,true,(fun ~term _ -> PT.exact_tac term),concl_pat,gty
  60     | [name,pat] ->
  61       let rec find_hyp n =
  62        function
  63           [] -> assert false
  64         | Some (Cic.Name s,Cic.Decl ty)::_ when name = s ->
  65            Cic.Rel n, CicSubstitution.lift n ty
  66         | Some (Cic.Name s,Cic.Def _)::_ -> assert false (*CSC: not implemented yet! But does this make any sense?*)
  67         | _::tl -> find_hyp (n+1) tl
  68       in
  69        let arg,gty = find_hyp 1 context in
  70        let dummy = "dummy" in
  71         Some arg,false,
  72          (fun ~term typ ->
  73            Tacticals.seq
  74             ~tactics:
  75               [ProofEngineStructuralRules.rename name dummy;
  76                PT.letin_tac
  77                 ~mk_fresh_name_callback:(fun _ _ _ ~typ -> Cic.Name name) term;
  78                ProofEngineStructuralRules.clearbody name;
  79                ReductionTactics.change_tac
  80                 ~pattern:
  81                   (None,[name,Cic.Implicit (Some `Hole)], None)
  82                 (ProofEngineTypes.const_lazy_term typ);
  83                ProofEngineStructuralRules.clear dummy
  84               ]),
  85          Some pat,gty
  86     | _::_ -> assert false
  87   in
  88   let if_right_to_left do_not_change a b =
  89     match direction with
  90     | `RightToLeft -> if do_not_change then a else b
  91     | `LeftToRight -> if do_not_change then b else a
  92   in
  93   let ty_eq,ugraph =
  94     CicTypeChecker.type_of_aux' metasenv context equality
  95       CicUniv.empty_ugraph in
  96   let (ty_eq,metasenv',arguments,fresh_meta) =
  97    ProofEngineHelpers.saturate_term
  98     (ProofEngineHelpers.new_meta_of_proof proof) metasenv context ty_eq 0 in
  99   let equality =
 100    if List.length arguments = 0 then
 101     equality
 102    else
 103     C.Appl (equality :: arguments) in
 104   (* t1x is t2 if we are rewriting in an hypothesis *)
 105   let eq_ind, ty, t1, t2, t1x =
 106     match ty_eq with
 107     | C.Appl [C.MutInd (uri, 0, []); ty; t1; t2]
 108       when LibraryObjects.is_eq_URI uri ->
 109         let ind_uri =
 110          if_right_to_left dir2
 111           LibraryObjects.eq_ind_URI LibraryObjects.eq_ind_r_URI
 112         in
 113         let eq_ind = C.Const (ind_uri uri,[]) in
 114          if dir2 then
 115           if_right_to_left true (eq_ind,ty,t2,t1,t2) (eq_ind,ty,t1,t2,t1)
 116          else
 117           if_right_to_left true (eq_ind,ty,t1,t2,t2) (eq_ind,ty,t2,t1,t1)
 118     | _ -> raise (PET.Fail (lazy "Rewrite: argument is not a proof of an equality")) in
 119   (* now we always do as if direction was `LeftToRight *)
 120   let fresh_name =
 121     FreshNamesGenerator.mk_fresh_name
 122     ~subst:[] metasenv' context C.Anonymous ~typ:ty in
 123   let lifted_t1 = CicSubstitution.lift 1 t1x in
 124   let lifted_gty = CicSubstitution.lift 1 gty in
 125   let lifted_conjecture =
 126     metano,(Some (fresh_name,Cic.Decl ty))::context,lifted_gty in
 127   let lifted_pattern =
 128     let lifted_concl_pat =
 129       match concl_pat with
 130       | None -> None
 131       | Some term -> Some (CicSubstitution.lift 1 term) in
 132     Some (fun _ m u -> lifted_t1, m, u),[],lifted_concl_pat
 133   in
 134   let subst,metasenv',ugraph,_,selected_terms_with_context =
 135    ProofEngineHelpers.select
 136     ~metasenv:metasenv' ~ugraph ~conjecture:lifted_conjecture
 137      ~pattern:lifted_pattern in
 138   let metasenv' = CicMetaSubst.apply_subst_metasenv subst metasenv' in
 139   let what,with_what =
 140    (* Note: Rel 1 does not live in the context context_of_t           *)
 141    (* The replace_lifting_csc 0 function will take care of lifting it *)
 142    (* to context_of_t                                                 *)
 143    List.fold_right
 144     (fun (context_of_t,t) (l1,l2) -> t::l1, Cic.Rel 1::l2)
 145     selected_terms_with_context ([],[]) in
 146   let t1 = CicMetaSubst.apply_subst subst t1 in
 147   let t2 = CicMetaSubst.apply_subst subst t2 in
 148   let ty = CicMetaSubst.apply_subst subst ty in
 149   let equality = CicMetaSubst.apply_subst subst equality in
 150   let abstr_gty =
 151    ProofEngineReduction.replace_lifting_csc 0
 152     ~equality:(==) ~what ~with_what:with_what ~where:lifted_gty in
 153   let abstr_gty = CicMetaSubst.apply_subst subst abstr_gty in
 154   let pred = C.Lambda (fresh_name, ty, abstr_gty) in
 155   (* The argument is either a meta if we are rewriting in the conclusion
 156      or the hypothesis if we are rewriting in an hypothesis *)
 157   let metasenv',arg,newtyp =
 158    match arg with
 159       None ->
 160        let gty' = CicSubstitution.subst t2 abstr_gty in
 161        let irl =
 162         CicMkImplicit.identity_relocation_list_for_metavariable context in
 163        let metasenv' = (fresh_meta,context,gty')::metasenv' in
 164         metasenv', C.Meta (fresh_meta,irl), Cic.Rel (-1) (* dummy term, never used *)
 165     | Some arg ->
 166        let gty' = CicSubstitution.subst t1 abstr_gty in
 167         metasenv',arg,gty'
 168   in
 169   let exact_proof =
 170     C.Appl [eq_ind ; ty ; t2 ; pred ; arg ; t1 ;equality]
 171   in
 172   let (proof',goals) =
 173     PET.apply_tactic
 174       (tac ~term:exact_proof newtyp) ((curi,metasenv',pbo,pty),goal)
 175   in
 176   let goals =
 177    goals@(ProofEngineHelpers.compare_metasenvs ~oldmetasenv:metasenv
 178     ~newmetasenv:metasenv')
 179   in
 180    (proof',goals)
 181  in
 182   ProofEngineTypes.mk_tactic (_rewrite_tac ~direction ~pattern equality)
 183
 184
 185 let rewrite_simpl_tac ~direction ~pattern equality =
 186  let rewrite_simpl_tac ~direction ~pattern equality status =
 187   ProofEngineTypes.apply_tactic
 188   (Tacticals.then_
 189    ~start:(rewrite_tac ~direction ~pattern equality)
 190    ~continuation:
 191      (ReductionTactics.simpl_tac
 192        ~pattern:(ProofEngineTypes.conclusion_pattern None)))
 193    status
 194  in
 195    ProofEngineTypes.mk_tactic (rewrite_simpl_tac ~direction ~pattern equality)
 196 ;;
 197
 198 let replace_tac ~(pattern: ProofEngineTypes.lazy_pattern) ~with_what =
 199  let replace_tac ~(pattern: ProofEngineTypes.lazy_pattern) ~with_what status =
 200   let _wanted, hyps_pat, concl_pat = pattern in
 201   let (proof, goal) = status in
 202   let module C = Cic in
 203   let module U = UriManager in
 204   let module P = PrimitiveTactics in
 205   let module T = Tacticals in
 206   let uri,metasenv,pbo,pty = proof in
 207   let (_,context,ty) as conjecture = CicUtil.lookup_meta goal metasenv in
 208   assert (hyps_pat = []); (*CSC: not implemented yet *)
 209   let context_len = List.length context in
 210   let subst,metasenv,u,_,selected_terms_with_context =
 211    ProofEngineHelpers.select ~metasenv ~ugraph:CicUniv.empty_ugraph
 212     ~conjecture ~pattern in
 213   let metasenv = CicMetaSubst.apply_subst_metasenv subst metasenv in
 214   let with_what, metasenv, u = with_what context metasenv u in
 215   let with_what = CicMetaSubst.apply_subst subst with_what in
 216   let pbo = CicMetaSubst.apply_subst subst pbo in
 217   let pty = CicMetaSubst.apply_subst subst pty in
 218   let status = (uri,metasenv,pbo,pty),goal in
 219   let ty_of_with_what,u =
 220    CicTypeChecker.type_of_aux'
 221     metasenv context with_what CicUniv.empty_ugraph in
 222   let whats =
 223    match selected_terms_with_context with
 224       [] -> raise (ProofEngineTypes.Fail (lazy "Replace: no term selected"))
 225     | l ->
 226       List.map
 227        (fun (context_of_t,t) ->
 228          let t_in_context =
 229           try
 230            let context_of_t_len = List.length context_of_t in
 231            if context_of_t_len = context_len then t
 232            else
 233             (let t_in_context,subst,metasenv' =
 234               CicMetaSubst.delift_rels [] metasenv
 235                (context_of_t_len - context_len) t
 236              in
 237               assert (subst = []);
 238               assert (metasenv = metasenv');
 239               t_in_context)
 240           with
 241            CicMetaSubst.DeliftingARelWouldCaptureAFreeVariable ->
 242             (*CSC: we could implement something stronger by completely changing
 243               the semantics of the tactic *)
 244             raise (ProofEngineTypes.Fail
 245              (lazy "Replace: one of the selected terms is not closed")) in
 246          let ty_of_t_in_context,u = (* TASSI: FIXME *)
 247           CicTypeChecker.type_of_aux' metasenv context t_in_context
 248            CicUniv.empty_ugraph in
 249          let b,u = CicReduction.are_convertible ~metasenv context
 250           ty_of_with_what ty_of_t_in_context u in
 251          if b then
 252           let concl_pat_for_t = ProofEngineHelpers.pattern_of ~term:ty [t] in
 253           let pattern_for_t = None,[],Some concl_pat_for_t in
 254            t_in_context,pattern_for_t
 255          else
 256           raise
 257            (ProofEngineTypes.Fail
 258              (lazy "Replace: one of the selected terms and the term to be replaced with have not convertible types"))
 259        ) l in
 260   let rec aux n whats status =
 261    match whats with
 262       [] -> ProofEngineTypes.apply_tactic T.id_tac status
 263     | (what,lazy_pattern)::tl ->
 264        let what = CicSubstitution.lift n what in
 265        let with_what = CicSubstitution.lift n with_what in
 266        let ty_of_with_what = CicSubstitution.lift n ty_of_with_what in
 267        ProofEngineTypes.apply_tactic
 268          (T.thens
 269             ~start:(
 270               P.cut_tac
 271                (C.Appl [
 272                  (C.MutInd (LibraryObjects.eq_URI (), 0, [])) ;
 273                  ty_of_with_what ;
 274                  what ;
 275                  with_what]))
 276             ~continuations:[
 277               T.then_
 278                 ~start:(
 279                   rewrite_tac ~direction:`LeftToRight ~pattern:lazy_pattern (C.Rel 1))
 280                  ~continuation:(
 281                    T.then_
 282                     ~start:(
 283                       ProofEngineTypes.mk_tactic
 284                        (function ((proof,goal) as status) ->
 285                          let _,metasenv,_,_ = proof in
 286                          let _,context,_ = CicUtil.lookup_meta goal metasenv in
 287                          let hyp =
 288                           try
 289                            match List.hd context with
 290                               Some (Cic.Name name,_) -> name
 291                             | _ -> assert false
 292                           with (Failure "hd") -> assert false
 293                          in
 294                           ProofEngineTypes.apply_tactic
 295                            (ProofEngineStructuralRules.clear ~hyp) status))
 296                     ~continuation:(aux_tac (n + 1) tl));
 297               T.id_tac])
 298          status
 299   and aux_tac n tl = ProofEngineTypes.mk_tactic (aux n tl) in
 300    aux 0 whats status
 301  in
 302    ProofEngineTypes.mk_tactic (replace_tac ~pattern ~with_what)
 303 ;;
 304
 305
 306 (* All these tacs do is applying the right constructor/theorem *)
 307
 308 let reflexivity_tac =
 309   IntroductionTactics.constructor_tac ~n:1
 310 ;;
 311
 312 let symmetry_tac =
 313  let symmetry_tac (proof, goal) =
 314   let module C = Cic in
 315   let module R = CicReduction in
 316   let module U = UriManager in
 317    let (_,metasenv,_,_) = proof in
 318     let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 319      match (R.whd context ty) with
 320         (C.Appl [(C.MutInd (uri, 0, [])); _; _; _])
 321          when LibraryObjects.is_eq_URI uri ->
 322           ProofEngineTypes.apply_tactic
 323            (PrimitiveTactics.apply_tac
 324             ~term: (C.Const (LibraryObjects.sym_eq_URI uri, [])))
 325            (proof,goal)
 326
 327       | _ -> raise (ProofEngineTypes.Fail (lazy "Symmetry failed"))
 328  in
 329   ProofEngineTypes.mk_tactic symmetry_tac
 330 ;;
 331
 332 let transitivity_tac ~term =
 333  let transitivity_tac ~term status =
 334   let (proof, goal) = status in
 335   let module C = Cic in
 336   let module R = CicReduction in
 337   let module U = UriManager in
 338   let module T = Tacticals in
 339    let (_,metasenv,_,_) = proof in
 340     let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 341      match (R.whd context ty) with
 342         (C.Appl [(C.MutInd (uri, 0, [])); _; _; _])
 343         when LibraryObjects.is_eq_URI uri ->
 344          ProofEngineTypes.apply_tactic
 345          (T.thens
 346           ~start:(PrimitiveTactics.apply_tac
 347             ~term: (C.Const (LibraryObjects.trans_eq_URI uri, [])))
 348           ~continuations:
 349             [PrimitiveTactics.exact_tac ~term ; T.id_tac ; T.id_tac])
 350           status
 351
 352       | _ -> raise (ProofEngineTypes.Fail (lazy "Transitivity failed"))
 353  in
 354   ProofEngineTypes.mk_tactic (transitivity_tac ~term)
 355 ;;
 356
 357