components/tactics/primitiveTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
  29 exception NotAnInductiveTypeToEliminate
  30 exception WrongUriToVariable of string
  31 exception NotAnEliminator
  32
  33 module PET = ProofEngineTypes
  34
  35 (* lambda_abstract newmeta ty *)
  36 (* returns a triple [bo],[context],[ty'] where              *)
  37 (* [ty] = Pi/LetIn [context].[ty'] ([context] is a vector!) *)
  38 (* and [bo] = Lambda/LetIn [context].(Meta [newmeta])       *)
  39 (* So, lambda_abstract is the core of the implementation of *)
  40 (* the Intros tactic.                                       *)
  41 (* howmany = -1 means Intros, howmany > 0 means Intros n    *)
  42 let lambda_abstract ?(howmany=(-1)) metasenv context newmeta ty mk_fresh_name =
  43  let module C = Cic in
  44   let rec collect_context context howmany do_whd ty =
  45    match howmany with
  46    | 0 ->
  47         let irl =
  48           CicMkImplicit.identity_relocation_list_for_metavariable context
  49         in
  50          context, ty, (C.Meta (newmeta,irl))
  51    | _ ->
  52       match ty with
  53         C.Cast (te,_)   -> collect_context context howmany do_whd te
  54       | C.Prod (n,s,t)  ->
  55          let n' = mk_fresh_name metasenv context n ~typ:s in
  56           let (context',ty,bo) =
  57            let entry = match n' with
  58               | C.Name _    -> Some (n',(C.Decl s))
  59               | C.Anonymous -> None
  60            in
  61            let ctx = entry :: context in
  62            collect_context ctx (howmany - 1) do_whd t
  63           in
  64            (context',ty,C.Lambda(n',s,bo))
  65       | C.LetIn (n,s,t) ->
  66          let (context',ty,bo) =
  67           collect_context ((Some (n,(C.Def (s,None))))::context) (howmany - 1) do_whd t
  68          in
  69           (context',ty,C.LetIn(n,s,bo))
  70       | _ as t ->
  71         if howmany <= 0 then
  72          let irl =
  73           CicMkImplicit.identity_relocation_list_for_metavariable context
  74          in
  75           context, t, (C.Meta (newmeta,irl))
  76         else if do_whd then
  77           let t = CicReduction.whd ~delta:true context t in
  78           collect_context context howmany false t
  79         else
  80          raise (PET.Fail (lazy "intro(s): not enough products or let-ins"))
  81   in
  82    collect_context context howmany true ty
  83
  84 let eta_expand metasenv context t arg =
  85  let module T = CicTypeChecker in
  86  let module S = CicSubstitution in
  87  let module C = Cic in
  88   let rec aux n =
  89    function
  90       t' when t' = S.lift n arg -> C.Rel (1 + n)
  91     | C.Rel m  -> if m <= n then C.Rel m else C.Rel (m+1)
  92     | C.Var (uri,exp_named_subst) ->
  93        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
  94         C.Var (uri,exp_named_subst')
  95     | C.Meta (i,l) ->
  96        let l' =
  97         List.map (function None -> None | Some t -> Some (aux n t)) l
  98        in
  99         C.Meta (i, l')
 100     | C.Sort _
 101     | C.Implicit _ as t -> t
 102     | C.Cast (te,ty) -> C.Cast (aux n te, aux n ty)
 103     | C.Prod (nn,s,t) -> C.Prod (nn, aux n s, aux (n+1) t)
 104     | C.Lambda (nn,s,t) -> C.Lambda (nn, aux n s, aux (n+1) t)
 105     | C.LetIn (nn,s,t) -> C.LetIn (nn, aux n s, aux (n+1) t)
 106     | C.Appl l -> C.Appl (List.map (aux n) l)
 107     | C.Const (uri,exp_named_subst) ->
 108        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 109         C.Const (uri,exp_named_subst')
 110     | C.MutInd (uri,i,exp_named_subst) ->
 111        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 112         C.MutInd (uri,i,exp_named_subst')
 113     | C.MutConstruct (uri,i,j,exp_named_subst) ->
 114        let exp_named_subst' = aux_exp_named_subst n exp_named_subst in
 115         C.MutConstruct (uri,i,j,exp_named_subst')
 116     | C.MutCase (sp,i,outt,t,pl) ->
 117        C.MutCase (sp,i,aux n outt, aux n t,
 118         List.map (aux n) pl)
 119     | C.Fix (i,fl) ->
 120        let tylen = List.length fl in
 121         let substitutedfl =
 122          List.map
 123           (fun (name,i,ty,bo) -> (name, i, aux n ty, aux (n+tylen) bo))
 124            fl
 125         in
 126          C.Fix (i, substitutedfl)
 127     | C.CoFix (i,fl) ->
 128        let tylen = List.length fl in
 129         let substitutedfl =
 130          List.map
 131           (fun (name,ty,bo) -> (name, aux n ty, aux (n+tylen) bo))
 132            fl
 133         in
 134          C.CoFix (i, substitutedfl)
 135   and aux_exp_named_subst n =
 136    List.map (function uri,t -> uri,aux n t)
 137   in
 138    let argty,_ =
 139     T.type_of_aux' metasenv context arg CicUniv.empty_ugraph (* TASSI: FIXME *)
 140    in
 141     let fresh_name =
 142      FreshNamesGenerator.mk_fresh_name ~subst:[]
 143       metasenv context (Cic.Name "Heta") ~typ:argty
 144     in
 145      (C.Appl [C.Lambda (fresh_name,argty,aux 0 t) ; arg])
 146
 147 (*CSC: ma serve solamente la prima delle new_uninst e l'unione delle due!!! *)
 148 let classify_metas newmeta in_subst_domain subst_in metasenv =
 149  List.fold_right
 150   (fun (i,canonical_context,ty) (old_uninst,new_uninst) ->
 151     if in_subst_domain i then
 152      old_uninst,new_uninst
 153     else
 154      let ty' = subst_in canonical_context ty in
 155       let canonical_context' =
 156        List.fold_right
 157         (fun entry canonical_context' ->
 158           let entry' =
 159            match entry with
 160               Some (n,Cic.Decl s) ->
 161                Some (n,Cic.Decl (subst_in canonical_context' s))
 162             | Some (n,Cic.Def (s,None)) ->
 163                Some (n,Cic.Def ((subst_in canonical_context' s),None))
 164             | None -> None
 165             | Some (n,Cic.Def (bo,Some ty)) ->
 166                Some
 167                 (n,
 168                   Cic.Def
 169                    (subst_in canonical_context' bo,
 170                     Some (subst_in canonical_context' ty)))
 171           in
 172            entry'::canonical_context'
 173         ) canonical_context []
 174      in
 175       if i < newmeta then
 176        ((i,canonical_context',ty')::old_uninst),new_uninst
 177       else
 178        old_uninst,((i,canonical_context',ty')::new_uninst)
 179   ) metasenv ([],[])
 180
 181 (* Useful only inside apply_tac *)
 182 let
 183  generalize_exp_named_subst_with_fresh_metas context newmeta uri exp_named_subst
 184 =
 185  let module C = Cic in
 186   let params =
 187     let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 188     CicUtil.params_of_obj o
 189   in
 190    let exp_named_subst_diff,new_fresh_meta,newmetasenvfragment,exp_named_subst'=
 191     let next_fresh_meta = ref newmeta in
 192     let newmetasenvfragment = ref [] in
 193     let exp_named_subst_diff = ref [] in
 194      let rec aux =
 195       function
 196          [],[] -> []
 197        | uri::tl,[] ->
 198           let ty =
 199             let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 200               match o with
 201                   C.Variable (_,_,ty,_,_) ->
 202                     CicSubstitution.subst_vars !exp_named_subst_diff ty
 203                 | _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 204           in
 205 (* CSC: patch to generate ?1 : ?2 : Type in place of ?1 : Type to simulate ?1 :< Type
 206            (match ty with
 207                C.Sort (C.Type _) as s -> (* TASSI: ?? *)
 208                  let fresh_meta = !next_fresh_meta in
 209                  let fresh_meta' = fresh_meta + 1 in
 210                   next_fresh_meta := !next_fresh_meta + 2 ;
 211                   let subst_item = uri,C.Meta (fresh_meta',[]) in
 212                    newmetasenvfragment :=
 213                     (fresh_meta,[],C.Sort (C.Type (CicUniv.fresh()))) ::
 214                      (* TASSI: ?? *)
 215                      (fresh_meta',[],C.Meta (fresh_meta,[])) :: !newmetasenvfragment ;
 216                    exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 217                    subst_item::(aux (tl,[]))
 218              | _ ->
 219 *)
 220               let irl =
 221                 CicMkImplicit.identity_relocation_list_for_metavariable context
 222               in
 223               let subst_item = uri,C.Meta (!next_fresh_meta,irl) in
 224                newmetasenvfragment :=
 225                 (!next_fresh_meta,context,ty)::!newmetasenvfragment ;
 226                exp_named_subst_diff := !exp_named_subst_diff @ [subst_item] ;
 227                incr next_fresh_meta ;
 228                subst_item::(aux (tl,[]))(*)*)
 229        | uri::tl1,((uri',_) as s)::tl2 ->
 230           assert (UriManager.eq uri uri') ;
 231           s::(aux (tl1,tl2))
 232        | [],_ -> assert false
 233      in
 234       let exp_named_subst' = aux (params,exp_named_subst) in
 235        !exp_named_subst_diff,!next_fresh_meta,
 236         List.rev !newmetasenvfragment, exp_named_subst'
 237    in
 238     new_fresh_meta,newmetasenvfragment,exp_named_subst',exp_named_subst_diff
 239 ;;
 240
 241 let new_metasenv_and_unify_and_t newmeta' metasenv' subst context term' ty termty goal_arity =
 242   let (consthead,newmetasenv,arguments,_) =
 243    TermUtil.saturate_term newmeta' metasenv' context termty
 244     goal_arity in
 245   let subst,newmetasenv',_ =
 246    CicUnification.fo_unif_subst
 247      subst context newmetasenv consthead ty CicUniv.empty_ugraph
 248   in
 249   let t =
 250     if List.length arguments = 0 then term' else Cic.Appl (term'::arguments)
 251   in
 252   subst,newmetasenv',t
 253
 254 let rec count_prods context ty =
 255  match CicReduction.whd context ty with
 256     Cic.Prod (n,s,t) -> 1 + count_prods (Some (n,Cic.Decl s)::context) t
 257   | _ -> 0
 258
 259 let apply_with_subst ~term ~subst ~maxmeta (proof, goal) =
 260   (* Assumption: The term "term" must be closed in the current context *)
 261  let module T = CicTypeChecker in
 262  let module R = CicReduction in
 263  let module C = Cic in
 264   let (_,metasenv,_subst,_,_, _) = proof in
 265   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 266   let newmeta = max (CicMkImplicit.new_meta metasenv subst) maxmeta in
 267    let exp_named_subst_diff,newmeta',newmetasenvfragment,term' =
 268     match term with
 269        C.Var (uri,exp_named_subst) ->
 270         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 271          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 272           exp_named_subst
 273         in
 274          exp_named_subst_diff,newmeta',newmetasenvfragment,
 275           C.Var (uri,exp_named_subst')
 276      | C.Const (uri,exp_named_subst) ->
 277         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 278          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 279           exp_named_subst
 280         in
 281          exp_named_subst_diff,newmeta',newmetasenvfragment,
 282           C.Const (uri,exp_named_subst')
 283      | C.MutInd (uri,tyno,exp_named_subst) ->
 284         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 285          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 286           exp_named_subst
 287         in
 288          exp_named_subst_diff,newmeta',newmetasenvfragment,
 289           C.MutInd (uri,tyno,exp_named_subst')
 290      | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 291         let newmeta',newmetasenvfragment,exp_named_subst',exp_named_subst_diff =
 292          generalize_exp_named_subst_with_fresh_metas context newmeta uri
 293           exp_named_subst
 294         in
 295          exp_named_subst_diff,newmeta',newmetasenvfragment,
 296           C.MutConstruct (uri,tyno,consno,exp_named_subst')
 297      | _ -> [],newmeta,[],term
 298    in
 299    let metasenv' = metasenv@newmetasenvfragment in
 300    let termty,_ =
 301      CicTypeChecker.type_of_aux' metasenv' context term' CicUniv.empty_ugraph
 302    in
 303    let termty =
 304      CicSubstitution.subst_vars exp_named_subst_diff termty in
 305    let goal_arity = count_prods context ty in
 306    let subst,newmetasenv',t =
 307     let rec add_one_argument n =
 308      try
 309       new_metasenv_and_unify_and_t newmeta' metasenv' subst context term' ty
 310         termty n
 311      with CicUnification.UnificationFailure _ when n > 0 ->
 312       add_one_argument (n - 1)
 313     in
 314      add_one_argument goal_arity
 315    in
 316    let in_subst_domain i = List.exists (function (j,_) -> i=j) subst in
 317    let apply_subst = CicMetaSubst.apply_subst subst in
 318    let old_uninstantiatedmetas,new_uninstantiatedmetas =
 319      (* subst_in doesn't need the context. Hence the underscore. *)
 320      let subst_in _ = CicMetaSubst.apply_subst subst in
 321      classify_metas newmeta in_subst_domain subst_in newmetasenv'
 322    in
 323    let bo' = apply_subst t in
 324    let newmetasenv'' = new_uninstantiatedmetas@old_uninstantiatedmetas in
 325    let subst_in =
 326      (* if we just apply the subtitution, the type is irrelevant:
 327               we may use Implicit, since it will be dropped *)
 328       ((metano,(context,bo',Cic.Implicit None))::subst)
 329    in
 330    let (newproof, newmetasenv''') =
 331     ProofEngineHelpers.subst_meta_and_metasenv_in_proof proof metano subst_in
 332      newmetasenv''
 333    in
 334    let subst = ((metano,(context,bo',ty))::subst) in
 335    subst,
 336    (newproof, List.map (function (i,_,_) -> i) new_uninstantiatedmetas),
 337    max maxmeta (CicMkImplicit.new_meta newmetasenv''' subst)
 338
 339
 340 (* ALB *)
 341 let apply_with_subst ~term ?(subst=[]) ?(maxmeta=0) status =
 342   try
 343 (*     apply_tac_verbose ~term status *)
 344     apply_with_subst ~term ~subst ~maxmeta status
 345       (* TODO cacciare anche altre eccezioni? *)
 346   with
 347   | CicUnification.UnificationFailure msg
 348   | CicTypeChecker.TypeCheckerFailure msg -> raise (PET.Fail msg)
 349
 350 (* ALB *)
 351 let apply_tac_verbose ~term status =
 352   let subst, status, _ = apply_with_subst ~term status in
 353   (CicMetaSubst.apply_subst subst), status
 354
 355 let apply_tac ~term status = snd (apply_tac_verbose ~term status)
 356
 357   (* TODO per implementare i tatticali e' necessario che tutte le tattiche
 358   sollevino _solamente_ Fail *)
 359 let apply_tac ~term =
 360  let apply_tac ~term status =
 361   try
 362     apply_tac ~term status
 363       (* TODO cacciare anche altre eccezioni? *)
 364   with
 365   | CicUnification.UnificationFailure msg
 366   | CicTypeChecker.TypeCheckerFailure msg ->
 367       raise (PET.Fail msg)
 368  in
 369   PET.mk_tactic (apply_tac ~term)
 370
 371 let intros_tac ?howmany ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) ()=
 372  let intros_tac (proof, goal)
 373  =
 374   let module C = Cic in
 375   let module R = CicReduction in
 376    let (_,metasenv,_subst,_,_, _) = proof in
 377    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 378     let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 379      let (context',ty',bo') =
 380       lambda_abstract ?howmany metasenv context newmeta ty mk_fresh_name_callback
 381      in
 382       let (newproof, _) =
 383        ProofEngineHelpers.subst_meta_in_proof proof metano bo'
 384         [newmeta,context',ty']
 385       in
 386        (newproof, [newmeta])
 387  in
 388   PET.mk_tactic intros_tac
 389
 390 let cut_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 391  let cut_tac
 392   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 393   term (proof, goal)
 394  =
 395   let module C = Cic in
 396    let curi,metasenv,_subst,pbo,pty, attrs = proof in
 397    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 398     let newmeta1 = ProofEngineHelpers.new_meta_of_proof ~proof in
 399     let newmeta2 = newmeta1 + 1 in
 400     let fresh_name =
 401      mk_fresh_name_callback metasenv context (Cic.Name "Hcut") ~typ:term in
 402     let context_for_newmeta1 =
 403      (Some (fresh_name,C.Decl term))::context in
 404     let irl1 =
 405      CicMkImplicit.identity_relocation_list_for_metavariable
 406       context_for_newmeta1
 407     in
 408     let irl2 =
 409       CicMkImplicit.identity_relocation_list_for_metavariable context
 410     in
 411      let newmeta1ty = CicSubstitution.lift 1 ty in
 412      let bo' =
 413       C.Appl
 414        [C.Lambda (fresh_name,term,C.Meta (newmeta1,irl1)) ;
 415         C.Meta (newmeta2,irl2)]
 416      in
 417       let (newproof, _) =
 418        ProofEngineHelpers.subst_meta_in_proof proof metano bo'
 419         [newmeta2,context,term; newmeta1,context_for_newmeta1,newmeta1ty];
 420       in
 421        (newproof, [newmeta1 ; newmeta2])
 422  in
 423   PET.mk_tactic (cut_tac ~mk_fresh_name_callback term)
 424
 425 let letin_tac ?(mk_fresh_name_callback=FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 426  let letin_tac
 427   ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 428   term (proof, goal)
 429  =
 430   let module C = Cic in
 431    let curi,metasenv,_subst,pbo,pty, attrs = proof in
 432    (* occur check *)
 433    let occur i t =
 434      let m = CicUtil.metas_of_term t in
 435      List.exists (fun (j,_) -> i=j) m
 436    in
 437    let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 438    if occur metano term then
 439      raise
 440        (ProofEngineTypes.Fail (lazy
 441          "You can't letin a term containing the current goal"));
 442     let _,_ =
 443       CicTypeChecker.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 444      let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 445      let fresh_name =
 446       mk_fresh_name_callback metasenv context (Cic.Name "Hletin") ~typ:term in
 447      let context_for_newmeta =
 448       (Some (fresh_name,C.Def (term,None)))::context in
 449      let irl =
 450       CicMkImplicit.identity_relocation_list_for_metavariable
 451        context_for_newmeta
 452      in
 453       let newmetaty = CicSubstitution.lift 1 ty in
 454       let bo' = C.LetIn (fresh_name,term,C.Meta (newmeta,irl)) in
 455        let (newproof, _) =
 456          ProofEngineHelpers.subst_meta_in_proof
 457            proof metano bo'[newmeta,context_for_newmeta,newmetaty]
 458        in
 459         (newproof, [newmeta])
 460  in
 461   PET.mk_tactic (letin_tac ~mk_fresh_name_callback term)
 462
 463   (** functional part of the "exact" tactic *)
 464 let exact_tac ~term =
 465  let exact_tac ~term (proof, goal) =
 466   (* Assumption: the term bo must be closed in the current context *)
 467   let (_,metasenv,_subst,_,_, _) = proof in
 468   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 469   let module T = CicTypeChecker in
 470   let module R = CicReduction in
 471   let ty_term,u = T.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 472   let b,_ = R.are_convertible context ty_term ty u in (* TASSI: FIXME *)
 473   if b then
 474    begin
 475     let (newproof, metasenv') =
 476       ProofEngineHelpers.subst_meta_in_proof proof metano term [] in
 477     (newproof, [])
 478    end
 479   else
 480    raise (PET.Fail (lazy "The type of the provided term is not the one expected."))
 481  in
 482   PET.mk_tactic (exact_tac ~term)
 483
 484 (* not really "primitive" tactics .... *)
 485
 486 module TC  = CicTypeChecker
 487 module UM  = UriManager
 488 module R   = CicReduction
 489 module C   = Cic
 490 module PEH = ProofEngineHelpers
 491 module PER = ProofEngineReduction
 492 module MS  = CicMetaSubst
 493 module S   = CicSubstitution
 494 module T   = Tacticals
 495 module RT  = ReductionTactics
 496
 497 let rec args_init n f =
 498    if n <= 0 then [] else f n :: args_init (pred n) f
 499
 500 let mk_predicate_for_elim
 501  ~context ~metasenv ~ugraph ~goal ~arg ~using ~cpattern ~args_no =
 502    let instantiated_eliminator =
 503       let f n = if n = 1 then arg else C.Implicit None in
 504       C.Appl (using :: args_init args_no f)
 505    in
 506    let _actual_arg, iety, _metasenv', _ugraph =
 507       CicRefine.type_of_aux' metasenv context instantiated_eliminator ugraph
 508    in
 509    let _actual_meta, actual_args = match iety with
 510       | C.Meta (i, _)                  -> i, []
 511       | C.Appl (C.Meta (i, _) :: args) -> i, args
 512       | _                              -> assert false
 513    in
 514 (* let _, upto = PEH.split_with_whd (List.nth splits pred_pos) in *)
 515    let rec mk_pred metasenv context' pred arg' = function
 516       | []           -> metasenv, pred, arg'
 517       | arg :: tail ->
 518 (* FG: we find the predicate for the eliminator as in the rewrite tactic ****)
 519          let argty, _ugraph = TC.type_of_aux' metasenv context' arg ugraph in
 520          let argty = CicReduction.whd context' argty in
 521                let fresh_name =
 522             FreshNamesGenerator.mk_fresh_name
 523             ~subst:[] metasenv context' C.Anonymous ~typ:argty
 524          in
 525          let hyp = Some (fresh_name, C.Decl argty) in
 526          let lazy_term c m u =
 527             let distance  = List.length c - List.length context in
 528             S.lift distance arg, m, u
 529          in
 530          let pattern = Some lazy_term, [], Some cpattern in
 531          let subst, metasenv, _ugraph, _conjecture, selected_terms =
 532             ProofEngineHelpers.select
 533             ~metasenv ~ugraph ~conjecture:(0, context, pred) ~pattern
 534          in
 535          let metasenv = MS.apply_subst_metasenv subst metasenv in
 536          let map (_context_of_t, t) l = t :: l in
 537          let what = List.fold_right map selected_terms [] in
 538          let arg' = MS.apply_subst subst arg' in
 539          let argty = MS.apply_subst subst argty in
 540          let pred = PER.replace_with_rel_1_from ~equality:(==) ~what 1 pred in
 541          let pred = MS.apply_subst subst pred in
 542          let pred = C.Lambda (fresh_name, argty, pred) in
 543          mk_pred metasenv (hyp :: context') pred arg' tail
 544    in
 545    let metasenv, pred, arg = mk_pred metasenv context goal arg actual_args in
 546    HLog.debug ("PRED: " ^ CicPp.ppterm ~metasenv pred ^ " ARGS: " ^ String.concat " " (List.map (CicPp.ppterm ~metasenv) actual_args));
 547    metasenv, pred, arg, actual_args
 548
 549 let beta_after_elim_tac upto predicate =
 550    let beta_after_elim_tac status =
 551       let proof, goal = status in
 552       let _, metasenv, _subst, _, _, _ = proof in
 553       let _, _, ty = CicUtil.lookup_meta goal metasenv in
 554       let mk_pattern ~equality ~upto ~predicate ty =
 555          (* code adapted from ProceduralConversion.generalize *)
 556          let meta = C.Implicit None in
 557          let hole = C.Implicit (Some `Hole) in
 558          let anon = C.Anonymous in
 559          let is_meta =
 560             let map b = function
 561                | C.Implicit None when b -> b
 562                | _                      -> false
 563             in
 564             List.fold_left map true
 565          in
 566          let rec gen_fix len k (name, i, ty, bo) =
 567             name, i, gen_term k ty, gen_term (k + len) bo
 568          and gen_cofix len k (name, ty, bo) =
 569             name, gen_term k ty, gen_term (k + len) bo
 570          and gen_term k = function
 571             | C.Sort _
 572             | C.Implicit _
 573             | C.Const (_, _)
 574             | C.Var (_, _)
 575             | C.MutInd (_, _, _)
 576             | C.MutConstruct (_, _, _, _)
 577             | C.Meta (_, _)
 578             | C.Rel _ -> meta
 579             | C.Appl (hd :: tl) when equality hd (S.lift k predicate) ->
 580                assert (List.length tl = upto);
 581                hole
 582             | C.Appl ts ->
 583                let ts = List.map (gen_term k) ts in
 584                if is_meta ts then meta else C.Appl ts
 585             | C.Cast (te, ty) ->
 586                let te, ty = gen_term k te, gen_term k ty in
 587                if is_meta [te; ty] then meta else C.Cast (te, ty)
 588             | C.MutCase (sp, i, outty, t, pl) ->
 589                let outty, t, pl = gen_term k outty, gen_term k t, List.map (gen_term k) pl in
 590                if is_meta (outty :: t :: pl) then meta else hole (* C.MutCase (sp, i, outty, t, pl) *)
 591             | C.Prod (_, s, t) ->
 592                let s, t = gen_term k s, gen_term (succ k) t in
 593                if is_meta [s; t] then meta else C.Prod (anon, s, t)
 594             | C.Lambda (_, s, t) ->
 595                let s, t = gen_term k s, gen_term (succ k) t in
 596                if is_meta [s; t] then meta else C.Lambda (anon, s, t)
 597             | C.LetIn (_, s, t) ->
 598                let s, t = gen_term k s, gen_term (succ k) t in
 599                if is_meta [s; t] then meta else C.LetIn (anon, s, t)
 600             | C.Fix (i, fl) -> C.Fix (i, List.map (gen_fix (List.length fl) k) fl)
 601             | C.CoFix (i, fl) -> C.CoFix (i, List.map (gen_cofix (List.length fl) k) fl)
 602          in
 603          None, [], Some (gen_term 0 ty)
 604       in
 605       let equality = CicUtil.alpha_equivalence in
 606       let pattern = mk_pattern ~equality ~upto ~predicate ty in
 607       let tactic = RT.head_beta_reduce_tac ~delta:false ~upto ~pattern in
 608       PET.apply_tactic tactic status
 609    in
 610    PET.mk_tactic beta_after_elim_tac
 611
 612 let elim_tac ?using ?(pattern = PET.conclusion_pattern None) term =
 613  let elim_tac (proof, goal) =
 614    let cpattern = match pattern with
 615       | None, [], Some cpattern -> cpattern
 616       | _                       -> raise (PET.Fail (lazy "not implemented"))
 617    in
 618    let ugraph = CicUniv.empty_ugraph in
 619    let curi, metasenv, _subst, proofbo, proofty, attrs = proof in
 620    let conjecture = CicUtil.lookup_meta goal metasenv in
 621    let metano, context, ty = conjecture in
 622     let termty,_ugraph = TC.type_of_aux' metasenv context term ugraph in
 623     let termty = CicReduction.whd context termty in
 624     let termty, metasenv', arguments, _fresh_meta =
 625      TermUtil.saturate_term
 626       (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
 627     let term = if arguments = [] then term else Cic.Appl (term::arguments) in
 628     let uri, exp_named_subst, typeno, _args =
 629      match termty with
 630         C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 631       | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 632           (uri,exp_named_subst,typeno,args)
 633       | _ -> raise NotAnInductiveTypeToEliminate
 634     in
 635      let eliminator_uri =
 636       let buri = UM.buri_of_uri uri in
 637       let name =
 638         let o,_ugraph = CicEnvironment.get_obj ugraph uri in
 639        match o with
 640           C.InductiveDefinition (tys,_,_,_) ->
 641            let (name,_,_,_) = List.nth tys typeno in
 642             name
 643         | _ -> assert false
 644       in
 645       let ty_ty,_ugraph = TC.type_of_aux' metasenv' context ty ugraph in
 646       let ext =
 647        match ty_ty with
 648           C.Sort C.Prop -> "_ind"
 649         | C.Sort C.Set  -> "_rec"
 650         | C.Sort C.CProp -> "_rec"
 651         | C.Sort (C.Type _)-> "_rect"
 652         | C.Meta (_,_) -> raise TheTypeOfTheCurrentGoalIsAMetaICannotChooseTheRightElimiantionPrinciple
 653         | _ -> assert false
 654       in
 655        UM.uri_of_string (buri ^ "/" ^ name ^ ext ^ ".con")
 656      in
 657       let eliminator_ref = match using with
 658          | None   -> C.Const (eliminator_uri, exp_named_subst)
 659          | Some t -> t
 660        in
 661        let ety, _ugraph =
 662          TC.type_of_aux' metasenv' context eliminator_ref ugraph in
 663 (* FG: ADDED PART ***********************************************************)
 664 (* FG: we can not assume eliminator is the default eliminator ***************)
 665    let splits, args_no = PEH.split_with_whd (context, ety) in
 666    let pred_pos = match List.hd splits with
 667       | _, C.Rel i when i > 1 && i <= args_no -> i
 668       | _, C.Appl (C.Rel i :: _) when i > 1 && i <= args_no -> i
 669       | _ -> raise NotAnEliminator
 670    in
 671    let metasenv', pred, term, actual_args = match pattern with
 672       | None, [], Some (C.Implicit (Some `Hole)) ->
 673          metasenv', C.Implicit None, term, []
 674       | _                                        ->
 675          mk_predicate_for_elim
 676             ~args_no ~context ~ugraph ~cpattern
 677             ~metasenv:metasenv' ~arg:term ~using:eliminator_ref ~goal:ty
 678    in
 679 (* FG: END OF ADDED PART ****************************************************)
 680       let term_to_refine =
 681          let f n =
 682             if n = pred_pos then pred else
 683             if n = 1 then term else C.Implicit None
 684          in
 685          C.Appl (eliminator_ref :: args_init args_no f)
 686       in
 687       let refined_term,_refined_termty,metasenv'',_ugraph =
 688          CicRefine.type_of_aux' metasenv' context term_to_refine ugraph
 689       in
 690       let new_goals =
 691          ProofEngineHelpers.compare_metasenvs
 692             ~oldmetasenv:metasenv ~newmetasenv:metasenv''
 693       in
 694       let proof' = curi,metasenv'',_subst,proofbo,proofty, attrs in
 695       let proof'', new_goals' =
 696          PET.apply_tactic (apply_tac ~term:refined_term) (proof',goal)
 697       in
 698       (* The apply_tactic can have closed some of the new_goals *)
 699       let patched_new_goals =
 700          let (_,metasenv''',_subst,_,_, _) = proof'' in
 701          List.filter
 702             (function i -> List.exists (function (j,_,_) -> j=i) metasenv''')
 703             new_goals @ new_goals'
 704       in
 705       let res = proof'', patched_new_goals in
 706       let upto = List.length actual_args in
 707       if upto = 0 then res else
 708       let continuation = beta_after_elim_tac upto pred in
 709       let dummy_status = proof,goal in
 710       PET.apply_tactic
 711          (T.then_ ~start:(PET.mk_tactic (fun _ -> res)) ~continuation)
 712          dummy_status
 713    in
 714    PET.mk_tactic elim_tac
 715 ;;
 716
 717 let cases_intros_tac ?(howmany=(-1)) ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[]) term =
 718  let cases_tac ~term (proof, goal) =
 719   let module TC = CicTypeChecker in
 720   let module U = UriManager in
 721   let module R = CicReduction in
 722   let module C = Cic in
 723   let (curi,metasenv,_subst, proofbo,proofty, attrs) = proof in
 724   let metano,context,ty = CicUtil.lookup_meta goal metasenv in
 725   let termty,_ = TC.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 726   let termty = CicReduction.whd context termty in
 727   let (termty,metasenv',arguments,fresh_meta) =
 728    TermUtil.saturate_term
 729     (ProofEngineHelpers.new_meta_of_proof proof) metasenv context termty 0 in
 730   let term = if arguments = [] then term else Cic.Appl (term::arguments) in
 731   let uri,exp_named_subst,typeno,args =
 732     match termty with
 733     | C.MutInd (uri,typeno,exp_named_subst) -> (uri,exp_named_subst,typeno,[])
 734     | C.Appl ((C.MutInd (uri,typeno,exp_named_subst))::args) ->
 735         (uri,exp_named_subst,typeno,args)
 736     | _ -> raise NotAnInductiveTypeToEliminate
 737   in
 738   let paramsno,itty,patterns,right_args =
 739     match CicEnvironment.get_obj CicUniv.empty_ugraph uri with
 740     | C.InductiveDefinition (tys,_,paramsno,_),_ ->
 741        let _,left_parameters,right_args =
 742          List.fold_right
 743            (fun x (n,acc1,acc2) ->
 744              if n > 0 then (n-1,acc1,x::acc2) else (n,x::acc1,acc2))
 745            args (List.length args - paramsno, [],[])
 746        in
 747        let _,_,itty,cl = List.nth tys typeno in
 748        let rec aux left_parameters context t =
 749          match left_parameters,CicReduction.whd context t with
 750          | [],C.Prod (name,source,target) ->
 751             let fresh_name =
 752               mk_fresh_name_callback metasenv' context name ~typ:source
 753             in
 754              C.Lambda (fresh_name,C.Implicit None,
 755              aux [] (Some (fresh_name,C.Decl source)::context) target)
 756          | hd::tl,C.Prod (name,source,target) ->
 757              (* left parameters instantiation *)
 758              aux tl context (CicSubstitution.subst hd target)
 759          | [],_ -> C.Implicit None
 760          | _ -> assert false
 761        in
 762         paramsno,itty,
 763         List.map (function (_,cty) -> aux left_parameters context cty) cl,
 764         right_args
 765     | _ -> assert false
 766   in
 767   let outtype =
 768     let n_right_args = List.length right_args in
 769     let n_lambdas = n_right_args + 1 in
 770     let lifted_ty = CicSubstitution.lift n_lambdas ty in
 771     let captured_ty =
 772       let what =
 773         List.map (CicSubstitution.lift n_lambdas) (right_args)
 774       in
 775       let with_what meta =
 776         let rec mkargs = function
 777           | 0 -> assert false
 778           | 1 -> []
 779           | n ->
 780               (if meta then Cic.Implicit None else Cic.Rel n)::(mkargs (n-1))
 781         in
 782         mkargs n_lambdas
 783       in
 784       let replaced = ref false in
 785       let replace = ProofEngineReduction.replace_lifting
 786        ~equality:(fun _ a b -> let rc = CicUtil.alpha_equivalence a b in
 787                   if rc then replaced := true; rc)
 788        ~context:[]
 789       in
 790       let captured =
 791         replace ~what:[CicSubstitution.lift n_lambdas term]
 792           ~with_what:[Cic.Rel 1] ~where:lifted_ty
 793       in
 794       if not !replaced then
 795         (* this means the matched term is not there,
 796          * but maybe right params are: we user rels (to right args lambdas) *)
 797         replace ~what ~with_what:(with_what false) ~where:captured
 798       else
 799         (* since the matched is there, rights should be inferrable *)
 800         replace ~what ~with_what:(with_what true) ~where:captured
 801     in
 802     let captured_term_ty =
 803       let term_ty = CicSubstitution.lift n_right_args termty in
 804       let rec mkrels = function 0 -> []|n -> (Cic.Rel n)::(mkrels (n-1)) in
 805       let rec fstn acc l n =
 806         if n = 0 then acc else fstn (acc@[List.hd l]) (List.tl l) (n-1)
 807       in
 808       match term_ty with
 809       | C.MutInd _ -> term_ty
 810       | C.Appl ((C.MutInd (a,b,c))::args) ->
 811            C.Appl ((C.MutInd (a,b,c))::
 812                fstn [] args paramsno @ mkrels n_right_args)
 813       | _ -> raise NotAnInductiveTypeToEliminate
 814     in
 815     let rec add_lambdas = function
 816       | 0 -> captured_ty
 817       | 1 ->
 818           C.Lambda (C.Name "matched", captured_term_ty, (add_lambdas 0))
 819       | n ->
 820            C.Lambda (C.Name ("right_"^(string_of_int (n-1))),
 821                      C.Implicit None, (add_lambdas (n-1)))
 822     in
 823     add_lambdas n_lambdas
 824   in
 825   let term_to_refine = C.MutCase (uri,typeno,outtype,term,patterns) in
 826   let refined_term,_,metasenv'',_ =
 827     CicRefine.type_of_aux' metasenv' context term_to_refine
 828       CicUniv.empty_ugraph
 829   in
 830   let new_goals =
 831     ProofEngineHelpers.compare_metasenvs
 832       ~oldmetasenv:metasenv ~newmetasenv:metasenv''
 833   in
 834   let proof' = curi,metasenv'',_subst,proofbo,proofty, attrs in
 835   let proof'', new_goals' =
 836     PET.apply_tactic (apply_tac ~term:refined_term) (proof',goal)
 837   in
 838   (* The apply_tactic can have closed some of the new_goals *)
 839   let patched_new_goals =
 840     let (_,metasenv''',_subst,_,_,_) = proof'' in
 841       List.filter
 842         (function i -> List.exists (function (j,_,_) -> j=i) metasenv''')
 843         new_goals @ new_goals'
 844     in
 845     proof'', patched_new_goals
 846   in
 847   PET.mk_tactic (cases_tac ~term)
 848 ;;
 849
 850
 851 let elim_intros_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 852                     ?depth ?using ?pattern what =
 853  Tacticals.then_ ~start:(elim_tac ?using ?pattern what)
 854   ~continuation:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 855 ;;
 856
 857 (* The simplification is performed only on the conclusion *)
 858 let elim_intros_simpl_tac ?(mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[])
 859                           ?depth ?using ?pattern what =
 860  Tacticals.then_ ~start:(elim_tac ?using ?pattern what)
 861   ~continuation:
 862    (Tacticals.thens
 863      ~start:(intros_tac ~mk_fresh_name_callback ?howmany:depth ())
 864      ~continuations:
 865        [ReductionTactics.simpl_tac
 866          ~pattern:(ProofEngineTypes.conclusion_pattern None)])
 867 ;;
 868
 869 (* FG: insetrts a "hole" in the context (derived from letin_tac) *)
 870
 871 let letout_tac =
 872    let mk_fresh_name_callback = FreshNamesGenerator.mk_fresh_name ~subst:[] in
 873    let term = C.Sort C.Set in
 874    let letout_tac (proof, goal) =
 875       let curi, metasenv, _subst, pbo, pty, attrs = proof in
 876       let metano, context, ty = CicUtil.lookup_meta goal metasenv in
 877       let newmeta = ProofEngineHelpers.new_meta_of_proof ~proof in
 878       let fresh_name = mk_fresh_name_callback metasenv context (Cic.Name "hole") ~typ:term in
 879       let context_for_newmeta = None :: context in
 880       let irl = CicMkImplicit.identity_relocation_list_for_metavariable context_for_newmeta in
 881       let newmetaty = CicSubstitution.lift 1 ty in
 882       let bo' = C.LetIn (fresh_name, term, C.Meta (newmeta,irl)) in
 883       let newproof, _ = ProofEngineHelpers.subst_meta_in_proof proof metano bo'[newmeta,context_for_newmeta,newmetaty] in
 884       newproof, [newmeta]
 885    in
 886    PET.mk_tactic letout_tac