helm/matita/matitaTypes.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28   (** user hit the cancel button *)
  29 exception Cancel
  30
  31   (** statement invoked in the wrong context (e.g. tactic with no ongoing proof)
  32    *)
  33 exception Statement_error of string
  34 let statement_error msg = raise (Statement_error msg)
  35
  36 exception Command_error of string
  37 let command_error msg = raise (Command_error msg)
  38
  39   (** parameters are: option name, error message *)
  40 exception Option_error of string * string
  41
  42 exception Unbound_identifier of string
  43
  44 type incomplete_proof = {
  45   proof: ProofEngineTypes.proof;
  46   stack: Continuationals.Stack.t;
  47 }
  48
  49 type proof_status =
  50   | No_proof
  51   | Incomplete_proof of incomplete_proof
  52   | Proof of ProofEngineTypes.proof
  53   | Intermediate of Cic.metasenv
  54       (* Status in which the proof could be while it is being processed by the
  55       * engine. No status entering/exiting the engine could be in it. *)
  56
  57 module StringMap = Map.Make (String)
  58
  59 type option_value =
  60   | String of string
  61   | Int of int
  62 type options = option_value StringMap.t
  63 let no_options = StringMap.empty
  64
  65 type ast_command = (CicNotationPt.term, CicNotationPt.obj) GrafiteAst.command
  66 type moo = ast_command list * GrafiteAst.metadata list
  67
  68 type status = {
  69   aliases: DisambiguateTypes.environment;
  70   multi_aliases: DisambiguateTypes.multiple_environment;
  71   moo_content_rev: moo;
  72   proof_status: proof_status;
  73   options: options;
  74   objects: UriManager.uri list;
  75   coercions: UriManager.uri list;
  76   notation_ids: CicNotation.notation_id list;
  77 }
  78
  79 let set_metasenv metasenv status =
  80   let proof_status =
  81     match status.proof_status with
  82     | No_proof -> Intermediate metasenv
  83     | Incomplete_proof ({ proof = (uri, _, proof, ty) } as incomplete_proof) ->
  84         Incomplete_proof
  85           { incomplete_proof with proof = (uri, metasenv, proof, ty) }
  86     | Intermediate _ -> Intermediate metasenv
  87     | Proof _ -> assert false
  88   in
  89   { status with proof_status = proof_status }
  90
  91 let dump_status status =
  92   HLog.message "status.aliases:\n";
  93   HLog.message "status.proof_status:";
  94   HLog.message
  95     (match status.proof_status with
  96     | No_proof -> "no proof\n"
  97     | Incomplete_proof _ -> "incomplete proof\n"
  98     | Proof _ -> "proof\n"
  99     | Intermediate _ -> "Intermediate\n");
 100   HLog.message "status.options\n";
 101   StringMap.iter (fun k v ->
 102     let v =
 103       match v with
 104       | String s -> s
 105       | Int i -> string_of_int i
 106     in
 107     HLog.message (k ^ "::=" ^ v)) status.options;
 108   HLog.message "status.coercions\n";
 109   HLog.message "status.objects:\n";
 110   List.iter
 111     (fun u -> HLog.message (UriManager.string_of_uri u)) status.objects
 112
 113 let get_option status name =
 114   try
 115     StringMap.find name status.options
 116   with Not_found -> raise (Option_error (name, "not found"))
 117
 118 let get_string_option status name =
 119   match get_option status name with
 120   | String s -> s
 121   | _ -> raise (Option_error (name, "not a string value"))
 122
 123 let set_option status name value =
 124   let mangle_dir s =
 125     let s = Str.global_replace (Str.regexp "//+") "/" s in
 126     let s = Str.global_replace (Str.regexp "/$") "" s in
 127     s
 128   in
 129   let types = [ "baseuri", (`String, mangle_dir); ] in
 130   let ty_and_mangler =
 131     try
 132       List.assoc name types
 133     with Not_found -> command_error (sprintf "Unknown option \"%s\"" name)
 134   in
 135   let value =
 136     match ty_and_mangler with
 137     | `String, f -> String (f value)
 138     | `Int, f ->
 139         (try
 140           Int (int_of_string (f value))
 141         with Failure _ ->
 142           command_error (sprintf "Not an integer value \"%s\"" value))
 143   in
 144   if StringMap.mem name status.options && name = "baseuri" then
 145     command_error "Redefinition of 'baseuri' is forbidden."
 146   else
 147     { status with options = StringMap.add name value status.options }
 148
 149 let add_moo_content cmds status =
 150   let content, metadata = status.moo_content_rev in
 151   let content' =
 152     List.fold_right
 153       (fun cmd acc ->
 154 (*         prerr_endline ("adding to moo command: " ^ GrafiteAstPp.pp_command cmd); *)
 155         match cmd with
 156         | GrafiteAst.Interpretation _
 157         | GrafiteAst.Default _ ->
 158             if List.mem cmd content then acc
 159             else cmd :: acc
 160         | GrafiteAst.Alias _ -> (* move Alias as the last inserted one *)
 161             cmd :: (List.filter ((<>) cmd) acc)
 162         | _ -> cmd :: acc)
 163       cmds content
 164   in
 165 (*   prerr_endline ("new moo content: " ^ String.concat " " (List.map
 166     GrafiteAstPp.pp_command content')); *)
 167   { status with moo_content_rev = content', metadata }
 168
 169 let add_moo_metadata new_metadata status =
 170   let content, metadata = status.moo_content_rev in
 171   let metadata' =
 172     List.fold_left
 173       (fun acc m ->
 174         match m with
 175         | GrafiteAst.Dependency buri ->
 176             let is_self = (* self dependency *)
 177               try
 178                 get_string_option status "baseuri" = buri
 179               with Option_error _ -> false  (* baseuri not yet set *)
 180             in
 181             if is_self
 182               || List.exists (GrafiteAst.eq_metadata m) metadata (* duplicate *)
 183             then acc
 184             else m :: acc
 185         | _ -> m :: acc)
 186       metadata new_metadata
 187   in
 188   { status with moo_content_rev = content, metadata' }
 189
 190   (* subset of MatitaConsole.console methods needed by MatitaInterpreter *)
 191 class type console =
 192   object
 193     method clear : unit -> unit
 194     method echo_error : string -> unit
 195     method echo_message : string -> unit
 196     method wrap_exn : 'a. (unit -> 'a) -> 'a option
 197     method choose_uri : string list -> string
 198     method show : ?msg:string -> unit -> unit
 199   end
 200
 201 type abouts =
 202   [ `Blank
 203   | `Current_proof
 204   | `Us
 205   ]
 206
 207 type mathViewer_entry =
 208   [ `About of abouts  (* current proof *)
 209   | `Check of string (* term *)
 210   | `Cic of Cic.term * Cic.metasenv
 211   | `Dir of string (* "directory" in cic uris namespace *)
 212   | `Uri of UriManager.uri (* cic object uri *)
 213   | `Whelp of string * UriManager.uri list (* query and results *)
 214   ]
 215
 216 let string_of_entry = function
 217   | `About `Blank -> "about:blank"
 218   | `About `Current_proof -> "about:proof"
 219   | `About `Us -> "about:us"
 220   | `Check _ -> "check:"
 221   | `Cic (_, _) -> "term:"
 222   | `Dir uri -> uri
 223   | `Uri uri -> UriManager.string_of_uri uri
 224   | `Whelp (query, _) -> query
 225
 226 let entry_of_string = function
 227   | "about:blank" -> `About `Blank
 228   | "about:proof" -> `About `Current_proof
 229   | "about:us"    -> `About `Us
 230   | _ ->  (* only about entries supported ATM *)
 231       raise (Invalid_argument "entry_of_string")
 232
 233 class type mathViewer =
 234   object
 235     (** @param reuse if set reused last opened cic browser otherwise
 236      *  opens a new one. default is false
 237      *)
 238     method show_entry: ?reuse:bool -> mathViewer_entry -> unit
 239     method show_uri_list:
 240       ?reuse:bool -> entry:mathViewer_entry -> UriManager.uri list -> unit
 241   end
 242
 243 let qualify status name = get_string_option status "baseuri" ^ "/" ^ name
 244
 245 let get_current_proof status =
 246   match status.proof_status with
 247   | Incomplete_proof { proof = p } -> p
 248   | _ -> statement_error "no ongoing proof"
 249
 250 let get_proof_metasenv status =
 251   match status.proof_status with
 252   | No_proof -> []
 253   | Proof (_, metasenv, _, _)
 254   | Incomplete_proof { proof = (_, metasenv, _, _) }
 255   | Intermediate metasenv ->
 256       metasenv
 257
 258 let get_proof_context status goal =
 259   match status.proof_status with
 260   | Incomplete_proof { proof = (_, metasenv, _, _) } ->
 261       let (_, context, _) = CicUtil.lookup_meta goal metasenv in
 262       context
 263   | _ -> []
 264
 265 let get_proof_conclusion status goal =
 266   match status.proof_status with
 267   | Incomplete_proof { proof = (_, metasenv, _, _) } ->
 268       let (_, _, conclusion) = CicUtil.lookup_meta goal metasenv in
 269       conclusion
 270   | _ -> statement_error "no ongoing proof"
 271
 272 let get_stack status =
 273   match status.proof_status with
 274   | Incomplete_proof p -> p.stack
 275   | Proof _ -> Continuationals.Stack.empty
 276   | _ -> assert false
 277
 278 let set_stack stack status =
 279   match status.proof_status with
 280   | Incomplete_proof p ->
 281       { status with proof_status = Incomplete_proof { p with stack = stack } }
 282   | Proof _ ->
 283       assert (Continuationals.Stack.is_empty stack);
 284       status
 285   | _ -> assert false
 286