cpc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pconv_5.ma".
  16 include "basic_2/rt_transition/cpm.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL R-CONVERSION FOR TERMS ************************)
  19
  20 definition cpc: sh → relation4 genv lenv term term ≝
  21                 λh,G,L,T1,T2. ❨G,L❩ ⊢ T1 ➡[h,0] T2 ∨ ❨G,L❩ ⊢ T2 ➡[h,0] T1.
  22
  23 interpretation
  24    "context-sensitive parallel r-conversion (term)"
  25    'PConv h G L T1 T2 = (cpc h G L T1 T2).
  26
  27 (* Basic properties *********************************************************)
  28
  29 lemma cpc_refl: ∀h,G,L. reflexive … (cpc h G L).
  30 /2 width=1 by or_intror/ qed.
  31
  32 lemma cpc_sym: ∀h,G,L. symmetric … (cpc h L G).
  33 #h #G #L #T1 #T2 * /2 width=1 by or_introl, or_intror/
  34 qed-.
  35
  36 (* Basic forward lemmas *****************************************************)
  37
  38 lemma cpc_fwd_cpr: ∀h,G,L,T1,T2. ❨G,L❩ ⊢ T1 ⬌[h] T2 →
  39                    ∃∃T. ❨G,L❩ ⊢ T1 ➡[h,0] T & ❨G,L❩ ⊢ T2 ➡[h,0] T.
  40 #h #G #L #T1 #T2 * /2 width=3 by ex2_intro/
  41 qed-.