components/tactics/paramodulation/equality.ml

   1 (* cOpyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 let _profiler = <:profiler<_profiler>>;;
  27
  28 (* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)
  29
  30 type rule = SuperpositionRight | SuperpositionLeft | Demodulation
  31 type uncomparable = int -> int
  32 type equality =
  33     uncomparable *       (* trick to break structural equality *)
  34     int  *               (* weight *)
  35     proof *
  36     (Cic.term *          (* type *)
  37      Cic.term *          (* left side *)
  38      Cic.term *          (* right side *)
  39      Utils.comparison) * (* ordering *)
  40     Cic.metasenv  *      (* environment for metas *)
  41     int                  (* id *)
  42 and proof =
  43   | Exact of Cic.term
  44   | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term)
  45             (* subst, (rule,eq1, eq2,predicate) *)
  46 and goal_proof = (rule * Utils.pos * int * Subst.substitution * Cic.term) list
  47 ;;
  48
  49 (* globals *)
  50 let maxid = ref 0;;
  51 let id_to_eq = Hashtbl.create 1024;;
  52
  53 let freshid () =
  54   incr maxid; !maxid
  55 ;;
  56
  57 let reset () =
  58   maxid := 0;
  59   Hashtbl.clear  id_to_eq
  60 ;;
  61
  62 let uncomparable = fun _ -> 0
  63
  64 let mk_equality (weight,p,(ty,l,r,o),m) =
  65   let id = freshid () in
  66   let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  67   Hashtbl.add id_to_eq id eq;
  68   eq
  69 ;;
  70
  71 let mk_tmp_equality (weight,(ty,l,r,o),m) =
  72   let id = -1 in
  73   uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
  74 ;;
  75
  76
  77 let open_equality (_,weight,proof,(ty,l,r,o),m,id) =
  78   (weight,proof,(ty,l,r,o),m,id)
  79
  80 let string_of_rule = function
  81   | SuperpositionRight -> "SupR"
  82   | SuperpositionLeft -> "SupL"
  83   | Demodulation -> "Demod"
  84 ;;
  85
  86 let string_of_equality ?env eq =
  87   match env with
  88   | None ->
  89       let w, _, (ty, left, right, o), m , id = open_equality eq in
  90       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  91               id w (CicPp.ppterm ty)
  92               (CicPp.ppterm left)
  93               (Utils.string_of_comparison o) (CicPp.ppterm right)
  94         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
  95   | Some (_, context, _) ->
  96       let names = Utils.names_of_context context in
  97       let w, _, (ty, left, right, o), m , id = open_equality eq in
  98       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  99               id w (CicPp.pp ty names)
 100               (CicPp.pp left names) (Utils.string_of_comparison o)
 101               (CicPp.pp right names)
 102         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 103 ;;
 104
 105 let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
 106   Pervasives.compare s1 s2
 107 ;;
 108
 109 let proof_of_id id =
 110   try
 111     let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
 112       p,l,r
 113   with
 114       Not_found -> assert false
 115
 116
 117 let string_of_proof ?(names=[]) p gp =
 118   let str_of_pos = function
 119     | Utils.Left -> "left"
 120     | Utils.Right -> "right"
 121   in
 122   let fst3 (x,_,_) = x in
 123   let rec aux margin name =
 124     let prefix = String.make margin ' ' ^ name ^ ": " in function
 125     | Exact t ->
 126         Printf.sprintf "%sExact (%s)\n"
 127           prefix (CicPp.pp t names)
 128     | Step (subst,(rule,eq1,(pos,eq2),pred)) ->
 129         Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
 130           prefix (string_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos)
 131           (CicPp.pp pred names)^
 132         aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id eq1)) ^
 133         aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id eq2))
 134   in
 135   aux 0 "" p ^
 136   String.concat "\n"
 137     (List.map
 138       (fun (r,pos,i,s,t) ->
 139         (Printf.sprintf
 140           "GOAL: %s %s %d %s %s\n" (string_of_rule r)
 141             (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^
 142         aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id i)))
 143       gp)
 144 ;;
 145
 146 let rec depend eq id seen =
 147   let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
 148   if List.mem ideq seen then
 149     false,seen
 150   else
 151     if id = ideq then
 152       true,seen
 153     else
 154       match p with
 155       | Exact _ -> false,seen
 156       | Step (_,(_,id1,(_,id2),_)) ->
 157           let seen = ideq::seen in
 158           let eq1 = Hashtbl.find id_to_eq id1 in
 159           let eq2 = Hashtbl.find id_to_eq id2 in
 160           let b1,seen = depend eq1 id seen in
 161           if b1 then b1,seen else depend eq2 id seen
 162 ;;
 163
 164 let depend eq id = fst (depend eq id []);;
 165
 166 let ppsubst = Subst.ppsubst ~names:[];;
 167
 168 (* returns an explicit named subst and a list of arguments for sym_eq_URI *)
 169 let build_ens uri termlist =
 170   let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 171   match obj with
 172   | Cic.Constant (_, _, _, uris, _) ->
 173       assert (List.length uris <= List.length termlist);
 174       let rec aux = function
 175         | [], tl -> [], tl
 176         | (uri::uris), (term::tl) ->
 177             let ens, args = aux (uris, tl) in
 178             (uri, term)::ens, args
 179         | _, _ -> assert false
 180       in
 181       aux (uris, termlist)
 182   | _ -> assert false
 183 ;;
 184
 185 let mk_sym uri ty t1 t2 p =
 186   let ens, args =  build_ens uri [ty;t1;t2;p] in
 187     Cic.Appl (Cic.Const(uri, ens) :: args)
 188 ;;
 189
 190 let mk_trans uri ty t1 t2 t3 p12 p23 =
 191   let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
 192     Cic.Appl (Cic.Const (uri, ens) :: args)
 193 ;;
 194
 195 let mk_eq_ind uri ty what pred p1 other p2 =
 196  Cic.Appl [Cic.Const (uri, []); ty; what; pred; p1; other; p2]
 197 ;;
 198
 199 let p_of_sym ens tl =
 200   let args = List.map snd ens @ tl in
 201   match args with
 202     | [_;_;_;p] -> p
 203     | _ -> assert false
 204 ;;
 205
 206 let open_trans ens tl =
 207   let args = List.map snd ens @ tl in
 208   match args with
 209     | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
 210     | _ -> assert false
 211 ;;
 212
 213 let open_sym ens tl =
 214   let args = List.map snd ens @ tl in
 215   match args with
 216     | [ty;l;r;p] -> ty,l,r,p
 217     | _ -> assert false
 218 ;;
 219
 220 let open_eq_ind args =
 221   match args with
 222   | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
 223   | _ -> assert false
 224 ;;
 225
 226 let open_pred pred =
 227   match pred with
 228   | Cic.Lambda (_,_,(Cic.Appl [Cic.MutInd (uri, 0,_);ty;l;r]))
 229      when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
 230   | _ -> prerr_endline (CicPp.ppterm pred); assert false
 231 ;;
 232
 233 let is_not_fixed t =
 234    CicSubstitution.subst (Cic.Implicit None) t <>
 235    CicSubstitution.subst (Cic.Rel 1) t
 236 ;;
 237
 238
 239 let canonical t =
 240   let rec remove_refl t =
 241     match t with
 242     | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
 243           when LibraryObjects.is_trans_eq_URI uri_trans ->
 244           let ty,l,m,r,p1,p2 = open_trans ens tl in
 245             (match p1,p2 with
 246               | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 ->
 247                   remove_refl p2
 248               | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] ->
 249                   remove_refl p1
 250               | _ -> Cic.Appl (List.map remove_refl args))
 251     | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
 252     | Cic.LetIn (name,bo,rest) ->
 253         Cic.LetIn (name,remove_refl bo,remove_refl rest)
 254     | _ -> t
 255   in
 256   let rec canonical t =
 257     match t with
 258       | Cic.LetIn(name,bo,rest) -> Cic.LetIn(name,canonical bo,canonical rest)
 259       | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
 260           when LibraryObjects.is_sym_eq_URI uri_sym ->
 261           (match p_of_sym ens tl with
 262              | Cic.Appl ((Cic.Const(uri,ens))::tl)
 263                  when LibraryObjects.is_sym_eq_URI uri ->
 264                    canonical (p_of_sym ens tl)
 265              | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
 266                  when LibraryObjects.is_trans_eq_URI uri_trans ->
 267                  let ty,l,m,r,p1,p2 = open_trans ens tl in
 268                    mk_trans uri_trans ty r m l
 269                      (canonical (mk_sym uri_sym ty m r p2))
 270                      (canonical (mk_sym uri_sym ty l m p1))
 271              | Cic.Appl (((Cic.Const(uri_ind,ens)) as he)::tl)
 272                  when LibraryObjects.is_eq_ind_URI uri_ind ||
 273                       LibraryObjects.is_eq_ind_r_URI uri_ind ->
 274                  let ty, what, pred, p1, other, p2 =
 275                    match tl with
 276                    | [ty;what;pred;p1;other;p2] -> ty, what, pred, p1, other, p2
 277                    | _ -> assert false
 278                  in
 279                  let pred,l,r =
 280                    match pred with
 281                    | Cic.Lambda (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;l;r])
 282                        when LibraryObjects.is_eq_URI uri ->
 283                          Cic.Lambda
 284                            (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;r;l]),l,r
 285                    | _ ->
 286                        prerr_endline (CicPp.ppterm pred);
 287                        assert false
 288                  in
 289                  let l = CicSubstitution.subst what l in
 290                  let r = CicSubstitution.subst what r in
 291                  Cic.Appl
 292                    [he;ty;what;pred;
 293                     canonical (mk_sym uri_sym ty l r p1);other;canonical p2]
 294              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
 295                  when LibraryObjects.is_eq_URI uri -> t
 296              | _ -> Cic.Appl (List.map canonical args))
 297       | Cic.Appl l -> Cic.Appl (List.map canonical l)
 298       | _ -> t
 299   in
 300   remove_refl (canonical t)
 301 ;;
 302
 303 let ty_of_lambda = function
 304   | Cic.Lambda (_,ty,_) -> ty
 305   | _ -> assert false
 306 ;;
 307
 308 let compose_contexts ctx1 ctx2 =
 309   ProofEngineReduction.replace_lifting
 310     ~equality:(=) ~what:[Cic.Implicit(Some `Hole)] ~with_what:[ctx2] ~where:ctx1
 311 ;;
 312
 313 let put_in_ctx ctx t =
 314   ProofEngineReduction.replace_lifting
 315     ~equality:(=) ~what:[Cic.Implicit (Some `Hole)] ~with_what:[t] ~where:ctx
 316 ;;
 317
 318 let mk_eq uri ty l r =
 319   Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r]
 320 ;;
 321
 322 let mk_refl uri ty t =
 323   Cic.Appl [Cic.MutConstruct(uri,0,1,[]);ty;t]
 324 ;;
 325
 326 let open_eq = function
 327   | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
 328       uri, ty, l ,r
 329   | _ -> assert false
 330 ;;
 331
 332 let contextualize uri ty left right t =
 333   let hole = Cic.Implicit (Some `Hole) in
 334   (* aux [uri] [ty] [left] [right] [ctx] [t]
 335    *
 336    * the parameters validate this invariant
 337    *   t: eq(uri) ty left right
 338    * that is used only by the base case
 339    *
 340    * ctx is a term with an hole. Cic.Implicit(Some `Hole) is the empty context
 341    * ty_ctx is the type of ctx_d
 342    *)
 343     let rec aux uri ty left right ctx_d ctx_ty = function
 344       | Cic.Appl ((Cic.Const(uri_sym,ens))::tl)
 345         when LibraryObjects.is_sym_eq_URI uri_sym  ->
 346           let ty,l,r,p = open_sym ens tl in
 347           mk_sym uri_sym ty l r (aux uri ty l r ctx_d ctx_ty p)
 348       | Cic.LetIn (name,body,rest) ->
 349           (* we should go in body *)
 350           Cic.LetIn (name,body,aux uri ty left right ctx_d ctx_ty rest)
 351       | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
 352         when LibraryObjects.is_eq_ind_URI uri_ind ||
 353              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 354           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 355           let ty2,eq,lp,rp = open_pred pred in
 356           let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
 357           let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 358           let is_not_fixed_lp = is_not_fixed lp in
 359           let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
 360           (* extract the context and the fixed term from the predicate *)
 361           let m, ctx_c, ty2 =
 362             let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
 363             (* they were under a lambda *)
 364             let m =  CicSubstitution.subst hole m in
 365             let ctx_c = CicSubstitution.subst hole ctx_c in
 366             let ty2 = CicSubstitution.subst hole ty2 in
 367             m, ctx_c, ty2
 368           in
 369           (* create the compound context and put the terms under it *)
 370           let ctx_dc = compose_contexts ctx_d ctx_c in
 371           let dc_what = put_in_ctx ctx_dc what in
 372           let dc_other = put_in_ctx ctx_dc other in
 373           (* m is already in ctx_c so it is put in ctx_d only *)
 374           let d_m = put_in_ctx ctx_d m in
 375           (* we also need what in ctx_c *)
 376           let c_what = put_in_ctx ctx_c what in
 377           (* now put the proofs in the compound context *)
 378           let p1 = (* p1: dc_what = d_m *)
 379             if is_not_fixed_lp then
 380               aux uri ty2 c_what m ctx_d ctx_ty p1
 381             else
 382               mk_sym uri_sym ctx_ty d_m dc_what
 383                 (aux uri ty2 m c_what ctx_d ctx_ty p1)
 384           in
 385           let p2 = (* p2: dc_other = dc_what *)
 386             if avoid_eq_ind then
 387               mk_sym uri_sym ctx_ty dc_what dc_other
 388                 (aux uri ty1 what other ctx_dc ctx_ty p2)
 389             else
 390               aux uri ty1 other what ctx_dc ctx_ty p2
 391           in
 392           (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
 393              if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
 394           let a,b,c,paeqb,pbeqc =
 395             if is_not_fixed_lp then
 396               dc_other,dc_what,d_m,p2,p1
 397             else
 398               d_m,dc_what,dc_other,
 399                 (mk_sym uri_sym ctx_ty dc_what d_m p1),
 400                 (mk_sym uri_sym ctx_ty dc_other dc_what p2)
 401           in
 402           mk_trans uri_trans ctx_ty a b c paeqb pbeqc
 403     | t when ctx_d = hole -> t
 404     | t ->
 405         let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 406         let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in
 407         let pred =
 408           (* ctx_d will go under a lambda, but put_in_ctx substitutes Rel 1 *)
 409           let r = CicSubstitution.lift 1 (put_in_ctx ctx_d left) in
 410           let l =
 411             let ctx_d = CicSubstitution.lift 1 ctx_d in
 412             put_in_ctx ctx_d (Cic.Rel 1)
 413           in
 414           let lty = CicSubstitution.lift 1 ctx_ty in
 415           Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r))
 416         in
 417         let d_left = put_in_ctx ctx_d left in
 418         let d_right = put_in_ctx ctx_d right in
 419         let refl_eq = mk_refl uri ctx_ty d_left in
 420         mk_sym uri_sym ctx_ty d_right d_left
 421           (mk_eq_ind uri_ind ty left pred refl_eq right t)
 422   in
 423   aux uri ty left right hole ty t
 424 ;;
 425
 426 let contextualize_rewrites t ty =
 427   let eq,ty,l,r = open_eq ty in
 428   contextualize eq ty l r t
 429 ;;
 430
 431 let add_subst subst =
 432   function
 433     | Exact t -> Exact (Subst.apply_subst subst t)
 434     | Step (s,(rule, id1, (pos,id2), pred)) ->
 435         Step (Subst.concat subst s,(rule, id1, (pos,id2), pred))
 436 ;;
 437
 438 let build_proof_step eq lift subst p1 p2 pos l r pred =
 439   let p1 = Subst.apply_subst_lift lift subst p1 in
 440   let p2 = Subst.apply_subst_lift lift subst p2 in
 441   let l  = CicSubstitution.lift lift l in
 442   let l = Subst.apply_subst_lift lift subst l in
 443   let r  = CicSubstitution.lift lift r in
 444   let r = Subst.apply_subst_lift lift subst r in
 445   let pred = CicSubstitution.lift lift pred in
 446   let pred = Subst.apply_subst_lift lift subst pred in
 447   let ty,body =
 448     match pred with
 449       | Cic.Lambda (_,ty,body) -> ty,body
 450       | _ -> assert false
 451   in
 452   let what, other =
 453     if pos = Utils.Left then l,r else r,l
 454   in
 455   let p =
 456     match pos with
 457       | Utils.Left ->
 458         mk_eq_ind (LibraryObjects.eq_ind_URI ~eq) ty what pred p1 other p2
 459       | Utils.Right ->
 460         mk_eq_ind (LibraryObjects.eq_ind_r_URI ~eq) ty what pred p1 other p2
 461   in
 462     p
 463 ;;
 464
 465 let parametrize_proof p l r ty =
 466   let parameters =
 467     CicUtil.metas_of_term p @ CicUtil.metas_of_term l @ CicUtil.metas_of_term r
 468   in (* ?if they are under a lambda? *)
 469   let parameters =
 470     HExtlib.list_uniq (List.sort Pervasives.compare parameters)
 471   in
 472   let what = List.map (fun (i,l) -> Cic.Meta (i,l)) parameters in
 473   let with_what, lift_no =
 474     List.fold_right (fun _ (acc,n) -> ((Cic.Rel n)::acc),n+1) what ([],1)
 475   in
 476   let p = CicSubstitution.lift (lift_no-1) p in
 477   let p =
 478     ProofEngineReduction.replace_lifting
 479     ~equality:(fun t1 t2 ->
 480       match t1,t2 with Cic.Meta (i,_),Cic.Meta(j,_) -> i=j | _ -> false)
 481     ~what ~with_what ~where:p
 482   in
 483   let ty_of_m _ = ty (*function
 484     | Cic.Meta (i,_) -> List.assoc i menv
 485     | _ -> assert false *)
 486   in
 487   let args, proof,_ =
 488     List.fold_left
 489       (fun (instance,p,n) m ->
 490         (instance@[m],
 491         Cic.Lambda
 492           (Cic.Name ("x"^string_of_int n),
 493           CicSubstitution.lift (lift_no - n - 1) (ty_of_m m),
 494           p),
 495         n+1))
 496       ([Cic.Rel 1],p,1)
 497       what
 498   in
 499   let instance = match args with | [x] -> x | _ -> Cic.Appl args in
 500   proof, instance
 501 ;;
 502
 503 let wfo goalproof proof id =
 504   let rec aux acc id =
 505     let p,_,_ = proof_of_id id in
 506     match p with
 507     | Exact _ -> if (List.mem id acc) then acc else id :: acc
 508     | Step (_,(_,id1, (_,id2), _)) ->
 509         let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
 510         let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
 511         id :: acc
 512   in
 513   let acc =
 514     match proof with
 515       | Exact _ -> [id]
 516       | Step (_,(_,id1, (_,id2), _)) -> aux (aux [id] id1) id2
 517   in
 518   List.fold_left (fun acc (_,_,id,_,_) -> aux acc id) acc goalproof
 519 ;;
 520
 521 let string_of_id names id =
 522   if id = 0 then "" else
 523   try
 524     let (_,p,(_,l,r,_),m,_) = open_equality (Hashtbl.find id_to_eq id) in
 525     match p with
 526     | Exact t ->
 527         Printf.sprintf "%d = %s: %s = %s [%s]" id
 528           (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
 529         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 530     | Step (_,(step,id1, (_,id2), _) ) ->
 531         Printf.sprintf "%6d: %s %6d %6d   %s = %s [%s]" id
 532           (string_of_rule step)
 533           id1 id2 (CicPp.pp l names) (CicPp.pp r names)
 534         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 535   with
 536       Not_found -> assert false
 537
 538 let pp_proof names goalproof proof subst id initial_goal =
 539   String.concat "\n" (List.map (string_of_id names) (wfo goalproof proof id)) ^
 540   "\ngoal:\n   " ^
 541     (String.concat "\n   "
 542       (fst (List.fold_right
 543         (fun (r,pos,i,s,pred) (acc,g) ->
 544           let _,_,left,right = open_eq g in
 545           let ty =
 546             match pos with
 547             | Utils.Left -> CicReduction.head_beta_reduce (Cic.Appl[pred;right])
 548             | Utils.Right -> CicReduction.head_beta_reduce (Cic.Appl[pred;left])
 549           in
 550           let ty = Subst.apply_subst s ty in
 551           ("("^ string_of_rule r ^ " " ^ string_of_int i^") -> "
 552           ^ CicPp.pp ty names) :: acc,ty) goalproof ([],initial_goal)))) ^
 553   "\nand then subsumed by " ^ string_of_int id ^ " when " ^ Subst.ppsubst subst
 554 ;;
 555
 556 module OT =
 557   struct
 558     type t = int
 559     let compare = Pervasives.compare
 560   end
 561
 562 module M = Map.Make(OT)
 563
 564 let rec find_deps m i =
 565   if M.mem i m then m
 566   else
 567     let p,_,_ = proof_of_id i in
 568     match p with
 569     | Exact _ -> M.add i [] m
 570     | Step (_,(_,id1,(_,id2),_)) ->
 571         let m = find_deps m id1 in
 572         let m = find_deps m id2 in
 573         (* without the uniq there is a stack overflow doing concatenation *)
 574         let xxx = [id1;id2] @ M.find id1 m @ M.find id2 m in
 575         let xxx = HExtlib.list_uniq (List.sort Pervasives.compare xxx) in
 576         M.add i xxx m
 577 ;;
 578
 579 let topological_sort l =
 580   (* build the partial order relation *)
 581   let m =
 582     List.fold_left (fun m i -> find_deps m i)
 583     M.empty l
 584   in
 585   let m = M.map (fun x -> Some x) m in
 586   (* utils *)
 587   let keys m = M.fold (fun i _ acc -> i::acc) m [] in
 588   let split l m = List.filter (fun i -> M.find i m = Some []) l in
 589   let purge l m =
 590     M.mapi
 591       (fun k v -> if List.mem k l then None else
 592          match v with
 593          | None -> None
 594          | Some ll -> Some (List.filter (fun i -> not (List.mem i l)) ll))
 595       m
 596   in
 597   let rec aux m res =
 598       let keys = keys m in
 599       let ok = split keys m in
 600       let m = purge ok m in
 601       let res = ok @ res in
 602       if ok = [] then res else aux m res
 603   in
 604   aux m []
 605 ;;
 606
 607
 608 (* returns the list of ids that should be factorized *)
 609 let get_duplicate_step_in_wfo l p =
 610   let ol = List.rev l in
 611   let h = Hashtbl.create 13 in
 612   (* NOTE: here the n parameter is an approximation of the dependency
 613      between equations. To do things seriously we should maintain a
 614      dependency graph. This approximation is not perfect. *)
 615   let add i =
 616     let p,_,_ = proof_of_id i in
 617     match p with
 618     | Exact _ -> true
 619     | _ ->
 620         try
 621           let no = Hashtbl.find h i in
 622           Hashtbl.replace h i (no+1);
 623           false
 624         with Not_found -> Hashtbl.add h i 1;true
 625   in
 626   let rec aux = function
 627     | Exact _ -> ()
 628     | Step (_,(_,i1,(_,i2),_)) ->
 629         let go_on_1 = add i1 in
 630         let go_on_2 = add i2 in
 631         if go_on_1 then aux (let p,_,_ = proof_of_id i1 in p);
 632         if go_on_2 then aux (let p,_,_ = proof_of_id i2 in p)
 633   in
 634   aux p;
 635   List.iter
 636     (fun (_,_,id,_,_) -> aux (let p,_,_ = proof_of_id id in p))
 637     ol;
 638   (* now h is complete *)
 639   let proofs = Hashtbl.fold (fun k count acc-> (k,count)::acc) h [] in
 640   let proofs = List.filter (fun (_,c) -> c > 1) proofs in
 641   let res = topological_sort (List.map (fun (i,_) -> i) proofs) in
 642   res
 643 ;;
 644
 645 let build_proof_term eq h lift proof =
 646   let proof_of_id aux id =
 647     let p,l,r = proof_of_id id in
 648     try List.assoc id h,l,r with Not_found -> aux p, l, r
 649   in
 650   let rec aux = function
 651      | Exact term -> CicSubstitution.lift lift term
 652      | Step (subst,(rule, id1, (pos,id2), pred)) ->
 653          let p1,_,_ = proof_of_id aux id1 in
 654          let p2,l,r = proof_of_id aux id2 in
 655          let varname =
 656            match rule with
 657            | SuperpositionRight -> Cic.Name ("SupR" ^ Utils.string_of_pos pos)
 658            | Demodulation -> Cic.Name ("DemEq"^ Utils.string_of_pos pos)
 659            | _ -> assert false
 660          in
 661          let pred =
 662            match pred with
 663            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 664            | _ -> assert false
 665          in
 666          let p =   build_proof_step eq lift subst p1 p2 pos l r pred in
 667 (*         let cond =  (not (List.mem 302 (Utils.metas_of_term p)) || id1 = 8 || id1 = 132) in
 668            if not cond then
 669              prerr_endline ("ERROR " ^ string_of_int id1 ^ " " ^ string_of_int id2);
 670            assert cond;*)
 671            p
 672   in
 673    aux proof
 674 ;;
 675
 676 let build_goal_proof eq l initial ty se =
 677   let se = List.map (fun i -> Cic.Meta (i,[])) se in
 678   let lets = get_duplicate_step_in_wfo l initial in
 679   let letsno = List.length lets in
 680   let _,mty,_,_ = open_eq ty in
 681   let lift_list l = List.map (fun (i,t) -> i,CicSubstitution.lift 1 t) l in
 682   let lets,_,h =
 683     List.fold_left
 684       (fun (acc,n,h) id ->
 685         let p,l,r = proof_of_id id in
 686         let cic = build_proof_term eq h n p in
 687         let real_cic,instance =
 688           parametrize_proof cic l r (CicSubstitution.lift n mty)
 689         in
 690         let h = (id, instance)::lift_list h in
 691         acc@[id,real_cic],n+1,h)
 692       ([],0,[]) lets
 693   in
 694   let proof,se =
 695     let rec aux se current_proof = function
 696       | [] -> current_proof,se
 697       | (rule,pos,id,subst,pred)::tl ->
 698           let p,l,r = proof_of_id id in
 699            let p = build_proof_term eq h letsno p in
 700            let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
 701          let varname =
 702            match rule with
 703            | SuperpositionLeft -> Cic.Name ("SupL" ^ Utils.string_of_pos pos)
 704            | Demodulation -> Cic.Name ("DemG"^ Utils.string_of_pos pos)
 705            | _ -> assert false
 706          in
 707          let pred =
 708            match pred with
 709            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 710            | _ -> assert false
 711          in
 712            let proof =
 713              build_proof_step eq letsno subst current_proof p pos l r pred
 714            in
 715            let proof,se = aux se proof tl in
 716            Subst.apply_subst_lift letsno subst proof,
 717            List.map (fun x -> Subst.apply_subst_lift letsno subst x) se
 718     in
 719     aux se (build_proof_term eq h letsno initial) l
 720   in
 721   let n,proof =
 722     let initial = proof in
 723     List.fold_right
 724       (fun (id,cic) (n,p) ->
 725         n-1,
 726         Cic.LetIn (
 727           Cic.Name ("H"^string_of_int id),
 728           cic, p))
 729     lets (letsno-1,initial)
 730   in
 731    canonical (contextualize_rewrites proof (CicSubstitution.lift letsno ty)),
 732    se
 733 ;;
 734
 735 let refl_proof eq_uri ty term =
 736   Cic.Appl [Cic.MutConstruct (eq_uri, 0, 1, []); ty; term]
 737 ;;
 738
 739 let metas_of_proof p =
 740   let eq =
 741     match LibraryObjects.eq_URI () with
 742     | Some u -> u
 743     | None ->
 744         raise
 745           (ProofEngineTypes.Fail
 746             (lazy "No default equality defined when calling metas_of_proof"))
 747   in
 748   let p = build_proof_term eq [] 0 p in
 749   Utils.metas_of_term p
 750 ;;
 751
 752 let remove_local_context eq =
 753    let w, p, (ty, left, right, o), menv,id = open_equality eq in
 754    let p = Utils.remove_local_context p in
 755    let ty = Utils.remove_local_context ty in
 756    let left = Utils.remove_local_context left in
 757    let right = Utils.remove_local_context right in
 758    w, p, (ty, left, right, o), menv, id
 759 ;;
 760
 761 let relocate newmeta menv to_be_relocated =
 762   let subst, newmetasenv, newmeta =
 763     List.fold_right
 764       (fun i (subst, metasenv, maxmeta) ->
 765         let _,context,ty = CicUtil.lookup_meta i menv in
 766         let irl = [] in
 767         let newmeta = Cic.Meta(maxmeta,irl) in
 768         let newsubst = Subst.buildsubst i context newmeta ty subst in
 769         newsubst, (maxmeta,context,ty)::metasenv, maxmeta+1)
 770       to_be_relocated (Subst.empty_subst, [], newmeta+1)
 771   in
 772   let menv = Subst.apply_subst_metasenv subst menv @ newmetasenv in
 773   subst, menv, newmeta
 774
 775 let fix_metas newmeta eq =
 776   let w, p, (ty, left, right, o), menv,_ = open_equality eq in
 777   let to_be_relocated =
 778 (* List.map (fun i ,_,_ -> i) menv *)
 779     HExtlib.list_uniq
 780       (List.sort Pervasives.compare
 781          (Utils.metas_of_term left @ Utils.metas_of_term right))
 782   in
 783   let subst, metasenv, newmeta = relocate newmeta menv to_be_relocated in
 784   let ty = Subst.apply_subst subst ty in
 785   let left = Subst.apply_subst subst left in
 786   let right = Subst.apply_subst subst right in
 787   let fix_proof = function
 788     | Exact p -> Exact (Subst.apply_subst subst p)
 789     | Step (s,(r,id1,(pos,id2),pred)) ->
 790         Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
 791   in
 792   let p = fix_proof p in
 793   let eq' = mk_equality (w, p, (ty, left, right, o), metasenv) in
 794   newmeta+1, eq'
 795
 796 exception NotMetaConvertible;;
 797
 798 let meta_convertibility_aux table t1 t2 =
 799   let module C = Cic in
 800   let rec aux ((table_l, table_r) as table) t1 t2 =
 801     match t1, t2 with
 802     | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
 803         let tl1, tl2 = [],[] in
 804         let m1_binding, table_l =
 805           try List.assoc m1 table_l, table_l
 806           with Not_found -> m2, (m1, m2)::table_l
 807         and m2_binding, table_r =
 808           try List.assoc m2 table_r, table_r
 809           with Not_found -> m1, (m2, m1)::table_r
 810         in
 811         if (m1_binding <> m2) || (m2_binding <> m1) then
 812           raise NotMetaConvertible
 813         else (
 814           try
 815             List.fold_left2
 816               (fun res t1 t2 ->
 817                  match t1, t2 with
 818                  | None, Some _ | Some _, None -> raise NotMetaConvertible
 819                  | None, None -> res
 820                  | Some t1, Some t2 -> (aux res t1 t2))
 821               (table_l, table_r) tl1 tl2
 822           with Invalid_argument _ ->
 823             raise NotMetaConvertible
 824         )
 825     | C.Var (u1, ens1), C.Var (u2, ens2)
 826     | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
 827         aux_ens table ens1 ens2
 828     | C.Cast (s1, t1), C.Cast (s2, t2)
 829     | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
 830     | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
 831     | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
 832         let table = aux table s1 s2 in
 833         aux table t1 t2
 834     | C.Appl l1, C.Appl l2 -> (
 835         try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 836         with Invalid_argument _ -> raise NotMetaConvertible
 837       )
 838     | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
 839         when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
 840     | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
 841         when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
 842         aux_ens table ens1 ens2
 843     | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
 844         when (UriManager.eq u1 u2) && i1 = i2 ->
 845         let table = aux table s1 s2 in
 846         let table = aux table t1 t2 in (
 847           try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 848           with Invalid_argument _ -> raise NotMetaConvertible
 849         )
 850     | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
 851         try
 852           List.fold_left2
 853             (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
 854                if i1 <> i2 then raise NotMetaConvertible
 855                else
 856                  let res = (aux res s1 s2) in aux res t1 t2)
 857             table il1 il2
 858         with Invalid_argument _ -> raise NotMetaConvertible
 859       )
 860     | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
 861         try
 862           List.fold_left2
 863             (fun res (n1, s1, t1) (n2, s2, t2) ->
 864                let res = aux res s1 s2 in aux res t1 t2)
 865             table il1 il2
 866         with Invalid_argument _ -> raise NotMetaConvertible
 867       )
 868     | t1, t2 when t1 = t2 -> table
 869     | _, _ -> raise NotMetaConvertible
 870
 871   and aux_ens table ens1 ens2 =
 872     let cmp (u1, t1) (u2, t2) =
 873       Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
 874     in
 875     let ens1 = List.sort cmp ens1
 876     and ens2 = List.sort cmp ens2 in
 877     try
 878       List.fold_left2
 879         (fun res (u1, t1) (u2, t2) ->
 880            if not (UriManager.eq u1 u2) then raise NotMetaConvertible
 881            else aux res t1 t2)
 882         table ens1 ens2
 883     with Invalid_argument _ -> raise NotMetaConvertible
 884   in
 885   aux table t1 t2
 886 ;;
 887
 888
 889 let meta_convertibility_eq eq1 eq2 =
 890   let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
 891   let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
 892   if ty <> ty' then
 893     false
 894   else if (left = left') && (right = right') then
 895     true
 896   else if (left = right') && (right = left') then
 897     true
 898   else
 899     try
 900       let table = meta_convertibility_aux ([], []) left left' in
 901       let _ = meta_convertibility_aux table right right' in
 902       true
 903     with NotMetaConvertible ->
 904       try
 905         let table = meta_convertibility_aux ([], []) left right' in
 906         let _ = meta_convertibility_aux table right left' in
 907         true
 908       with NotMetaConvertible ->
 909         false
 910 ;;
 911
 912
 913 let meta_convertibility t1 t2 =
 914   if t1 = t2 then
 915     true
 916   else
 917     try
 918       ignore(meta_convertibility_aux ([], []) t1 t2);
 919       true
 920     with NotMetaConvertible ->
 921       false
 922 ;;
 923
 924 exception TermIsNotAnEquality;;
 925
 926 let term_is_equality term =
 927   match term with
 928   | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _]
 929     when LibraryObjects.is_eq_URI uri -> true
 930   | _ -> false
 931 ;;
 932
 933 let equality_of_term proof term =
 934   match term with
 935   | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2]
 936     when LibraryObjects.is_eq_URI uri ->
 937       let o = !Utils.compare_terms t1 t2 in
 938       let stat = (ty,t1,t2,o) in
 939       let w = Utils.compute_equality_weight stat in
 940       let e = mk_equality (w, Exact proof, stat,[]) in
 941       e
 942   | _ ->
 943       raise TermIsNotAnEquality
 944 ;;
 945
 946 let is_weak_identity eq =
 947   let _,_,(_,left, right,_),_,_ = open_equality eq in
 948   left = right || meta_convertibility left right
 949 ;;
 950
 951 let is_identity (_, context, ugraph) eq =
 952   let _,_,(ty,left,right,_),menv,_ = open_equality eq in
 953   left = right ||
 954   (* (meta_convertibility left right)) *)
 955   fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
 956 ;;
 957
 958
 959 let term_of_equality eq_uri equality =
 960   let _, _, (ty, left, right, _), menv, _= open_equality equality in
 961   let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
 962   let argsno = List.length menv in
 963   let t =
 964     CicSubstitution.lift argsno
 965       (Cic.Appl [Cic.MutInd (eq_uri, 0, []); ty; left; right])
 966   in
 967   snd (
 968     List.fold_right
 969       (fun (i,_,ty) (n, t) ->
 970          let name = Cic.Name ("X" ^ (string_of_int n)) in
 971          let ty = CicSubstitution.lift (n-1) ty in
 972          let t =
 973            ProofEngineReduction.replace
 974              ~equality:eq ~what:[i]
 975              ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
 976          in
 977            (n-1, Cic.Prod (name, ty, t)))
 978       menv (argsno, t))
 979 ;;
 980
 981 let symmetric eq_ty l id uri m =
 982   let eq = Cic.MutInd(uri,0,[]) in
 983   let pred =
 984     Cic.Lambda (Cic.Name "Sym",eq_ty,
 985      Cic.Appl [CicSubstitution.lift 1 eq ;
 986                CicSubstitution.lift 1 eq_ty;
 987                Cic.Rel 1;CicSubstitution.lift 1 l])
 988   in
 989   let prefl =
 990     Exact (Cic.Appl
 991       [Cic.MutConstruct(uri,0,1,[]);eq_ty;l])
 992   in
 993   let id1 =
 994     let eq = mk_equality (0,prefl,(eq_ty,l,l,Utils.Eq),m) in
 995     let (_,_,_,_,id) = open_equality eq in
 996     id
 997   in
 998   Step(Subst.empty_subst,
 999     (Demodulation,id1,(Utils.Left,id),pred))
1000 ;;
1001
1002 module IntOT = struct
1003   type t = int
1004   let compare = Pervasives.compare
1005 end
1006
1007 module IntSet = Set.Make(IntOT);;
1008
1009 let n_purged = ref 0;;
1010
1011 let collect alive1 alive2 alive3 =
1012   let _ = <:start<collect>> in
1013   let deps_of id =
1014     let p,_,_ = proof_of_id id in
1015     match p with
1016     | Exact _ -> IntSet.empty
1017     | Step (_,(_,id1,(_,id2),_)) ->
1018           IntSet.add id1 (IntSet.add id2 IntSet.empty)
1019   in
1020   let rec close s =
1021     let news = IntSet.fold (fun id s -> IntSet.union (deps_of id) s) s s in
1022     if IntSet.equal news s then s else close news
1023   in
1024   let l_to_s s l = List.fold_left (fun s x -> IntSet.add x s) s l in
1025   let alive_set = l_to_s (l_to_s (l_to_s IntSet.empty alive2) alive1) alive3 in
1026   let closed_alive_set = close alive_set in
1027   let to_purge =
1028     Hashtbl.fold
1029       (fun k _ s ->
1030         if not (IntSet.mem k closed_alive_set) then
1031           k::s else s) id_to_eq []
1032   in
1033   n_purged := !n_purged + List.length to_purge;
1034   List.iter (Hashtbl.remove id_to_eq) to_purge;
1035   let _ = <:stop<collect>> in ()
1036 ;;
1037
1038 let id_of e =
1039   let _,_,_,_,id = open_equality e in id
1040 ;;
1041
1042 let get_stats () =
1043   <:show<Equality.>> ^
1044   "# of purged eq by the collector: " ^ string_of_int !n_purged ^ "\n"
1045 ;;