components/tactics/primitiveTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open ProofEngineTypes
  29
  30 exception TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
  31 exception NotAnInductiveTypeToEliminate
  32 exception WrongUriToVariable of string
  33
  34 (* lambda_abstract newmeta ty *)
  35 (* returns a triple [bo],[context],[ty'] where              *)
  36 (* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
  37 (* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
  38 (* So, lambda_abstract is the core of the implementation of *)
  39 (* the Intros tactic.                                       *)
  40 (* howmany = -1 means Intros, howmany > 0 means Intros n    *)
  41 let lambda_abstract ?(howmany=(-1)) metasenv context newmeta ty mk_fresh_name =
  42  let module C = Cic in
  43   let rec collect_context context howmany ty =
  44    match howmany with
  45    | 0 ->
  46         let irl =
  47           CicMkImplicit.identity_relocation_list_for_metavariable context
  48         in
  49          context, ty, (C.Meta (newmeta,irl))
  50    | _ ->
  51       match ty with
  52         C.Cast (te,_)   -> collect_context context howmany te
  53       | C.Prod (n,s,t)  ->
  54          let n' = mk_fresh_name metasenv context n ~typ:s in
  55           let (context',ty,bo) =
  56            collect_context ((Some (n',(C.Decl s)))::context) (howmany - 1) t
  57           in
  58            (context',ty,C.Lambda(n',s,bo))
  59       | C.LetIn (n,s,t) ->
  60          let (context',ty,bo) =
  61           collect_context ((Some (n,(C.Def (s,None))))::context) (howmany - 1) t
  62          in
  63           (context',ty,C.LetIn(n,s,bo))
  64       | _ as t ->
  65         if howmany <= 0 then
  66          let irl =
  67           CicMkImplicit.identity_relocation_list_for_metavariable context
  68          in
  69           context, t, (C.Meta (newmeta,irl))
  70         else
  71          raise (Fail (lazy "intro(s): not enough products or let-ins"))
  72   in
  73    collect_context context howmany ty
  74
  75 let eta_expand metasenv context t arg =
  76  let module T = CicTypeChecker in
  77  let module S = CicSubstitution in
  78  let module C = Cic in
  79   let rec aux n =
  80    function
  81       t' when t' = S.lift n arg -> C.Rel (1 + n)
  82     | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
  83     | C.Var (uri,exp_named_subst) ->
  84        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  85         C.Var (uri,exp_named_subst')
  86     | C.Meta (i,l) ->
  87        let l' =
  88         List.map (function None -> None | Some t -> Some (aux n t)) l
  89        in
  90         C.Meta (i, l')
  91     | C.Sort _
  92     | C.Implicit _ as t -> t
  93     | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
  94     | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
  95     | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
  96     | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
  97     | C.Appl l -> C.Appl (List.map (aux n) l)
  98     | C.Const (uri,exp_named_subst) ->
  99        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 100         C.Const (uri,exp_named_subst')
 101     | C.MutInd (uri,i,exp_named_subst) ->
 102        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 103         C.MutInd (uri,i,exp_named_subst')
 104     | C.MutConstruct (uri,i,j,exp_named_subst) ->
 105        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 106         C.MutConstruct (uri,i,j,exp_named_subst')
 107     | C.MutCase (sp,i,outt,t,pl) ->
 108        C.MutCase (sp,i,aux n outt, aux n t,
 109         List.map (aux n) pl)
 110     | C.Fix (i,fl) ->
 111        let tylen = List.length fl in
 112         let substitutedfl =
 113          List.map
 114           (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
 115            fl
 116         in
 117          C.Fix (i, substitutedfl)
 118     | C.CoFix (i,fl) ->
 119        let tylen = List.length fl in
 120         let substitutedfl =
 121          List.map
 122           (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 123            fl
 124         in
 125          C.CoFix (i, substitutedfl)
 126   and aux_exp_named_subst n =
 127    List.map (function uri,t -> uri,aux n t)
 128   in
 129    let argty,_ =
 130     T.type_of_aux' metasenv context arg CicUniv.empty_ugraph (* TASSI: FIXME *)
 131    in
 132     let fresh_name =
 133      FreshNamesGenerator.mk_fresh_name ~subst:[]
 134       metasenv context (Cic.Name "Heta") ~typ:argty
 135     in
 136      (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])
 137
 138 (*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
 139 let classify_metas newmeta in_subst_domain subst_in metasenv =
 140  List.fold_right
 141   (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
 142     if in_subst_domain i then
 143      old_uninst,new_uninst
 144     else
 145      let ty' = subst_in canonical_context ty in
 146       let canonical_context' =
 147        List.fold_right
 148         (fun entry canonical_context' ->
 149           let entry' =
 150            match entry with
 151               Some (n,Cic.Decl s) ->
 152                Some (n,Cic.Decl (subst_in canonical_context' s))
 153             | Some (n,Cic.Def (s,None)) ->
 154                Some (n,Cic.Def ((subst_in canonical_context' s),None))
 155             | None -> None
 156             | Some (n,Cic.Def (bo,Some ty)) ->
 157                Some
 158                 (n,
 159                   Cic.Def
 160                    (subst_in canonical_context' bo,
 161                     Some (subst_in canonical_context' ty)))
 162           in
 163            entry'::canonical_context'
 164         ) canonical_context []
 165      in
 166       if i < newmeta then
 167        ((i,canonical_context',ty')::old_uninst),new_uninst
 168       else
 169        old_uninst,((i,canonical_context',ty')::new_uninst)
 170   ) metasenv ([],[])
 171
 172 (* Useful only inside apply_tac *)
 173 let
 174  generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
 175 =
 176  let module C = Cic in
 177   let params =
 178     let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 179     CicUtil.params_of_obj o
 180   in
 181    let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
 182     let next_fresh_meta = ref newmeta in
 183     let newmetasenvfragment = ref [] in
 184     let exp_named_subst_diff = ref [] in
 185      let rec aux =
 186       function
 187          [],[] -> []
 188        | uri::tl,[] ->
 189           let ty =
 190             let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 191               match o with
 192                   C.Variable (_,_,ty,_,_) ->
 193                     CicSubstitution.subst_vars !exp_named_subst_diff ty
 194                 | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 195           in
 196 (* CSC: patch to generate ?1 : ?2 : Type in place of ?1 : Type to simulate ?1 :< Type
 197            (match ty with
 198                C.Sort (C.Type _) as s -> (* TASSI: ?? *)
 199                  let fresh_meta = !next_fresh_meta in
 200                  let fresh_meta' = fresh_meta + 1 in
 201                   next_fresh_meta := !next_fresh_meta + 2 ;
 202                   let subst_item = uri,C.Meta (fresh_meta',[]) in
 203                    newmetasenvfragment :=
 204                     (fresh_meta,[],C.Sort (C.Type (CicUniv.fresh()))) ::
 205                      (* TASSI: ?? *)
 206                      (fresh_meta',[],C.Meta (fresh_meta,[])) :: !newmetasenvfragment ;
 207                    exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 208                    subst_item::(aux (tl,[]))
 209              | _ ->
 210 *)
 211               let irl =
 212                 CicMkImplicit.identity_relocation_list_for_metavariable context
 213               in
 214               let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
 215                newmetasenvfragment :=
 216                 (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
 217                exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 218                incr next_fresh_meta ;
 219                subst_item::(aux (tl,[]))(*)*)
 220        | uri::tl1,((uri',_) as s)::tl2 ->
 221           assert (UriManager.eq uri uri') ;
 222           s::(aux (tl1,tl2))
 223        | [],_ -> assert false
 224      in
 225       let exp_named_subst' = aux (params,exp_named_subst) in
 226        !exp_named_subst_diff,!next_fresh_meta,
 227         List.rev !newmetasenvfragment, exp_named_subst'
 228    in
 229     new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
 230 ;;
 231
 232 let new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty termty goal_arity =
 233   let (consthead,newmetasenv,arguments,_) =
 234    TermUtil.saturate_term newmeta' metasenv' context termty
 235     goal_arity in
 236   let subst,newmetasenv',_ =
 237    CicUnification.fo_unif newmetasenv context consthead ty CicUniv.empty_ugraph
 238   in
 239   let t =
 240     if List.length arguments = 0 then term' else Cic.Appl (term'::arguments)
 241   in
 242   subst,newmetasenv',t
 243
 244 let rec count_prods context ty =
 245  match CicReduction.whd context ty with
 246     Cic.Prod (n,s,t) -> 1 + count_prods (Some (n,Cic.Decl s)::context) t
 247   | _ -> 0
 248
 249 let apply_with_subst ~term ~subst ~maxmeta (proof, goal) =
 250   (* Assumption: The term "term" must be closed in the current context *)
 251  let module T = CicTypeChecker in
 252  let module R = CicReduction in
 253  let module C = Cic in
 254   let (_,metasenv,_,_, _) = proof in
 255   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 256   let newmeta = max (CicMkImplicit.new_meta metasenv subst) maxmeta in
 257    let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
 258     match term with
 259        C.Var (uri,exp_named_subst) ->
 260         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 261          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 262           exp_named_subst
 263         in
 264          exp_named_subst_diff,newmeta',newmetasenvfragment,
 265           C.Var (uri,exp_named_subst')
 266      | C.Const (uri,exp_named_subst) ->
 267         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 268          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 269           exp_named_subst
 270         in
 271          exp_named_subst_diff,newmeta',newmetasenvfragment,
 272           C.Const (uri,exp_named_subst')
 273      | C.MutInd (uri,tyno,exp_named_subst) ->
 274         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 275          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 276           exp_named_subst
 277         in
 278          exp_named_subst_diff,newmeta',newmetasenvfragment,
 279           C.MutInd (uri,tyno,exp_named_subst')
 280      | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 281         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 282          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 283           exp_named_subst
 284         in
 285          exp_named_subst_diff,newmeta',newmetasenvfragment,
 286           C.MutConstruct (uri,tyno,consno,exp_named_subst')
 287      | _ -> [],newmeta,[],term
 288    in
 289    let metasenv' = metasenv@newmetasenvfragment in
 290    let termty,_ =
 291      CicTypeChecker.type_of_aux' metasenv' context term' CicUniv.empty_ugraph
 292    in
 293    let termty =
 294      CicSubstitution.subst_vars exp_named_subst_diff termty in
 295    let goal_arity = count_prods context ty in
 296    let subst,newmetasenv',t =
 297     let rec add_one_argument n =
 298      try
 299       new_metasenv_and_unify_and_t newmeta' metasenv' context term' ty
 300         termty n
 301      with CicUnification.UnificationFailure _ when n > 0 ->
 302       add_one_argument (n - 1)
 303     in
 304      add_one_argument goal_arity
 305    in
 306    let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
 307    let apply_subst = CicMetaSubst.apply_subst subst in
 308    let old_uninstantiatedmetas,new_uninstantiatedmetas =
 309      (* subst_in doesn't need the context. Hence the underscore. *)
 310      let subst_in _ = CicMetaSubst.apply_subst subst in
 311      classify_metas newmeta in_subst_domain subst_in newmetasenv'
 312    in
 313    let bo' = apply_subst t in
 314    let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
 315    let subst_in =
 316      (* if we just apply the subtitution, the type is irrelevant:
 317               we may use Implicit, since it will be dropped *)
 318      CicMetaSubst.apply_subst ((metano,(context,bo',Cic.Implicit None))::subst)
 319    in
 320    let (newproof, newmetasenv''') =
 321     ProofEngineHelpers.subst_meta_and_metasenv_in_proof proof metano subst_in
 322      newmetasenv''
 323    in
 324    let subst = ((metano,(context,bo',Cic.Implicit None))::subst) in
 325    subst,
 326    (newproof, List.map (function (i,_,_) -> i) new_uninstantiatedmetas),
 327    max maxmeta (CicMkImplicit.new_meta newmetasenv''' subst)
 328
 329
 330 (* ALB *)
 331 let apply_with_subst ~term ?(subst=[]) ?(maxmeta=0) status =
 332   try
 333 (*     apply_tac_verbose ~term status *)
 334     apply_with_subst ~term ~subst ~maxmeta status
 335       (* TODO cacciare anche altre eccezioni? *)
 336   with
 337   | CicUnification.UnificationFailure msg
 338   | CicTypeChecker.TypeCheckerFailure msg -> raise (Fail msg)
 339
 340 (* ALB *)
 341 let apply_tac_verbose ~term status =
 342   let subst, status, _ = apply_with_subst ~term status in
 343   (CicMetaSubst.apply_subst subst), status
 344
 345 let apply_tac ~term status = snd (apply_tac_verbose ~term status)
 346
 347   (* TODO per implementare i tatticali e' necessario che tutte le tattiche
 348   sollevino _solamente_ Fail *)
 349 let apply_tac ~term =
 350  let apply_tac ~term status =
 351   try
 352     apply_tac ~term status
 353       (* TODO cacciare anche altre eccezioni? *)
 354   with
 355   | CicUnification.UnificationFailure msg
 356   | CicTypeChecker.TypeCheckerFailure msg ->
 357       raise (Fail msg)
 358  in
 359   mk_tactic (apply_tac ~term)
 360
 361 let intros_tac ?howmany ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) ()=
 362  let intros_tac
 363   ?(mk_fresh_name_callback = (FreshNamesGenerator.mk_fresh_name ~subst:[])) ()
 364   (proof, goal)
 365  =
 366   let module C = Cic in
 367   let module R = CicReduction in
 368    let (_,metasenv,_,_, _) = proof in
 369    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 370     let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 371      let (context',ty',bo') =
 372       lambda_abstract ?howmany metasenv context newmeta ty mk_fresh_name_callback
 373      in
 374       let (newproof, _) =
 375        ProofEngineHelpers.subst_meta_in_proof proof metano bo'
 376         [newmeta,context',ty']
 377       in
 378        (newproof, [newmeta])
 379  in
 380   mk_tactic (intros_tac ~mk_fresh_name_callback ())
 381
 382 let cut_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 383  let cut_tac
 384   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 385   term (proof, goal)
 386  =
 387   let module C = Cic in
 388    let curi,metasenv,pbo,pty, attrs = proof in
 389    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 390     let newmeta1 = ProofEngineHelpers.new_meta_of_proof ~proof in
 391     let newmeta2 = newmeta1 + 1 in
 392     let fresh_name =
 393      mk_fresh_name_callback metasenv context (Cic.Name "Hcut") ~typ:term in
 394     let context_for_newmeta1 =
 395      (Some (fresh_name,C.Decl term))::context in
 396     let irl1 =
 397      CicMkImplicit.identity_relocation_list_for_metavariable
 398       context_for_newmeta1
 399     in
 400     let irl2 =
 401       CicMkImplicit.identity_relocation_list_for_metavariable context
 402     in
 403      let newmeta1ty = CicSubstitution.lift 1 ty in
 404      let bo' =
 405       C.Appl
 406        [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
 407         C.Meta (newmeta2,irl2)]
 408      in
 409       let (newproof, _) =
 410        ProofEngineHelpers.subst_meta_in_proof proof metano bo'
 411         [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
 412       in
 413        (newproof, [newmeta1 ; newmeta2])
 414  in
 415   mk_tactic (cut_tac ~mk_fresh_name_callback term)
 416
 417 let letin_tac ?(mk_fresh_name_callback=FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 418  let letin_tac
 419   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 420   term (proof, goal)
 421  =
 422   let module C = Cic in
 423    let curi,metasenv,pbo,pty, attrs = proof in
 424    (* occur check *)
 425    let occur i t =
 426      let m = CicUtil.metas_of_term t in
 427      List.exists (fun (j,_) -> i=j) m
 428    in
 429    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 430    if occur metano term then
 431      raise
 432        (ProofEngineTypes.Fail (lazy
 433          "You can't letin a term containing the current goal"));
 434     let _,_ =
 435       CicTypeChecker.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 436      let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 437      let fresh_name =
 438       mk_fresh_name_callback metasenv context (Cic.Name "Hletin") ~typ:term in
 439      let context_for_newmeta =
 440       (Some (fresh_name,C.Def (term,None)))::context in
 441      let irl =
 442       CicMkImplicit.identity_relocation_list_for_metavariable
 443        context_for_newmeta
 444      in
 445       let newmetaty = CicSubstitution.lift 1 ty in
 446       let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
 447        let (newproof, _) =
 448          ProofEngineHelpers.subst_meta_in_proof
 449            proof metano bo'[newmeta,context_for_newmeta,newmetaty]
 450        in
 451         (newproof, [newmeta])
 452  in
 453   mk_tactic (letin_tac ~mk_fresh_name_callback term)
 454
 455   (** functional part of the "exact" tactic *)
 456 let exact_tac ~term =
 457  let exact_tac ~term (proof, goal) =
 458   (* Assumption: the term bo must be closed in the current context *)
 459   let (_,metasenv,_,_, _) = proof in
 460   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 461   let module T = CicTypeChecker in
 462   let module R = CicReduction in
 463   let ty_term,u = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 464   let b,_ = R.are_convertible context ty_term ty u in (* TASSI: FIXME *)
 465   if b then
 466    begin
 467     let (newproof, metasenv') =
 468       ProofEngineHelpers.subst_meta_in_proof proof metano term [] in
 469     (newproof, [])
 470    end
 471   else
 472    raise (Fail (lazy "The type of the provided term is not the one expected."))
 473  in
 474   mk_tactic (exact_tac ~term)
 475
 476 (* not really "primitive" tactics .... *)
 477 let elim_tac ~term =
 478  let elim_tac ~term (proof, goal) =
 479   let module T = CicTypeChecker in
 480   let module U = UriManager in
 481   let module R = CicReduction in
 482   let module C = Cic in
 483    let (curi,metasenv,proofbo,proofty, attrs) = proof in
 484    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 485     let termty,_ = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 486     let termty = CicReduction.whd context termty in
 487     let (termty,metasenv',arguments,fresh_meta) =
 488      TermUtil.saturate_term
 489       (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
 490     let term = if arguments = [] then term else Cic.Appl (term::arguments) in
 491     let uri,exp_named_subst,typeno,args =
 492      match termty with
 493         C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 494       | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 495           (uri,exp_named_subst,typeno,args)
 496       | _ -> raise NotAnInductiveTypeToEliminate
 497     in
 498      let eliminator_uri =
 499       let buri = U.buri_of_uri uri in
 500       let name =
 501         let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 502        match o with
 503           C.InductiveDefinition (tys,_,_,_) ->
 504            let (name,_,_,_) = List.nth tys typeno in
 505             name
 506         | _ -> assert false
 507       in
 508       let ty_ty,_ = T.type_of_aux' metasenv' context ty CicUniv.empty_ugraph in
 509       let ext =
 510        match ty_ty with
 511           C.Sort C.Prop -> "_ind"
 512         | C.Sort C.Set  -> "_rec"
 513         | C.Sort C.CProp -> "_rec"
 514         | C.Sort (C.Type _)-> "_rect"
 515         | C.Meta (_,_) -> raise TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
 516         | _ -> assert false
 517       in
 518        U.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
 519      in
 520       let eliminator_ref = C.Const (eliminator_uri,exp_named_subst) in
 521        let ety,_ =
 522          T.type_of_aux' metasenv' context eliminator_ref CicUniv.empty_ugraph in
 523         let rec find_args_no =
 524          function
 525             C.Prod (_,_,t) -> 1 + find_args_no t
 526           | C.Cast (s,_) -> find_args_no s
 527           | C.LetIn (_,_,t) -> 0 + find_args_no t
 528           | _ -> 0
 529         in
 530          let args_no = find_args_no ety in
 531          let term_to_refine =
 532           let rec make_tl base_case =
 533            function
 534               0 -> [base_case]
 535             | n -> (C.Implicit None)::(make_tl base_case (n - 1))
 536           in
 537            C.Appl (eliminator_ref :: make_tl term (args_no - 1))
 538          in
 539           let refined_term,_,metasenv'',_ =
 540            CicRefine.type_of_aux' metasenv' context term_to_refine
 541              CicUniv.empty_ugraph
 542           in
 543            let new_goals =
 544             ProofEngineHelpers.compare_metasenvs
 545              ~oldmetasenv:metasenv ~newmetasenv:metasenv''
 546            in
 547            let proof' = curi,metasenv'',proofbo,proofty, attrs in
 548             let proof'', new_goals' =
 549              apply_tactic (apply_tac ~term:refined_term) (proof',goal)
 550             in
 551              (* The apply_tactic can have closed some of the new_goals *)
 552              let patched_new_goals =
 553               let (_,metasenv''',_,_, _) = proof'' in
 554                List.filter
 555                 (function i -> List.exists (function (j,_,_) -> j=i) metasenv'''
 556                 ) new_goals @ new_goals'
 557              in
 558               proof'', patched_new_goals
 559  in
 560   mk_tactic (elim_tac ~term)
 561 ;;
 562
 563 let cases_intros_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 564  let cases_tac ~term (proof, goal) =
 565   let module T = CicTypeChecker in
 566   let module U = UriManager in
 567   let module R = CicReduction in
 568   let module C = Cic in
 569    let (curi,metasenv,proofbo,proofty, attrs) = proof in
 570    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 571     let termty,_ = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 572     let termty = CicReduction.whd context termty in
 573     let (termty,metasenv',arguments,fresh_meta) =
 574      TermUtil.saturate_term
 575       (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
 576     let term = if arguments = [] then term else Cic.Appl (term::arguments) in
 577     let uri,exp_named_subst,typeno,args =
 578      match termty with
 579         C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 580       | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 581           (uri,exp_named_subst,typeno,args)
 582       | _ -> raise NotAnInductiveTypeToEliminate
 583     in
 584      let paramsno,itty,patterns =
 585       match CicEnvironment.get_obj CicUniv.empty_ugraph uri with
 586          C.InductiveDefinition (tys,_,paramsno,_),_ ->
 587           let _,_,itty,cl = List.nth tys typeno in
 588           let rec aux n context t =
 589            match n,CicReduction.whd context t with
 590               0,C.Prod (name,source,target) ->
 591                let fresh_name =
 592                 mk_fresh_name_callback metasenv' context name
 593                  (*CSC: WRONG TYPE HERE: I can get a "bad" name*)
 594                  ~typ:source
 595                in
 596                 C.Lambda (fresh_name,C.Implicit None,
 597                  aux 0 (Some (fresh_name,C.Decl source)::context) target)
 598             | n,C.Prod (name,source,target) ->
 599                let fresh_name =
 600                 mk_fresh_name_callback metasenv' context name
 601                  (*CSC: WRONG TYPE HERE: I can get a "bad" name*)
 602                  ~typ:source
 603                in
 604                 aux (n-1) (Some (fresh_name,C.Decl source)::context) target
 605             | 0,_ -> C.Implicit None
 606             | _,_ -> assert false
 607           in
 608            paramsno,itty,
 609            List.map (function (_,cty) -> aux paramsno context cty) cl
 610        | _ -> assert false
 611      in
 612       let outtype =
 613        let target =
 614         C.Lambda (C.Name "fixme",C.Implicit None,
 615          ProofEngineReduction.replace_lifting
 616           ~equality:(ProofEngineReduction.alpha_equivalence)
 617           ~what:[CicSubstitution.lift (paramsno+1) term]
 618           ~with_what:[C.Rel (paramsno+1)]
 619           ~where:(CicSubstitution.lift (paramsno+1) ty))
 620        in
 621         let rec add_lambdas =
 622          function
 623             0 -> target
 624           | n -> C.Lambda (C.Name "fixme",C.Implicit None,add_lambdas (n-1))
 625         in
 626          add_lambdas (count_prods context itty - paramsno)
 627       in
 628        let term_to_refine =
 629         C.MutCase (uri,typeno,outtype,term,patterns)
 630        in
 631         let refined_term,_,metasenv'',_ =
 632          CicRefine.type_of_aux' metasenv' context term_to_refine
 633            CicUniv.empty_ugraph
 634         in
 635          let new_goals =
 636           ProofEngineHelpers.compare_metasenvs
 637            ~oldmetasenv:metasenv ~newmetasenv:metasenv''
 638          in
 639          let proof' = curi,metasenv'',proofbo,proofty, attrs in
 640           let proof'', new_goals' =
 641            apply_tactic (apply_tac ~term:refined_term) (proof',goal)
 642           in
 643            (* The apply_tactic can have closed some of the new_goals *)
 644            let patched_new_goals =
 645             let (_,metasenv''',_,_,_) = proof'' in
 646              List.filter
 647               (function i -> List.exists (function (j,_,_) -> j=i) metasenv'''
 648               ) new_goals @ new_goals'
 649            in
 650             proof'', patched_new_goals
 651  in
 652   mk_tactic (cases_tac ~term)
 653 ;;
 654
 655
 656 let elim_intros_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 657                     ?depth ?using what =
 658  Tacticals.then_ ~start:(elim_tac ~term:what)
 659   ~continuation:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 660 ;;
 661
 662 (* The simplification is performed only on the conclusion *)
 663 let elim_intros_simpl_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 664                           ?depth ?using what =
 665  Tacticals.then_ ~start:(elim_tac ~term:what)
 666   ~continuation:
 667    (Tacticals.thens
 668      ~start:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 669      ~continuations:
 670        [ReductionTactics.simpl_tac
 671          ~pattern:(ProofEngineTypes.conclusion_pattern None)])
 672 ;;
 673
 674 (* FG: insetrts a "hole" in the context (derived from letin_tac) *)
 675
 676 module C = Cic
 677
 678 let letout_tac =
 679    let mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[] in
 680    let term = C.Sort C.Set in
 681    let letout_tac (proof, goal) =
 682       let curi, metasenv, pbo, pty, attrs = proof in
 683       let metano, context, ty = CicUtil.lookup_meta goal metasenv in
 684       let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 685       let fresh_name = mk_fresh_name_callback metasenv context (Cic.Name "hole") ~typ:term in
 686       let context_for_newmeta = None :: context in
 687       let irl = CicMkImplicit.identity_relocation_list_for_metavariable context_for_newmeta in
 688       let newmetaty = CicSubstitution.lift 1 ty in
 689       let bo' = C.LetIn (fresh_name, term, C.Meta (newmeta,irl)) in
 690       let newproof, _ = ProofEngineHelpers.subst_meta_in_proof proof metano bo'[newmeta,context_for_newmeta,newmetaty] in
 691       newproof, [newmeta]
 692    in
 693    mk_tactic letout_tac