components/tactics/paramodulation/equality.ml

   1 (* cOpyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)
  27
  28 type rule = SuperpositionRight | SuperpositionLeft | Demodulation
  29 type uncomparable = int -> int
  30 type equality =
  31     uncomparable *       (* trick to break structural equality *)
  32     int  *               (* weight *)
  33     proof *
  34     (Cic.term *          (* type *)
  35      Cic.term *          (* left side *)
  36      Cic.term *          (* right side *)
  37      Utils.comparison) * (* ordering *)
  38     Cic.metasenv  *      (* environment for metas *)
  39     int                  (* id *)
  40 and proof =
  41   | Exact of Cic.term
  42   | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term)
  43             (* subst, (rule,eq1, eq2,predicate) *)
  44 and goal_proof = (rule * Utils.pos * int * Subst.substitution * Cic.term) list
  45 ;;
  46
  47 (* globals *)
  48 let maxid = ref 0;;
  49 let id_to_eq = Hashtbl.create 1024;;
  50
  51 let freshid () =
  52   incr maxid; !maxid
  53 ;;
  54
  55 let reset () =
  56   maxid := 0;
  57   Hashtbl.clear  id_to_eq
  58 ;;
  59
  60 let uncomparable = fun _ -> 0
  61
  62 let mk_equality (weight,p,(ty,l,r,o),m) =
  63   let id = freshid () in
  64   let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  65   Hashtbl.add id_to_eq id eq;
  66   eq
  67 ;;
  68
  69 let mk_tmp_equality (weight,(ty,l,r,o),m) =
  70   let id = -1 in
  71   uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
  72 ;;
  73
  74
  75 let open_equality (_,weight,proof,(ty,l,r,o),m,id) =
  76   (weight,proof,(ty,l,r,o),m,id)
  77
  78 let string_of_rule = function
  79   | SuperpositionRight -> "SupR"
  80   | SuperpositionLeft -> "SupL"
  81   | Demodulation -> "Demod"
  82 ;;
  83
  84 let string_of_equality ?env eq =
  85   match env with
  86   | None ->
  87       let w, _, (ty, left, right, o), m , id = open_equality eq in
  88       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  89               id w (CicPp.ppterm ty)
  90               (CicPp.ppterm left)
  91               (Utils.string_of_comparison o) (CicPp.ppterm right)
  92         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
  93   | Some (_, context, _) ->
  94       let names = Utils.names_of_context context in
  95       let w, _, (ty, left, right, o), m , id = open_equality eq in
  96       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  97               id w (CicPp.pp ty names)
  98               (CicPp.pp left names) (Utils.string_of_comparison o)
  99               (CicPp.pp right names)
 100         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 101 ;;
 102
 103 let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
 104   Pervasives.compare s1 s2
 105 ;;
 106
 107 let proof_of_id id =
 108   try
 109     let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
 110       p,l,r
 111   with
 112       Not_found -> assert false
 113
 114
 115 let string_of_proof ?(names=[]) p gp =
 116   let str_of_pos = function
 117     | Utils.Left -> "left"
 118     | Utils.Right -> "right"
 119   in
 120   let fst3 (x,_,_) = x in
 121   let rec aux margin name =
 122     let prefix = String.make margin ' ' ^ name ^ ": " in function
 123     | Exact t ->
 124         Printf.sprintf "%sExact (%s)\n"
 125           prefix (CicPp.pp t names)
 126     | Step (subst,(rule,eq1,(pos,eq2),pred)) ->
 127         Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
 128           prefix (string_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos)
 129           (CicPp.pp pred names)^
 130         aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id eq1)) ^
 131         aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id eq2))
 132   in
 133   aux 0 "" p ^
 134   String.concat "\n"
 135     (List.map
 136       (fun (r,pos,i,s,t) ->
 137         (Printf.sprintf
 138           "GOAL: %s %s %d %s %s\n" (string_of_rule r)
 139             (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^
 140         aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id i)))
 141       gp)
 142 ;;
 143
 144 let rec depend eq id seen =
 145   let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
 146   if List.mem ideq seen then
 147     false,seen
 148   else
 149     if id = ideq then
 150       true,seen
 151     else
 152       match p with
 153       | Exact _ -> false,seen
 154       | Step (_,(_,id1,(_,id2),_)) ->
 155           let seen = ideq::seen in
 156           let eq1 = Hashtbl.find id_to_eq id1 in
 157           let eq2 = Hashtbl.find id_to_eq id2 in
 158           let b1,seen = depend eq1 id seen in
 159           if b1 then b1,seen else depend eq2 id seen
 160 ;;
 161
 162 let depend eq id = fst (depend eq id []);;
 163
 164 let ppsubst = Subst.ppsubst ~names:[];;
 165
 166 (* returns an explicit named subst and a list of arguments for sym_eq_URI *)
 167 let build_ens uri termlist =
 168   let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 169   match obj with
 170   | Cic.Constant (_, _, _, uris, _) ->
 171       assert (List.length uris <= List.length termlist);
 172       let rec aux = function
 173         | [], tl -> [], tl
 174         | (uri::uris), (term::tl) ->
 175             let ens, args = aux (uris, tl) in
 176             (uri, term)::ens, args
 177         | _, _ -> assert false
 178       in
 179       aux (uris, termlist)
 180   | _ -> assert false
 181 ;;
 182
 183 let mk_sym uri ty t1 t2 p =
 184   let ens, args =  build_ens uri [ty;t1;t2;p] in
 185     Cic.Appl (Cic.Const(uri, ens) :: args)
 186 ;;
 187
 188 let mk_trans uri ty t1 t2 t3 p12 p23 =
 189   let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
 190     Cic.Appl (Cic.Const (uri, ens) :: args)
 191 ;;
 192
 193 let mk_eq_ind uri ty what pred p1 other p2 =
 194  Cic.Appl [Cic.Const (uri, []); ty; what; pred; p1; other; p2]
 195 ;;
 196
 197 let p_of_sym ens tl =
 198   let args = List.map snd ens @ tl in
 199   match args with
 200     | [_;_;_;p] -> p
 201     | _ -> assert false
 202 ;;
 203
 204 let open_trans ens tl =
 205   let args = List.map snd ens @ tl in
 206   match args with
 207     | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
 208     | _ -> assert false
 209 ;;
 210
 211 let open_sym ens tl =
 212   let args = List.map snd ens @ tl in
 213   match args with
 214     | [ty;l;r;p] -> ty,l,r,p
 215     | _ -> assert false
 216 ;;
 217
 218 let open_eq_ind args =
 219   match args with
 220   | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
 221   | _ -> assert false
 222 ;;
 223
 224 let open_pred pred =
 225   match pred with
 226   | Cic.Lambda (_,ty,(Cic.Appl [Cic.MutInd (uri, 0,_);_;l;r]))
 227      when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
 228   | _ -> prerr_endline (CicPp.ppterm pred); assert false
 229 ;;
 230
 231 let is_not_fixed t =
 232    CicSubstitution.subst (Cic.Implicit None) t <>
 233    CicSubstitution.subst (Cic.Rel 1) t
 234 ;;
 235
 236
 237 let canonical t =
 238   let rec remove_refl t =
 239     match t with
 240     | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
 241           when LibraryObjects.is_trans_eq_URI uri_trans ->
 242           let ty,l,m,r,p1,p2 = open_trans ens tl in
 243             (match p1,p2 with
 244               | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 ->
 245                   remove_refl p2
 246               | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] ->
 247                   remove_refl p1
 248               | _ -> Cic.Appl (List.map remove_refl args))
 249     | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
 250     | Cic.LetIn (name,bo,rest) ->
 251         Cic.LetIn (name,remove_refl bo,remove_refl rest)
 252     | _ -> t
 253   in
 254   let rec canonical t =
 255     match t with
 256       | Cic.LetIn(name,bo,rest) -> Cic.LetIn(name,canonical bo,canonical rest)
 257       | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
 258           when LibraryObjects.is_sym_eq_URI uri_sym ->
 259           (match p_of_sym ens tl with
 260              | Cic.Appl ((Cic.Const(uri,ens))::tl)
 261                  when LibraryObjects.is_sym_eq_URI uri ->
 262                    canonical (p_of_sym ens tl)
 263              | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
 264                  when LibraryObjects.is_trans_eq_URI uri_trans ->
 265                  let ty,l,m,r,p1,p2 = open_trans ens tl in
 266                    mk_trans uri_trans ty r m l
 267                      (canonical (mk_sym uri_sym ty m r p2))
 268                      (canonical (mk_sym uri_sym ty l m p1))
 269              | Cic.Appl (((Cic.Const(uri_ind,ens)) as he)::tl)
 270                  when LibraryObjects.is_eq_ind_URI uri_ind ||
 271                       LibraryObjects.is_eq_ind_r_URI uri_ind ->
 272                  let ty, what, pred, p1, other, p2 =
 273                    match tl with
 274                    | [ty;what;pred;p1;other;p2] -> ty, what, pred, p1, other, p2
 275                    | _ -> assert false
 276                  in
 277                  let pred,l,r =
 278                    match pred with
 279                    | Cic.Lambda (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;l;r])
 280                        when LibraryObjects.is_eq_URI uri ->
 281                          Cic.Lambda
 282                            (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;r;l]),l,r
 283                    | _ ->
 284                        prerr_endline (CicPp.ppterm pred);
 285                        assert false
 286                  in
 287                  let l = CicSubstitution.subst what l in
 288                  let r = CicSubstitution.subst what r in
 289                  Cic.Appl
 290                    [he;ty;what;pred;
 291                     canonical (mk_sym uri_sym ty l r p1);other;canonical p2]
 292              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
 293                  when LibraryObjects.is_eq_URI uri -> t
 294              | _ -> Cic.Appl (List.map canonical args))
 295       | Cic.Appl l -> Cic.Appl (List.map canonical l)
 296       | _ -> t
 297   in
 298   remove_refl (canonical t)
 299 ;;
 300
 301 let ty_of_lambda = function
 302   | Cic.Lambda (_,ty,_) -> ty
 303   | _ -> assert false
 304 ;;
 305
 306 let compose_contexts ctx1 ctx2 =
 307   ProofEngineReduction.replace_lifting
 308     ~equality:(=) ~what:[Cic.Implicit(Some `Hole)] ~with_what:[ctx2] ~where:ctx1
 309 ;;
 310
 311 let put_in_ctx ctx t =
 312   ProofEngineReduction.replace_lifting
 313     ~equality:(=) ~what:[Cic.Implicit (Some `Hole)] ~with_what:[t] ~where:ctx
 314 ;;
 315
 316 let mk_eq uri ty l r =
 317   Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r]
 318 ;;
 319
 320 let mk_refl uri ty t =
 321   Cic.Appl [Cic.MutConstruct(uri,0,1,[]);ty;t]
 322 ;;
 323
 324 let open_eq = function
 325   | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
 326       uri, ty, l ,r
 327   | _ -> assert false
 328 ;;
 329
 330 let contextualize uri ty left right t =
 331   let hole = Cic.Implicit (Some `Hole) in
 332   (* aux [uri] [ty] [left] [right] [ctx] [t]
 333    *
 334    * the parameters validate this invariant
 335    *   t: eq(uri) ty left right
 336    * that is used only by the base case
 337    *
 338    * ctx is a term with an hole. Cic.Implicit(Some `Hole) is the empty context
 339    *)
 340     let rec aux uri ty left right ctx_d = function
 341       | Cic.Appl ((Cic.Const(uri_sym,ens))::tl)
 342         when LibraryObjects.is_sym_eq_URI uri_sym  ->
 343           let ty,l,r,p = open_sym ens tl in
 344           mk_sym uri_sym ty l r (aux uri ty l r ctx_d p)
 345       | Cic.LetIn (name,body,rest) ->
 346           (* we should go in body *)
 347           Cic.LetIn (name,body,aux uri ty left right ctx_d rest)
 348       | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
 349         when LibraryObjects.is_eq_ind_URI uri_ind ||
 350              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 351           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 352           let ty2,eq,lp,rp = open_pred pred in
 353           let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
 354           let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 355           let is_not_fixed_lp = is_not_fixed lp in
 356           let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
 357           (* extract the context and the fixed term from the predicate *)
 358           let m, ctx_c =
 359             let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
 360             (* they were under a lambda *)
 361             let m =  CicSubstitution.subst (Cic.Implicit None) m in
 362             let ctx_c = CicSubstitution.subst hole ctx_c in
 363             m, ctx_c
 364           in
 365           (* create the compound context and put the terms under it *)
 366           let ctx_dc = compose_contexts ctx_d ctx_c in
 367           let dc_what = put_in_ctx ctx_dc what in
 368           let dc_other = put_in_ctx ctx_dc other in
 369           (* m is already in ctx_c so it is put in ctx_d only *)
 370           let d_m = put_in_ctx ctx_d m in
 371           (* we also need what in ctx_c *)
 372           let c_what = put_in_ctx ctx_c what in
 373           (* now put the proofs in the compound context *)
 374           let p1 = (* p1: dc_what = d_m *)
 375             if is_not_fixed_lp then
 376               aux uri ty1 c_what m ctx_d p1
 377             else
 378               mk_sym uri_sym ty d_m dc_what
 379                 (aux uri ty1 m c_what ctx_d p1)
 380           in
 381           let p2 = (* p2: dc_other = dc_what *)
 382             if avoid_eq_ind then
 383               mk_sym uri_sym ty dc_what dc_other
 384                 (aux uri ty1 what other ctx_dc p2)
 385             else
 386               aux uri ty1 other what ctx_dc p2
 387           in
 388           (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
 389              if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
 390           let a,b,c,paeqb,pbeqc =
 391             if is_not_fixed_lp then
 392               dc_other,dc_what,d_m,p2,p1
 393             else
 394               d_m,dc_what,dc_other,
 395                 (mk_sym uri_sym ty dc_what d_m p1),
 396                 (mk_sym uri_sym ty dc_other dc_what p2)
 397           in
 398           mk_trans uri_trans ty a b c paeqb pbeqc
 399     | t ->
 400         let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 401         let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in
 402         let pred =
 403           (* ctx_d will go under a lambda, but put_in_ctx substitutes Rel 1 *)
 404           let r = CicSubstitution.lift 1 (put_in_ctx ctx_d left) in
 405           let l =
 406             let ctx_d = CicSubstitution.lift 1 ctx_d in
 407             put_in_ctx ctx_d (Cic.Rel 1)
 408           in
 409           let lty = CicSubstitution.lift 1 ty in
 410           Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r))
 411         in
 412         let d_left = put_in_ctx ctx_d left in
 413         let d_right = put_in_ctx ctx_d right in
 414         let refl_eq = mk_refl uri ty d_left in
 415         mk_sym uri_sym ty d_right d_left
 416           (mk_eq_ind uri_ind ty left pred refl_eq right t)
 417   in
 418   aux uri ty left right hole t
 419 ;;
 420
 421 let contextualize_rewrites t ty =
 422   let eq,ty,l,r = open_eq ty in
 423   contextualize eq ty l r t
 424 ;;
 425
 426 let add_subst subst =
 427   function
 428     | Exact t -> Exact (Subst.apply_subst subst t)
 429     | Step (s,(rule, id1, (pos,id2), pred)) ->
 430         Step (Subst.concat subst s,(rule, id1, (pos,id2), pred))
 431 ;;
 432
 433 let build_proof_step ?(sym=false) lift subst p1 p2 pos l r pred =
 434   let p1 = Subst.apply_subst_lift lift subst p1 in
 435   let p2 = Subst.apply_subst_lift lift subst p2 in
 436   let l  = CicSubstitution.lift lift l in
 437   let l = Subst.apply_subst_lift lift subst l in
 438   let r  = CicSubstitution.lift lift r in
 439   let r = Subst.apply_subst_lift lift subst r in
 440   let pred = CicSubstitution.lift lift pred in
 441   let pred = Subst.apply_subst_lift lift subst pred in
 442   let ty,body =
 443     match pred with
 444       | Cic.Lambda (_,ty,body) -> ty,body
 445       | _ -> assert false
 446   in
 447   let what, other =
 448     if pos = Utils.Left then l,r else r,l
 449   in
 450   let p =
 451     match pos with
 452       | Utils.Left ->
 453         mk_eq_ind (Utils.eq_ind_URI ()) ty what pred p1 other p2
 454       | Utils.Right ->
 455         mk_eq_ind (Utils.eq_ind_r_URI ()) ty what pred p1 other p2
 456   in
 457   if sym then
 458     let uri,pl,pr =
 459       let eq,_,pl,pr = open_eq body in
 460       LibraryObjects.sym_eq_URI ~eq, pl, pr
 461     in
 462     let l = CicSubstitution.subst other pl in
 463     let r = CicSubstitution.subst other pr in
 464     mk_sym uri ty l r p
 465   else
 466     p
 467 ;;
 468
 469 let parametrize_proof p l r ty =
 470   let parameters = CicUtil.metas_of_term p
 471 @ CicUtil.metas_of_term l
 472 @ CicUtil.metas_of_term r
 473 in (* ?if they are under a lambda? *)
 474   let parameters =
 475     HExtlib.list_uniq (List.sort Pervasives.compare parameters)
 476   in
 477   let what = List.map (fun (i,l) -> Cic.Meta (i,l)) parameters in
 478   let with_what, lift_no =
 479     List.fold_right (fun _ (acc,n) -> ((Cic.Rel n)::acc),n+1) what ([],1)
 480   in
 481   let p = CicSubstitution.lift (lift_no-1) p in
 482   let p =
 483     ProofEngineReduction.replace_lifting
 484     ~equality:(fun t1 t2 ->
 485       match t1,t2 with Cic.Meta (i,_),Cic.Meta(j,_) -> i=j | _ -> false)
 486     ~what ~with_what ~where:p
 487   in
 488   let ty_of_m _ = ty (*function
 489     | Cic.Meta (i,_) -> List.assoc i menv
 490     | _ -> assert false *)
 491   in
 492   let args, proof,_ =
 493     List.fold_left
 494       (fun (instance,p,n) m ->
 495         (instance@[m],
 496         Cic.Lambda
 497           (Cic.Name ("x"^string_of_int n),
 498           CicSubstitution.lift (lift_no - n - 1) (ty_of_m m),
 499           p),
 500         n+1))
 501       ([Cic.Rel 1],p,1)
 502       what
 503   in
 504   let instance = match args with | [x] -> x | _ -> Cic.Appl args in
 505   proof, instance
 506 ;;
 507
 508 let wfo goalproof proof id =
 509   let rec aux acc id =
 510     let p,_,_ = proof_of_id id in
 511     match p with
 512     | Exact _ -> if (List.mem id acc) then acc else id :: acc
 513     | Step (_,(_,id1, (_,id2), _)) ->
 514         let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
 515         let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
 516         id :: acc
 517   in
 518   let acc =
 519     match proof with
 520       | Exact _ -> [id]
 521       | Step (_,(_,id1, (_,id2), _)) -> aux (aux [id] id1) id2
 522   in
 523   List.fold_left (fun acc (_,_,id,_,_) -> aux acc id) acc goalproof
 524 ;;
 525
 526 let string_of_id names id =
 527   if id = 0 then "" else
 528   try
 529     let (_,p,(_,l,r,_),m,_) = open_equality (Hashtbl.find id_to_eq id) in
 530     match p with
 531     | Exact t ->
 532         Printf.sprintf "%d = %s: %s = %s [%s]" id
 533           (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
 534         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 535     | Step (_,(step,id1, (_,id2), _) ) ->
 536         Printf.sprintf "%6d: %s %6d %6d   %s = %s [%s]" id
 537           (string_of_rule step)
 538           id1 id2 (CicPp.pp l names) (CicPp.pp r names)
 539         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 540   with
 541       Not_found -> assert false
 542
 543 let pp_proof names goalproof proof subst id initial_goal =
 544   String.concat "\n" (List.map (string_of_id names) (wfo goalproof proof id)) ^
 545   "\ngoal:\n   " ^
 546     (String.concat "\n   "
 547       (fst (List.fold_right
 548         (fun (r,pos,i,s,pred) (acc,g) ->
 549           let _,_,left,right = open_eq g in
 550           let ty =
 551             match pos with
 552             | Utils.Left -> CicReduction.head_beta_reduce (Cic.Appl[pred;right])
 553             | Utils.Right -> CicReduction.head_beta_reduce (Cic.Appl[pred;left])
 554           in
 555           let ty = Subst.apply_subst s ty in
 556           ("("^ string_of_rule r ^ " " ^ string_of_int i^") -> "
 557           ^ CicPp.pp ty names) :: acc,ty) goalproof ([],initial_goal)))) ^
 558   "\nand then subsumed by " ^ string_of_int id ^ " when " ^ Subst.ppsubst subst
 559 ;;
 560
 561 module OT =
 562   struct
 563     type t = int
 564     let compare = Pervasives.compare
 565   end
 566
 567 module M = Map.Make(OT)
 568
 569 let rec find_deps m i =
 570   if M.mem i m then m
 571   else
 572     let p,_,_ = proof_of_id i in
 573     match p with
 574     | Exact _ -> M.add i [] m
 575     | Step (_,(_,id1,(_,id2),_)) ->
 576         let m = find_deps m id1 in
 577         let m = find_deps m id2 in
 578         M.add i (M.find id1 m @ M.find id2 m @ [id1;id2]) m
 579 ;;
 580
 581 let topological_sort l =
 582   (* build the partial order relation *)
 583   let m =
 584     List.fold_left (fun m i -> find_deps m i)
 585     M.empty l
 586   in
 587   let m = M.map (fun x -> Some x) m in
 588   (* utils *)
 589   let keys m = M.fold (fun i _ acc -> i::acc) m [] in
 590   let split l m = List.filter (fun i -> M.find i m = Some []) l in
 591   let purge l m =
 592     M.mapi
 593       (fun k v -> if List.mem k l then None else
 594          match v with
 595          | None -> None
 596          | Some ll -> Some (List.filter (fun i -> not (List.mem i l)) ll))
 597       m
 598   in
 599   let rec aux m =
 600       let keys = keys m in
 601       let ok = split keys m in
 602       let m = purge ok m in
 603       ok @ (if ok = [] then [] else aux m)
 604   in
 605   aux m
 606 ;;
 607
 608
 609 (* returns the list of ids that should be factorized *)
 610 let get_duplicate_step_in_wfo l p =
 611   let ol = List.rev l in
 612   let h = Hashtbl.create 13 in
 613   (* NOTE: here the n parameter is an approximation of the dependency
 614      between equations. To do things seriously we should maintain a
 615      dependency graph. This approximation is not perfect. *)
 616   let add i =
 617     let p,_,_ = proof_of_id i in
 618     match p with
 619     | Exact _ -> true
 620     | _ ->
 621         try
 622           let no = Hashtbl.find h i in
 623           Hashtbl.replace h i (no+1);
 624           false
 625         with Not_found -> Hashtbl.add h i 1;true
 626   in
 627   let rec aux = function
 628     | Exact _ -> ()
 629     | Step (_,(_,i1,(_,i2),_)) ->
 630         let go_on_1 = add i1 in
 631         let go_on_2 = add i2 in
 632         if go_on_1 then aux (let p,_,_ = proof_of_id i1 in p);
 633         if go_on_2 then aux (let p,_,_ = proof_of_id i2 in p)
 634   in
 635   aux p;
 636   List.iter
 637     (fun (_,_,id,_,_) -> aux (let p,_,_ = proof_of_id id in p))
 638     ol;
 639   (* now h is complete *)
 640   let proofs = Hashtbl.fold (fun k count acc-> (k,count)::acc) h [] in
 641   let proofs = List.filter (fun (_,c) -> c > 1) proofs in
 642   topological_sort (List.map (fun (i,_) -> i) proofs)
 643 ;;
 644
 645 let build_proof_term h lift proof =
 646   let proof_of_id aux id =
 647     let p,l,r = proof_of_id id in
 648     try List.assoc id h,l,r with Not_found -> aux p, l, r
 649   in
 650   let rec aux = function
 651      | Exact term -> CicSubstitution.lift lift term
 652      | Step (subst,(rule, id1, (pos,id2), pred)) ->
 653          let p1,_,_ = proof_of_id aux id1 in
 654          let p2,l,r = proof_of_id aux id2 in
 655          let varname =
 656            match rule with
 657            | SuperpositionRight -> Cic.Name ("SupR" ^ Utils.string_of_pos pos)
 658            | Demodulation -> Cic.Name ("DemEq"^ Utils.string_of_pos pos)
 659            | _ -> assert false
 660          in
 661          let pred =
 662            match pred with
 663            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 664            | _ -> assert false
 665          in
 666          let p =   build_proof_step lift subst p1 p2 pos l r pred in
 667 (*         let cond =  (not (List.mem 302 (Utils.metas_of_term p)) || id1 = 8 || id1 = 132) in
 668            if not cond then
 669              prerr_endline ("ERROR " ^ string_of_int id1 ^ " " ^ string_of_int id2);
 670            assert cond;*)
 671            p
 672   in
 673    aux proof
 674 ;;
 675
 676 let build_goal_proof l initial ty se =
 677   let se = List.map (fun i -> Cic.Meta (i,[])) se in
 678   let lets = get_duplicate_step_in_wfo l initial in
 679   let letsno = List.length lets in
 680   let _,mty,_,_ = open_eq ty in
 681   let lift_list l = List.map (fun (i,t) -> i,CicSubstitution.lift 1 t) l
 682   in
 683   let lets,_,h =
 684     List.fold_left
 685       (fun (acc,n,h) id ->
 686         let p,l,r = proof_of_id id in
 687         let cic = build_proof_term h n p in
 688         let real_cic,instance =
 689           parametrize_proof cic l r (CicSubstitution.lift n mty)
 690         in
 691         let h = (id, instance)::lift_list h in
 692         acc@[id,real_cic],n+1,h)
 693       ([],0,[]) lets
 694   in
 695   let proof,se =
 696     let rec aux se current_proof = function
 697       | [] -> current_proof,se
 698       | (rule,pos,id,subst,pred)::tl ->
 699           let p,l,r = proof_of_id id in
 700            let p = build_proof_term h letsno p in
 701            let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
 702          let varname =
 703            match rule with
 704            | SuperpositionLeft -> Cic.Name ("SupL" ^ Utils.string_of_pos pos)
 705            | Demodulation -> Cic.Name ("DemG"^ Utils.string_of_pos pos)
 706            | _ -> assert false
 707          in
 708          let pred =
 709            match pred with
 710            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 711            | _ -> assert false
 712          in
 713            let proof =
 714              build_proof_step letsno subst current_proof p pos l r pred
 715            in
 716            let proof,se = aux se proof tl in
 717            Subst.apply_subst_lift letsno subst proof,
 718            List.map (fun x -> Subst.apply_subst_lift letsno subst x) se
 719     in
 720     aux se (build_proof_term h letsno initial) l
 721   in
 722   let n,proof =
 723     let initial = proof in
 724     List.fold_right
 725       (fun (id,cic) (n,p) ->
 726         n-1,
 727         Cic.LetIn (
 728           Cic.Name ("H"^string_of_int id),
 729           cic, p))
 730     lets (letsno-1,initial)
 731   in
 732     (proof,se)
 733   (* canonical (contextualize_rewrites proof (CicSubstitution.lift letsno ty)),
 734    se *)
 735 ;;
 736
 737 let refl_proof ty term =
 738   Cic.Appl
 739     [Cic.MutConstruct
 740        (Utils.eq_URI (), 0, 1, []);
 741        ty; term]
 742 ;;
 743
 744 let metas_of_proof p =
 745   let p = build_proof_term [] 0 p in
 746   Utils.metas_of_term p
 747 ;;
 748
 749 let relocate newmeta menv to_be_relocated =
 750   let subst, newmetasenv, newmeta =
 751     List.fold_right
 752       (fun i (subst, metasenv, maxmeta) ->
 753         let _,context,ty = CicUtil.lookup_meta i menv in
 754         let irl = [] in
 755         let newmeta = Cic.Meta(maxmeta,irl) in
 756         let newsubst = Subst.buildsubst i context newmeta ty subst in
 757         newsubst, (maxmeta,context,ty)::metasenv, maxmeta+1)
 758       to_be_relocated (Subst.empty_subst, [], newmeta+1)
 759   in
 760   let menv = Subst.apply_subst_metasenv subst menv @ newmetasenv in
 761   subst, menv, newmeta
 762
 763
 764 let fix_metas newmeta eq =
 765   let w, p, (ty, left, right, o), menv,_ = open_equality eq in
 766   let to_be_relocated =
 767 (* List.map (fun i ,_,_ -> i) menv *)
 768     HExtlib.list_uniq
 769       (List.sort Pervasives.compare
 770          (Utils.metas_of_term left @ Utils.metas_of_term right))
 771   in
 772   let subst, metasenv, newmeta = relocate newmeta menv to_be_relocated in
 773   let ty = Subst.apply_subst subst ty in
 774   let left = Subst.apply_subst subst left in
 775   let right = Subst.apply_subst subst right in
 776   let fix_proof = function
 777     | Exact p -> Exact (Subst.apply_subst subst p)
 778     | Step (s,(r,id1,(pos,id2),pred)) ->
 779         Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
 780   in
 781   let p = fix_proof p in
 782   let eq' = mk_equality (w, p, (ty, left, right, o), metasenv) in
 783   newmeta+1, eq'
 784
 785 exception NotMetaConvertible;;
 786
 787 let meta_convertibility_aux table t1 t2 =
 788   let module C = Cic in
 789   let rec aux ((table_l, table_r) as table) t1 t2 =
 790     match t1, t2 with
 791     | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
 792         let m1_binding, table_l =
 793           try List.assoc m1 table_l, table_l
 794           with Not_found -> m2, (m1, m2)::table_l
 795         and m2_binding, table_r =
 796           try List.assoc m2 table_r, table_r
 797           with Not_found -> m1, (m2, m1)::table_r
 798         in
 799         if (m1_binding <> m2) || (m2_binding <> m1) then
 800           raise NotMetaConvertible
 801         else (
 802           try
 803             List.fold_left2
 804               (fun res t1 t2 ->
 805                  match t1, t2 with
 806                  | None, Some _ | Some _, None -> raise NotMetaConvertible
 807                  | None, None -> res
 808                  | Some t1, Some t2 -> (aux res t1 t2))
 809               (table_l, table_r) tl1 tl2
 810           with Invalid_argument _ ->
 811             raise NotMetaConvertible
 812         )
 813     | C.Var (u1, ens1), C.Var (u2, ens2)
 814     | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
 815         aux_ens table ens1 ens2
 816     | C.Cast (s1, t1), C.Cast (s2, t2)
 817     | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
 818     | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
 819     | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
 820         let table = aux table s1 s2 in
 821         aux table t1 t2
 822     | C.Appl l1, C.Appl l2 -> (
 823         try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 824         with Invalid_argument _ -> raise NotMetaConvertible
 825       )
 826     | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
 827         when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
 828     | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
 829         when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
 830         aux_ens table ens1 ens2
 831     | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
 832         when (UriManager.eq u1 u2) && i1 = i2 ->
 833         let table = aux table s1 s2 in
 834         let table = aux table t1 t2 in (
 835           try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 836           with Invalid_argument _ -> raise NotMetaConvertible
 837         )
 838     | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
 839         try
 840           List.fold_left2
 841             (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
 842                if i1 <> i2 then raise NotMetaConvertible
 843                else
 844                  let res = (aux res s1 s2) in aux res t1 t2)
 845             table il1 il2
 846         with Invalid_argument _ -> raise NotMetaConvertible
 847       )
 848     | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
 849         try
 850           List.fold_left2
 851             (fun res (n1, s1, t1) (n2, s2, t2) ->
 852                let res = aux res s1 s2 in aux res t1 t2)
 853             table il1 il2
 854         with Invalid_argument _ -> raise NotMetaConvertible
 855       )
 856     | t1, t2 when t1 = t2 -> table
 857     | _, _ -> raise NotMetaConvertible
 858
 859   and aux_ens table ens1 ens2 =
 860     let cmp (u1, t1) (u2, t2) =
 861       Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
 862     in
 863     let ens1 = List.sort cmp ens1
 864     and ens2 = List.sort cmp ens2 in
 865     try
 866       List.fold_left2
 867         (fun res (u1, t1) (u2, t2) ->
 868            if not (UriManager.eq u1 u2) then raise NotMetaConvertible
 869            else aux res t1 t2)
 870         table ens1 ens2
 871     with Invalid_argument _ -> raise NotMetaConvertible
 872   in
 873   aux table t1 t2
 874 ;;
 875
 876
 877 let meta_convertibility_eq eq1 eq2 =
 878   let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
 879   let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
 880   if ty <> ty' then
 881     false
 882   else if (left = left') && (right = right') then
 883     true
 884   else if (left = right') && (right = left') then
 885     true
 886   else
 887     try
 888       let table = meta_convertibility_aux ([], []) left left' in
 889       let _ = meta_convertibility_aux table right right' in
 890       true
 891     with NotMetaConvertible ->
 892       try
 893         let table = meta_convertibility_aux ([], []) left right' in
 894         let _ = meta_convertibility_aux table right left' in
 895         true
 896       with NotMetaConvertible ->
 897         false
 898 ;;
 899
 900
 901 let meta_convertibility t1 t2 =
 902   if t1 = t2 then
 903     true
 904   else
 905     try
 906       ignore(meta_convertibility_aux ([], []) t1 t2);
 907       true
 908     with NotMetaConvertible ->
 909       false
 910 ;;
 911
 912 exception TermIsNotAnEquality;;
 913
 914 let term_is_equality term =
 915   let iseq uri = UriManager.eq uri (Utils.eq_URI ()) in
 916   match term with
 917   | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _] when iseq uri -> true
 918   | _ -> false
 919 ;;
 920
 921 let equality_of_term proof term =
 922   let eq_uri = Utils.eq_URI () in
 923   let iseq uri = UriManager.eq uri eq_uri in
 924   match term with
 925   | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2] when iseq uri ->
 926       let o = !Utils.compare_terms t1 t2 in
 927       let stat = (ty,t1,t2,o) in
 928       let w = Utils.compute_equality_weight stat in
 929       let e = mk_equality (w, Exact proof, stat,[]) in
 930       e
 931   | _ ->
 932       raise TermIsNotAnEquality
 933 ;;
 934
 935 let is_weak_identity eq =
 936   let _,_,(_,left, right,_),_,_ = open_equality eq in
 937   left = right || meta_convertibility left right
 938 ;;
 939
 940 let is_identity (_, context, ugraph) eq =
 941   let _,_,(ty,left,right,_),menv,_ = open_equality eq in
 942   left = right ||
 943   (* (meta_convertibility left right)) *)
 944   fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
 945 ;;
 946
 947
 948 let term_of_equality equality =
 949   let _, _, (ty, left, right, _), menv, _= open_equality equality in
 950   let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
 951   let argsno = List.length menv in
 952   let t =
 953     CicSubstitution.lift argsno
 954       (Cic.Appl [Cic.MutInd (Utils.eq_URI (), 0, []); ty; left; right])
 955   in
 956   snd (
 957     List.fold_right
 958       (fun (i,_,ty) (n, t) ->
 959          let name = Cic.Name ("X" ^ (string_of_int n)) in
 960          let ty = CicSubstitution.lift (n-1) ty in
 961          let t =
 962            ProofEngineReduction.replace
 963              ~equality:eq ~what:[i]
 964              ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
 965          in
 966            (n-1, Cic.Prod (name, ty, t)))
 967       menv (argsno, t))
 968 ;;
 969
 970 let symmetric eq_ty l id uri m =
 971   let eq = Cic.MutInd(uri,0,[]) in
 972   let pred =
 973     Cic.Lambda (Cic.Name "Sym",eq_ty,
 974      Cic.Appl [CicSubstitution.lift 1 eq ;
 975                CicSubstitution.lift 1 eq_ty;
 976                Cic.Rel 1;CicSubstitution.lift 1 l])
 977   in
 978   let prefl =
 979     Exact (Cic.Appl
 980       [Cic.MutConstruct(uri,0,1,[]);eq_ty;l])
 981   in
 982   let id1 =
 983     let eq = mk_equality (0,prefl,(eq_ty,l,l,Utils.Eq),m) in
 984     let (_,_,_,_,id) = open_equality eq in
 985     id
 986   in
 987   Step(Subst.empty_subst,
 988     (Demodulation,id1,(Utils.Left,id),pred))
 989 ;;
 990