helm/http_getter/http_getter_common.ml

   1 (*
   2  * Copyright (C) 2003:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Http_getter_types;;
  30 open Printf;;
  31
  32 let string_of_ls_flag = function No -> "NO" | Yes -> "YES" | Ann -> "ANN"
  33 let string_of_encoding = function
  34   | Enc_normal -> "Normal"
  35   | Enc_gzipped -> "GZipped"
  36
  37 let is_cic_obj_uri uri = Pcre.pmatch ~pat:"^cic:" uri
  38 let is_theory_uri uri = Pcre.pmatch ~pat:"^theory:" uri
  39 let is_cic_uri uri = is_cic_obj_uri uri || is_theory_uri uri
  40 let is_nuprl_uri uri = Pcre.pmatch ~pat:"^nuprl:" uri
  41 let is_rdf_uri uri = Pcre.pmatch ~pat:"^helm:rdf(.*):(.*)//(.*)" uri
  42 let is_xsl_uri uri = Pcre.pmatch ~pat:"^\\w+\\.xsl" uri
  43
  44 let is_blank_line =
  45   let blank_line_RE = Pcre.regexp "(^#)|(^\\s*$)" in
  46   fun line ->
  47     Pcre.pmatch ~rex:blank_line_RE line
  48
  49 let rec http_getter_uri_of_string = function
  50   | uri when is_rdf_uri uri ->
  51       (match Pcre.split ~pat:"//" uri with
  52       | [ prefix; uri ] ->
  53           let rest =
  54             match http_getter_uri_of_string uri with
  55             | Cic_uri xmluri -> xmluri
  56             | _ -> raise (Http_getter_invalid_URI uri)
  57           in
  58           Rdf_uri (prefix, rest)
  59       | _ -> raise (Http_getter_invalid_URI uri))
  60   | uri when is_cic_uri uri -> Cic_uri (Cic (Pcre.replace ~pat:"^cic:" uri))
  61   | uri when is_nuprl_uri uri -> Nuprl_uri (Pcre.replace ~pat:"^nuprl:" uri)
  62   | uri when is_theory_uri uri ->
  63       Cic_uri (Theory (Pcre.replace ~pat:"^theory:" uri))
  64   | uri -> raise (Http_getter_invalid_URI uri)
  65
  66 let patch_xml line =
  67   Pcre.replace
  68     ~pat:(sprintf "DOCTYPE (.*) SYSTEM\\s+\"%s/" Http_getter_env.dtd_base_url)
  69     ~templ:(
  70       sprintf "DOCTYPE $1 SYSTEM \"%s/getdtd?uri=" Http_getter_env.my_own_url)
  71     line
  72 let patch_xsl =
  73   let mk_patch_fun tag line =
  74     Pcre.replace
  75       ~pat:(sprintf "%s\\s+href=\"" tag)
  76       ~templ:(
  77         sprintf "%s href=\"%s/getxslt?uri=" tag Http_getter_env.my_own_url)
  78       line
  79   in
  80   let (patch_import, patch_include) =
  81     (mk_patch_fun "xsl:import", mk_patch_fun "xsl:include")
  82   in
  83   fun line -> patch_include (patch_import line)
  84 let patch_dtd line =
  85   Pcre.replace
  86     ~pat:"ENTITY (.*) SYSTEM\\s+\""
  87     ~templ:(
  88       sprintf "ENTITY $1 SYSTEM \"%s/getdtd?uri=" Http_getter_env.my_own_url)
  89     line
  90
  91 let pp_error s =
  92   sprintf "<html><body><h1>Http Getter error: %s</h1></body></html>" s
  93 let pp_internal_error s =
  94   sprintf "<html><body><h1>Http Getter Internal error: %s</h1></body></html>" s
  95 let pp_msg s = sprintf "<html><body><h1>%s</h1></body></html>" s
  96 let null_pp s = s
  97
  98 let mk_return_fun pp_fun contype msg outchan =
  99   Http_daemon.respond
 100     ~body:(pp_fun msg) ~headers:["Content-Type", contype] outchan
 101
 102 let return_html_error = mk_return_fun pp_error "text/html"
 103 let return_html_internal_error = mk_return_fun pp_internal_error "text/html"
 104 let return_html_msg = mk_return_fun pp_msg "text/html"
 105 let return_html_raw = mk_return_fun null_pp "text/html"
 106 let return_xml_raw = mk_return_fun null_pp "text/xml"
 107 let return_file ~fname ?contype ?contenc ?(patch_fun = fun x -> x) outchan =
 108   let headers =
 109     match (contype, contenc) with
 110     | (Some t, Some e) -> ["Content-Encoding", e; "Content-Type", t]
 111     | (Some t, None) -> ["Content-Type" , t]
 112     | (None, Some e) -> ["Content-Encoding", e]
 113     | (None, None) -> []
 114   in
 115   Http_daemon.send_basic_headers ~code:200 outchan;
 116   Http_daemon.send_headers headers outchan;
 117   Http_daemon.send_CRLF outchan;
 118   Http_getter_misc.iter_file
 119     (fun line -> output_string outchan (patch_fun line ^ "\n"))
 120     fname
 121 let return_400 body outchan = Http_daemon.respond_error ~code:400 ~body outchan
 122