helm/http_getter/http_getter_common.ml

   1 (*
   2  * Copyright (C) 2003:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Http_getter_types;;
  30 open Printf;;
  31
  32 let string_of_ls_flag = function No -> "NO" | Yes -> "YES" | Ann -> "ANN"
  33 let string_of_encoding = function
  34   | Enc_normal -> "Normal"
  35   | Enc_gzipped -> "GZipped"
  36
  37 let is_cic_obj_uri uri = Pcre.pmatch ~pat:"^cic:" uri
  38 let is_theory_uri uri = Pcre.pmatch ~pat:"^theory:" uri
  39 let is_cic_uri uri = is_cic_obj_uri uri || is_theory_uri uri
  40 let is_nuprl_uri uri = Pcre.pmatch ~pat:"^nuprl:" uri
  41 let is_rdf_uri uri = Pcre.pmatch ~pat:"^helm:rdf(.*):(.*)//(.*)" uri
  42 let is_xsl_uri uri = Pcre.pmatch ~pat:"^\\w+\\.xsl" uri
  43
  44 let rec http_getter_uri_of_string = function
  45   | uri when is_rdf_uri uri ->
  46       (match Pcre.split ~pat:"//" uri with
  47       | [ prefix; uri ] ->
  48           let rest =
  49             match http_getter_uri_of_string uri with
  50             | Cic_uri xmluri -> xmluri
  51             | _ -> raise (Http_getter_invalid_URI uri)
  52           in
  53           Rdf_uri (prefix, rest)
  54       | _ -> raise (Http_getter_invalid_URI uri))
  55   | uri when is_cic_uri uri -> Cic_uri (Cic (Pcre.replace ~pat:"^cic:" uri))
  56   | uri when is_nuprl_uri uri -> Nuprl_uri (Pcre.replace ~pat:"^nuprl:" uri)
  57   | uri when is_theory_uri uri ->
  58       Cic_uri (Theory (Pcre.replace ~pat:"^theory:" uri))
  59   | uri -> raise (Http_getter_invalid_URI uri)
  60
  61 let patch_xml line =
  62   Pcre.replace
  63     ~pat:(sprintf "DOCTYPE (.*) SYSTEM\\s+\"%s/" Http_getter_env.dtd_base_url)
  64     ~templ:(
  65       sprintf "DOCTYPE $1 SYSTEM \"%s/getdtd?uri=" Http_getter_env.my_own_url)
  66     line
  67 let patch_xsl =
  68   let mk_patch_fun tag line =
  69     Pcre.replace
  70       ~pat:(sprintf "%s\\s+href=\"" tag)
  71       ~templ:(
  72         sprintf "%s href=\"%s/getxslt?uri=" tag Http_getter_env.my_own_url)
  73       line
  74   in
  75   let (patch_import, patch_include) =
  76     (mk_patch_fun "xsl:import", mk_patch_fun "xsl:include")
  77   in
  78   fun line -> patch_include (patch_import line)
  79 let patch_dtd line =
  80   Pcre.replace
  81     ~pat:"ENTITY (.*) SYSTEM\\s+\""
  82     ~templ:(
  83       sprintf "ENTITY $1 SYSTEM \"%s/getdtd?uri=" Http_getter_env.my_own_url)
  84     line
  85
  86 let pp_error s =
  87   sprintf "<html><body><h1>Http Getter error: %s</h1></body></html>" s
  88 let pp_internal_error s =
  89   sprintf "<html><body><h1>Http Getter Internal error: %s</h1></body></html>" s
  90 let pp_msg s = sprintf "<html><body><h1>%s</h1></body></html>" s
  91 let null_pp s = s
  92
  93 let mk_return_fun pp_fun contype msg outchan =
  94   Http_daemon.respond
  95     ~body:(pp_fun msg) ~headers:["Content-Type", contype] outchan
  96
  97 let return_html_error = mk_return_fun pp_error "text/html"
  98 let return_html_internal_error = mk_return_fun pp_internal_error "text/html"
  99 let return_html_msg = mk_return_fun pp_msg "text/html"
 100 let return_html_raw = mk_return_fun null_pp "text/html"
 101 let return_xml_raw = mk_return_fun null_pp "text/xml"
 102 let return_file
 103   ~fname ?contype ?contenc ?(patch_fun = fun x -> x) ?(gunzip = false) outchan
 104   =
 105   let headers =
 106     match (contype, contenc) with
 107     | (Some t, Some e) -> ["Content-Encoding", e; "Content-Type", t]
 108     | (Some t, None) -> ["Content-Type" , t]
 109     | (None, Some e) -> ["Content-Encoding", e]
 110     | (None, None) -> []
 111   in
 112   Http_daemon.send_basic_headers ~code:200 outchan;
 113   Http_daemon.send_headers headers outchan;
 114   Http_daemon.send_CRLF outchan;
 115   if gunzip then begin  (* gunzip needed, uncompress file, apply patch_fun to
 116                         it, compress the result and sent it to client *)
 117     let (tmp1, tmp2) =
 118       (Http_getter_misc.tempfile (), Http_getter_misc.tempfile ())
 119     in
 120     Http_getter_misc.gunzip ~keep:true ~output:tmp1 fname;  (* gunzip to tmp1 *)
 121     let new_file = open_out tmp2 in
 122     Http_getter_misc.iter_file  (* tmp2 = patch(tmp1) *)
 123       (fun line -> output_string new_file (patch_fun line ^ "\n"))
 124       tmp1;
 125     close_out new_file;
 126     Http_getter_misc.gzip ~output:tmp1 tmp2;  (* tmp1 = gzip(tmp2); rm tmp2 *)
 127     Http_getter_misc.iter_file  (* send tmp1 to client as is*)
 128       (fun line -> output_string outchan (line ^ "\n"))
 129       tmp1;
 130     Sys.remove tmp1       (* rm tmp1 *)
 131   end else  (* no need to gunzip, apply patch_fun directly to file *)
 132     Http_getter_misc.iter_file
 133       (fun line -> output_string outchan (patch_fun line ^ "\n"))
 134       fname
 135 ;;
 136 let return_400 body outchan = Http_daemon.respond_error ~code:400 ~body outchan
 137