helm/DEVEL/ocaml-http/http_daemon.mli

   1
   2 (*
   3   OCaml HTTP - do it yourself (fully OCaml) HTTP daemon
   4
   5   Copyright (C) <2002-2004> Stefano Zacchiroli <zack@cs.unibo.it>
   6
   7   This program is free software; you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation; either version 2 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program; if not, write to the Free Software
  19   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20 *)
  21
  22 (** Main OCaml HTTP module.
  23     Here you can find two set of functions:
  24     - functions which let you start an HTTP Daemon (start* functions)
  25     - facility functions which let you sent responses back to clients *)
  26
  27   (** send a CRLF sequence on the given output channel, this is mandatory after
  28   the last header was sent and before start sending the response body *)
  29 val send_CRLF: out_channel -> unit
  30
  31   (** send response status line, version is the http version used in response,
  32   either code or status must be given (not both, not none) which represent the
  33   HTTP response code, outchan is the output channel to which send status line *)
  34 val send_status_line:
  35   ?version:Http_types.version -> code:Http_types.status_code ->
  36   out_channel ->
  37     unit
  38
  39   (** like send_status_line but additionally will also send "Date" and "Server"
  40   standard headers *)
  41 val send_basic_headers:
  42   ?version: Http_types.version -> code:Http_types.status_code ->
  43   out_channel ->
  44     unit
  45
  46   (** send an HTTP header on outchan *)
  47 val send_header: header: string -> value: string -> out_channel -> unit
  48
  49   (** as send_header, but for a list of pairs <header, value> *)
  50 val send_headers: headers:(string * string) list -> out_channel -> unit
  51
  52 (*
  53   (** send a file through an out_channel, file can be passed as an in_channel
  54   (if 'file' is given) or as a file name (if 'name' is given) *)
  55 val send_file: ?name:string -> ?file:in_channel -> out_channel -> unit
  56 *)
  57   (** send a file through an out_channel *)
  58 val send_file: src:Http_types.file_source -> out_channel -> unit
  59
  60   (** high level response function, respond on outchan sending: basic headers
  61   (including Content-Length computed using 'body' argument), headers probided
  62   via 'headers' argument, body given via 'body' argument.  Default response
  63   status is 200, default response HTTP version is Http_common.http_version *)
  64 val respond:
  65   ?body:string -> ?headers:(string * string) list ->
  66   ?version:Http_types.version -> ?code:Http_types.status_code ->
  67   out_channel ->
  68     unit
  69
  70   (** send a 404 (not found) HTTP response *)
  71 val respond_not_found:
  72   url:string -> ?version: Http_types.version -> out_channel -> unit
  73
  74   (** send a 403 (forbidden) HTTP response *)
  75 val respond_forbidden:
  76   url:string -> ?version: Http_types.version -> out_channel -> unit
  77
  78   (** send a "redirection" class response, optional body argument contains data
  79   that will be displayed in the body of the response, default response status is
  80   301 (moved permanently), only redirection status are accepted by this
  81   function, other values will raise Failure *)
  82 val respond_redirect:
  83   location:string -> ?body:string ->
  84   ?version: Http_types.version -> ?code:Http_types.status_code ->
  85   out_channel ->
  86     unit
  87
  88   (** respond with a 401 (Unauthorized) response asking for authentication
  89   * against given realm (default is the server name) *)
  90 val respond_unauthorized:
  91   ?version: Http_types.version -> ?realm:string -> out_channel -> unit
  92
  93   (** send an "error" response (i.e. 400 <= status < 600), optional body
  94   argument as per send_redirect, default response status is 400 (bad request),
  95   only error status are accepted by this function, other values will
  96   raise Failure *)
  97 val respond_error:
  98   ?body:string ->
  99   ?version: Http_types.version -> ?code:Http_types.status_code ->
 100   out_channel ->
 101     unit
 102
 103   (** tipical static pages http daemon behaviour, if requested url is a file,
 104   return it, it it is a directory return a directory listing of it *)
 105 val respond_file:
 106   fname:string -> ?version: Http_types.version -> out_channel -> unit
 107
 108   (** respond using a prebuilt Http_types.response object *)
 109 val respond_with: Http_types.response -> out_channel -> unit
 110
 111   (** starts an HTTP daemon listening
 112   * @param addr adress on which daemon will be listening, can be both a numeric
 113   *   address (e.g. "127.0.0.1") and an hostname (e.g. "localhost"). Default is
 114   *   the wildcard address "0.0.0.0"
 115   * @param port TCP port on which the daemon will be listening. Default is the
 116   *   HTTP port 80
 117   * @param timeout timeout in seconds after which an incoming HTTP request will
 118   *   be terminated closing the corresponding TCP connection. Passing None will
 119   *   disable the timeout. Default is 5 minutes (300 seconds)
 120   * @param mode requests handling mode, it can have three different values.
 121   *   `Single -> all requests will be handled by the same process,
 122   *   `Fork   -> each request will be handled by a separate process
 123   *   `Thread -> each request will be handled by a separate thread
 124   *   Default is `Fork
 125   * @param root document root (i.e. directory to which ocaml http will chdir
 126   *   before starting handling requests). Default is current working directory
 127   * @param callback function which will be called each time a correct HTTP
 128   *   request will be received. 1st callback argument is the path requested by
 129   *   the HTTP client; 2nd argument is a list of pairs <parameter, value>
 130   *   representing decoded query string; 3rd argument is an output channel
 131   *   connected with the client
 132   *)
 133 val start:
 134   ?addr: string -> ?port: int ->
 135   ?timeout: int option -> ?mode: Http_types.daemon_mode -> ?root: string ->
 136   (string -> (string * string) list -> out_channel -> unit) ->
 137     unit
 138
 139   (** identical to 'start' above but callback receive two arguments, the second
 140   one is an out_channel as per 'start', but the secondo one is a Request.request
 141   object *)
 142 val start':
 143   ?addr: string -> ?port: int ->
 144   ?timeout: int option -> ?mode: Http_types.daemon_mode -> ?root: string ->
 145   (Http_types.request -> out_channel -> unit) ->
 146     unit
 147
 148   (** Object oriented interface to HTTP daemons.
 149   @param addr address on which daemon will listen for connections
 150   @param port port which daemon will bind
 151   see {! Http_types.daemon} *)
 152 class daemon:
 153   ?addr: string -> ?port: int ->
 154     unit ->
 155       Http_types.daemon
 156
 157   (** Trivial static pages HTTP daemon.
 158   Daemons created using this module will serve directory indexes and files found
 159   starting from the working directory *)
 160 module Trivial :
 161   sig
 162       (** callback function, exposed if you like to use it as a basis to define
 163       a more powerful daemon *)
 164     val callback : string -> 'a -> out_channel -> unit
 165
 166       (** start the "trivial" HTTP daemon *)
 167     val start : ?addr:string -> ?port:int -> unit -> unit
 168   end
 169