helm/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27 open GrafiteTypes
  28
  29 module TA = GrafiteAst
  30
  31 let debug = false
  32 let debug_print = if debug then prerr_endline else ignore
  33
  34   (** raised when one of the script margins (top or bottom) is reached *)
  35 exception Margin
  36
  37 let safe_substring s i j =
  38   try String.sub s i j with Invalid_argument _ -> assert false
  39
  40 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  41 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)((.|\n)*)"
  42 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  43 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  44 let newline_RE = Pcre.regexp "\n"
  45
  46 let comment str =
  47   if Pcre.pmatch ~rex:multiline_RE str then
  48     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  49   else
  50     "\n(**\n" ^ str ^ "\n*)"
  51
  52 let first_line s =
  53   let s = Pcre.replace ~rex:heading_nl_RE s in
  54   try
  55     let nl_pos = String.index s '\n' in
  56     String.sub s 0 nl_pos
  57   with Not_found -> s
  58
  59   (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
  60 let goal_ast n =
  61   let module A = GrafiteAst in
  62   let loc = DisambiguateTypes.dummy_floc in
  63   A.Executable (loc, A.Tactical (loc,
  64     A.Tactic (loc, A.Goal (loc, n)),
  65     Some (A.Dot loc)))
  66
  67 type guistuff = {
  68   mathviewer:MatitaTypes.mathViewer;
  69   urichooser: UriManager.uri list -> UriManager.uri list;
  70   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  71   develcreator: containing:string option -> unit;
  72   mutable filenamedata: string option * MatitamakeLib.development option
  73 }
  74
  75 let eval_with_engine guistuff status user_goal parsed_text st =
  76   let module TAPp = GrafiteAstPp in
  77   let include_ =
  78     match guistuff.filenamedata with
  79     | None,None -> []
  80     | None,Some devel -> [MatitamakeLib.root_for_development devel ]
  81     | Some f,_ ->
  82         match MatitamakeLib.development_for_dir (Filename.dirname f) with
  83         | None -> []
  84         | Some devel -> [MatitamakeLib.root_for_development devel ]
  85   in
  86   let include_ =
  87     include_ @ (Helm_registry.get_list Helm_registry.string "matita.includes")
  88   in
  89   let parsed_text_length = String.length parsed_text in
  90   let loc, ex =
  91     match st with TA.Executable (loc,ex) -> loc, ex | _ -> assert false in
  92   let initial_space,parsed_text =
  93    try
  94     let pieces = Pcre.extract ~rex:heading_nl_RE' parsed_text in
  95      pieces.(1), pieces.(2)
  96    with
  97     Not_found -> "", parsed_text in
  98   (* we add the goal command if needed *)
  99   let inital_space,new_status,new_status_and_text_list' =
 100     match status.proof_status with
 101 (*     | Incomplete_proof { stack = stack }
 102       when not (List.mem user_goal (Continuationals.head_goals stack)) ->
 103         let status =
 104           MatitaEngine.eval_ast
 105             ~do_heavy_checks:true status (goal_ast user_goal)
 106         in
 107         let initial_space = if initial_space = "" then "\n" else initial_space
 108         in
 109         "\n", status,
 110         [ status,
 111           initial_space ^ TAPp.pp_tactical (TA.Select (loc, [user_goal])) ] *)
 112       | _ -> initial_space,status,[] in
 113   let new_status =
 114     GrafiteEngine.eval_ast
 115       ~baseuri_of_script:(GrafiteParserMisc.baseuri_of_script ~include_paths:include_)
 116       ~disambiguate_tactic:GrafiteDisambiguate.disambiguate_tactic
 117       ~disambiguate_command:GrafiteDisambiguate.disambiguate_command
 118       ~do_heavy_checks:true new_status st
 119   in
 120   let new_aliases =
 121     match ex with
 122       | TA.Command (_, TA.Alias _)
 123       | TA.Command (_, TA.Include _)
 124       | TA.Command (_, TA.Interpretation _) -> []
 125       | _ -> MatitaSync.alias_diff ~from:status new_status
 126   in
 127   (* we remove the defined object since we consider them "automatic aliases" *)
 128   let dummy_st =
 129     TA.Comment (DisambiguateTypes.dummy_floc,
 130       TA.Note (DisambiguateTypes.dummy_floc, ""))
 131   in
 132   let initial_space,status,new_status_and_text_list_rev =
 133     let module DTE = DisambiguateTypes.Environment in
 134     let module UM = UriManager in
 135     let baseuri = GrafiteTypes.get_string_option new_status "baseuri" in
 136     List.fold_left (
 137       fun (initial_space,status,acc) (k,((v,_) as value)) ->
 138         let b =
 139          try
 140           UM.buri_of_uri (UM.uri_of_string v) = baseuri
 141          with
 142           UriManager.IllFormedUri _ -> false (* v is a description, not a URI *)
 143         in
 144         if b then
 145           initial_space,status,acc
 146         else
 147          let new_text =
 148           let initial_space =
 149            if initial_space = "" then "\n" else initial_space in
 150             initial_space ^
 151              DisambiguatePp.pp_environment
 152               (DisambiguateTypes.Environment.add k value
 153                 DisambiguateTypes.Environment.empty) in
 154          let new_status =
 155           MatitaSync.set_proof_aliases status [k,value]
 156          in
 157           "\n",new_status,((new_status, (new_text, dummy_st))::acc)
 158     ) (initial_space,status,[]) new_aliases in
 159   let parsed_text = initial_space ^ parsed_text in
 160   let res =
 161    List.rev new_status_and_text_list_rev @ new_status_and_text_list' @
 162     [new_status, (parsed_text, st)]
 163   in
 164    res,parsed_text_length
 165
 166 let eval_with_engine guistuff status user_goal parsed_text st =
 167   try
 168     eval_with_engine guistuff status user_goal parsed_text st
 169   with
 170   | GrafiteParserMisc.UnableToInclude what
 171   | GrafiteEngine.IncludedFileNotCompiled what as exc ->
 172       let compile_needed_and_go_on d =
 173         let target = what in
 174         let refresh_cb () =
 175           while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 176         in
 177         if not(MatitamakeLib.build_development_in_bg ~target refresh_cb d) then
 178           raise exc
 179         else
 180           eval_with_engine guistuff status user_goal parsed_text st
 181       in
 182       let do_nothing () = [], 0 in
 183       let handle_with_devel d =
 184         let name = MatitamakeLib.name_for_development d in
 185         let title = "Unable to include " ^ what in
 186         let message =
 187           what ^ " is handled by development <b>" ^ name ^ "</b>.\n\n" ^
 188           "<i>Should I compile it and Its dependencies?</i>"
 189         in
 190         (match guistuff.ask_confirmation ~title ~message with
 191         | `YES -> compile_needed_and_go_on d
 192         | `NO -> raise exc
 193         | `CANCEL -> do_nothing ())
 194       in
 195       let handle_without_devel filename =
 196         let title = "Unable to include " ^ what in
 197         let message =
 198          what ^ " is <b>not</b> handled by a development.\n" ^
 199          "All dependencies are automatically solved for a development.\n\n" ^
 200          "<i>Do you want to set up a development?</i>"
 201         in
 202         (match guistuff.ask_confirmation ~title ~message with
 203         | `YES ->
 204             (match filename with
 205             | Some f ->
 206                 guistuff.develcreator ~containing:(Some (Filename.dirname f))
 207             | None -> guistuff.develcreator ~containing:None);
 208             do_nothing ()
 209         | `NO -> raise exc
 210         | `CANCEL -> do_nothing())
 211       in
 212       match guistuff.filenamedata with
 213       | None,None -> handle_without_devel None
 214       | None,Some d -> handle_with_devel d
 215       | Some f,_ ->
 216           match MatitamakeLib.development_for_dir (Filename.dirname f) with
 217           | None -> handle_without_devel (Some f)
 218           | Some d -> handle_with_devel d
 219 ;;
 220
 221 let disambiguate_macro_term term status user_goal =
 222   let module MD = MatitaDisambiguator in
 223   let dbd = LibraryDb.instance () in
 224   let metasenv = GrafiteTypes.get_proof_metasenv status in
 225   let context = GrafiteTypes.get_proof_context status user_goal in
 226   let interps =
 227    MD.disambiguate_term ~dbd ~context ~metasenv ~aliases:status.aliases
 228     ~universe:(Some status.multi_aliases) term in
 229   match interps with
 230   | [_,_,x,_], _ -> x
 231   | _ -> assert false
 232
 233 let pp_eager_statement_ast =
 234   GrafiteAstPp.pp_statement ~term_pp:CicNotationPp.pp_term
 235     ~lazy_term_pp:(fun _ -> assert false) ~obj_pp:(fun _ -> assert false)
 236
 237 let eval_macro guistuff status user_goal unparsed_text parsed_text script mac =
 238   let module TAPp = GrafiteAstPp in
 239   let module MQ = MetadataQuery in
 240   let module MDB = LibraryDb in
 241   let module CTC = CicTypeChecker in
 242   let module CU = CicUniv in
 243   (* no idea why ocaml wants this *)
 244   let parsed_text_length = String.length parsed_text in
 245   let dbd = LibraryDb.instance () in
 246   (* XXX use a real CIC -> string pretty printer *)
 247   let pp_macro = TAPp.pp_macro ~term_pp:CicPp.ppterm in
 248   match mac with
 249   (* WHELP's stuff *)
 250   | TA.WMatch (loc, term) ->
 251       let term = disambiguate_macro_term term status user_goal in
 252       let l =  Whelp.match_term ~dbd term in
 253       let query_url =
 254         MatitaMisc.strip_suffix ~suffix:"."
 255           (HExtlib.trim_blanks unparsed_text)
 256       in
 257       let entry = `Whelp (query_url, l) in
 258       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 259       [], parsed_text_length
 260   | TA.WInstance (loc, term) ->
 261       let term = disambiguate_macro_term term status user_goal in
 262       let l = Whelp.instance ~dbd term in
 263       let entry = `Whelp (pp_macro (TA.WInstance (loc, term)), l) in
 264       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 265       [], parsed_text_length
 266   | TA.WLocate (loc, s) ->
 267       let l = Whelp.locate ~dbd s in
 268       let entry = `Whelp (pp_macro (TA.WLocate (loc, s)), l) in
 269       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 270       [], parsed_text_length
 271   | TA.WElim (loc, term) ->
 272       let term = disambiguate_macro_term term status user_goal in
 273       let uri =
 274         match term with
 275         | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None
 276         | _ -> failwith "Not a MutInd"
 277       in
 278       let l = Whelp.elim ~dbd uri in
 279       let entry = `Whelp (pp_macro (TA.WElim (loc, term)), l) in
 280       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 281       [], parsed_text_length
 282   | TA.WHint (loc, term) ->
 283       let term = disambiguate_macro_term term status user_goal in
 284       let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
 285       let l = List.map fst (MQ.experimental_hint ~dbd s) in
 286       let entry = `Whelp (pp_macro (TA.WHint (loc, term)), l) in
 287       guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 288       [], parsed_text_length
 289   (* REAL macro *)
 290   | TA.Hint loc ->
 291       let proof = GrafiteTypes.get_current_proof status in
 292       let proof_status = proof, user_goal in
 293       let l = List.map fst (MQ.experimental_hint ~dbd proof_status) in
 294       let selected = guistuff.urichooser l in
 295       (match selected with
 296       | [] -> [], parsed_text_length
 297       | [uri] ->
 298           let suri = UriManager.string_of_uri uri in
 299           let ast =
 300             TA.Executable (loc, (TA.Tactical (loc,
 301               TA.Tactic (loc,
 302                 TA.Apply (loc, CicNotationPt.Uri (suri, None))),
 303                 Some (TA.Dot loc))))
 304           in
 305         let new_status =
 306          GrafiteEngine.eval_ast
 307           ~baseuri_of_script:(fun _ -> assert false)
 308           ~disambiguate_tactic:GrafiteDisambiguate.disambiguate_tactic
 309           ~disambiguate_command:GrafiteDisambiguate.disambiguate_command
 310           status ast in
 311         let extra_text =
 312           comment parsed_text ^ "\n" ^ pp_eager_statement_ast ast in
 313         [ new_status , (extra_text, ast) ], parsed_text_length
 314       | _ ->
 315           HLog.error
 316             "The result of the urichooser should be only 1 uri, not:\n";
 317           List.iter (
 318             fun u -> HLog.error (UriManager.string_of_uri u ^ "\n")
 319           ) selected;
 320           assert false)
 321   | TA.Check (_,term) ->
 322       let metasenv = GrafiteTypes.get_proof_metasenv status in
 323       let context = GrafiteTypes.get_proof_context status user_goal in
 324       let interps =
 325         MatitaDisambiguator.disambiguate_term ~dbd ~context ~metasenv
 326          ~aliases:status.aliases ~universe:(Some status.multi_aliases) term
 327       in
 328       let _, metasenv , term, ugraph =
 329         match interps with
 330         | [x], _ -> x
 331         | _ -> assert false
 332       in
 333       let ty,_ = CTC.type_of_aux' metasenv context term ugraph in
 334       let t_and_ty = Cic.Cast (term,ty) in
 335       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 336       [], parsed_text_length
 337 (*   | TA.Abort _ ->
 338       let rec go_back () =
 339         let status = script#status.proof_status in
 340         match status with
 341         | No_proof -> ()
 342         | _ -> script#retract ();go_back()
 343       in
 344       [], parsed_text_length, Some go_back
 345   | TA.Redo (_, Some i) ->  [], parsed_text_length,
 346       Some (fun () -> for j = 1 to i do advance () done)
 347   | TA.Redo (_, None) ->   [], parsed_text_length,
 348       Some (fun () -> advance ())
 349   | TA.Undo (_, Some i) ->  [], parsed_text_length,
 350       Some (fun () -> for j = 1 to i do script#retract () done)
 351   | TA.Undo (_, None) -> [], parsed_text_length,
 352       Some (fun () -> script#retract ()) *)
 353   (* TODO *)
 354   | TA.Quit _ -> failwith "not implemented"
 355   | TA.Print (_,kind) -> failwith "not implemented"
 356   | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
 357   | TA.Search_term (_, search_kind, term) -> failwith "not implemented"
 358
 359 let eval_executable guistuff status user_goal unparsed_text parsed_text script
 360   ex
 361 =
 362   let module TAPp = GrafiteAstPp in
 363   let module MD = MatitaDisambiguator in
 364   let module ML = MatitaMisc in
 365   match ex with
 366   | TA.Command (loc, _) | TA.Tactical (loc, _, _) ->
 367       (try
 368         (match GrafiteParserMisc.baseuri_of_baseuri_decl (TA.Executable (loc,ex)) with
 369         | None -> ()
 370         | Some u ->
 371             if not (GrafiteMisc.is_empty u) then
 372               match
 373                 guistuff.ask_confirmation
 374                   ~title:"Baseuri redefinition"
 375                   ~message:(
 376                     "Baseuri " ^ u ^ " already exists.\n" ^
 377                     "Do you want to redefine the corresponding "^
 378                     "part of the library?")
 379               with
 380               | `YES ->
 381                   let basedir = Helm_registry.get "matita.basedir" in
 382                    LibraryClean.clean_baseuris ~basedir [u]
 383               | `NO -> ()
 384               | `CANCEL -> raise MatitaTypes.Cancel);
 385         eval_with_engine
 386          guistuff status user_goal parsed_text (TA.Executable (loc, ex))
 387       with MatitaTypes.Cancel -> [], 0)
 388   | TA.Macro (_,mac) ->
 389       eval_macro guistuff status user_goal unparsed_text parsed_text script mac
 390
 391 let rec eval_statement (buffer : GText.buffer) guistuff status user_goal
 392  script statement
 393 =
 394   let st, unparsed_text =
 395     match statement with
 396     | `Raw text ->
 397         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 398         GrafiteParser.parse_statement (Ulexing.from_utf8_string text), text
 399     | `Ast (st, text) -> st, text
 400   in
 401   let text_of_loc loc =
 402     let parsed_text_length = snd (HExtlib.loc_of_floc loc) in
 403     let parsed_text = safe_substring unparsed_text 0 parsed_text_length in
 404     parsed_text, parsed_text_length
 405   in
 406   match st with
 407   | GrafiteAst.Comment (loc, _) ->
 408       let parsed_text, parsed_text_length = text_of_loc loc in
 409       let remain_len = String.length unparsed_text - parsed_text_length in
 410       let s = String.sub unparsed_text parsed_text_length remain_len in
 411       let s,len =
 412        try
 413         eval_statement buffer guistuff status user_goal script
 414          (`Raw s)
 415        with
 416           HExtlib.Localized (floc, exn) ->
 417            HExtlib.raise_localized_exception ~offset:parsed_text_length floc exn
 418         | MatitaDisambiguator.DisambiguationError (offset,errorll) ->
 419            raise
 420             (MatitaDisambiguator.DisambiguationError
 421               (offset+parsed_text_length, errorll))
 422       in
 423       (match s with
 424       | (status, (text, ast)) :: tl ->
 425           ((status, (parsed_text ^ text, ast))::tl), (parsed_text_length + len)
 426       | [] -> [], 0)
 427   | GrafiteAst.Executable (loc, ex) ->
 428       let parsed_text, parsed_text_length = text_of_loc loc in
 429       eval_executable guistuff status user_goal unparsed_text parsed_text
 430         script ex
 431
 432 let fresh_script_id =
 433   let i = ref 0 in
 434   fun () -> incr i; !i
 435
 436 class script  ~(source_view: GSourceView.source_view)
 437               ~(mathviewer: MatitaTypes.mathViewer)
 438               ~set_star
 439               ~ask_confirmation
 440               ~urichooser
 441               ~develcreator
 442               () =
 443 let buffer = source_view#buffer in
 444 let source_buffer = source_view#source_buffer in
 445 object (self)
 446   val scriptId = fresh_script_id ()
 447
 448   val guistuff = {
 449     mathviewer = mathviewer;
 450     urichooser = urichooser;
 451     ask_confirmation = ask_confirmation;
 452     develcreator = develcreator;
 453     filenamedata = (None, None)}
 454
 455   method private getFilename =
 456     match guistuff.filenamedata with Some f,_ -> f | _ -> assert false
 457
 458   method filename = self#getFilename
 459
 460   method private ppFilename =
 461     match guistuff.filenamedata with
 462     | Some f,_ -> f
 463     | None,_ -> sprintf ".unnamed%d.ma" scriptId
 464
 465   initializer
 466     ignore (GMain.Timeout.add ~ms:300000
 467        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 468     ignore (buffer#connect#modified_changed
 469       (fun _ -> set_star (Filename.basename self#ppFilename) buffer#modified))
 470
 471   val mutable statements = [];    (** executed statements *)
 472   val mutable history = [ MatitaSync.init () ];
 473     (** list of states before having executed statements. Head element of this
 474       * list is the current state, last element is the state at the beginning of
 475       * the script.
 476       * Invariant: this list length is 1 + length of statements *)
 477
 478   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 479   val mutable userGoal = ~-1
 480
 481   (** text mark and tag representing locked part of a script *)
 482   val locked_mark =
 483     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 484   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 485   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 486
 487   method locked_mark = locked_mark
 488   method locked_tag = locked_tag
 489   method error_tag = error_tag
 490
 491     (* history can't be empty, the invariant above grant that it contains at
 492      * least the init status *)
 493   method status = match history with hd :: _ -> hd | _ -> assert false
 494
 495   method private _advance ?statement () =
 496     let rec aux st =
 497       let (entries, parsed_len) =
 498         eval_statement buffer guistuff self#status userGoal self st
 499       in
 500       let (new_statuses, new_statements, new_asts) =
 501         let statuses, statements = List.split entries in
 502         let texts, asts = List.split statements in
 503         statuses, texts, asts
 504       in
 505       history <- List.rev new_statuses @ history;
 506       statements <- List.rev new_statements @ statements;
 507       let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 508       let new_text = String.concat "" new_statements in
 509       if statement <> None then
 510         buffer#insert ~iter:start new_text
 511       else begin
 512         let s = match st with `Raw s | `Ast (_, s) -> s in
 513         if new_text <> String.sub s 0 parsed_len then begin
 514           buffer#delete ~start ~stop:(start#copy#forward_chars parsed_len);
 515           buffer#insert ~iter:start new_text;
 516         end;
 517       end;
 518       self#moveMark (String.length new_text);
 519       (*
 520       (match List.rev new_asts with (* advance again on punctuation *)
 521       | TA.Executable (_, TA.Tactical (_, tac, _)) :: _ ->
 522           let baseoffset =
 523             (buffer#get_iter_at_mark (`MARK locked_mark))#offset
 524           in
 525           let text = self#getFuture in
 526           (try
 527             (match parse_statement baseoffset 0 buffer text with
 528             | TA.Executable (loc, TA.Tactical (_, tac, None)) as st
 529               when GrafiteAst.is_punctuation tac ->
 530                 let len = snd (CicNotationPt.loc_of_floc loc) in
 531                 aux (`Ast (st, String.sub text 0 len))
 532             | _ -> ())
 533           with CicNotationParser.Parse_error _ | End_of_file -> ())
 534       | _ -> ())
 535       *)
 536     in
 537     let s = match statement with Some s -> s | None -> self#getFuture in
 538     HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 539     (try aux (`Raw s) with End_of_file -> raise Margin)
 540
 541   method private _retract offset status new_statements new_history =
 542     let cur_status = match history with s::_ -> s | [] -> assert false in
 543     MatitaSync.time_travel ~present:cur_status ~past:status;
 544     statements <- new_statements;
 545     history <- new_history;
 546     self#moveMark (- offset)
 547
 548   method advance ?statement () =
 549     try
 550       self#_advance ?statement ();
 551       self#notify
 552     with
 553     | Margin -> self#notify
 554     | exc -> self#notify; raise exc
 555
 556   method retract () =
 557     try
 558       let cmp,new_statements,new_history,status =
 559        match statements,history with
 560           stat::statements, _::(status::_ as history) ->
 561            String.length stat, statements, history, status
 562        | [],[_] -> raise Margin
 563        | _,_ -> assert false
 564       in
 565        self#_retract cmp status new_statements new_history;
 566        self#notify
 567     with
 568     | Margin -> self#notify
 569     | exc -> self#notify; raise exc
 570
 571   method private getFuture =
 572     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 573       ~stop:buffer#end_iter ()
 574
 575
 576   (** @param rel_offset relative offset from current position of locked_mark *)
 577   method private moveMark rel_offset =
 578     let mark = `MARK locked_mark in
 579     let old_insert = buffer#get_iter_at_mark `INSERT in
 580     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 581     let current_mark_pos = buffer#get_iter_at_mark mark in
 582     let new_mark_pos =
 583       match rel_offset with
 584       | 0 -> current_mark_pos
 585       | n when n > 0 -> current_mark_pos#forward_chars n
 586       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 587     in
 588     buffer#move_mark mark ~where:new_mark_pos;
 589     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 590     buffer#move_mark `INSERT old_insert;
 591     let mark_position = buffer#get_iter_at_mark mark in
 592     if source_view#move_mark_onscreen mark then
 593      begin
 594       buffer#move_mark mark mark_position;
 595       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 596      end;
 597     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 598
 599   method clean_dirty_lock =
 600     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 601     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 602     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 603
 604   val mutable observers = []
 605
 606   method addObserver (o: GrafiteTypes.status -> unit) =
 607     observers <- o :: observers
 608
 609   method private notify =
 610     let status = self#status in
 611     List.iter (fun o -> o status) observers
 612
 613   method loadFromFile f =
 614     buffer#set_text (HExtlib.input_file f);
 615     self#reset_buffer;
 616     buffer#set_modified false
 617
 618   method assignFileName file =
 619     let abspath = MatitaMisc.absolute_path file in
 620     let devel = MatitamakeLib.development_for_dir (Filename.dirname abspath) in
 621     guistuff.filenamedata <- Some abspath, devel
 622
 623   method saveToFile () =
 624     let oc = open_out self#getFilename in
 625     output_string oc (buffer#get_text ~start:buffer#start_iter
 626                         ~stop:buffer#end_iter ());
 627     close_out oc;
 628     buffer#set_modified false
 629
 630   method private _saveToBackupFile () =
 631     if buffer#modified then
 632       begin
 633         let f = self#ppFilename ^ "~" in
 634         let oc = open_out f in
 635         output_string oc (buffer#get_text ~start:buffer#start_iter
 636                             ~stop:buffer#end_iter ());
 637         close_out oc;
 638         HLog.debug ("backup " ^ f ^ " saved")
 639       end
 640
 641   method private goto_top =
 642     let init =
 643       let rec last x = function
 644       | [] -> x
 645       | hd::tl -> last hd tl
 646       in
 647       last self#status history
 648     in
 649     (* FIXME: this is not correct since there is no undo for
 650      * library_objects.set_default... *)
 651     MatitaSync.time_travel ~present:self#status ~past:init
 652
 653   method private reset_buffer =
 654     statements <- [];
 655     history <- [ MatitaSync.init () ];
 656     userGoal <- ~-1;
 657     self#notify;
 658     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 659     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 660
 661   method reset () =
 662     self#reset_buffer;
 663     source_buffer#begin_not_undoable_action ();
 664     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 665     source_buffer#end_not_undoable_action ();
 666     buffer#set_modified false;
 667
 668   method template () =
 669     let template = HExtlib.input_file BuildTimeConf.script_template in
 670     buffer#insert ~iter:(buffer#get_iter `START) template;
 671     guistuff.filenamedata <-
 672       (None,MatitamakeLib.development_for_dir (Unix.getcwd ()));
 673     buffer#set_modified false;
 674     set_star (Filename.basename self#ppFilename) false
 675
 676   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 677     let old_locked_mark =
 678      `MARK
 679        (buffer#create_mark ~name:"old_locked_mark"
 680          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 681     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 682     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 683     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 684     match pos with
 685     | `Top ->
 686         dispose_old_locked_mark ();
 687         self#goto_top;
 688         self#reset_buffer;
 689         self#notify
 690     | `Bottom ->
 691         (try
 692           let rec dowhile () =
 693             self#_advance ();
 694             let newpos = getpos () in
 695             if (getoldpos ())#compare newpos < 0 then
 696               begin
 697                 buffer#move_mark old_locked_mark newpos;
 698                 dowhile ()
 699               end
 700           in
 701           dowhile ();
 702           dispose_old_locked_mark ();
 703           self#notify
 704         with
 705         | Margin -> dispose_old_locked_mark (); self#notify
 706         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 707     | `Cursor ->
 708         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 709         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 710         let remember =
 711          `MARK
 712            (buffer#create_mark ~name:"initial_insert"
 713              ~left_gravity:true (cursor_iter ())) in
 714         let dispose_remember () = buffer#delete_mark remember in
 715         let remember_iter () =
 716          buffer#get_iter_at_mark (`NAME "initial_insert") in
 717         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 718         let icmp = cmp () in
 719         let forward_until_cursor () = (* go forward until locked > cursor *)
 720           let rec aux () =
 721             self#_advance ();
 722             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 723             then
 724              begin
 725               buffer#move_mark old_locked_mark (getpos ());
 726               aux ()
 727              end
 728           in
 729           aux ()
 730         in
 731         let rec back_until_cursor len = (* go backward until locked < cursor *)
 732          function
 733             statements, (status::_ as history) when len <= 0 ->
 734              self#_retract (icmp - len) status statements history
 735           | statement::tl1, _::tl2 ->
 736              back_until_cursor (len - String.length statement) (tl1,tl2)
 737           | _,_ -> assert false
 738         in
 739         (try
 740           begin
 741            if icmp < 0 then       (* locked < cursor *)
 742              (forward_until_cursor (); self#notify)
 743            else if icmp > 0 then  (* locked > cursor *)
 744              (back_until_cursor icmp (statements,history); self#notify)
 745            else                  (* cursor = locked *)
 746                ()
 747           end ;
 748           dispose_remember ();
 749           dispose_old_locked_mark ();
 750         with
 751         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 752         | exc -> dispose_remember (); dispose_old_locked_mark ();
 753                  self#notify; raise exc)
 754
 755   method onGoingProof () =
 756     match self#status.proof_status with
 757     | No_proof | Proof _ -> false
 758     | Incomplete_proof _ -> true
 759     | Intermediate _ -> assert false
 760
 761 (*   method proofStatus = MatitaTypes.get_proof_status self#status *)
 762   method proofMetasenv = GrafiteTypes.get_proof_metasenv self#status
 763   method proofContext = GrafiteTypes.get_proof_context self#status userGoal
 764   method proofConclusion= GrafiteTypes.get_proof_conclusion self#status userGoal
 765   method stack = GrafiteTypes.get_stack self#status
 766   method setGoal n = userGoal <- n
 767   method goal = userGoal
 768
 769   method eos =
 770     let s = self#getFuture in
 771     let rec is_there_and_executable s =
 772       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 773       let st = GrafiteParser.parse_statement (Ulexing.from_utf8_string s) in
 774       match st with
 775       | GrafiteAst.Comment (loc,_)->
 776           let parsed_text_length = snd (HExtlib.loc_of_floc loc) in
 777           let remain_len = String.length s - parsed_text_length in
 778           let next = String.sub s parsed_text_length remain_len in
 779           is_there_and_executable next
 780       | GrafiteAst.Executable (loc, ex) -> false
 781     in
 782     try
 783       is_there_and_executable s
 784     with
 785     | CicNotationParser.Parse_error _ -> false
 786     | Margin | End_of_file -> true
 787
 788   (* debug *)
 789   method dump () =
 790     HLog.debug "script status:";
 791     HLog.debug ("history size: " ^ string_of_int (List.length history));
 792     HLog.debug (sprintf "%d statements:" (List.length statements));
 793     List.iter HLog.debug statements;
 794     HLog.debug ("Current file name: " ^
 795       (match guistuff.filenamedata with
 796       |None,_ -> "[ no name ]"
 797       | Some f,_ -> f));
 798
 799 end
 800
 801 let _script = ref None
 802
 803 let script ~source_view ~mathviewer ~urichooser ~develcreator ~ask_confirmation ~set_star ()
 804 =
 805   let s = new script
 806     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~develcreator ~set_star ()
 807   in
 808   _script := Some s;
 809   s
 810
 811 let current () = match !_script with None -> assert false | Some s -> s
 812