helm/matita/library/algebra/monoids.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/algebra/monoids/".
  16
  17 include "algebra/semigroups.ma".
  18
  19 record isMonoid (SS:SemiGroup) (e:SS) : Prop ≝
  20  { e_is_left_unit: is_left_unit SS e;
  21    e_is_right_unit: is_right_unit SS e
  22  }.
  23
  24 record Monoid : Type ≝
  25  { semigroup: SemiGroup;
  26    e: semigroup;
  27    properties: isMonoid ? e
  28  }.
  29
  30 coercion cic:/matita/algebra/monoids/semigroup.con.
  31
  32 notation "hvbox(! \sub S)"
  33 for @{ 'munit $S }.
  34
  35 interpretation "Monoid unit" 'munit S =
  36  (cic:/matita/algebra/monoids/e.con S).
  37
  38 notation < "M"
  39 for @{ 'semigroup $M }.
  40
  41 interpretation "Semigroup coercion" 'semigroup M =
  42  (cic:/matita/algebra/monoids/semigroup.con M).
  43
  44 definition is_left_inverse ≝
  45  λM:Monoid.
  46   λopp: M → M.
  47    ∀x:M. op M (opp x) x = ! \sub M.
  48
  49 definition is_right_inverse ≝
  50  λM:Monoid.
  51   λopp: M → M.
  52    ∀x:M. op M x (opp x) = ! \sub M.
  53
  54 theorem is_left_inverse_to_is_right_inverse_to_eq:
  55  ∀M:Monoid. ∀oppL,oppR.
  56   is_left_inverse M oppL → is_right_inverse M oppR →
  57    ∀x:M. oppL x = oppR x.
  58  intros;
  59  generalize in match (H x); intro;
  60  generalize in match (eq_f ? ? (λy. op M y (oppR x)) ? ? H2);
  61  simplify; fold simplify (op M);
  62  intro; clear H2;
  63  generalize in match (properties (semigroup M));
  64  fold simplify (Type_of_Monoid M);
  65  intro;
  66  unfold isSemiGroup in H2; unfold associative in H2;
  67  rewrite > H2 in H3; clear H2;
  68  rewrite > H1 in H3;
  69  rewrite > (e_is_left_unit ? ? (properties M)) in H3;
  70  rewrite > (e_is_right_unit ? ? (properties M)) in H3;
  71  assumption.
  72 qed.
  73