helm/mowgli/home/xsl/deadlines.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet version="1.0"
   4                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   5
   6 <xsl:import href="common.xsl"/>
   7
   8 <xsl:output method="xml"/>
   9
  10 <xsl:param name="events-class" select="''"/>
  11 <xsl:param name="today" select="''"/>
  12
  13 <xsl:template match="/">
  14  <html>
  15   <head>
  16    <title>
  17     <xsl:value-of select="$events-class"/>
  18     <xsl:text> Events Sorted by Deadlines</xsl:text>
  19    </title>
  20   </head>
  21   <body>
  22     <h1>
  23      <xsl:value-of select="$events-class"/>
  24      <xsl:text> Events</xsl:text>
  25     </h1>
  26     <xsl:variable name="url">
  27      <xsl:choose>
  28       <xsl:when test="$events-class='Other'">other-events.html</xsl:when>
  29       <xsl:otherwise>mowgli-events.html</xsl:otherwise>
  30      </xsl:choose>
  31     </xsl:variable>
  32     [<a href="{$url}">Sorted by event date</a>] [Sorted by deadline]
  33     <br /><br />
  34     <hr />
  35     <ul>
  36      <xsl:apply-templates select="events/event/deadline[date &gt;= $today]">
  37       <xsl:sort select="date" data-type="number"/>
  38      </xsl:apply-templates>
  39     </ul>
  40     <hr />
  41     <h1>Past Events</h1>
  42     <ul>
  43      <xsl:apply-templates select="events/event/deadline[date &lt; $today]">
  44       <xsl:sort select="date" data-type="number" order="descending"/>
  45      </xsl:apply-templates>
  46     </ul>
  47   </body>
  48  </html>
  49 </xsl:template>
  50
  51 <xsl:template match="deadline">
  52  <li>
  53   <b>
  54    <xsl:variable name="kind">
  55     <xsl:call-template name="color_of_deadline_kind">
  56      <xsl:with-param name="kind" select="@kind"/>
  57     </xsl:call-template>
  58    </xsl:variable>
  59    <span style="color: {$kind}">
  60     <xsl:call-template name="print_date">
  61      <xsl:with-param name="date" select="date/text()"/>
  62     </xsl:call-template>
  63    </span>
  64   </b>
  65   <xsl:text> </xsl:text>
  66   <xsl:value-of select="description"/>
  67   <xsl:text> </xsl:text>
  68   <a href="{../url}" target="_top"><xsl:value-of select="../name"/></a>
  69  </li>
  70 </xsl:template>
  71
  72 </xsl:stylesheet>
  73