helm/ocaml/cic_acic/doubleTypeInference.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 exception Impossible of int;;
  27 exception NotWellTyped of string;;
  28 exception WrongUriToConstant of string;;
  29 exception WrongUriToVariable of string;;
  30 exception WrongUriToMutualInductiveDefinitions of string;;
  31 exception ListTooShort;;
  32 exception RelToHiddenHypothesis;;
  33
  34 let syntactic_equality_add_time = ref 0.0;;
  35 let type_of_aux'_add_time = ref 0.0;;
  36 let number_new_type_of_aux'_double_work = ref 0;;
  37 let number_new_type_of_aux' = ref 0;;
  38 let number_new_type_of_aux'_prop = ref 0;;
  39
  40 let double_work = ref 0;;
  41
  42 let xxx_type_of_aux' m c t =
  43  let t1 = Sys.time () in
  44  let res,_ = CicTypeChecker.type_of_aux' m c t CicUniv.empty_ugraph in
  45  let t2 = Sys.time () in
  46  type_of_aux'_add_time := !type_of_aux'_add_time +. t2 -. t1 ;
  47  res
  48 ;;
  49
  50 type types = {synthesized : Cic.term ; expected : Cic.term option};;
  51
  52 (* does_not_occur n te                              *)
  53 (* returns [true] if [Rel n] does not occur in [te] *)
  54 let rec does_not_occur n =
  55  let module C = Cic in
  56   function
  57      C.Rel m when m = n -> false
  58    | C.Rel _
  59    | C.Meta _
  60    | C.Sort _
  61    | C.Implicit _ -> true
  62    | C.Cast (te,ty) ->
  63       does_not_occur n te && does_not_occur n ty
  64    | C.Prod (name,so,dest) ->
  65       does_not_occur n so &&
  66        does_not_occur (n + 1) dest
  67    | C.Lambda (name,so,dest) ->
  68       does_not_occur n so &&
  69        does_not_occur (n + 1) dest
  70    | C.LetIn (name,so,dest) ->
  71       does_not_occur n so &&
  72        does_not_occur (n + 1) dest
  73    | C.Appl l ->
  74       List.fold_right (fun x i -> i && does_not_occur n x) l true
  75    | C.Var (_,exp_named_subst)
  76    | C.Const (_,exp_named_subst)
  77    | C.MutInd (_,_,exp_named_subst)
  78    | C.MutConstruct (_,_,_,exp_named_subst) ->
  79       List.fold_right (fun (_,x) i -> i && does_not_occur n x)
  80        exp_named_subst true
  81    | C.MutCase (_,_,out,te,pl) ->
  82       does_not_occur n out && does_not_occur n te &&
  83        List.fold_right (fun x i -> i && does_not_occur n x) pl true
  84    | C.Fix (_,fl) ->
  85       let len = List.length fl in
  86        let n_plus_len = n + len in
  87        let tys =
  88         List.map (fun (n,_,ty,_) -> Some (C.Name n,(Cic.Decl ty))) fl
  89        in
  90         List.fold_right
  91          (fun (_,_,ty,bo) i ->
  92            i && does_not_occur n ty &&
  93            does_not_occur n_plus_len bo
  94          ) fl true
  95    | C.CoFix (_,fl) ->
  96       let len = List.length fl in
  97        let n_plus_len = n + len in
  98        let tys =
  99         List.map (fun (n,ty,_) -> Some (C.Name n,(Cic.Decl ty))) fl
 100        in
 101         List.fold_right
 102          (fun (_,ty,bo) i ->
 103            i && does_not_occur n ty &&
 104            does_not_occur n_plus_len bo
 105          ) fl true
 106 ;;
 107
 108 let rec beta_reduce =
 109  let module S = CicSubstitution in
 110  let module C = Cic in
 111   function
 112       C.Rel _ as t -> t
 113     | C.Var (uri,exp_named_subst) ->
 114        let exp_named_subst' =
 115         List.map (function (i,t) -> i, beta_reduce t) exp_named_subst
 116        in
 117         C.Var (uri,exp_named_subst)
 118     | C.Meta (n,l) ->
 119        C.Meta (n,
 120         List.map
 121          (function None -> None | Some t -> Some (beta_reduce t)) l
 122        )
 123     | C.Sort _ as t -> t
 124     | C.Implicit _ -> assert false
 125     | C.Cast (te,ty) ->
 126        C.Cast (beta_reduce te, beta_reduce ty)
 127     | C.Prod (n,s,t) ->
 128        C.Prod (n, beta_reduce s, beta_reduce t)
 129     | C.Lambda (n,s,t) ->
 130        C.Lambda (n, beta_reduce s, beta_reduce t)
 131     | C.LetIn (n,s,t) ->
 132        C.LetIn (n, beta_reduce s, beta_reduce t)
 133     | C.Appl ((C.Lambda (name,s,t))::he::tl) ->
 134        let he' = S.subst he t in
 135         if tl = [] then
 136          beta_reduce he'
 137         else
 138          (match he' with
 139              C.Appl l -> beta_reduce (C.Appl (l@tl))
 140            | _ -> beta_reduce (C.Appl (he'::tl)))
 141     | C.Appl l ->
 142        C.Appl (List.map beta_reduce l)
 143     | C.Const (uri,exp_named_subst) ->
 144        let exp_named_subst' =
 145         List.map (function (i,t) -> i, beta_reduce t) exp_named_subst
 146        in
 147         C.Const (uri,exp_named_subst')
 148     | C.MutInd (uri,i,exp_named_subst) ->
 149        let exp_named_subst' =
 150         List.map (function (i,t) -> i, beta_reduce t) exp_named_subst
 151        in
 152         C.MutInd (uri,i,exp_named_subst')
 153     | C.MutConstruct (uri,i,j,exp_named_subst) ->
 154        let exp_named_subst' =
 155         List.map (function (i,t) -> i, beta_reduce t) exp_named_subst
 156        in
 157         C.MutConstruct (uri,i,j,exp_named_subst')
 158     | C.MutCase (sp,i,outt,t,pl) ->
 159        C.MutCase (sp,i,beta_reduce outt,beta_reduce t,
 160         List.map beta_reduce pl)
 161     | C.Fix (i,fl) ->
 162        let fl' =
 163         List.map
 164          (function (name,i,ty,bo) ->
 165            name,i,beta_reduce ty,beta_reduce bo
 166          ) fl
 167        in
 168         C.Fix (i,fl')
 169     | C.CoFix (i,fl) ->
 170        let fl' =
 171         List.map
 172          (function (name,ty,bo) ->
 173            name,beta_reduce ty,beta_reduce bo
 174          ) fl
 175        in
 176         C.CoFix (i,fl')
 177 ;;
 178
 179 (* syntactic_equality up to the                 *)
 180 (* distinction between fake dependent products  *)
 181 (* and non-dependent products, alfa-conversion  *)
 182 (*CSC: must alfa-conversion be considered or not? *)
 183 let syntactic_equality t t' =
 184  let module C = Cic in
 185  let rec syntactic_equality t t' =
 186   if t = t' then true
 187   else
 188    match t, t' with
 189       C.Var (uri,exp_named_subst), C.Var (uri',exp_named_subst') ->
 190        UriManager.eq uri uri' &&
 191         syntactic_equality_exp_named_subst exp_named_subst exp_named_subst'
 192     | C.Cast (te,ty), C.Cast (te',ty') ->
 193        syntactic_equality te te' &&
 194         syntactic_equality ty ty'
 195     | C.Prod (_,s,t), C.Prod (_,s',t') ->
 196        syntactic_equality s s' &&
 197         syntactic_equality t t'
 198     | C.Lambda (_,s,t), C.Lambda (_,s',t') ->
 199        syntactic_equality s s' &&
 200         syntactic_equality t t'
 201     | C.LetIn (_,s,t), C.LetIn(_,s',t') ->
 202        syntactic_equality s s' &&
 203         syntactic_equality t t'
 204     | C.Appl l, C.Appl l' ->
 205        List.fold_left2 (fun b t1 t2 -> b && syntactic_equality t1 t2) true l l'
 206     | C.Const (uri,exp_named_subst), C.Const (uri',exp_named_subst') ->
 207        UriManager.eq uri uri' &&
 208         syntactic_equality_exp_named_subst exp_named_subst exp_named_subst'
 209     | C.MutInd (uri,i,exp_named_subst), C.MutInd (uri',i',exp_named_subst') ->
 210        UriManager.eq uri uri' && i = i' &&
 211         syntactic_equality_exp_named_subst exp_named_subst exp_named_subst'
 212     | C.MutConstruct (uri,i,j,exp_named_subst),
 213       C.MutConstruct (uri',i',j',exp_named_subst') ->
 214        UriManager.eq uri uri' && i = i' && j = j' &&
 215         syntactic_equality_exp_named_subst exp_named_subst exp_named_subst'
 216     | C.MutCase (sp,i,outt,t,pl), C.MutCase (sp',i',outt',t',pl') ->
 217        UriManager.eq sp sp' && i = i' &&
 218         syntactic_equality outt outt' &&
 219          syntactic_equality t t' &&
 220           List.fold_left2
 221            (fun b t1 t2 -> b && syntactic_equality t1 t2) true pl pl'
 222     | C.Fix (i,fl), C.Fix (i',fl') ->
 223        i = i' &&
 224         List.fold_left2
 225          (fun b (_,i,ty,bo) (_,i',ty',bo') ->
 226            b && i = i' &&
 227             syntactic_equality ty ty' &&
 228              syntactic_equality bo bo') true fl fl'
 229     | C.CoFix (i,fl), C.CoFix (i',fl') ->
 230        i = i' &&
 231         List.fold_left2
 232          (fun b (_,ty,bo) (_,ty',bo') ->
 233            b &&
 234             syntactic_equality ty ty' &&
 235              syntactic_equality bo bo') true fl fl'
 236     | _, _ -> false (* we already know that t != t' *)
 237  and syntactic_equality_exp_named_subst exp_named_subst1 exp_named_subst2 =
 238   List.fold_left2
 239    (fun b (_,t1) (_,t2) -> b && syntactic_equality t1 t2) true
 240    exp_named_subst1 exp_named_subst2
 241  in
 242   try
 243    syntactic_equality t t'
 244   with
 245    _ -> false
 246 ;;
 247
 248 let xxx_syntactic_equality t t' =
 249  let t1 = Sys.time () in
 250  let res = syntactic_equality t t' in
 251  let t2 = Sys.time () in
 252  syntactic_equality_add_time := !syntactic_equality_add_time +. t2 -. t1 ;
 253  res
 254 ;;
 255
 256
 257 let rec split l n =
 258  match (l,n) with
 259     (l,0) -> ([], l)
 260   | (he::tl, n) -> let (l1,l2) = split tl (n-1) in (he::l1,l2)
 261   | (_,_) -> raise ListTooShort
 262 ;;
 263
 264 let type_of_constant uri =
 265  let module C = Cic in
 266  let module R = CicReduction in
 267  let module U = UriManager in
 268   let cobj =
 269    match CicEnvironment.is_type_checked CicUniv.empty_ugraph uri with
 270       CicEnvironment.CheckedObj (cobj,_) -> cobj
 271     | CicEnvironment.UncheckedObj uobj ->
 272        raise (NotWellTyped "Reference to an unchecked constant")
 273   in
 274    match cobj with
 275       C.Constant (_,_,ty,_,_) -> ty
 276     | C.CurrentProof (_,_,_,ty,_,_) -> ty
 277     | _ -> raise (WrongUriToConstant (U.string_of_uri uri))
 278 ;;
 279
 280 let type_of_variable uri =
 281  let module C = Cic in
 282  let module R = CicReduction in
 283  let module U = UriManager in
 284   match CicEnvironment.is_type_checked CicUniv.empty_ugraph uri with
 285      CicEnvironment.CheckedObj ((C.Variable (_,_,ty,_,_)),_) -> ty
 286    | CicEnvironment.UncheckedObj (C.Variable _) ->
 287       raise (NotWellTyped "Reference to an unchecked variable")
 288    |  _ -> raise (WrongUriToVariable (UriManager.string_of_uri uri))
 289 ;;
 290
 291 let type_of_mutual_inductive_defs uri i =
 292  let module C = Cic in
 293  let module R = CicReduction in
 294  let module U = UriManager in
 295   let cobj =
 296    match CicEnvironment.is_type_checked CicUniv.empty_ugraph uri with
 297       CicEnvironment.CheckedObj (cobj,_) -> cobj
 298     | CicEnvironment.UncheckedObj uobj ->
 299        raise (NotWellTyped "Reference to an unchecked inductive type")
 300   in
 301    match cobj with
 302       C.InductiveDefinition (dl,_,_,_) ->
 303        let (_,_,arity,_) = List.nth dl i in
 304         arity
 305     | _ -> raise (WrongUriToMutualInductiveDefinitions (U.string_of_uri uri))
 306 ;;
 307
 308 let type_of_mutual_inductive_constr uri i j =
 309  let module C = Cic in
 310  let module R = CicReduction in
 311  let module U = UriManager in
 312   let cobj =
 313    match CicEnvironment.is_type_checked CicUniv.empty_ugraph uri with
 314       CicEnvironment.CheckedObj (cobj,_) -> cobj
 315     | CicEnvironment.UncheckedObj uobj ->
 316        raise (NotWellTyped "Reference to an unchecked constructor")
 317   in
 318    match cobj with
 319       C.InductiveDefinition (dl,_,_,_) ->
 320        let (_,_,_,cl) = List.nth dl i in
 321         let (_,ty) = List.nth cl (j-1) in
 322          ty
 323     | _ -> raise (WrongUriToMutualInductiveDefinitions (U.string_of_uri uri))
 324 ;;
 325
 326 (* type_of_aux' is just another name (with a different scope) for type_of_aux *)
 327 let rec type_of_aux' subterms_to_types metasenv context t expectedty =
 328  (* Coscoy's double type-inference algorithm             *)
 329  (* It computes the inner-types of every subterm of [t], *)
 330  (* even when they are not needed to compute the types   *)
 331  (* of other terms.                                      *)
 332  let rec type_of_aux context t expectedty =
 333   let module C = Cic in
 334   let module R = CicReduction in
 335   let module S = CicSubstitution in
 336   let module U = UriManager in
 337    let synthesized =
 338     match t with
 339        C.Rel n ->
 340         (try
 341           match List.nth context (n - 1) with
 342              Some (_,C.Decl t) -> S.lift n t
 343            | Some (_,C.Def (_,Some ty)) -> S.lift n ty
 344            | Some (_,C.Def (bo,None)) ->
 345               type_of_aux context (S.lift n bo) expectedty
 346                  | None -> raise RelToHiddenHypothesis
 347          with
 348           _ -> raise (NotWellTyped "Not a close term")
 349         )
 350      | C.Var (uri,exp_named_subst) ->
 351         visit_exp_named_subst context uri exp_named_subst ;
 352         CicSubstitution.subst_vars exp_named_subst (type_of_variable uri)
 353      | C.Meta (n,l) ->
 354         (* Let's visit all the subterms that will not be visited later *)
 355         let (_,canonical_context,_) = CicUtil.lookup_meta n metasenv in
 356          let lifted_canonical_context =
 357           let rec aux i =
 358            function
 359               [] -> []
 360             | (Some (n,C.Decl t))::tl ->
 361                (Some (n,C.Decl (S.subst_meta l (S.lift i t))))::(aux (i+1) tl)
 362             | (Some (n,C.Def (t,None)))::tl ->
 363                (Some (n,C.Def ((S.subst_meta l (S.lift i t)),None)))::
 364                 (aux (i+1) tl)
 365             | None::tl -> None::(aux (i+1) tl)
 366             | (Some (_,C.Def (_,Some _)))::_ -> assert false
 367           in
 368            aux 1 canonical_context
 369          in
 370           let _ =
 371            List.iter2
 372             (fun t ct ->
 373               match t,ct with
 374                  _,None -> ()
 375                | Some t,Some (_,C.Def (ct,_)) ->
 376                   let expected_type =
 377                    R.whd context
 378                     (xxx_type_of_aux' metasenv context ct)
 379                   in
 380                    (* Maybe I am a bit too paranoid, because   *)
 381                    (* if the term is well-typed than t and ct  *)
 382                    (* are convertible. Nevertheless, I compute *)
 383                    (* the expected type.                       *)
 384                    ignore (type_of_aux context t (Some expected_type))
 385                | Some t,Some (_,C.Decl ct) ->
 386                   ignore (type_of_aux context t (Some ct))
 387                | _,_ -> assert false (* the term is not well typed!!! *)
 388             ) l lifted_canonical_context
 389           in
 390            let (_,canonical_context,ty) = CicUtil.lookup_meta n metasenv in
 391             (* Checks suppressed *)
 392             CicSubstitution.subst_meta l ty
 393      | C.Sort (C.Type t) -> (* TASSI: CONSTRAINT *)
 394          C.Sort (C.Type (CicUniv.fresh()))
 395      | C.Sort _ -> C.Sort (C.Type (CicUniv.fresh())) (* TASSI: CONSTRAINT *)
 396      | C.Implicit _ -> raise (Impossible 21)
 397      | C.Cast (te,ty) ->
 398         (* Let's visit all the subterms that will not be visited later *)
 399         let _ = type_of_aux context te (Some (beta_reduce ty)) in
 400         let _ = type_of_aux context ty None in
 401          (* Checks suppressed *)
 402          ty
 403      | C.Prod (name,s,t) ->
 404         let sort1 = type_of_aux context s None
 405         and sort2 = type_of_aux ((Some (name,(C.Decl s)))::context) t None in
 406          sort_of_prod context (name,s) (sort1,sort2)
 407      | C.Lambda (n,s,t) ->
 408         (* Let's visit all the subterms that will not be visited later *)
 409          let _ = type_of_aux context s None in
 410          let expected_target_type =
 411           match expectedty with
 412              None -> None
 413            | Some expectedty' ->
 414               let ty =
 415                match R.whd context expectedty' with
 416                   C.Prod (_,_,expected_target_type) ->
 417                    beta_reduce expected_target_type
 418                 | _ -> assert false
 419               in
 420                Some ty
 421          in
 422           let type2 =
 423            type_of_aux ((Some (n,(C.Decl s)))::context) t expected_target_type
 424           in
 425            (* Checks suppressed *)
 426            C.Prod (n,s,type2)
 427      | C.LetIn (n,s,t) ->
 428 (*CSC: What are the right expected types for the source and *)
 429 (*CSC: target of a LetIn? None used.                        *)
 430         (* Let's visit all the subterms that will not be visited later *)
 431         let ty = type_of_aux context s None in
 432          let t_typ =
 433           (* Checks suppressed *)
 434           type_of_aux ((Some (n,(C.Def (s,Some ty))))::context) t None
 435          in  (* CicSubstitution.subst s t_typ *)
 436           if does_not_occur 1 t_typ then
 437            (* since [Rel 1] does not occur in typ, substituting any term *)
 438            (* in place of [Rel 1] is equivalent to delifting once        *)
 439            CicSubstitution.subst (C.Implicit None) t_typ
 440           else
 441            C.LetIn (n,s,t_typ)
 442      | C.Appl (he::tl) when List.length tl > 0 ->
 443         (*
 444         let expected_hetype =
 445          (* Inefficient, the head is computed twice. But I know *)
 446          (* of no other solution. *)
 447          (beta_reduce
 448           (R.whd context (xxx_type_of_aux' metasenv context he)))
 449         in
 450          let hetype = type_of_aux context he (Some expected_hetype) in
 451          let tlbody_and_type =
 452           let rec aux =
 453            function
 454               _,[] -> []
 455             | C.Prod (n,s,t),he::tl ->
 456                (he, type_of_aux context he (Some (beta_reduce s)))::
 457                 (aux (R.whd context (S.subst he t), tl))
 458             | _ -> assert false
 459           in
 460            aux (expected_hetype, tl) *)
 461          let hetype = R.whd context (type_of_aux context he None) in
 462          let tlbody_and_type =
 463           let rec aux =
 464            function
 465               _,[] -> []
 466             | C.Prod (n,s,t),he::tl ->
 467                (he, type_of_aux context he (Some (beta_reduce s)))::
 468                 (aux (R.whd context (S.subst he t), tl))
 469             | _ -> assert false
 470           in
 471            aux (hetype, tl)
 472          in
 473           eat_prods context hetype tlbody_and_type
 474      | C.Appl _ -> raise (NotWellTyped "Appl: no arguments")
 475      | C.Const (uri,exp_named_subst) ->
 476         visit_exp_named_subst context uri exp_named_subst ;
 477         CicSubstitution.subst_vars exp_named_subst (type_of_constant uri)
 478      | C.MutInd (uri,i,exp_named_subst) ->
 479         visit_exp_named_subst context uri exp_named_subst ;
 480         CicSubstitution.subst_vars exp_named_subst
 481          (type_of_mutual_inductive_defs uri i)
 482      | C.MutConstruct (uri,i,j,exp_named_subst) ->
 483         visit_exp_named_subst context uri exp_named_subst ;
 484         CicSubstitution.subst_vars exp_named_subst
 485          (type_of_mutual_inductive_constr uri i j)
 486      | C.MutCase (uri,i,outtype,term,pl) ->
 487         let outsort = type_of_aux context outtype None in
 488         let (need_dummy, k) =
 489          let rec guess_args context t =
 490           match CicReduction.whd context t with
 491              C.Sort _ -> (true, 0)
 492            | C.Prod (name, s, t) ->
 493               let (b, n) = guess_args ((Some (name,(C.Decl s)))::context) t in
 494                if n = 0 then
 495                 (* last prod before sort *)
 496                 match CicReduction.whd context s with
 497                    C.MutInd (uri',i',_) when U.eq uri' uri && i' = i ->
 498                     (false, 1)
 499                  | C.Appl ((C.MutInd (uri',i',_)) :: _)
 500                     when U.eq uri' uri && i' = i -> (false, 1)
 501                  | _ -> (true, 1)
 502                else
 503                 (b, n + 1)
 504            | _ -> raise (NotWellTyped "MutCase: outtype ill-formed")
 505          in
 506           let (b, k) = guess_args context outsort in
 507            if not b then (b, k - 1) else (b, k)
 508         in
 509         let (parameters, arguments,exp_named_subst) =
 510          let type_of_term =
 511           xxx_type_of_aux' metasenv context term
 512          in
 513           match
 514            R.whd context (type_of_aux context term
 515             (Some (beta_reduce type_of_term)))
 516           with
 517              (*CSC manca il caso dei CAST *)
 518              C.MutInd (uri',i',exp_named_subst) ->
 519               (* Checks suppressed *)
 520               [],[],exp_named_subst
 521            | C.Appl (C.MutInd (uri',i',exp_named_subst) :: tl) ->
 522              let params,args =
 523               split tl (List.length tl - k)
 524              in params,args,exp_named_subst
 525            | _ ->
 526              raise (NotWellTyped "MutCase: the term is not an inductive one")
 527         in
 528          (* Checks suppressed *)
 529          (* Let's visit all the subterms that will not be visited later *)
 530          let (cl,parsno) =
 531            let obj,_ =
 532              try
 533                CicEnvironment.get_cooked_obj CicUniv.empty_ugraph uri
 534              with Not_found -> assert false
 535            in
 536           match obj with
 537              C.InductiveDefinition (tl,_,parsno,_) ->
 538               let (_,_,_,cl) = List.nth tl i in (cl,parsno)
 539            | _ ->
 540              raise (WrongUriToMutualInductiveDefinitions (U.string_of_uri uri))
 541          in
 542           let _ =
 543            List.fold_left
 544             (fun j (p,(_,c)) ->
 545               let cons =
 546                if parameters = [] then
 547                 (C.MutConstruct (uri,i,j,exp_named_subst))
 548                else
 549                 (C.Appl (C.MutConstruct (uri,i,j,exp_named_subst)::parameters))
 550               in
 551                let expectedtype =
 552                 type_of_branch context parsno need_dummy outtype cons
 553                   (xxx_type_of_aux' metasenv context cons)
 554                in
 555                 ignore (type_of_aux context p
 556                  (Some (beta_reduce expectedtype))) ;
 557                 j+1
 558             ) 1 (List.combine pl cl)
 559           in
 560            if not need_dummy then
 561             C.Appl ((outtype::arguments)@[term])
 562            else if arguments = [] then
 563             outtype
 564            else
 565             C.Appl (outtype::arguments)
 566      | C.Fix (i,fl) ->
 567         (* Let's visit all the subterms that will not be visited later *)
 568         let context' =
 569          List.rev
 570           (List.map
 571             (fun (n,_,ty,_) ->
 572               let _ = type_of_aux context ty None in
 573                (Some (C.Name n,(C.Decl ty)))
 574             ) fl
 575           ) @
 576           context
 577         in
 578          let _ =
 579           List.iter
 580            (fun (_,_,ty,bo) ->
 581              let expectedty =
 582               beta_reduce (CicSubstitution.lift (List.length fl) ty)
 583              in
 584               ignore (type_of_aux context' bo (Some expectedty))
 585            ) fl
 586          in
 587           (* Checks suppressed *)
 588           let (_,_,ty,_) = List.nth fl i in
 589            ty
 590      | C.CoFix (i,fl) ->
 591         (* Let's visit all the subterms that will not be visited later *)
 592         let context' =
 593          List.rev
 594           (List.map
 595             (fun (n,ty,_) ->
 596               let _ = type_of_aux context ty None in
 597                (Some (C.Name n,(C.Decl ty)))
 598             ) fl
 599           ) @
 600           context
 601         in
 602          let _ =
 603           List.iter
 604            (fun (_,ty,bo) ->
 605              let expectedty =
 606               beta_reduce (CicSubstitution.lift (List.length fl) ty)
 607              in
 608               ignore (type_of_aux context' bo (Some expectedty))
 609            ) fl
 610          in
 611           (* Checks suppressed *)
 612           let (_,ty,_) = List.nth fl i in
 613            ty
 614    in
 615     let synthesized' = beta_reduce synthesized in
 616      let types,res =
 617       match expectedty with
 618          None ->
 619           (* No expected type *)
 620           {synthesized = synthesized' ; expected = None}, synthesized
 621        | Some ty when xxx_syntactic_equality synthesized' ty ->
 622           (* The expected type is synthactically equal to *)
 623           (* the synthesized type. Let's forget it.       *)
 624           {synthesized = synthesized' ; expected = None}, synthesized
 625        | Some expectedty' ->
 626           {synthesized = synthesized' ; expected = Some expectedty'},
 627           expectedty'
 628      in
 629       assert (not (Cic.CicHash.mem subterms_to_types t));
 630       Cic.CicHash.add subterms_to_types t types ;
 631       res
 632
 633  and visit_exp_named_subst context uri exp_named_subst =
 634   let uris_and_types =
 635      let obj,_ =
 636        try
 637          CicEnvironment.get_cooked_obj CicUniv.empty_ugraph uri
 638        with Not_found -> assert false
 639      in
 640     let params = CicUtil.params_of_obj obj in
 641      List.map
 642       (function uri ->
 643          let obj,_ =
 644            try
 645              CicEnvironment.get_cooked_obj CicUniv.empty_ugraph uri
 646            with Not_found -> assert false
 647          in
 648          match obj with
 649            Cic.Variable (_,None,ty,_,_) -> uri,ty
 650          | _ -> assert false (* the theorem is well-typed *)
 651       ) params
 652   in
 653    let rec check uris_and_types subst =
 654     match uris_and_types,subst with
 655        _,[] -> []
 656      | (uri,ty)::tytl,(uri',t)::substtl when uri = uri' ->
 657         ignore (type_of_aux context t (Some ty)) ;
 658         let tytl' =
 659          List.map
 660           (function uri,t' -> uri,(CicSubstitution.subst_vars [uri',t] t')) tytl
 661         in
 662          check tytl' substtl
 663      | _,_ -> assert false (* the theorem is well-typed *)
 664    in
 665     check uris_and_types exp_named_subst
 666
 667  and sort_of_prod context (name,s) (t1, t2) =
 668   let module C = Cic in
 669    let t1' = CicReduction.whd context t1 in
 670    let t2' = CicReduction.whd ((Some (name,C.Decl s))::context) t2 in
 671    match (t1', t2') with
 672       (C.Sort _, C.Sort s2)
 673         when (s2 = C.Prop or s2 = C.Set or s2 = C.CProp) ->
 674          (* different from Coq manual!!! *)
 675          C.Sort s2
 676     | (C.Sort (C.Type t1), C.Sort (C.Type t2)) ->
 677         C.Sort (C.Type (CicUniv.fresh()))
 678     | (C.Sort _,C.Sort (C.Type t1)) ->
 679         (* TASSI: CONSRTAINTS: the same in cictypechecker,cicrefine *)
 680         C.Sort (C.Type t1) (* c'e' bisogno di un fresh? *)
 681     | (C.Meta _, C.Sort _) -> t2'
 682     | (C.Meta _, (C.Meta (_,_) as t))
 683     | (C.Sort _, (C.Meta (_,_) as t)) when CicUtil.is_closed t ->
 684         t2'
 685     | (_,_) ->
 686       raise
 687        (NotWellTyped
 688         ("Prod: sort1= " ^ CicPp.ppterm t1' ^ " ; sort2= " ^ CicPp.ppterm t2'))
 689
 690  and eat_prods context hetype =
 691   (*CSC: siamo sicuri che le are_convertible non lavorino con termini non *)
 692   (*CSC: cucinati                                                         *)
 693   function
 694      [] -> hetype
 695    | (hete, hety)::tl ->
 696     (match (CicReduction.whd context hetype) with
 697         Cic.Prod (n,s,t) ->
 698          (* Checks suppressed *)
 699          eat_prods context (CicSubstitution.subst hete t) tl
 700       | _ -> raise (NotWellTyped "Appl: wrong Prod-type")
 701     )
 702
 703 and type_of_branch context argsno need_dummy outtype term constype =
 704  let module C = Cic in
 705  let module R = CicReduction in
 706   match R.whd context constype with
 707      C.MutInd (_,_,_) ->
 708       if need_dummy then
 709        outtype
 710       else
 711        C.Appl [outtype ; term]
 712    | C.Appl (C.MutInd (_,_,_)::tl) ->
 713       let (_,arguments) = split tl argsno
 714       in
 715        if need_dummy && arguments = [] then
 716         outtype
 717        else
 718         C.Appl (outtype::arguments@(if need_dummy then [] else [term]))
 719    | C.Prod (name,so,de) ->
 720       let term' =
 721        match CicSubstitution.lift 1 term with
 722           C.Appl l -> C.Appl (l@[C.Rel 1])
 723         | t -> C.Appl [t ; C.Rel 1]
 724       in
 725        C.Prod (C.Anonymous,so,type_of_branch
 726         ((Some (name,(C.Decl so)))::context) argsno need_dummy
 727         (CicSubstitution.lift 1 outtype) term' de)
 728   | _ -> raise (Impossible 20)
 729
 730  in
 731   type_of_aux context t expectedty
 732 ;;
 733
 734 let double_type_of metasenv context t expectedty =
 735  let subterms_to_types = Cic.CicHash.create 503 in
 736   ignore (type_of_aux' subterms_to_types metasenv context t expectedty) ;
 737   subterms_to_types
 738 ;;