helm/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27 open MatitaTypes
  28
  29 module TA = GrafiteAst
  30
  31 let debug = false
  32 let debug_print = if debug then prerr_endline else ignore
  33
  34   (** raised when one of the script margins (top or bottom) is reached *)
  35 exception Margin
  36
  37 let safe_substring s i j =
  38   try String.sub s i j with Invalid_argument _ -> assert false
  39
  40 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  41 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)((.|\n)*)"
  42 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  43 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  44 let newline_RE = Pcre.regexp "\n"
  45
  46 let comment str =
  47   if Pcre.pmatch ~rex:multiline_RE str then
  48     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  49   else
  50     "\n(**\n" ^ str ^ "\n*)"
  51
  52 let first_line s =
  53   let s = Pcre.replace ~rex:heading_nl_RE s in
  54   try
  55     let nl_pos = String.index s '\n' in
  56     String.sub s 0 nl_pos
  57   with Not_found -> s
  58
  59   (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
  60 let goal_ast n =
  61   let module A = GrafiteAst in
  62   let loc = DisambiguateTypes.dummy_floc in
  63   A.Executable (loc, A.Tactical (loc,
  64     A.Tactic (loc, A.Goal (loc, n)),
  65     Some (A.Dot loc)))
  66
  67 type guistuff = {
  68   mathviewer:MatitaTypes.mathViewer;
  69   urichooser: UriManager.uri list -> UriManager.uri list;
  70   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  71   develcreator: containing:string option -> unit;
  72   mutable filenamedata: string option * MatitamakeLib.development option
  73 }
  74
  75 let eval_with_engine guistuff status user_goal parsed_text st =
  76   let module TAPp = GrafiteAstPp in
  77   let include_ =
  78     match guistuff.filenamedata with
  79     | None,None -> []
  80     | None,Some devel -> [MatitamakeLib.root_for_development devel ]
  81     | Some f,_ ->
  82         match MatitamakeLib.development_for_dir (Filename.dirname f) with
  83         | None -> []
  84         | Some devel -> [MatitamakeLib.root_for_development devel ]
  85   in
  86   let parsed_text_length = String.length parsed_text in
  87   let loc, ex =
  88     match st with TA.Executable (loc,ex) -> loc, ex | _ -> assert false in
  89   let initial_space,parsed_text =
  90    try
  91     let pieces = Pcre.extract ~rex:heading_nl_RE' parsed_text in
  92      pieces.(1), pieces.(2)
  93    with
  94     Not_found -> "", parsed_text in
  95   (* we add the goal command if needed *)
  96   let inital_space,new_status,new_status_and_text_list' =
  97     match status.proof_status with
  98 (*     | Incomplete_proof { stack = stack }
  99       when not (List.mem user_goal (Continuationals.head_goals stack)) ->
 100         let status =
 101           MatitaEngine.eval_ast ~include_paths:include_
 102             ~do_heavy_checks:true status (goal_ast user_goal)
 103         in
 104         let initial_space = if initial_space = "" then "\n" else initial_space
 105         in
 106         "\n", status,
 107         [ status,
 108           initial_space ^ TAPp.pp_tactical (TA.Select (loc, [user_goal])) ] *)
 109       | _ -> initial_space,status,[] in
 110   let new_status =
 111     MatitaEngine.eval_ast
 112       ~include_paths:include_ ~do_heavy_checks:true new_status st
 113   in
 114   let new_aliases =
 115     match ex with
 116       | TA.Command (_, TA.Alias _)
 117       | TA.Command (_, TA.Include _)
 118       | TA.Command (_, TA.Interpretation _) -> []
 119       | _ -> MatitaSync.alias_diff ~from:status new_status
 120   in
 121   (* we remove the defined object since we consider them "automatic aliases" *)
 122   let dummy_st =
 123     TA.Comment (DisambiguateTypes.dummy_floc,
 124       TA.Note (DisambiguateTypes.dummy_floc, ""))
 125   in
 126   let initial_space,status,new_status_and_text_list_rev =
 127     let module DTE = DisambiguateTypes.Environment in
 128     let module UM = UriManager in
 129     List.fold_left (
 130       fun (initial_space,status,acc) (k,((v,_) as value)) ->
 131         let b =
 132           try
 133             let v = UM.strip_xpointer (UM.uri_of_string v) in
 134             List.mem v new_status.objects
 135           with UM.IllFormedUri _ -> false
 136         in
 137         if b then
 138           initial_space,status,acc
 139         else
 140          let new_text =
 141           let initial_space =
 142            if initial_space = "" then "\n" else initial_space in
 143             initial_space ^
 144              DisambiguatePp.pp_environment
 145               (DisambiguateTypes.Environment.add k value
 146                 DisambiguateTypes.Environment.empty) in
 147          let new_status =
 148           MatitaSync.set_proof_aliases status [k,value]
 149          in
 150           "\n",new_status,((new_status, (new_text, dummy_st))::acc)
 151     ) (initial_space,status,[]) new_aliases in
 152   let parsed_text = initial_space ^ parsed_text in
 153   let res =
 154    List.rev new_status_and_text_list_rev @ new_status_and_text_list' @
 155     [new_status, (parsed_text, st)]
 156   in
 157    res,parsed_text_length
 158
 159 let eval_with_engine guistuff status user_goal parsed_text st =
 160   try
 161     eval_with_engine guistuff status user_goal parsed_text st
 162   with
 163   | MatitaEngine.UnableToInclude what
 164   | MatitaEngine.IncludedFileNotCompiled what as exc ->
 165       let compile_needed_and_go_on d =
 166         let target = what in
 167         let refresh_cb () =
 168           while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 169         in
 170         if not(MatitamakeLib.build_development_in_bg ~target refresh_cb d) then
 171           raise exc
 172         else
 173           eval_with_engine guistuff status user_goal parsed_text st
 174       in
 175       let do_nothing () = [], 0 in
 176       let handle_with_devel d =
 177         let name = MatitamakeLib.name_for_development d in
 178         let title = "Unable to include " ^ what in
 179         let message =
 180           what ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
 181           "<i>Should I compile it and Its dependencies?</i>"
 182         in
 183         (match guistuff.ask_confirmation ~title ~message with
 184         | `YES -> compile_needed_and_go_on d
 185         | `NO -> raise exc
 186         | `CANCEL -> do_nothing ())
 187       in
 188       let handle_without_devel filename =
 189         let title = "Unable to include " ^ what in
 190         let message =
 191          what ^ " is <b>not</b> handled by a development.\n" ^
 192          "All dependencies are automatically solved for a development.\n\n" ^
 193          "<i>Do you want to set up a development?</i>"
 194         in
 195         (match guistuff.ask_confirmation ~title ~message with
 196         | `YES ->
 197             (match filename with
 198             | Some f ->
 199                 guistuff.develcreator ~containing:(Some (Filename.dirname f))
 200             | None -> guistuff.develcreator ~containing:None);
 201             do_nothing ()
 202         | `NO -> raise exc
 203         | `CANCEL -> do_nothing())
 204       in
 205       match guistuff.filenamedata with
 206       | None,None -> handle_without_devel None
 207       | None,Some d -> handle_with_devel d
 208       | Some f,_ ->
 209           match MatitamakeLib.development_for_dir (Filename.dirname f) with
 210           | None -> handle_without_devel (Some f)
 211           | Some d -> handle_with_devel d
 212 ;;
 213
 214 let disambiguate_macro_term term status user_goal =
 215   let module MD = MatitaDisambiguator in
 216   let dbd = LibraryDb.instance () in
 217   let metasenv = MatitaTypes.get_proof_metasenv status in
 218   let context = MatitaTypes.get_proof_context status user_goal in
 219   let interps =
 220    MD.disambiguate_term ~dbd ~context ~metasenv ~aliases:status.aliases
 221     ~universe:(Some status.multi_aliases) term in
 222   match interps with
 223   | [_,_,x,_], _ -> x
 224   | _ -> assert false
 225
 226 let eval_macro guistuff status user_goal unparsed_text parsed_text script mac =
 227   let module TAPp = GrafiteAstPp in
 228   let module MQ = MetadataQuery in
 229   let module MDB = LibraryDb in
 230   let module CTC = CicTypeChecker in
 231   let module CU = CicUniv in
 232   (* no idea why ocaml wants this *)
 233   let parsed_text_length = String.length parsed_text in
 234   let dbd = LibraryDb.instance () in
 235   match mac with
 236   (* WHELP's stuff *)
 237   | TA.WMatch (loc, term) ->
 238       let term = disambiguate_macro_term term status user_goal in
 239       let l =  Whelp.match_term ~dbd term in
 240       let query_url =
 241         MatitaMisc.strip_suffix ~suffix:"."
 242           (HExtlib.trim_blanks unparsed_text)
 243       in
 244       let entry = `Whelp (query_url, l) in
 245       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 246       [], parsed_text_length
 247   | TA.WInstance (loc, term) ->
 248       let term = disambiguate_macro_term term status user_goal in
 249       let l = Whelp.instance ~dbd term in
 250       let entry = `Whelp (TAPp.pp_macro_cic (TA.WInstance (loc, term)), l) in
 251       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 252       [], parsed_text_length
 253   | TA.WLocate (loc, s) ->
 254       let l = Whelp.locate ~dbd s in
 255       let entry = `Whelp (TAPp.pp_macro_cic (TA.WLocate (loc, s)), l) in
 256       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 257       [], parsed_text_length
 258   | TA.WElim (loc, term) ->
 259       let term = disambiguate_macro_term term status user_goal in
 260       let uri =
 261         match term with
 262         | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None
 263         | _ -> failwith "Not a MutInd"
 264       in
 265       let l = Whelp.elim ~dbd uri in
 266       let entry = `Whelp (TAPp.pp_macro_cic (TA.WElim (loc, term)), l) in
 267       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 268       [], parsed_text_length
 269   | TA.WHint (loc, term) ->
 270       let term = disambiguate_macro_term term status user_goal in
 271       let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
 272       let l = List.map fst (MQ.experimental_hint ~dbd s) in
 273       let entry = `Whelp (TAPp.pp_macro_cic (TA.WHint (loc, term)), l) in
 274       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 275       [], parsed_text_length
 276   (* REAL macro *)
 277   | TA.Hint loc ->
 278       let proof = MatitaTypes.get_current_proof status in
 279       let proof_status = proof, user_goal in
 280       let l = List.map fst (MQ.experimental_hint ~dbd proof_status) in
 281       let selected = guistuff.urichooser l in
 282       (match selected with
 283       | [] -> [], parsed_text_length
 284       | [uri] ->
 285           let suri = UriManager.string_of_uri uri in
 286           let ast =
 287             TA.Executable (loc, (TA.Tactical (loc,
 288               TA.Tactic (loc,
 289                 TA.Apply (loc, CicNotationPt.Uri (suri, None))),
 290                 Some (TA.Dot loc))))
 291           in
 292         let new_status = MatitaEngine.eval_ast status ast in
 293         let extra_text =
 294           comment parsed_text ^
 295           "\n" ^ TAPp.pp_statement ast
 296         in
 297         [ new_status , (extra_text, ast) ], parsed_text_length
 298       | _ ->
 299           HLog.error
 300             "The result of the urichooser should be only 1 uri, not:\n";
 301           List.iter (
 302             fun u -> HLog.error (UriManager.string_of_uri u ^ "\n")
 303           ) selected;
 304           assert false)
 305   | TA.Check (_,term) ->
 306       let metasenv = MatitaTypes.get_proof_metasenv status in
 307       let context = MatitaTypes.get_proof_context status user_goal in
 308       let interps =
 309         MatitaDisambiguator.disambiguate_term ~dbd ~context ~metasenv
 310          ~aliases:status.aliases ~universe:(Some status.multi_aliases) term
 311       in
 312       let _, metasenv , term, ugraph =
 313         match interps with
 314         | [x], _ -> x
 315         | _ -> assert false
 316       in
 317       let ty,_ = CTC.type_of_aux' metasenv context term ugraph in
 318       let t_and_ty = Cic.Cast (term,ty) in
 319       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 320       [], parsed_text_length
 321 (*   | TA.Abort _ ->
 322       let rec go_back () =
 323         let status = script#status.proof_status in
 324         match status with
 325         | No_proof -> ()
 326         | _ -> script#retract ();go_back()
 327       in
 328       [], parsed_text_length, Some go_back
 329   | TA.Redo (_, Some i) ->  [], parsed_text_length,
 330       Some (fun () -> for j = 1 to i do advance () done)
 331   | TA.Redo (_, None) ->   [], parsed_text_length,
 332       Some (fun () -> advance ())
 333   | TA.Undo (_, Some i) ->  [], parsed_text_length,
 334       Some (fun () -> for j = 1 to i do script#retract () done)
 335   | TA.Undo (_, None) -> [], parsed_text_length,
 336       Some (fun () -> script#retract ()) *)
 337   (* TODO *)
 338   | TA.Quit _ -> failwith "not implemented"
 339   | TA.Print (_,kind) -> failwith "not implemented"
 340   | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
 341   | TA.Search_term (_, search_kind, term) -> failwith "not implemented"
 342
 343 let eval_executable guistuff status user_goal unparsed_text parsed_text script
 344   ex
 345 =
 346   let module TAPp = GrafiteAstPp in
 347   let module MD = MatitaDisambiguator in
 348   let module ML = MatitaMisc in
 349   match ex with
 350   | TA.Command (loc, _) | TA.Tactical (loc, _, _) ->
 351       (try
 352         (match MatitaMisc.baseuri_of_baseuri_decl (TA.Executable (loc,ex)) with
 353         | None -> ()
 354         | Some u ->
 355             if not (MatitaMisc.is_empty u) then
 356               match
 357                 guistuff.ask_confirmation
 358                   ~title:"Baseuri redefinition"
 359                   ~message:(
 360                     "Baseuri " ^ u ^ " already exists.\n" ^
 361                     "Do you want to redefine the corresponding "^
 362                     "part of the library?")
 363               with
 364               | `YES ->
 365                   let basedir = Helm_registry.get "matita.basedir" in
 366                    LibraryClean.clean_baseuris ~basedir [u]
 367               | `NO -> ()
 368               | `CANCEL -> raise MatitaTypes.Cancel);
 369         eval_with_engine
 370           guistuff status user_goal parsed_text (TA.Executable (loc, ex))
 371       with MatitaTypes.Cancel -> [], 0)
 372   | TA.Macro (_,mac) ->
 373       eval_macro guistuff status user_goal unparsed_text parsed_text script mac
 374
 375 let rec eval_statement (buffer : GText.buffer) guistuff status user_goal
 376  script statement
 377 =
 378   let st, unparsed_text =
 379     match statement with
 380     | `Raw text ->
 381         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 382         GrafiteParser.parse_statement (Ulexing.from_utf8_string text), text
 383     | `Ast (st, text) -> st, text
 384   in
 385   let text_of_loc loc =
 386     let parsed_text_length = snd (HExtlib.loc_of_floc loc) in
 387     let parsed_text = safe_substring unparsed_text 0 parsed_text_length in
 388     parsed_text, parsed_text_length
 389   in
 390   match st with
 391   | GrafiteAst.Comment (loc, _) ->
 392       let parsed_text, parsed_text_length = text_of_loc loc in
 393       let remain_len = String.length unparsed_text - parsed_text_length in
 394       let s = String.sub unparsed_text parsed_text_length remain_len in
 395       let s,len =
 396        try
 397         eval_statement buffer guistuff status user_goal script
 398          (`Raw s)
 399        with
 400           HExtlib.Localized (floc, exn) ->
 401            HExtlib.raise_localized_exception ~offset:parsed_text_length floc exn
 402         | MatitaDisambiguator.DisambiguationError (offset,errorll) ->
 403            raise
 404             (MatitaDisambiguator.DisambiguationError
 405               (offset+parsed_text_length, errorll))
 406       in
 407       (match s with
 408       | (status, (text, ast)) :: tl ->
 409           ((status, (parsed_text ^ text, ast))::tl), (parsed_text_length + len)
 410       | [] -> [], 0)
 411   | GrafiteAst.Executable (loc, ex) ->
 412       let parsed_text, parsed_text_length = text_of_loc loc in
 413       eval_executable guistuff status user_goal unparsed_text parsed_text
 414         script ex
 415
 416 let fresh_script_id =
 417   let i = ref 0 in
 418   fun () -> incr i; !i
 419
 420 class script  ~(source_view: GSourceView.source_view)
 421               ~(init: MatitaTypes.status)
 422               ~(mathviewer: MatitaTypes.mathViewer)
 423               ~set_star
 424               ~ask_confirmation
 425               ~urichooser
 426               ~develcreator
 427               () =
 428 let buffer = source_view#buffer in
 429 let source_buffer = source_view#source_buffer in
 430 object (self)
 431   val scriptId = fresh_script_id ()
 432
 433   val guistuff = {
 434     mathviewer = mathviewer;
 435     urichooser = urichooser;
 436     ask_confirmation = ask_confirmation;
 437     develcreator = develcreator;
 438     filenamedata = (None, None)}
 439
 440   method private getFilename =
 441     match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
 442
 443   method filename = self#getFilename
 444
 445   method private ppFilename =
 446     match guistuff.filenamedata with
 447     | Some f,_ -> f
 448     | None,_ -> sprintf ".unnamed%d.ma" scriptId
 449
 450   initializer
 451     ignore (GMain.Timeout.add ~ms:300000
 452        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 453     ignore (buffer#connect#modified_changed
 454       (fun _ -> set_star (Filename.basename self#ppFilename) buffer#modified))
 455
 456   val mutable statements = [];    (** executed statements *)
 457   val mutable history = [ init ];
 458     (** list of states before having executed statements. Head element of this
 459       * list is the current state, last element is the state at the beginning of
 460       * the script.
 461       * Invariant: this list length is 1 + length of statements *)
 462
 463   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 464   val mutable userGoal = ~-1
 465
 466   (** text mark and tag representing locked part of a script *)
 467   val locked_mark =
 468     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 469   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 470   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 471
 472   method locked_mark = locked_mark
 473   method locked_tag = locked_tag
 474   method error_tag = error_tag
 475
 476     (* history can't be empty, the invariant above grant that it contains at
 477      * least the init status *)
 478   method status = match history with hd :: _ -> hd | _ -> assert false
 479
 480   method private _advance ?statement () =
 481     let rec aux st =
 482       let (entries, parsed_len) =
 483         eval_statement buffer guistuff self#status userGoal self st
 484       in
 485       let (new_statuses, new_statements, new_asts) =
 486         let statuses, statements = List.split entries in
 487         let texts, asts = List.split statements in
 488         statuses, texts, asts
 489       in
 490       history <- List.rev new_statuses @ history;
 491       statements <- List.rev new_statements @ statements;
 492       let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 493       let new_text = String.concat "" new_statements in
 494       if statement <> None then
 495        buffer#insert ~iter:start new_text
 496       else
 497         let s = match st with `Raw s | `Ast (_, s) -> s in
 498         if new_text <> String.sub s 0 parsed_len then
 499         begin
 500           let stop = start#copy#forward_chars parsed_len in
 501           buffer#delete ~start ~stop;
 502           buffer#insert ~iter:start new_text;
 503         end;
 504       self#moveMark (String.length new_text);
 505       (*
 506       (match List.rev new_asts with (* advance again on punctuation *)
 507       | TA.Executable (_, TA.Tactical (_, tac, _)) :: _ ->
 508           let baseoffset =
 509             (buffer#get_iter_at_mark (`MARK locked_mark))#offset
 510           in
 511           let text = self#getFuture in
 512           (try
 513             (match parse_statement baseoffset 0 buffer text with
 514             | TA.Executable (loc, TA.Tactical (_, tac, None)) as st
 515               when GrafiteAst.is_punctuation tac ->
 516                 let len = snd (CicNotationPt.loc_of_floc loc) in
 517                 aux (`Ast (st, String.sub text 0 len))
 518             | _ -> ())
 519           with CicNotationParser.Parse_error _ | End_of_file -> ())
 520       | _ -> ())
 521       *)
 522     in
 523     let s = match statement with Some s -> s | None -> self#getFuture in
 524     HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 525     (try aux (`Raw s) with End_of_file -> raise Margin)
 526
 527   method private _retract offset status new_statements new_history =
 528     let cur_status = match history with s::_ -> s | [] -> assert false in
 529     MatitaSync.time_travel ~present:cur_status ~past:status;
 530     statements <- new_statements;
 531     history <- new_history;
 532     self#moveMark (- offset)
 533
 534   method advance ?statement () =
 535     try
 536       self#_advance ?statement ();
 537       self#notify
 538     with
 539     | Margin -> self#notify
 540     | exc -> self#notify; raise exc
 541
 542   method retract () =
 543     try
 544       let cmp,new_statements,new_history,status =
 545        match statements,history with
 546           stat::statements, _::(status::_ as history) ->
 547            String.length stat, statements, history, status
 548        | [],[_] -> raise Margin
 549        | _,_ -> assert false
 550       in
 551        self#_retract cmp status new_statements new_history;
 552        self#notify
 553     with
 554     | Margin -> self#notify
 555     | exc -> self#notify; raise exc
 556
 557   method private getFuture =
 558     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 559       ~stop:buffer#end_iter ()
 560
 561
 562   (** @param rel_offset relative offset from current position of locked_mark *)
 563   method private moveMark rel_offset =
 564     let mark = `MARK locked_mark in
 565     let old_insert = buffer#get_iter_at_mark `INSERT in
 566     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 567     let current_mark_pos = buffer#get_iter_at_mark mark in
 568     let new_mark_pos =
 569       match rel_offset with
 570       | 0 -> current_mark_pos
 571       | n when n > 0 -> current_mark_pos#forward_chars n
 572       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 573     in
 574     buffer#move_mark mark ~where:new_mark_pos;
 575     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 576     buffer#move_mark `INSERT old_insert;
 577     let mark_position = buffer#get_iter_at_mark mark in
 578     if source_view#move_mark_onscreen mark then
 579      begin
 580       buffer#move_mark mark mark_position;
 581       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 582      end;
 583     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 584
 585   method clean_dirty_lock =
 586     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 587     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 588     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 589
 590   val mutable observers = []
 591
 592   method addObserver (o: MatitaTypes.status -> unit) =
 593     observers <- o :: observers
 594
 595   method private notify =
 596     let status = self#status in
 597     List.iter (fun o -> o status) observers
 598
 599   method loadFromFile f =
 600     buffer#set_text (HExtlib.input_file f);
 601     self#reset_buffer;
 602     buffer#set_modified false
 603
 604   method assignFileName file =
 605     let abspath = MatitaMisc.absolute_path file in
 606     let devel = MatitamakeLib.development_for_dir (Filename.dirname abspath) in
 607     guistuff.filenamedata <- Some abspath, devel
 608
 609   method saveToFile () =
 610     let oc = open_out self#getFilename in
 611     output_string oc (buffer#get_text ~start:buffer#start_iter
 612                         ~stop:buffer#end_iter ());
 613     close_out oc;
 614     buffer#set_modified false
 615
 616   method private _saveToBackupFile () =
 617     if buffer#modified then
 618       begin
 619         let f = self#ppFilename ^ "~" in
 620         let oc = open_out f in
 621         output_string oc (buffer#get_text ~start:buffer#start_iter
 622                             ~stop:buffer#end_iter ());
 623         close_out oc;
 624         HLog.debug ("backup " ^ f ^ " saved")
 625       end
 626
 627   method private goto_top =
 628     MatitaSync.time_travel ~present:self#status ~past:init
 629
 630   method private reset_buffer =
 631     statements <- [];
 632     history <- [ init ];
 633     userGoal <- ~-1;
 634     self#notify;
 635     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 636     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 637
 638   method reset () =
 639     self#reset_buffer;
 640     source_buffer#begin_not_undoable_action ();
 641     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 642     source_buffer#end_not_undoable_action ();
 643     buffer#set_modified false
 644
 645   method template () =
 646     let template = HExtlib.input_file BuildTimeConf.script_template in
 647     buffer#insert ~iter:(buffer#get_iter `START) template;
 648     guistuff.filenamedata <-
 649       (None,MatitamakeLib.development_for_dir (Unix.getcwd ()));
 650     buffer#set_modified false;
 651     set_star (Filename.basename self#ppFilename) false
 652
 653   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 654     let old_locked_mark =
 655      `MARK
 656        (buffer#create_mark ~name:"old_locked_mark"
 657          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 658     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 659     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 660     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 661     match pos with
 662     | `Top ->
 663         dispose_old_locked_mark ();
 664         self#goto_top;
 665         self#reset_buffer;
 666         self#notify
 667     | `Bottom ->
 668         (try
 669           let rec dowhile () =
 670             self#_advance ();
 671             let newpos = getpos () in
 672             if (getoldpos ())#compare newpos < 0 then
 673               begin
 674                 buffer#move_mark old_locked_mark newpos;
 675                 dowhile ()
 676               end
 677           in
 678           dowhile ();
 679           dispose_old_locked_mark ();
 680           self#notify
 681         with
 682         | Margin -> dispose_old_locked_mark (); self#notify
 683         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 684     | `Cursor ->
 685         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 686         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 687         let remember =
 688          `MARK
 689            (buffer#create_mark ~name:"initial_insert"
 690              ~left_gravity:true (cursor_iter ())) in
 691         let dispose_remember () = buffer#delete_mark remember in
 692         let remember_iter () =
 693          buffer#get_iter_at_mark (`NAME "initial_insert") in
 694         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 695         let icmp = cmp () in
 696         let forward_until_cursor () = (* go forward until locked > cursor *)
 697           let rec aux () =
 698             self#_advance ();
 699             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 700             then
 701              begin
 702               buffer#move_mark old_locked_mark (getpos ());
 703               aux ()
 704              end
 705           in
 706           aux ()
 707         in
 708         let rec back_until_cursor len = (* go backward until locked < cursor *)
 709          function
 710             statements, (status::_ as history) when len <= 0 ->
 711              self#_retract (icmp - len) status statements history
 712           | statement::tl1, _::tl2 ->
 713              back_until_cursor (len - String.length statement) (tl1,tl2)
 714           | _,_ -> assert false
 715         in
 716         (try
 717           begin
 718            if icmp < 0 then       (* locked < cursor *)
 719              (forward_until_cursor (); self#notify)
 720            else if icmp > 0 then  (* locked > cursor *)
 721              (back_until_cursor icmp (statements,history); self#notify)
 722            else                  (* cursor = locked *)
 723                ()
 724           end ;
 725           dispose_remember ();
 726           dispose_old_locked_mark ();
 727         with
 728         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 729         | exc -> dispose_remember (); dispose_old_locked_mark ();
 730                  self#notify; raise exc)
 731
 732   method onGoingProof () =
 733     match self#status.proof_status with
 734     | No_proof | Proof _ -> false
 735     | Incomplete_proof _ -> true
 736     | Intermediate _ -> assert false
 737
 738 (*   method proofStatus = MatitaTypes.get_proof_status self#status *)
 739   method proofMetasenv = MatitaTypes.get_proof_metasenv self#status
 740   method proofContext = MatitaTypes.get_proof_context self#status userGoal
 741   method proofConclusion = MatitaTypes.get_proof_conclusion self#status userGoal
 742   method stack = MatitaTypes.get_stack self#status
 743   method setGoal n = userGoal <- n
 744   method goal = userGoal
 745
 746   method eos =
 747     let s = self#getFuture in
 748     let rec is_there_and_executable s =
 749       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 750       let st = GrafiteParser.parse_statement (Ulexing.from_utf8_string s) in
 751       match st with
 752       | GrafiteAst.Comment (loc,_)->
 753           let parsed_text_length = snd (HExtlib.loc_of_floc loc) in
 754           let remain_len = String.length s - parsed_text_length in
 755           let next = String.sub s parsed_text_length remain_len in
 756           is_there_and_executable next
 757       | GrafiteAst.Executable (loc, ex) -> false
 758     in
 759     try
 760       is_there_and_executable s
 761     with
 762     | CicNotationParser.Parse_error _ -> false
 763     | Margin | End_of_file -> true
 764
 765   (* debug *)
 766   method dump () =
 767     HLog.debug "script status:";
 768     HLog.debug ("history size: " ^ string_of_int (List.length history));
 769     HLog.debug (sprintf "%d statements:" (List.length statements));
 770     List.iter HLog.debug statements;
 771     HLog.debug ("Current file name: " ^
 772       (match guistuff.filenamedata with
 773       |None,_ -> "[ no name ]"
 774       | Some f,_ -> f));
 775
 776 end
 777
 778 let _script = ref None
 779
 780 let script ~source_view ~init ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
 781 =
 782   let s = new script
 783     ~source_view ~init ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star ()
 784   in
 785   _script := Some s;
 786   s
 787
 788 let current () = match !_script with None -> assert false | Some s -> s
 789