helm/ocaml/cic/deannotate.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 let expect_possible_parameters = ref false;;
  27
  28 exception NotExpectingPossibleParameters;;
  29
  30 (* converts annotated terms into cic terms (forgetting ids and names) *)
  31 let rec deannotate_term =
  32  let module C = Cic in
  33   function
  34      C.ARel (_,n,_) -> C.Rel n
  35    | C.AVar (_,uri) -> C.Var uri
  36    | C.AMeta (_,n, l) ->
  37       let l' =
  38        List.map
  39         (function
  40             None -> None
  41           | Some at -> Some (deannotate_term at)
  42         ) l
  43       in
  44        C.Meta (n, l')
  45    | C.ASort (_,s) -> C.Sort s
  46    | C.AImplicit _ -> C.Implicit
  47    | C.ACast (_,va,ty) -> C.Cast (deannotate_term va, deannotate_term ty)
  48    | C.AProd (_,name,so,ta) ->
  49       C.Prod (name, deannotate_term so, deannotate_term ta)
  50    | C.ALambda (_,name,so,ta) ->
  51       C.Lambda (name, deannotate_term so, deannotate_term ta)
  52    | C.ALetIn (_,name,so,ta) ->
  53       C.LetIn (name, deannotate_term so, deannotate_term ta)
  54    | C.AAppl (_,l) -> C.Appl (List.map deannotate_term l)
  55    | C.AConst (_,uri, cookingsno) -> C.Const (uri, cookingsno)
  56    | C.AMutInd (_,uri,cookingsno,i) -> C.MutInd (uri,cookingsno,i)
  57    | C.AMutConstruct (_,uri,cookingsno,i,j) ->
  58       C.MutConstruct (uri,cookingsno,i,j)
  59    | C.AMutCase (_,uri,cookingsno,i,outtype,te,pl) ->
  60       C.MutCase (uri,cookingsno,i,deannotate_term outtype,
  61        deannotate_term te, List.map deannotate_term pl)
  62    | C.AFix (_,funno,ifl) ->
  63       C.Fix (funno, List.map deannotate_inductiveFun ifl)
  64    | C.ACoFix (_,funno,ifl) ->
  65       C.CoFix (funno, List.map deannotate_coinductiveFun ifl)
  66
  67 and deannotate_inductiveFun (name,index,ty,bo) =
  68  (name, index, deannotate_term ty, deannotate_term bo)
  69
  70 and deannotate_coinductiveFun (name,ty,bo) =
  71  (name, deannotate_term ty, deannotate_term bo)
  72 ;;
  73
  74 let deannotate_inductiveType (name, isinductive, arity, cons) =
  75  (name, isinductive, deannotate_term arity,
  76   List.map (fun (id,ty,recs) -> (id,deannotate_term ty, recs)) cons)
  77 ;;
  78
  79 let deannotate_obj =
  80  let module C = Cic in
  81   function
  82      C.ADefinition (_, id, bo, ty, params) ->
  83       (match params with
  84           C.Possible params ->
  85            if !expect_possible_parameters then
  86             C.Definition (id, deannotate_term bo, deannotate_term ty, params)
  87            else
  88             raise NotExpectingPossibleParameters
  89         | C.Actual params ->
  90            C.Definition (id, deannotate_term bo, deannotate_term ty, params)
  91       )
  92    | C.AAxiom (_, id, ty, params) ->
  93       C.Axiom (id, deannotate_term ty, params)
  94    | C.AVariable (_, name, bo, ty) ->
  95       C.Variable (name,
  96        (match bo with None -> None | Some bo -> Some (deannotate_term bo)),
  97        deannotate_term ty)
  98    | C.ACurrentProof (_, name, conjs, bo, ty) ->
  99       C.CurrentProof (
 100        name,
 101         List.map
 102          (function
 103            (_,id,acontext,con) ->
 104             let context =
 105              List.map
 106               (function
 107                   _,Some (n,(C.ADef at)) ->
 108                    Some (n,(C.Def (deannotate_term at)))
 109                 | _,Some (n,(C.ADecl at)) ->
 110                    Some (n,(C.Decl (deannotate_term at)))
 111                 | _,None -> None
 112               ) acontext
 113             in
 114              (id,context,deannotate_term con)
 115          ) conjs,
 116        deannotate_term bo,deannotate_term ty
 117       )
 118    | C.AInductiveDefinition (_, tys, params, parno) ->
 119       C.InductiveDefinition ( List.map deannotate_inductiveType tys,
 120        params, parno)
 121 ;;