helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri uri =
  57   let term = CicUtil.term_of_uri uri in
  58   (uri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   let_defs:[
 175     [ defs = LIST1 [
 176         name = IDENT;
 177         args = LIST1 [
 178           PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 179           ty = term; PAREN ")" ->
 180             (names, ty)
 181         ];
 182         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 183         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 184         SYMBOL <:unicode<def>> (* ≝ *);
 185         t1 = term ->
 186           let rec list_of_binder binder ty final_term = function
 187             | [] -> final_term
 188             | name::tl ->
 189                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 190                   list_of_binder binder ty final_term tl)
 191           in
 192           let rec binder_of_arg_list binder final_term = function
 193             | [] -> final_term
 194             | (l,ty)::tl ->
 195                 list_of_binder binder ty
 196                   (binder_of_arg_list binder final_term tl) l
 197           in
 198           let t1' = binder_of_arg_list `Lambda t1 args in
 199           let ty' =
 200             match ty with
 201             | None -> None
 202             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 203           in
 204           let rec get_position_of name n = function
 205             | [] -> (None,n)
 206             | nam::tl ->
 207                 if nam = name then
 208                   (Some n,n)
 209                 else
 210                   (get_position_of name (n+1) tl)
 211           in
 212           let rec find_arg name n = function
 213             | [] -> (fail loc (sprintf "Argument %s not found" name))
 214             | (l,_)::tl ->
 215                 let (got,len) = get_position_of name 0 l in
 216                 (match got with
 217                 | None -> (find_arg name (n+len) tl)
 218                 | Some where -> n + where)
 219           in
 220           let index =
 221             (match index_name with
 222              | None -> 0
 223              | (Some name) -> find_arg name 0 args)
 224           in
 225           ((Cic.Name name,ty'), t1', index)
 226       ] SEP "and" -> defs
 227     ]];
 228   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 229   binder_vars: [
 230       [ vars = LIST1 IDENT SEP SYMBOL ",";
 231         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 232       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 233         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 234       ]
 235   ];
 236   term0: [ [ t = term; EOI -> return_term loc t ] ];
 237   term:
 238     [ "letin" NONA
 239       [ "let"; var = typed_name;
 240         SYMBOL <:unicode<def>> (* ≝ *);
 241         t1 = term; "in"; t2 = term ->
 242           return_term loc (CicAst.LetIn (var, t1, t2))
 243       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 244         defs = let_defs; "in"; body = term ->
 245             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 246       ]
 247     | "binder" RIGHTA
 248       [
 249         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 250           let binder = mk_binder_ast b typ vars body in
 251           return_term loc binder
 252       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 253           let binder = mk_binder_ast b typ vars body in
 254           return_term loc binder
 255       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 256           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 257       ]
 258     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 259     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 260     | "logic_inv" NONA    [ (* nothing here by default *) ]
 261     | "relop" LEFTA
 262       [ t1 = term; SYMBOL "="; t2 = term ->
 263         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 264       ]
 265     | "add" LEFTA     [ (* nothing here by default *) ]
 266     | "mult" LEFTA    [ (* nothing here by default *) ]
 267     | "power" LEFTA   [ (* nothing here by default *) ]
 268     | "inv" NONA      [ (* nothing here by default *) ]
 269     | "apply" LEFTA
 270       [ t1 = term; t2 = term ->
 271         let rec aux = function
 272           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 273           | term -> [term]
 274         in
 275         CicAst.Appl (aux t1 @ [t2])
 276       ]
 277     | "simple" NONA
 278       [ sort = sort -> CicAst.Sort sort
 279       | n = substituted_name -> return_term loc n
 280       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 281       | IMPLICIT -> return_term loc CicAst.Implicit
 282       | m = META;
 283         substs = [
 284           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 285             substs
 286         ] ->
 287             let index =
 288               try
 289                 int_of_string (String.sub m 1 (String.length m - 1))
 290               with Failure "int_of_string" ->
 291                 fail loc ("Invalid meta variable number: " ^ m)
 292             in
 293             return_term loc (CicAst.Meta (index, substs))
 294       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 295         "match"; t = term;
 296         indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
 297         "with";
 298         PAREN "[";
 299         patterns = LIST0 [
 300           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 301           ->
 302             ((lhs: CicAst.case_pattern), rhs)
 303         ] SEP SYMBOL "|";
 304         PAREN "]" ->
 305           return_term loc
 306             (CicAst.Case (t, indty_ident, outtyp, patterns))
 307       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 308           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 309       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 310       ]
 311     ];
 312   tactic_where: [
 313     [ where = OPT [ "in"; ident = IDENT -> ident ] -> where ]
 314   ];
 315   tactic_term: [ [ t = term -> t ] ];
 316   ident_list0: [
 317     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 318   ];
 319   ident_list1: [
 320     [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 321   ];
 322   reduction_kind: [
 323     [ [ IDENT "reduce" ] -> `Reduce
 324     | [ IDENT "simplify" ] -> `Simpl
 325     | [ IDENT "whd" ] -> `Whd ]
 326   ];
 327   tactic: [
 328     [ [ IDENT "absurd" ]; t = tactic_term ->
 329         TacticAst.Absurd (loc, t)
 330     | [ IDENT "apply" ]; t = tactic_term ->
 331         TacticAst.Apply (loc, t)
 332     | [ IDENT "assumption" ] ->
 333         TacticAst.Assumption loc
 334     | [ IDENT "auto" ] ; num = OPT [ i = NUM -> int_of_string i ] ->
 335           TacticAst.Auto (loc,num)
 336     | [ IDENT "change" ];
 337       t1 = tactic_term; "with"; t2 = tactic_term;
 338       where = tactic_where ->
 339         TacticAst.Change (loc, t1, t2, where)
 340     (* TODO Change_pattern *)
 341     | [ IDENT "contradiction" ] ->
 342         TacticAst.Contradiction loc
 343     | [ IDENT "cut" ];
 344       t = tactic_term ->
 345         TacticAst.Cut (loc, t)
 346     | [ IDENT "decompose" ];
 347       principles = ident_list1; where = IDENT ->
 348         TacticAst.Decompose (loc, where, principles)
 349     | [ IDENT "discriminate" ];
 350       hyp = IDENT ->
 351         TacticAst.Discriminate (loc, hyp)
 352     | [ IDENT "elimType" ]; t = tactic_term ->
 353         TacticAst.ElimType (loc, t)
 354     | [ IDENT "elim" ];
 355       t1 = tactic_term;
 356       using = OPT [ "using"; using = tactic_term -> using ] ->
 357         TacticAst.Elim (loc, t1, using)
 358     | [ IDENT "exact" ]; t = tactic_term ->
 359         TacticAst.Exact (loc, t)
 360     | [ IDENT "exists" ] ->
 361         TacticAst.Exists loc
 362     | [ IDENT "fold" ];
 363       kind = reduction_kind; t = tactic_term ->
 364         TacticAst.Fold (loc, kind, t)
 365     | [ IDENT "fourier" ] ->
 366         TacticAst.Fourier loc
 367     | IDENT "goal"; n = NUM -> TacticAst.Goal (loc, int_of_string n)
 368     | [ IDENT "injection" ]; ident = IDENT ->
 369         TacticAst.Injection (loc, ident)
 370     | [ IDENT "intros" ];
 371       num = OPT [ num = int -> num ];
 372       idents = OPT ident_list0 ->
 373         let idents = match idents with None -> [] | Some idents -> idents in
 374         TacticAst.Intros (loc, num, idents)
 375     | [ IDENT "intro" ] ->
 376         TacticAst.Intros (loc, Some 1, [])
 377     | [ IDENT "left" ] -> TacticAst.Left loc
 378     | [ "let" | "Let" ];
 379       t = tactic_term; "in"; where = IDENT ->
 380         TacticAst.LetIn (loc, t, where)
 381     | kind = reduction_kind;
 382       pat = OPT [
 383         "in"; pat = [ IDENT "goal" -> `Goal | IDENT "hyp" -> `Everywhere ] ->
 384           pat
 385       ];
 386       terms = LIST0 term SEP SYMBOL "," ->
 387         (match (pat, terms) with
 388         | None, [] -> TacticAst.Reduce (loc, kind, None)
 389         | None, terms -> TacticAst.Reduce (loc, kind, Some (terms, `Goal))
 390         | Some pat, [] -> fail loc "Missing term [list]"
 391         | Some pat, terms -> TacticAst.Reduce (loc, kind, Some (terms, pat)))
 392     | [ IDENT "reflexivity" ] ->
 393         TacticAst.Reflexivity loc
 394     | [ IDENT "replace" ];
 395       t1 = tactic_term; "with"; t2 = tactic_term ->
 396         TacticAst.Replace (loc, t1, t2)
 397     | [ IDENT "rewrite" ; IDENT "left" ] ; t = term ->
 398         TacticAst.Rewrite (loc,`Left, t, None)
 399     | [ IDENT "rewrite" ; IDENT "right" ] ; t = term ->
 400         TacticAst.Rewrite (loc,`Right, t, None)
 401     (* TODO Replace_pattern *)
 402     | [ IDENT "right" ] -> TacticAst.Right loc
 403     | [ IDENT "ring" ] -> TacticAst.Ring loc
 404     | [ IDENT "split" ] -> TacticAst.Split loc
 405     | [ IDENT "symmetry" ] ->
 406         TacticAst.Symmetry loc
 407     | [ IDENT "transitivity" ];
 408       t = tactic_term ->
 409         TacticAst.Transitivity (loc, t)
 410     ]
 411   ];
 412   tactical:
 413     [ "sequence" LEFTA
 414       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 415           TacticAst.Seq (loc, tacticals)
 416       ]
 417     | "then" NONA
 418       [ tac = tactical;
 419         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 420           (TacticAst.Then (loc, tac, tacs))
 421       ]
 422     | "loops" RIGHTA
 423       [ [ IDENT "do" ]; count = int; tac = tactical ->
 424           TacticAst.Do (loc, count, tac)
 425       | [ IDENT "repeat" ]; tac = tactical ->
 426           TacticAst.Repeat (loc, tac)
 427       ]
 428     | "simple" NONA
 429       [ IDENT "tries";
 430         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 431           TacticAst.Tries (loc, tacs)
 432       | IDENT "try"; tac = NEXT ->
 433           TacticAst.Try (loc, tac)
 434       | IDENT "fail" -> TacticAst.Fail loc
 435       | IDENT "id" -> TacticAst.IdTac loc
 436       | PAREN "("; tac = tactical; PAREN ")" -> tac
 437       | tac = tactic -> TacticAst.Tactic (loc, tac)
 438       ]
 439     ];
 440   theorem_flavour: [
 441     [ [ IDENT "definition"  ] -> `Definition
 442     | [ IDENT "fact"        ] -> `Fact
 443     | [ IDENT "lemma"       ] -> `Lemma
 444     | [ IDENT "remark"      ] -> `Remark
 445     | [ IDENT "theorem"     ] -> `Theorem
 446     ]
 447   ];
 448   inductive_spec: [ [
 449     fst_name = IDENT; params = LIST0 [
 450       PAREN "("; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 451       typ = term; PAREN ")" -> (names, typ) ];
 452     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 453     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 454     tl = OPT [ "with";
 455       types = LIST1 [
 456         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 457        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 458           (name, true, typ, constructors) ] SEP "with" -> types
 459     ] ->
 460       let params =
 461         List.fold_right
 462           (fun (names, typ) acc ->
 463             (List.map (fun name -> (name, typ)) names) @ acc)
 464           params []
 465       in
 466       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 467       let tl_ind_types = match tl with None -> [] | Some types -> types in
 468       let ind_types = fst_ind_type :: tl_ind_types in
 469       (params, ind_types)
 470   ] ];
 471
 472   macro: [
 473     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 474 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 475     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 476 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 477         TacticAst.Undo (loc, int_opt steps)
 478     | [ IDENT "redo"   ]; steps = OPT NUM ->
 479         TacticAst.Redo (loc, int_opt steps) *)
 480     | [ IDENT "check"   ]; t = term ->
 481         TacticAst.Check (loc, t)
 482     | [ IDENT "hint" ] -> TacticAst.Hint loc
 483     | [ IDENT "whelp"; "match" ] ; t = term ->
 484         TacticAst.WMatch (loc,t)
 485     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 486         TacticAst.WInstance (loc,t)
 487     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 488         TacticAst.WLocate (loc,id)
 489     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 490         TacticAst.WElim (loc, t)
 491     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 492         TacticAst.WHint (loc,t)
 493     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 494     ]
 495   ];
 496
 497   alias_spec: [
 498     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 499       let alpha = "[a-zA-Z]" in
 500       let num = "[0-9]+" in
 501       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 502       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 503       let rex = Str.regexp ("^"^ident^"$") in
 504       if Str.string_match rex id 0 then
 505         let rex = Str.regexp
 506           ("^\\(cic:/\\|theory:/\\)"^ident^
 507            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 508            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 509         in
 510         if Str.string_match rex uri 0 then
 511           TacticAst.Ident_alias (id, uri)
 512         else
 513           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 514       else
 515         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 516     | IDENT "symbol"; symbol = QSTRING;
 517       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 518       SYMBOL "="; dsc = QSTRING ->
 519         let instance =
 520           match instance with Some i -> int_of_string i | None -> 0
 521         in
 522         TacticAst.Symbol_alias (symbol, instance, dsc)
 523     | IDENT "num";
 524       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 525       SYMBOL "="; dsc = QSTRING ->
 526         let instance =
 527           match instance with Some i -> int_of_string i | None -> 0
 528         in
 529         TacticAst.Number_alias (instance, dsc)
 530     ]
 531   ];
 532
 533   command: [[
 534       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 535         TacticAst.Set (loc, n, v)
 536     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 537     | flavour = theorem_flavour; name = OPT IDENT; SYMBOL ":"; typ = term;
 538       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 539         TacticAst.Theorem (loc, flavour, name, typ, body)
 540     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 541         defs = let_defs ->
 542           let name,ty =
 543             match defs with
 544             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 545             | ((Cic.Name name,None),_,_) :: _ ->
 546                 fail loc ("No type given for " ^ name)
 547             | _ -> assert false
 548           in
 549           let body = CicAst.Ident (name,None) in
 550           TacticAst.Theorem(loc, `Definition, Some name, ty,
 551             Some (CicAst.LetRec (ind_kind, defs, body)))
 552
 553     | [ IDENT "inductive" ]; spec = inductive_spec ->
 554         let (params, ind_types) = spec in
 555         TacticAst.Inductive (loc, params, ind_types)
 556     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 557         let (params, ind_types) = spec in
 558         let ind_types = (* set inductive flags to false (coinductive) *)
 559           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 560             ind_types
 561         in
 562         TacticAst.Inductive (loc, params, ind_types)
 563     | [ IDENT "coercion" ] ; name = IDENT ->
 564         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 565     | [ IDENT "coercion" ] ; name = URI ->
 566         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 567     | [ IDENT "alias"   ]; spec = alias_spec ->
 568         TacticAst.Alias (loc, spec)
 569   ]];
 570
 571   executable: [
 572     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 573     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 574     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 575     ]
 576   ];
 577
 578   comment: [
 579     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 580        TacticAst.Code (loc, ex)
 581     | str = NOTE ->
 582        TacticAst.Note (loc, str)
 583     ]
 584   ];
 585
 586   statement: [
 587     [ ex = executable -> TacticAst.Executable (loc,ex)
 588     | com = comment -> TacticAst.Comment (loc, com)
 589     ]
 590   ];
 591   statements: [
 592     [ l = LIST0 [ statement ] -> l
 593     ]
 594   ];
 595 END
 596
 597 let exc_located_wrapper f =
 598   try
 599     f ()
 600   with
 601   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 602       raise (Parse_error (floc, msg))
 603   | Stdpp.Exc_located (floc, exn) ->
 604       raise (Parse_error (floc, (Printexc.to_string exn)))
 605
 606 let parse_term stream =
 607   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 608 let parse_statement stream =
 609   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 610 let parse_statements stream =
 611   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 612
 613
 614 (**/**)
 615
 616 (** {2 Interface for gTopLevel} *)
 617
 618 module EnvironmentP3 =
 619   struct
 620     type t = environment
 621
 622     let empty = ""
 623
 624     let aliases_grammar = Grammar.gcreate cic_lexer
 625     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 626
 627     let to_string env =
 628       let aliases =
 629         Environment.fold
 630           (fun domain_item (dsc, _) acc ->
 631             let s =
 632               match domain_item with
 633               | Id id ->
 634                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 635               | Symbol (symb, i) ->
 636                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 637                   ^ "."
 638               | Num i ->
 639                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 640             in
 641             s :: acc)
 642           env []
 643       in
 644       String.concat "\n" (List.sort compare aliases)
 645
 646     EXTEND
 647       GLOBAL: aliases;
 648       aliases: [  (* build an environment from an aliases list *)
 649         [ aliases = LIST0 alias; EOI ->
 650             List.fold_left
 651               (fun env (domain_item, codomain_item) ->
 652                 Environment.add domain_item codomain_item env)
 653               Environment.empty aliases
 654         ]
 655       ];
 656       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 657         [ IDENT "alias";
 658           choice =
 659             [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
 660                 (Id id, choice_of_uri uri)
 661             | IDENT "symbol"; symbol = QSTRING;
 662               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 663               SYMBOL "="; dsc = QSTRING ->
 664                 (Symbol (symbol, int_of_string instance),
 665                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 666             | IDENT "num";
 667               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 668               SYMBOL "="; dsc = QSTRING ->
 669                 (Num (int_of_string instance),
 670                  DisambiguateChoices.lookup_num_by_dsc dsc)
 671             ] -> choice ]
 672       ];
 673     END
 674
 675     let of_string s =
 676       if s = empty then
 677         Environment.empty
 678       else
 679         exc_located_wrapper
 680           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 681   end
 682
 683 (* vim:set encoding=utf8: *)