components/tactics/paramodulation/equality.ml

   1 (* cOpyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* let _profiler = <:profiler<_profiler>>;; *)
  27
  28 (* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)
  29
  30 type rule = SuperpositionRight | SuperpositionLeft | Demodulation
  31 type uncomparable = int -> int
  32
  33 type equality =
  34     uncomparable *       (* trick to break structural equality *)
  35     int  *               (* weight *)
  36     proof *
  37     (Cic.term *          (* type *)
  38      Cic.term *          (* left side *)
  39      Cic.term *          (* right side *)
  40      Utils.comparison) * (* ordering *)
  41     Cic.metasenv  *      (* environment for metas *)
  42     int                  (* id *)
  43 and proof =
  44   | Exact of Cic.term
  45   | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term)
  46             (* subst, (rule,eq1, eq2,predicate) *)
  47 and goal_proof = (rule * Utils.pos * int * Subst.substitution * Cic.term) list
  48 ;;
  49 (* the hashtbl eq_id -> proof, max_eq_id *)
  50 type equality_bag = (int,equality) Hashtbl.t * int ref
  51
  52 type goal = goal_proof * Cic.metasenv * Cic.term
  53
  54 (* globals *)
  55 let mk_equality_bag () =
  56   Hashtbl.create 1024, ref 0
  57 ;;
  58
  59 let freshid (_,i) =
  60   incr i; !i
  61 ;;
  62
  63 let add_to_bag (id_to_eq,_) id eq =
  64   Hashtbl.add id_to_eq id eq
  65 ;;
  66
  67 let uncomparable = fun _ -> 0
  68
  69 let mk_equality bag (weight,p,(ty,l,r,o),m) =
  70   let id = freshid bag in
  71   let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  72   add_to_bag bag id eq;
  73   eq
  74 ;;
  75
  76 let mk_tmp_equality (weight,(ty,l,r,o),m) =
  77   let id = -1 in
  78   uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
  79 ;;
  80
  81
  82 let open_equality (_,weight,proof,(ty,l,r,o),m,id) =
  83   (weight,proof,(ty,l,r,o),m,id)
  84
  85 let string_of_rule = function
  86   | SuperpositionRight -> "SupR"
  87   | SuperpositionLeft -> "SupL"
  88   | Demodulation -> "Demod"
  89 ;;
  90
  91 let string_of_equality ?env eq =
  92   match env with
  93   | None ->
  94       let w, _, (ty, left, right, o), m , id = open_equality eq in
  95       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  96               id w (CicPp.ppterm ty)
  97               (CicPp.ppterm left)
  98               (Utils.string_of_comparison o) (CicPp.ppterm right)
  99 (*         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m)) *)
 100          "..."
 101   | Some (_, context, _) ->
 102       let names = Utils.names_of_context context in
 103       let w, _, (ty, left, right, o), m , id = open_equality eq in
 104       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
 105               id w (CicPp.pp ty names)
 106               (CicPp.pp left names) (Utils.string_of_comparison o)
 107               (CicPp.pp right names)
 108 (*         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m)) *)
 109            "..."
 110 ;;
 111
 112 let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
 113   Pervasives.compare s1 s2
 114 ;;
 115
 116 let rec max_weight_in_proof ((id_to_eq,_) as bag) current =
 117   function
 118    | Exact _ -> current
 119    | Step (_, (_,id1,(_,id2),_)) ->
 120        let eq1 = Hashtbl.find id_to_eq id1 in
 121        let eq2 = Hashtbl.find id_to_eq id2 in
 122        let (w1,p1,(_,_,_,_),_,_) = open_equality eq1 in
 123        let (w2,p2,(_,_,_,_),_,_) = open_equality eq2 in
 124        let current = max current w1 in
 125        let current = max_weight_in_proof bag current p1 in
 126        let current = max current w2 in
 127        max_weight_in_proof bag current p2
 128
 129 let max_weight_in_goal_proof ((id_to_eq,_) as bag) =
 130   List.fold_left
 131     (fun current (_,_,id,_,_) ->
 132        let eq = Hashtbl.find id_to_eq id in
 133        let (w,p,(_,_,_,_),_,_) = open_equality eq in
 134        let current = max current w in
 135        max_weight_in_proof bag current p)
 136
 137 let max_weight bag goal_proof proof =
 138   let current = max_weight_in_proof bag 0 proof in
 139   max_weight_in_goal_proof bag current goal_proof
 140
 141 let proof_of_id (id_to_eq,_) id =
 142   try
 143     let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
 144       p,l,r
 145   with
 146       Not_found -> assert false
 147
 148
 149 let string_of_proof ?(names=[]) bag p gp =
 150   let str_of_pos = function
 151     | Utils.Left -> "left"
 152     | Utils.Right -> "right"
 153   in
 154   let fst3 (x,_,_) = x in
 155   let rec aux margin name =
 156     let prefix = String.make margin ' ' ^ name ^ ": " in function
 157     | Exact t ->
 158         Printf.sprintf "%sExact (%s)\n"
 159           prefix (CicPp.pp t names)
 160     | Step (subst,(rule,eq1,(pos,eq2),pred)) ->
 161         Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
 162           prefix (string_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos)
 163           (CicPp.pp pred names)^
 164         aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id bag eq1)) ^
 165         aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id bag eq2))
 166   in
 167   aux 0 "" p ^
 168   String.concat "\n"
 169     (List.map
 170       (fun (r,pos,i,s,t) ->
 171         (Printf.sprintf
 172           "GOAL: %s %s %d %s %s\n" (string_of_rule r)
 173             (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^
 174         aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id bag i)))
 175       gp)
 176 ;;
 177
 178 let rec depend ((id_to_eq,_) as bag) eq id seen =
 179   let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
 180   if List.mem ideq seen then
 181     false,seen
 182   else
 183     if id = ideq then
 184       true,seen
 185     else
 186       match p with
 187       | Exact _ -> false,seen
 188       | Step (_,(_,id1,(_,id2),_)) ->
 189           let seen = ideq::seen in
 190           let eq1 = Hashtbl.find id_to_eq id1 in
 191           let eq2 = Hashtbl.find id_to_eq id2 in
 192           let b1,seen = depend bag eq1 id seen in
 193           if b1 then b1,seen else depend bag eq2 id seen
 194 ;;
 195
 196 let depend bag eq id = fst (depend bag eq id []);;
 197
 198 let ppsubst = Subst.ppsubst ~names:[];;
 199
 200 (* returns an explicit named subst and a list of arguments for sym_eq_URI *)
 201 let build_ens uri termlist =
 202   let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 203   match obj with
 204   | Cic.Constant (_, _, _, uris, _) ->
 205       (* assert (List.length uris <= List.length termlist); *)
 206       let rec aux = function
 207         | [], tl -> [], tl
 208         | (uri::uris), (term::tl) ->
 209             let ens, args = aux (uris, tl) in
 210             (uri, term)::ens, args
 211         | _, _ -> assert false
 212       in
 213       aux (uris, termlist)
 214   | _ -> assert false
 215 ;;
 216
 217 let mk_sym uri ty t1 t2 p =
 218   let ens, args =  build_ens uri [ty;t1;t2;p] in
 219     Cic.Appl (Cic.Const(uri, ens) :: args)
 220 ;;
 221
 222 let mk_trans uri ty t1 t2 t3 p12 p23 =
 223   let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
 224     Cic.Appl (Cic.Const (uri, ens) :: args)
 225 ;;
 226
 227 let mk_eq_ind uri ty what pred p1 other p2 =
 228   let ens, args = build_ens uri [ty; what; pred; p1; other; p2] in
 229   Cic.Appl (Cic.Const (uri, ens) :: args)
 230 ;;
 231
 232 let p_of_sym ens tl =
 233   let args = List.map snd ens @ tl in
 234   match args with
 235     | [_;_;_;p] -> p
 236     | _ -> assert false
 237 ;;
 238
 239 let open_trans ens tl =
 240   let args = List.map snd ens @ tl in
 241   match args with
 242     | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
 243     | _ -> assert false
 244 ;;
 245
 246 let open_sym ens tl =
 247   let args = List.map snd ens @ tl in
 248   match args with
 249     | [ty;l;r;p] -> ty,l,r,p
 250     | _ -> assert false
 251 ;;
 252
 253 let open_eq_ind args =
 254   match args with
 255   | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
 256   | _ -> assert false
 257 ;;
 258
 259 let open_pred pred =
 260   match pred with
 261   | Cic.Lambda (_,_,(Cic.Appl [Cic.MutInd (uri, 0,_);ty;l;r]))
 262      when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
 263   | _ -> prerr_endline (CicPp.ppterm pred); assert false
 264 ;;
 265
 266 let is_not_fixed t =
 267    CicSubstitution.subst (Cic.Implicit None) t <>
 268    CicSubstitution.subst (Cic.Rel 1) t
 269 ;;
 270
 271 let canonical t context menv =
 272   let rec remove_refl t =
 273     match t with
 274     | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
 275           when LibraryObjects.is_trans_eq_URI uri_trans ->
 276           let ty,l,m,r,p1,p2 = open_trans ens tl in
 277             (match p1,p2 with
 278               | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 ->
 279                   remove_refl p2
 280               | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] ->
 281                   remove_refl p1
 282               | _ -> Cic.Appl (List.map remove_refl args))
 283     | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
 284     | Cic.LetIn (name,bo,rest) ->
 285         Cic.LetIn (name,remove_refl bo,remove_refl rest)
 286     | _ -> t
 287   in
 288   let rec canonical context t =
 289     match t with
 290       | Cic.LetIn(name,bo,rest) ->
 291           let context' = (Some (name,Cic.Def (bo,None)))::context in
 292           Cic.LetIn(name,canonical context bo,canonical context' rest)
 293       | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
 294           when LibraryObjects.is_sym_eq_URI uri_sym ->
 295           (match p_of_sym ens tl with
 296              | Cic.Appl ((Cic.Const(uri,ens))::tl)
 297                  when LibraryObjects.is_sym_eq_URI uri ->
 298                    canonical context (p_of_sym ens tl)
 299              | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
 300                  when LibraryObjects.is_trans_eq_URI uri_trans ->
 301                  let ty,l,m,r,p1,p2 = open_trans ens tl in
 302                    mk_trans uri_trans ty r m l
 303                      (canonical context (mk_sym uri_sym ty m r p2))
 304                      (canonical context (mk_sym uri_sym ty l m p1))
 305              | Cic.Appl (([Cic.Const(uri_feq,ens);ty1;ty2;f;x;y;p])) ->
 306                  let eq = LibraryObjects.eq_URI_of_eq_f_URI uri_feq in
 307                  let eq_f_sym =
 308                    Cic.Const (LibraryObjects.eq_f_sym_URI ~eq, [])
 309                  in
 310                  Cic.Appl (([eq_f_sym;ty1;ty2;f;x;y;p]))
 311              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
 312                  when LibraryObjects.is_eq_URI uri -> t
 313              | _ -> Cic.Appl (List.map (canonical context) args))
 314       | Cic.Appl l -> Cic.Appl (List.map (canonical context) l)
 315       | _ -> t
 316   in
 317   remove_refl (canonical context t)
 318 ;;
 319
 320 let compose_contexts ctx1 ctx2 =
 321   ProofEngineReduction.replace_lifting
 322     ~equality:(=) ~what:[Cic.Implicit(Some `Hole)] ~with_what:[ctx2] ~where:ctx1
 323 ;;
 324
 325 let put_in_ctx ctx t =
 326   ProofEngineReduction.replace_lifting
 327     ~equality:(=) ~what:[Cic.Implicit (Some `Hole)] ~with_what:[t] ~where:ctx
 328 ;;
 329
 330 let mk_eq uri ty l r =
 331   let ens, args = build_ens uri [ty; l; r] in
 332   Cic.Appl (Cic.MutInd(uri,0,ens) :: args)
 333 ;;
 334
 335 let mk_refl uri ty t =
 336   let ens, args = build_ens uri [ty; t] in
 337   Cic.Appl (Cic.MutConstruct(uri,0,1,ens) :: args)
 338 ;;
 339
 340 let open_eq = function
 341   | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
 342       uri, ty, l ,r
 343   | _ -> assert false
 344 ;;
 345
 346 let mk_feq uri_feq ty ty1 left pred right t =
 347   let ens, args = build_ens uri_feq [ty;ty1;pred;left;right;t] in
 348   Cic.Appl (Cic.Const(uri_feq,ens) :: args)
 349 ;;
 350
 351 let rec look_ahead aux = function
 352   | Cic.Appl ((Cic.Const(uri_ind,ens))::tl) as t
 353         when LibraryObjects.is_eq_ind_URI uri_ind ||
 354              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 355           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 356           let ty2,eq,lp,rp = open_pred pred in
 357           let hole = Cic.Implicit (Some `Hole) in
 358           let ty2 = CicSubstitution.subst hole ty2 in
 359           aux ty1 (CicSubstitution.subst other lp) (CicSubstitution.subst other rp) hole ty2 t
 360   | Cic.Lambda (n,s,t) -> Cic.Lambda (n,s,look_ahead aux t)
 361   | t -> t
 362 ;;
 363
 364 let contextualize uri ty left right t =
 365   let hole = Cic.Implicit (Some `Hole) in
 366   (* aux [uri] [ty] [left] [right] [ctx] [ctx_ty] [t]
 367    *
 368    * the parameters validate this invariant
 369    *   t: eq(uri) ty left right
 370    * that is used only by the base case
 371    *
 372    * ctx is a term with an hole. Cic.Implicit(Some `Hole) is the empty context
 373    * ctx_ty is the type of ctx
 374    *)
 375     let rec aux uri ty left right ctx_d ctx_ty t =
 376       match t with
 377       | Cic.Appl ((Cic.Const(uri_sym,ens))::tl)
 378         when LibraryObjects.is_sym_eq_URI uri_sym  ->
 379           let ty,l,r,p = open_sym ens tl in
 380           mk_sym uri_sym ty l r (aux uri ty l r ctx_d ctx_ty p)
 381       | Cic.LetIn (name,body,rest) ->
 382           Cic.LetIn (name,look_ahead (aux uri) body, aux uri ty left right ctx_d ctx_ty rest)
 383       | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
 384         when LibraryObjects.is_eq_ind_URI uri_ind ||
 385              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 386           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 387           let ty2,eq,lp,rp = open_pred pred in
 388           let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
 389           let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 390           let is_not_fixed_lp = is_not_fixed lp in
 391           let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
 392           (* extract the context and the fixed term from the predicate *)
 393           let m, ctx_c, ty2 =
 394             let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
 395             (* they were under a lambda *)
 396             let m =  CicSubstitution.subst hole m in
 397             let ctx_c = CicSubstitution.subst hole ctx_c in
 398             let ty2 = CicSubstitution.subst hole ty2 in
 399             m, ctx_c, ty2
 400           in
 401           (* create the compound context and put the terms under it *)
 402           let ctx_dc = compose_contexts ctx_d ctx_c in
 403           let dc_what = put_in_ctx ctx_dc what in
 404           let dc_other = put_in_ctx ctx_dc other in
 405           (* m is already in ctx_c so it is put in ctx_d only *)
 406           let d_m = put_in_ctx ctx_d m in
 407           (* we also need what in ctx_c *)
 408           let c_what = put_in_ctx ctx_c what in
 409           (* now put the proofs in the compound context *)
 410           let p1 = (* p1: dc_what = d_m *)
 411             if is_not_fixed_lp then
 412               aux uri ty2 c_what m ctx_d ctx_ty p1
 413             else
 414               mk_sym uri_sym ctx_ty d_m dc_what
 415                 (aux uri ty2 m c_what ctx_d ctx_ty p1)
 416           in
 417           let p2 = (* p2: dc_other = dc_what *)
 418             if avoid_eq_ind then
 419               mk_sym uri_sym ctx_ty dc_what dc_other
 420                 (aux uri ty1 what other ctx_dc ctx_ty p2)
 421              else
 422               aux uri ty1 other what ctx_dc ctx_ty p2
 423           in
 424           (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
 425              if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
 426           let a,b,c,paeqb,pbeqc =
 427             if is_not_fixed_lp then
 428               dc_other,dc_what,d_m,p2,p1
 429             else
 430               d_m,dc_what,dc_other,
 431                 (mk_sym uri_sym ctx_ty dc_what d_m p1),
 432                 (mk_sym uri_sym ctx_ty dc_other dc_what p2)
 433           in
 434           mk_trans uri_trans ctx_ty a b c paeqb pbeqc
 435     | t when ctx_d = hole -> t
 436     | t ->
 437 (*         let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in *)
 438 (*         let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in *)
 439
 440         let uri_feq = LibraryObjects.eq_f_URI ~eq:uri in
 441         let pred =
 442 (*           let r = CicSubstitution.lift 1 (put_in_ctx ctx_d left) in *)
 443           let l =
 444             let ctx_d = CicSubstitution.lift 1 ctx_d in
 445             put_in_ctx ctx_d (Cic.Rel 1)
 446           in
 447 (*           let lty = CicSubstitution.lift 1 ctx_ty in  *)
 448 (*           Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r)) *)
 449           Cic.Lambda (Cic.Name "foo",ty,l)
 450         in
 451 (*         let d_left = put_in_ctx ctx_d left in *)
 452 (*         let d_right = put_in_ctx ctx_d right in *)
 453 (*         let refl_eq = mk_refl uri ctx_ty d_left in *)
 454 (*         mk_sym uri_sym ctx_ty d_right d_left *)
 455 (*           (mk_eq_ind uri_ind ty left pred refl_eq right t) *)
 456           (mk_feq uri_feq ty ctx_ty left pred right t)
 457   in
 458   aux uri ty left right hole ty t
 459 ;;
 460
 461 let contextualize_rewrites t ty =
 462   let eq,ty,l,r = open_eq ty in
 463   contextualize eq ty l r t
 464 ;;
 465
 466 let add_subst subst =
 467   function
 468     | Exact t -> Exact (Subst.apply_subst subst t)
 469     | Step (s,(rule, id1, (pos,id2), pred)) ->
 470         Step (Subst.concat subst s,(rule, id1, (pos,id2), pred))
 471 ;;
 472
 473 let build_proof_step eq lift subst p1 p2 pos l r pred =
 474   let p1 = Subst.apply_subst_lift lift subst p1 in
 475   let p2 = Subst.apply_subst_lift lift subst p2 in
 476   let l  = CicSubstitution.lift lift l in
 477   let l = Subst.apply_subst_lift lift subst l in
 478   let r  = CicSubstitution.lift lift r in
 479   let r = Subst.apply_subst_lift lift subst r in
 480   let pred = CicSubstitution.lift lift pred in
 481   let pred = Subst.apply_subst_lift lift subst pred in
 482   let ty,body =
 483     match pred with
 484       | Cic.Lambda (_,ty,body) -> ty,body
 485       | _ -> assert false
 486   in
 487   let what, other =
 488     if pos = Utils.Left then l,r else r,l
 489   in
 490   let p =
 491     match pos with
 492       | Utils.Left ->
 493         mk_eq_ind (LibraryObjects.eq_ind_URI ~eq) ty what pred p1 other p2
 494       | Utils.Right ->
 495         mk_eq_ind (LibraryObjects.eq_ind_r_URI ~eq) ty what pred p1 other p2
 496   in
 497     p
 498 ;;
 499
 500 let parametrize_proof menv p l r ty =
 501   let uniq l = HExtlib.list_uniq (List.sort Pervasives.compare l) in
 502   let mot = CicUtil.metas_of_term_set in
 503   let parameters = uniq (mot p @ mot l @ mot r) in
 504   (* ?if they are under a lambda? *)
 505 (*
 506   let parameters =
 507     HExtlib.list_uniq (List.sort Pervasives.compare parameters)
 508   in
 509 *)
 510   let what = List.map (fun (i,l) -> Cic.Meta (i,l)) parameters in
 511   let with_what, lift_no =
 512     List.fold_right (fun _ (acc,n) -> ((Cic.Rel n)::acc),n+1) what ([],1)
 513   in
 514   let p = CicSubstitution.lift (lift_no-1) p in
 515   let p =
 516     ProofEngineReduction.replace_lifting
 517     ~equality:(fun t1 t2 ->
 518       match t1,t2 with Cic.Meta (i,_),Cic.Meta(j,_) -> i=j | _ -> false)
 519     ~what ~with_what ~where:p
 520   in
 521   let ty_of_m _ = Cic.Implicit (Some `Type)
 522 (*
 523   let ty_of_m = function
 524     | Cic.Meta (i,_) ->
 525         (try
 526           let _,_,ty = CicUtil.lookup_meta i menv in ty
 527         with CicUtil.Meta_not_found _ ->
 528           prerr_endline "eccoci";assert false)
 529     | _ -> assert false
 530 *)
 531   (*
 532   let ty_of_m _ = ty (*function
 533     | Cic.Meta (i,_) -> List.assoc i menv
 534     | _ -> assert false *)
 535   *)
 536   in
 537   let args, proof,_ =
 538     List.fold_left
 539       (fun (instance,p,n) m ->
 540         (instance@[m],
 541         Cic.Lambda
 542           (Cic.Name ("X"^string_of_int n),
 543           CicSubstitution.lift (lift_no - n - 1) (ty_of_m m),
 544           p),
 545         n+1))
 546       ([Cic.Rel 1],p,1)
 547       what
 548   in
 549   let instance = match args with | [x] -> x | _ -> Cic.Appl args in
 550   proof, instance
 551 ;;
 552
 553 let wfo bag goalproof proof id =
 554   let rec aux acc id =
 555     let p,_,_ = proof_of_id bag id in
 556     match p with
 557     | Exact _ -> if (List.mem id acc) then acc else id :: acc
 558     | Step (_,(_,id1, (_,id2), _)) ->
 559         let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
 560         let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
 561         id :: acc
 562   in
 563   let acc =
 564     match proof with
 565       | Exact _ -> [id]
 566       | Step (_,(_,id1, (_,id2), _)) -> aux (aux [id] id1) id2
 567   in
 568   List.fold_left (fun acc (_,_,id,_,_) -> aux acc id) acc goalproof
 569 ;;
 570
 571 let string_of_id (id_to_eq,_) names id =
 572   if id = 0 then "" else
 573   try
 574     let (_,p,(_,l,r,_),m,_) = open_equality (Hashtbl.find id_to_eq id) in
 575     match p with
 576     | Exact t ->
 577         Printf.sprintf "%d = %s: %s = %s [%s]" id
 578           (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
 579           "..."
 580 (*         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m)) *)
 581     | Step (_,(step,id1, (_,id2), _) ) ->
 582         Printf.sprintf "%6d: %s %6d %6d   %s = %s [%s]" id
 583           (string_of_rule step)
 584           id1 id2 (CicPp.pp l names) (CicPp.pp r names)
 585 (*         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m)) *)
 586           "..."
 587   with
 588       Not_found -> assert false
 589
 590 let pp_proof bag names goalproof proof subst id initial_goal =
 591   String.concat "\n" (List.map (string_of_id bag names) (wfo bag goalproof proof id)) ^
 592   "\ngoal:\n   " ^
 593     (String.concat "\n   "
 594       (fst (List.fold_right
 595         (fun (r,pos,i,s,pred) (acc,g) ->
 596           let _,_,left,right = open_eq g in
 597           let ty =
 598             match pos with
 599             | Utils.Left -> CicReduction.head_beta_reduce (Cic.Appl[pred;right])
 600             | Utils.Right -> CicReduction.head_beta_reduce (Cic.Appl[pred;left])
 601           in
 602           let ty = Subst.apply_subst s ty in
 603           ("("^ string_of_rule r ^ " " ^ string_of_int i^") -> "
 604           ^ CicPp.pp ty names) :: acc,ty) goalproof ([],initial_goal)))) ^
 605   "\nand then subsumed by " ^ string_of_int id ^ " when " ^ Subst.ppsubst subst
 606 ;;
 607
 608 module OT =
 609   struct
 610     type t = int
 611     let compare = Pervasives.compare
 612   end
 613
 614 module M = Map.Make(OT)
 615
 616 let rec find_deps bag m i =
 617   if M.mem i m then m
 618   else
 619     let p,_,_ = proof_of_id bag i in
 620     match p with
 621     | Exact _ -> M.add i [] m
 622     | Step (_,(_,id1,(_,id2),_)) ->
 623         let m = find_deps bag m id1 in
 624         let m = find_deps bag m id2 in
 625         (* without the uniq there is a stack overflow doing concatenation *)
 626         let xxx = [id1;id2] @ M.find id1 m @ M.find id2 m in
 627         let xxx = HExtlib.list_uniq (List.sort Pervasives.compare xxx) in
 628         M.add i xxx m
 629 ;;
 630
 631 let topological_sort bag l =
 632   (* build the partial order relation *)
 633   let m = List.fold_left (fun m i -> find_deps bag m i) M.empty l in
 634   let m = (* keep only deps inside l *)
 635     List.fold_left
 636       (fun m' i ->
 637         M.add i (List.filter (fun x -> List.mem x l) (M.find i m)) m')
 638       M.empty l
 639   in
 640   let m = M.map (fun x -> Some x) m in
 641   (* utils *)
 642   let keys m = M.fold (fun i _ acc -> i::acc) m [] in
 643   let split l m = List.filter (fun i -> M.find i m = Some []) l in
 644   let purge l m =
 645     M.mapi
 646       (fun k v -> if List.mem k l then None else
 647          match v with
 648          | None -> None
 649          | Some ll -> Some (List.filter (fun i -> not (List.mem i l)) ll))
 650       m
 651   in
 652   let rec aux m res =
 653       let keys = keys m in
 654       let ok = split keys m in
 655       let m = purge ok m in
 656       let res = ok @ res in
 657       if ok = [] then res else aux m res
 658   in
 659   let rc = List.rev (aux m []) in
 660   rc
 661 ;;
 662
 663
 664 (* returns the list of ids that should be factorized *)
 665 let get_duplicate_step_in_wfo bag l p =
 666   let ol = List.rev l in
 667   let h = Hashtbl.create 13 in
 668   (* NOTE: here the n parameter is an approximation of the dependency
 669      between equations. To do things seriously we should maintain a
 670      dependency graph. This approximation is not perfect. *)
 671   let add i =
 672     let p,_,_ = proof_of_id bag i in
 673     match p with
 674     | Exact _ -> true
 675     | _ ->
 676         try
 677           let no = Hashtbl.find h i in
 678           Hashtbl.replace h i (no+1);
 679           false
 680         with Not_found -> Hashtbl.add h i 1;true
 681   in
 682   let rec aux = function
 683     | Exact _ -> ()
 684     | Step (_,(_,i1,(_,i2),_)) ->
 685         let go_on_1 = add i1 in
 686         let go_on_2 = add i2 in
 687         if go_on_1 then aux (let p,_,_ = proof_of_id bag i1 in p);
 688         if go_on_2 then aux (let p,_,_ = proof_of_id bag i2 in p)
 689   in
 690   aux p;
 691   List.iter
 692     (fun (_,_,id,_,_) -> aux (let p,_,_ = proof_of_id bag id in p))
 693     ol;
 694   (* now h is complete *)
 695   let proofs = Hashtbl.fold (fun k count acc-> (k,count)::acc) h [] in
 696   let proofs = List.filter (fun (_,c) -> c > 1) proofs in
 697   let res = topological_sort bag (List.map (fun (i,_) -> i) proofs) in
 698   res
 699 ;;
 700
 701 let build_proof_term bag eq h lift proof =
 702   let proof_of_id aux id =
 703     let p,l,r = proof_of_id bag id in
 704     try List.assoc id h,l,r with Not_found -> aux p, l, r
 705   in
 706   let rec aux = function
 707      | Exact term ->
 708          CicSubstitution.lift lift term
 709      | Step (subst,(rule, id1, (pos,id2), pred)) ->
 710          let p1,_,_ = proof_of_id aux id1 in
 711          let p2,l,r = proof_of_id aux id2 in
 712          let varname =
 713            match rule with
 714            | SuperpositionRight -> Cic.Name ("SupR" ^ Utils.string_of_pos pos)
 715            | Demodulation -> Cic.Name ("DemEq"^ Utils.string_of_pos pos)
 716            | _ -> assert false
 717          in
 718          let pred =
 719            match pred with
 720            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 721            | _ -> assert false
 722          in
 723          let p = build_proof_step eq lift subst p1 p2 pos l r pred in
 724 (*         let cond =  (not (List.mem 302 (Utils.metas_of_term p)) || id1 = 8 || id1 = 132) in
 725            if not cond then
 726              prerr_endline ("ERROR " ^ string_of_int id1 ^ " " ^ string_of_int id2);
 727            assert cond;*)
 728            p
 729   in
 730    aux proof
 731 ;;
 732
 733 let build_goal_proof bag eq l initial ty se context menv =
 734   let se = List.map (fun i -> Cic.Meta (i,[])) se in
 735   let lets = get_duplicate_step_in_wfo bag l initial in
 736   let letsno = List.length lets in
 737   let _,mty,_,_ = open_eq ty in
 738   let lift_list l = List.map (fun (i,t) -> i,CicSubstitution.lift 1 t) l in
 739   let lets,_,h =
 740     List.fold_left
 741       (fun (acc,n,h) id ->
 742         let p,l,r = proof_of_id bag id in
 743         let cic = build_proof_term bag eq h n p in
 744         let real_cic,instance =
 745           parametrize_proof menv cic l r (CicSubstitution.lift n mty)
 746         in
 747         let h = (id, instance)::lift_list h in
 748         acc@[id,real_cic],n+1,h)
 749       ([],0,[]) lets
 750   in
 751   let proof,se =
 752     let rec aux se current_proof = function
 753       | [] -> current_proof,se
 754       | (rule,pos,id,subst,pred)::tl ->
 755           let p,l,r = proof_of_id bag id in
 756            let p = build_proof_term bag eq h letsno p in
 757            let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
 758          let varname =
 759            match rule with
 760            | SuperpositionLeft -> Cic.Name ("SupL" ^ Utils.string_of_pos pos)
 761            | Demodulation -> Cic.Name ("DemG"^ Utils.string_of_pos pos)
 762            | _ -> assert false
 763          in
 764          let pred =
 765            match pred with
 766            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 767            | _ -> assert false
 768          in
 769            let proof =
 770              build_proof_step eq letsno subst current_proof p pos l r pred
 771            in
 772            let proof,se = aux se proof tl in
 773            Subst.apply_subst_lift letsno subst proof,
 774            List.map (fun x -> Subst.apply_subst(*_lift letsno*) subst x) se
 775     in
 776     aux se (build_proof_term bag eq h letsno initial) l
 777   in
 778   let n,proof =
 779     let initial = proof in
 780     List.fold_right
 781       (fun (id,cic) (n,p) ->
 782         n-1,
 783         Cic.LetIn (
 784           Cic.Name ("H"^string_of_int id),
 785           cic, p))
 786     lets (letsno-1,initial)
 787   in
 788    canonical
 789      (contextualize_rewrites proof (CicSubstitution.lift letsno ty))
 790      context menv,
 791    se
 792 ;;
 793
 794 let refl_proof eq_uri ty term =
 795   Cic.Appl [Cic.MutConstruct (eq_uri, 0, 1, []); ty; term]
 796 ;;
 797
 798 let metas_of_proof bag p =
 799   let eq =
 800     match LibraryObjects.eq_URI () with
 801     | Some u -> u
 802     | None ->
 803         raise
 804           (ProofEngineTypes.Fail
 805             (lazy "No default equality defined when calling metas_of_proof"))
 806   in
 807   let p = build_proof_term bag eq [] 0 p in
 808   Utils.metas_of_term p
 809 ;;
 810
 811 let remove_local_context eq =
 812    let w, p, (ty, left, right, o), menv,id = open_equality eq in
 813    let p = Utils.remove_local_context p in
 814    let ty = Utils.remove_local_context ty in
 815    let left = Utils.remove_local_context left in
 816    let right = Utils.remove_local_context right in
 817    w, p, (ty, left, right, o), menv, id
 818 ;;
 819
 820 let relocate newmeta menv to_be_relocated =
 821   let subst, newmetasenv, newmeta =
 822     List.fold_right
 823       (fun i (subst, metasenv, maxmeta) ->
 824         let _,context,ty = CicUtil.lookup_meta i menv in
 825         let irl = [] in
 826         let newmeta = Cic.Meta(maxmeta,irl) in
 827         let newsubst = Subst.buildsubst i context newmeta ty subst in
 828         newsubst, (maxmeta,context,ty)::metasenv, maxmeta+1)
 829       to_be_relocated (Subst.empty_subst, [], newmeta+1)
 830   in
 831   let menv = Subst.apply_subst_metasenv subst menv @ newmetasenv in
 832   subst, menv, newmeta
 833
 834 let fix_metas_goal newmeta goal =
 835   let (proof, menv, ty) = goal in
 836   let to_be_relocated =
 837     HExtlib.list_uniq (List.sort Pervasives.compare (Utils.metas_of_term ty))
 838   in
 839   let subst, menv, newmeta = relocate newmeta menv to_be_relocated in
 840   let ty = Subst.apply_subst subst ty in
 841   let proof =
 842     match proof with
 843     | [] -> assert false (* is a nonsense to relocate the initial goal *)
 844     | (r,pos,id,s,p) :: tl -> (r,pos,id,Subst.concat subst s,p) :: tl
 845   in
 846   newmeta+1,(proof, menv, ty)
 847 ;;
 848
 849 let fix_metas bag newmeta eq =
 850   let w, p, (ty, left, right, o), menv,_ = open_equality eq in
 851   let to_be_relocated =
 852 (* List.map (fun i ,_,_ -> i) menv *)
 853     HExtlib.list_uniq
 854       (List.sort Pervasives.compare
 855          (Utils.metas_of_term left @ Utils.metas_of_term right))
 856   in
 857   let subst, metasenv, newmeta = relocate newmeta menv to_be_relocated in
 858   let ty = Subst.apply_subst subst ty in
 859   let left = Subst.apply_subst subst left in
 860   let right = Subst.apply_subst subst right in
 861   let fix_proof = function
 862     | Exact p -> Exact (Subst.apply_subst subst p)
 863     | Step (s,(r,id1,(pos,id2),pred)) ->
 864         Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
 865   in
 866   let p = fix_proof p in
 867   let eq' = mk_equality bag (w, p, (ty, left, right, o), metasenv) in
 868   newmeta+1, eq'
 869
 870 exception NotMetaConvertible;;
 871
 872 let meta_convertibility_aux table t1 t2 =
 873   let module C = Cic in
 874   let rec aux ((table_l,table_r) as table) t1 t2 =
 875     match t1, t2 with
 876     | C.Meta (m1, tl1), C.Meta (m2, tl2) when m1 = m2 -> table
 877     | C.Meta (m1, tl1), C.Meta (m2, tl2) when m1 < m2 -> aux table t2 t1
 878     | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
 879         let m1_binding, table_l =
 880           try List.assoc m1 table_l, table_l
 881           with Not_found -> m2, (m1, m2)::table_l
 882         and m2_binding, table_r =
 883           try List.assoc m2 table_r, table_r
 884           with Not_found -> m1, (m2, m1)::table_r
 885         in
 886         if (m1_binding <> m2) || (m2_binding <> m1) then
 887           raise NotMetaConvertible
 888         else table_l,table_r
 889     | C.Var (u1, ens1), C.Var (u2, ens2)
 890     | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
 891         aux_ens table ens1 ens2
 892     | C.Cast (s1, t1), C.Cast (s2, t2)
 893     | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
 894     | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
 895     | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
 896         let table = aux table s1 s2 in
 897         aux table t1 t2
 898     | C.Appl l1, C.Appl l2 -> (
 899         try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 900         with Invalid_argument _ -> raise NotMetaConvertible
 901       )
 902     | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
 903         when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
 904     | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
 905         when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
 906         aux_ens table ens1 ens2
 907     | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
 908         when (UriManager.eq u1 u2) && i1 = i2 ->
 909         let table = aux table s1 s2 in
 910         let table = aux table t1 t2 in (
 911           try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 912           with Invalid_argument _ -> raise NotMetaConvertible
 913         )
 914     | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
 915         try
 916           List.fold_left2
 917             (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
 918                if i1 <> i2 then raise NotMetaConvertible
 919                else
 920                  let res = (aux res s1 s2) in aux res t1 t2)
 921             table il1 il2
 922         with Invalid_argument _ -> raise NotMetaConvertible
 923       )
 924     | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
 925         try
 926           List.fold_left2
 927             (fun res (n1, s1, t1) (n2, s2, t2) ->
 928                let res = aux res s1 s2 in aux res t1 t2)
 929             table il1 il2
 930         with Invalid_argument _ -> raise NotMetaConvertible
 931       )
 932     | t1, t2 when t1 = t2 -> table
 933     | _, _ -> raise NotMetaConvertible
 934
 935   and aux_ens table ens1 ens2 =
 936     let cmp (u1, t1) (u2, t2) =
 937       Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
 938     in
 939     let ens1 = List.sort cmp ens1
 940     and ens2 = List.sort cmp ens2 in
 941     try
 942       List.fold_left2
 943         (fun res (u1, t1) (u2, t2) ->
 944            if not (UriManager.eq u1 u2) then raise NotMetaConvertible
 945            else aux res t1 t2)
 946         table ens1 ens2
 947     with Invalid_argument _ -> raise NotMetaConvertible
 948   in
 949   aux table t1 t2
 950 ;;
 951
 952
 953 let meta_convertibility_eq eq1 eq2 =
 954   let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
 955   let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
 956   if ty <> ty' then
 957     false
 958   else if (left = left') && (right = right') then
 959     true
 960   else if (left = right') && (right = left') then
 961     true
 962   else
 963     try
 964       let table = meta_convertibility_aux ([],[]) left left' in
 965       let _ = meta_convertibility_aux table right right' in
 966       true
 967     with NotMetaConvertible ->
 968       try
 969         let table = meta_convertibility_aux ([],[]) left right' in
 970         let _ = meta_convertibility_aux table right left' in
 971         true
 972       with NotMetaConvertible ->
 973         false
 974 ;;
 975
 976
 977 let meta_convertibility t1 t2 =
 978   if t1 = t2 then
 979     true
 980   else
 981     try
 982       ignore(meta_convertibility_aux ([],[]) t1 t2);
 983       true
 984     with NotMetaConvertible ->
 985       false
 986 ;;
 987
 988 exception TermIsNotAnEquality;;
 989
 990 let term_is_equality term =
 991   match term with
 992   | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _]
 993     when LibraryObjects.is_eq_URI uri -> true
 994   | _ -> false
 995 ;;
 996
 997 let equality_of_term bag proof term =
 998   match term with
 999   | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2]
1000     when LibraryObjects.is_eq_URI uri ->
1001       let o = !Utils.compare_terms t1 t2 in
1002       let stat = (ty,t1,t2,o) in
1003       let w = Utils.compute_equality_weight stat in
1004       let e = mk_equality bag (w, Exact proof, stat,[]) in
1005       e
1006   | _ ->
1007       raise TermIsNotAnEquality
1008 ;;
1009
1010 let is_weak_identity eq =
1011   let _,_,(_,left, right,_),_,_ = open_equality eq in
1012    left = right
1013    (* doing metaconv here is meaningless *)
1014 ;;
1015
1016 let is_identity (_, context, ugraph) eq =
1017   let _,_,(ty,left,right,_),menv,_ = open_equality eq in
1018   (* doing metaconv here is meaningless *)
1019   left = right
1020 (*   fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
1021  *   *)
1022 ;;
1023
1024
1025 let term_of_equality eq_uri equality =
1026   let _, _, (ty, left, right, _), menv, _= open_equality equality in
1027   let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
1028   let argsno = List.length menv in
1029   let t =
1030     CicSubstitution.lift argsno
1031       (Cic.Appl [Cic.MutInd (eq_uri, 0, []); ty; left; right])
1032   in
1033   snd (
1034     List.fold_right
1035       (fun (i,_,ty) (n, t) ->
1036          let name = Cic.Name ("X" ^ (string_of_int n)) in
1037          let ty = CicSubstitution.lift (n-1) ty in
1038          let t =
1039            ProofEngineReduction.replace
1040              ~equality:eq ~what:[i]
1041              ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
1042          in
1043            (n-1, Cic.Prod (name, ty, t)))
1044       menv (argsno, t))
1045 ;;
1046
1047 let symmetric bag eq_ty l id uri m =
1048   let eq = Cic.MutInd(uri,0,[]) in
1049   let pred =
1050     Cic.Lambda (Cic.Name "Sym",eq_ty,
1051      Cic.Appl [CicSubstitution.lift 1 eq ;
1052                CicSubstitution.lift 1 eq_ty;
1053                Cic.Rel 1;CicSubstitution.lift 1 l])
1054   in
1055   let prefl =
1056     Exact (Cic.Appl
1057       [Cic.MutConstruct(uri,0,1,[]);eq_ty;l])
1058   in
1059   let id1 =
1060     let eq = mk_equality bag (0,prefl,(eq_ty,l,l,Utils.Eq),m) in
1061     let (_,_,_,_,id) = open_equality eq in
1062     id
1063   in
1064   Step(Subst.empty_subst,
1065     (Demodulation,id1,(Utils.Left,id),pred))
1066 ;;
1067
1068 module IntOT = struct
1069   type t = int
1070   let compare = Pervasives.compare
1071 end
1072
1073 module IntSet = Set.Make(IntOT);;
1074
1075 let n_purged = ref 0;;
1076
1077 let collect ((id_to_eq,_) as bag) alive1 alive2 alive3 =
1078 (*   let _ = <:start<collect>> in *)
1079   let deps_of id =
1080     let p,_,_ = proof_of_id bag id in
1081     match p with
1082     | Exact _ -> IntSet.empty
1083     | Step (_,(_,id1,(_,id2),_)) ->
1084           IntSet.add id1 (IntSet.add id2 IntSet.empty)
1085   in
1086   let rec close s =
1087     let news = IntSet.fold (fun id s -> IntSet.union (deps_of id) s) s s in
1088     if IntSet.equal news s then s else close news
1089   in
1090   let l_to_s s l = List.fold_left (fun s x -> IntSet.add x s) s l in
1091   let alive_set = l_to_s (l_to_s (l_to_s IntSet.empty alive2) alive1) alive3 in
1092   let closed_alive_set = close alive_set in
1093   let to_purge =
1094     Hashtbl.fold
1095       (fun k _ s ->
1096         if not (IntSet.mem k closed_alive_set) then
1097           k::s else s) id_to_eq []
1098   in
1099   n_purged := !n_purged + List.length to_purge;
1100   List.iter (Hashtbl.remove id_to_eq) to_purge;
1101 (*   let _ = <:stop<collect>> in ()   *)
1102 ;;
1103
1104 let id_of e =
1105   let _,_,_,_,id = open_equality e in id
1106 ;;
1107
1108 let get_stats () = ""
1109 (*
1110   <:show<Equality.>> ^
1111   "# of purged eq by the collector: " ^ string_of_int !n_purged ^ "\n"
1112 *)
1113 ;;
1114
1115 let rec pp_proofterm name t context =
1116   let rec skip_lambda tys ctx = function
1117     | Cic.Lambda (n,s,t) -> skip_lambda (s::tys) ((Some n)::ctx) t
1118     | t -> ctx,tys,t
1119   in
1120   let rename s name =
1121     match name with
1122     | Cic.Name s1 -> Cic.Name (s ^ s1)
1123     | _ -> assert false
1124   in
1125   let rec skip_letin ctx = function
1126     | Cic.LetIn (n,b,t) ->
1127         pp_proofterm (Some (rename "Lemma " n)) b ctx::
1128           skip_letin ((Some n)::ctx) t
1129     | t ->
1130         let ppterm t = CicPp.pp t ctx in
1131         let rec pp inner = function
1132           | Cic.Appl [Cic.Const (uri,[]);_;l;m;r;p1;p2]
1133               when Pcre.pmatch ~pat:"trans_eq" (UriManager.string_of_uri uri)->
1134                 if not inner then
1135                   ("     " ^ ppterm l) :: pp true p1 @
1136                             [ "   = " ^ ppterm m ] @ pp true p2 @
1137                             [ "   = " ^ ppterm r ]
1138                 else
1139                    pp true p1 @
1140                             [ "   = " ^ ppterm m ] @ pp true p2
1141           | Cic.Appl [Cic.Const (uri,[]);_;l;m;p]
1142               when Pcre.pmatch ~pat:"sym_eq" (UriManager.string_of_uri uri)->
1143                 pp true p
1144           | Cic.Appl [Cic.Const (uri,[]);_;_;_;_;_;p]
1145               when Pcre.pmatch ~pat:"eq_f" (UriManager.string_of_uri uri)->
1146                 pp true p
1147           | Cic.Appl [Cic.Const (uri,[]);_;_;_;_;_;p]
1148               when Pcre.pmatch ~pat:"eq_f1" (UriManager.string_of_uri uri)->
1149                 pp true p
1150           | Cic.Appl [Cic.MutConstruct (uri,_,_,[]);_;_;t;p]
1151               when Pcre.pmatch ~pat:"ex.ind" (UriManager.string_of_uri uri)->
1152                       [ "witness " ^ ppterm t ] @ pp true p
1153           | Cic.Appl (t::_) ->[ " [by " ^ ppterm t ^ "]"]
1154           | t ->[ " [by " ^ ppterm t ^ "]"]
1155         in
1156         let rec compat = function
1157           | a::b::tl -> (b ^ a) :: compat tl
1158           | h::[] -> [h]
1159           | [] -> []
1160         in
1161         let compat l = List.hd l :: compat (List.tl l) in
1162         compat (pp false t) @ ["";""]
1163   in
1164   let names, tys, body = skip_lambda [] context t in
1165   let ppname name = (match name with Some (Cic.Name s) -> s | _ -> "") in
1166   ppname name ^ ":\n" ^
1167   (if context = [] then
1168      let rec pp_l ctx = function
1169           | (t,name)::tl ->
1170               "   " ^ ppname name ^ ": " ^ CicPp.pp t ctx ^ "\n" ^
1171               pp_l (name::ctx) tl
1172           | [] -> "\n\n"
1173      in
1174        pp_l [] (List.rev (List.combine tys names))
1175    else "")
1176     ^
1177   String.concat "\n" (skip_letin names body)
1178 ;;
1179
1180 let pp_proofterm t =
1181   "\n\n" ^
1182   pp_proofterm (Some (Cic.Name "Hypothesis")) t []
1183 ;;
1184