helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri uri =
  57   let term = CicUtil.term_of_uri uri in
  58   (uri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72
  73 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  74
  75 let fail floc msg =
  76   let (x, y) = CicAst.loc_of_floc floc in
  77   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  78
  79 let name_of_string = function
  80   | "_" -> Cic.Anonymous
  81   | s -> Cic.Name s
  82
  83 let string_of_name = function
  84   | Cic.Anonymous -> "_"
  85   | Cic.Name s -> s
  86
  87 let int_opt = function
  88   | None -> None
  89   | Some lexeme -> Some (int_of_string lexeme)
  90
  91 let int_of_string s =
  92   try
  93     Pervasives.int_of_string s
  94   with Failure _ ->
  95     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  96
  97   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  98   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
  99   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 100   * type in a block of mutual inductive types.
 101   *
 102   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 103   *)
 104 let ind_expansion uri =
 105   let len = String.length uri in
 106   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 107     uri ^ "#xpointer(1/1)"
 108   else
 109     uri
 110
 111 let mk_binder_ast binder typ vars body =
 112   List.fold_right
 113     (fun var body ->
 114        let name = name_of_string var in
 115        CicAst.Binder (binder, (name, typ), body))
 116     vars body
 117
 118 EXTEND
 119   GLOBAL: term term0 statement;
 120   int: [
 121     [ num = NUM ->
 122         try
 123           int_of_string num
 124         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 125     ]
 126   ];
 127   meta_subst: [
 128     [ s = SYMBOL "_" -> None
 129     | t = term -> Some t ]
 130   ];
 131   binder_low: [
 132     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 133     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 134     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 135   ];
 136   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 137   sort: [
 138     [ "Prop" -> `Prop
 139     | "Set" -> `Set
 140     | "Type" -> `Type
 141     | "CProp" -> `CProp ]
 142   ];
 143   typed_name: [
 144     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 145         (Cic.Name i, Some typ)
 146     | i = IDENT -> (Cic.Name i, None)
 147     ]
 148   ];
 149   subst: [
 150     [ subst = OPT [
 151         SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152         PAREN "[";
 153         substs = LIST1 [
 154           i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155         ] SEP SYMBOL ";";
 156         PAREN "]" ->
 157           substs
 158       ] -> subst
 159     ]
 160   ];
 161   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 162     [ s = IDENT; subst = subst -> CicAst.Ident (s, subst)
 163     | s = URI; subst = subst -> CicAst.Uri (ind_expansion s, subst)
 164     ]
 165   ];
 166   name: [ (* as substituted_name with no explicit substitution *)
 167     [ s = [ IDENT | SYMBOL ] -> s ]
 168   ];
 169   pattern: [
 170     [ n = name -> (n, [])
 171     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 172         (head, vars)
 173     ]
 174   ];
 175   let_defs:[
 176     [ defs = LIST1 [
 177         name = IDENT;
 178         args = LIST1 [
 179           PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 180           ty = term; PAREN ")" ->
 181             (names, ty)
 182         ];
 183         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 184         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 185         SYMBOL <:unicode<def>> (* ≝ *);
 186         t1 = term ->
 187           let rec list_of_binder binder ty final_term = function
 188             | [] -> final_term
 189             | name::tl ->
 190                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 191                   list_of_binder binder ty final_term tl)
 192           in
 193           let rec binder_of_arg_list binder final_term = function
 194             | [] -> final_term
 195             | (l,ty)::tl ->
 196                 list_of_binder binder ty
 197                   (binder_of_arg_list binder final_term tl) l
 198           in
 199           let t1' = binder_of_arg_list `Lambda t1 args in
 200           let ty' =
 201             match ty with
 202             | None -> None
 203             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 204           in
 205           let rec get_position_of name n = function
 206             | [] -> (None,n)
 207             | nam::tl ->
 208                 if nam = name then
 209                   (Some n,n)
 210                 else
 211                   (get_position_of name (n+1) tl)
 212           in
 213           let rec find_arg name n = function
 214             | [] -> (fail loc (sprintf "Argument %s not found" name))
 215             | (l,_)::tl ->
 216                 let (got,len) = get_position_of name 0 l in
 217                 (match got with
 218                 | None -> (find_arg name (n+len) tl)
 219                 | Some where -> n + where)
 220           in
 221           let index =
 222             (match index_name with
 223              | None -> 0
 224              | (Some name) -> find_arg name 0 args)
 225           in
 226           ((Cic.Name name,ty'), t1', index)
 227       ] SEP "and" -> defs
 228     ]];
 229   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 230   binder_vars: [
 231       [ vars = LIST1 IDENT SEP SYMBOL ",";
 232         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 233       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 234         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 235       ]
 236   ];
 237   term0: [ [ t = term; EOI -> return_term loc t ] ];
 238   term:
 239     [ "letin" NONA
 240       [ "let"; var = typed_name;
 241         SYMBOL <:unicode<def>> (* ≝ *);
 242         t1 = term; "in"; t2 = term ->
 243           return_term loc (CicAst.LetIn (var, t1, t2))
 244       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 245         defs = let_defs; "in"; body = term ->
 246             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 247       ]
 248     | "binder" RIGHTA
 249       [
 250         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 251           let binder = mk_binder_ast b typ vars body in
 252           return_term loc binder
 253       ]
 254     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 255     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 256     | "logic_inv" NONA    [ (* nothing here by default *) ]
 257     | "relop" LEFTA
 258       [ t1 = term; SYMBOL "="; t2 = term ->
 259         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 260       ]
 261     | "add" LEFTA     [ (* nothing here by default *) ]
 262     | "mult" LEFTA    [ (* nothing here by default *) ]
 263     | "power" LEFTA   [ (* nothing here by default *) ]
 264     | "inv" NONA      [ (* nothing here by default *) ]
 265     | "apply" LEFTA
 266       [ t1 = term; t2 = term ->
 267         let rec aux = function
 268           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 269           | term -> [term]
 270         in
 271         CicAst.Appl (aux t1 @ [t2])
 272       ]
 273     | "binder" RIGHTA
 274       [
 275         b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 276           let binder = mk_binder_ast b typ vars body in
 277           return_term loc binder
 278       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 279           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 280       ]
 281     | "simple" NONA
 282       [ sort = sort -> CicAst.Sort sort
 283       | n = substituted_name -> return_term loc n
 284       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 285       | IMPLICIT -> return_term loc CicAst.Implicit
 286       | m = META;
 287         substs = [
 288           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 289             substs
 290         ] ->
 291             let index =
 292               try
 293                 int_of_string (String.sub m 1 (String.length m - 1))
 294               with Failure "int_of_string" ->
 295                 fail loc ("Invalid meta variable number: " ^ m)
 296             in
 297             return_term loc (CicAst.Meta (index, substs))
 298       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 299         "match"; t = term;
 300         indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
 301         "with";
 302         PAREN "[";
 303         patterns = LIST0 [
 304           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 305           ->
 306             ((lhs: CicAst.case_pattern), rhs)
 307         ] SEP SYMBOL "|";
 308         PAREN "]" ->
 309           return_term loc
 310             (CicAst.Case (t, indty_ident, outtyp, patterns))
 311       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 312           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 313       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 314       ]
 315     ];
 316   tactic_where: [
 317     [ where = OPT [ "in"; ident = IDENT -> ident ] -> where ]
 318   ];
 319   tactic_term: [ [ t = term -> t ] ];
 320   ident_list0: [
 321     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 322   ];
 323   ident_list1: [
 324     [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 325   ];
 326   reduction_kind: [
 327     [ [ IDENT "reduce" ] -> `Reduce
 328     | [ IDENT "simplify" ] -> `Simpl
 329     | [ IDENT "whd" ] -> `Whd ]
 330   ];
 331   tactic: [
 332     [ [ IDENT "absurd" ]; t = tactic_term ->
 333         TacticAst.Absurd (loc, t)
 334     | [ IDENT "apply" ]; t = tactic_term ->
 335         TacticAst.Apply (loc, t)
 336     | [ IDENT "assumption" ] ->
 337         TacticAst.Assumption loc
 338     | [ IDENT "auto" ] ; num = OPT [ i = NUM -> int_of_string i ] ->
 339           TacticAst.Auto (loc,num)
 340     | [ IDENT "change" ];
 341       t1 = tactic_term; "with"; t2 = tactic_term;
 342       where = tactic_where ->
 343         TacticAst.Change (loc, t1, t2, where)
 344     (* TODO Change_pattern *)
 345     | [ IDENT "contradiction" ] ->
 346         TacticAst.Contradiction loc
 347     | [ IDENT "cut" ];
 348       t = tactic_term ->
 349         TacticAst.Cut (loc, t)
 350     | [ IDENT "decompose" ];
 351       principles = ident_list1; where = IDENT ->
 352         TacticAst.Decompose (loc, where, principles)
 353     | [ IDENT "discriminate" ];
 354       hyp = IDENT ->
 355         TacticAst.Discriminate (loc, hyp)
 356     | [ IDENT "elimType" ]; t = tactic_term ->
 357         TacticAst.ElimType (loc, t)
 358     | [ IDENT "elim" ];
 359       t1 = tactic_term;
 360       using = OPT [ "using"; using = tactic_term -> using ] ->
 361         TacticAst.Elim (loc, t1, using)
 362     | [ IDENT "exact" ]; t = tactic_term ->
 363         TacticAst.Exact (loc, t)
 364     | [ IDENT "exists" ] ->
 365         TacticAst.Exists loc
 366     | [ IDENT "fold" ];
 367       kind = reduction_kind; t = tactic_term ->
 368         TacticAst.Fold (loc, kind, t)
 369     | [ IDENT "fourier" ] ->
 370         TacticAst.Fourier loc
 371     | IDENT "goal"; n = NUM -> TacticAst.Goal (loc, int_of_string n)
 372     | [ IDENT "injection" ]; ident = IDENT ->
 373         TacticAst.Injection (loc, ident)
 374     | [ IDENT "intros" ];
 375       num = OPT [ num = int -> num ];
 376       idents = OPT ident_list0 ->
 377         let idents = match idents with None -> [] | Some idents -> idents in
 378         TacticAst.Intros (loc, num, idents)
 379     | [ IDENT "intro" ] ->
 380         TacticAst.Intros (loc, None, [])
 381     | [ IDENT "left" ] -> TacticAst.Left loc
 382     | [ "let" | "Let" ];
 383       t = tactic_term; "in"; where = IDENT ->
 384         TacticAst.LetIn (loc, t, where)
 385     | kind = reduction_kind;
 386       pat = OPT [
 387         "in"; pat = [ IDENT "goal" -> `Goal | IDENT "hyp" -> `Everywhere ] ->
 388           pat
 389       ];
 390       terms = LIST0 term SEP SYMBOL "," ->
 391         (match (pat, terms) with
 392         | None, [] -> TacticAst.Reduce (loc, kind, None)
 393         | None, terms -> TacticAst.Reduce (loc, kind, Some (terms, `Goal))
 394         | Some pat, [] -> fail loc "Missing term [list]"
 395         | Some pat, terms -> TacticAst.Reduce (loc, kind, Some (terms, pat)))
 396     | [ IDENT "reflexivity" ] ->
 397         TacticAst.Reflexivity loc
 398     | [ IDENT "replace" ];
 399       t1 = tactic_term; "with"; t2 = tactic_term ->
 400         TacticAst.Replace (loc, t1, t2)
 401     | [ IDENT "rewrite" ; IDENT "left" ] ; t = term ->
 402         TacticAst.Rewrite (loc,`Left, t, None)
 403     | [ IDENT "rewrite" ; IDENT "right" ] ; t = term ->
 404         TacticAst.Rewrite (loc,`Right, t, None)
 405     (* TODO Replace_pattern *)
 406     | [ IDENT "right" ] -> TacticAst.Right loc
 407     | [ IDENT "ring" ] -> TacticAst.Ring loc
 408     | [ IDENT "split" ] -> TacticAst.Split loc
 409     | [ IDENT "symmetry" ] ->
 410         TacticAst.Symmetry loc
 411     | [ IDENT "transitivity" ];
 412       t = tactic_term ->
 413         TacticAst.Transitivity (loc, t)
 414     ]
 415   ];
 416   tactical:
 417     [ "sequence" LEFTA
 418       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 419           TacticAst.Seq (loc, tacticals)
 420       ]
 421     | "then" NONA
 422       [ tac = tactical;
 423         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 424           (TacticAst.Then (loc, tac, tacs))
 425       ]
 426     | "loops" RIGHTA
 427       [ [ IDENT "do" ]; count = int; tac = tactical ->
 428           TacticAst.Do (loc, count, tac)
 429       | [ IDENT "repeat" ]; tac = tactical ->
 430           TacticAst.Repeat (loc, tac)
 431       ]
 432     | "simple" NONA
 433       [ IDENT "tries";
 434         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 435           TacticAst.Tries (loc, tacs)
 436       | IDENT "try"; tac = NEXT ->
 437           TacticAst.Try (loc, tac)
 438       | IDENT "fail" -> TacticAst.Fail loc
 439       | IDENT "id" -> TacticAst.IdTac loc
 440       | PAREN "("; tac = tactical; PAREN ")" -> tac
 441       | tac = tactic -> TacticAst.Tactic (loc, tac)
 442       ]
 443     ];
 444   theorem_flavour: [
 445     [ [ IDENT "definition"  ] -> `Definition
 446     | [ IDENT "fact"        ] -> `Fact
 447     | [ IDENT "lemma"       ] -> `Lemma
 448     | [ IDENT "remark"      ] -> `Remark
 449     | [ IDENT "theorem"     ] -> `Theorem
 450     ]
 451   ];
 452   inductive_spec: [ [
 453     fst_name = IDENT; params = LIST0 [
 454       PAREN "("; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 455       typ = term; PAREN ")" -> (names, typ) ];
 456     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 457     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 458     tl = OPT [ "with";
 459       types = LIST1 [
 460         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 461        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 462           (name, true, typ, constructors) ] SEP "with" -> types
 463     ] ->
 464       let params =
 465         List.fold_right
 466           (fun (names, typ) acc ->
 467             (List.map (fun name -> (name, typ)) names) @ acc)
 468           params []
 469       in
 470       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 471       let tl_ind_types = match tl with None -> [] | Some types -> types in
 472       let ind_types = fst_ind_type :: tl_ind_types in
 473       (params, ind_types)
 474   ] ];
 475
 476   macro: [[
 477       [ IDENT "abort" ] -> TacticAst.Abort loc
 478     | [ IDENT "quit"  ] -> TacticAst.Quit loc
 479     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 480     | [ IDENT "undo"   ]; steps = OPT NUM ->
 481         TacticAst.Undo (loc, int_opt steps)
 482     | [ IDENT "redo"   ]; steps = OPT NUM ->
 483         TacticAst.Redo (loc, int_opt steps)
 484     | [ IDENT "check"   ]; t = term ->
 485         TacticAst.Check (loc, t)
 486     | [ IDENT "hint" ] -> TacticAst.Hint loc
 487     | [ IDENT "whelp"; "match" ] ; t = term ->
 488         TacticAst.WMatch (loc,t)
 489     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 490         TacticAst.WInstance (loc,t)
 491     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 492         TacticAst.WLocate (loc,id)
 493     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 494         TacticAst.WElim (loc, t)
 495     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 496         TacticAst.WHint (loc,t)
 497     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 498   ]];
 499
 500   alias_spec: [
 501     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 502       let alpha = "[a-zA-Z]" in
 503       let num = "[0-9]+" in
 504       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 505       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 506       let rex = Str.regexp ("^"^ident^"$") in
 507       if Str.string_match rex id 0 then
 508         let rex = Str.regexp
 509           ("^\\(cic:/\\|theory:/\\)"^ident^
 510            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 511            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 512         in
 513         if Str.string_match rex uri 0 then
 514           TacticAst.Ident_alias (id, uri)
 515         else
 516           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 517       else
 518         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 519     | IDENT "symbol"; symbol = QSTRING;
 520       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 521       SYMBOL "="; dsc = QSTRING ->
 522         let instance =
 523           match instance with Some i -> int_of_string i | None -> 0
 524         in
 525         TacticAst.Symbol_alias (symbol, instance, dsc)
 526     | IDENT "num";
 527       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 528       SYMBOL "="; dsc = QSTRING ->
 529         let instance =
 530           match instance with Some i -> int_of_string i | None -> 0
 531         in
 532         TacticAst.Number_alias (instance, dsc)
 533     ]
 534   ];
 535
 536   command: [[
 537       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 538         TacticAst.Set (loc, n, v)
 539     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 540     | flavour = theorem_flavour; name = OPT IDENT; SYMBOL ":"; typ = term;
 541       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 542         TacticAst.Theorem (loc, flavour, name, typ, body)
 543     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 544         defs = let_defs ->
 545           let name,ty =
 546             match defs with
 547             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 548             | ((Cic.Name name,None),_,_) :: _ ->
 549                 fail loc ("No type given for " ^ name)
 550             | _ -> assert false
 551           in
 552           let body = CicAst.Ident (name,None) in
 553           TacticAst.Theorem(loc, `Definition, Some name, ty,
 554             Some (CicAst.LetRec (ind_kind, defs, body)))
 555
 556     | [ IDENT "inductive" ]; spec = inductive_spec ->
 557         let (params, ind_types) = spec in
 558         TacticAst.Inductive (loc, params, ind_types)
 559     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 560         let (params, ind_types) = spec in
 561         let ind_types = (* set inductive flags to false (coinductive) *)
 562           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 563             ind_types
 564         in
 565         TacticAst.Inductive (loc, params, ind_types)
 566     | [ IDENT "coercion" ] ; name = IDENT ->
 567         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 568     | [ IDENT "coercion" ] ; name = URI ->
 569         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 570     | [ IDENT "alias"   ]; spec = alias_spec ->
 571         TacticAst.Alias (loc, spec)
 572   ]];
 573
 574   executable: [
 575     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 576     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 577     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 578     ]
 579   ];
 580
 581   comment: [
 582     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 583        TacticAst.Code (loc, ex)
 584     | str = NOTE ->
 585        TacticAst.Note (loc, str)
 586     ]
 587   ];
 588
 589   statement: [
 590     [ ex = executable -> TacticAst.Executable (loc,ex)
 591     | com = comment -> TacticAst.Comment (loc, com)
 592     ]
 593   ];
 594 END
 595
 596 let exc_located_wrapper f =
 597   try
 598     f ()
 599   with
 600   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 601       raise (Parse_error (floc, msg))
 602   | Stdpp.Exc_located (floc, exn) ->
 603       raise (Parse_error (floc, (Printexc.to_string exn)))
 604
 605 let parse_term stream =
 606   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 607 let parse_statement stream =
 608   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 609
 610 (**/**)
 611
 612 (** {2 Interface for gTopLevel} *)
 613
 614 module EnvironmentP3 =
 615   struct
 616     type t = environment
 617
 618     let empty = ""
 619
 620     let aliases_grammar = Grammar.gcreate cic_lexer
 621     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 622
 623     let to_string env =
 624       let aliases =
 625         Environment.fold
 626           (fun domain_item (dsc, _) acc ->
 627             let s =
 628               match domain_item with
 629               | Id id ->
 630                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 631               | Symbol (symb, i) ->
 632                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 633                   ^ "."
 634               | Num i ->
 635                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 636             in
 637             s :: acc)
 638           env []
 639       in
 640       String.concat "\n" (List.sort compare aliases)
 641
 642     EXTEND
 643       GLOBAL: aliases;
 644       aliases: [  (* build an environment from an aliases list *)
 645         [ aliases = LIST0 alias; EOI ->
 646             List.fold_left
 647               (fun env (domain_item, codomain_item) ->
 648                 Environment.add domain_item codomain_item env)
 649               Environment.empty aliases
 650         ]
 651       ];
 652       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 653         [ IDENT "alias";
 654           choice =
 655             [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
 656                 (Id id, choice_of_uri uri)
 657             | IDENT "symbol"; symbol = QSTRING;
 658               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 659               SYMBOL "="; dsc = QSTRING ->
 660                 (Symbol (symbol, int_of_string instance),
 661                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 662             | IDENT "num";
 663               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 664               SYMBOL "="; dsc = QSTRING ->
 665                 (Num (int_of_string instance),
 666                  DisambiguateChoices.lookup_num_by_dsc dsc)
 667             ] -> choice ]
 668       ];
 669     END
 670
 671     let of_string s =
 672       if s = empty then
 673         Environment.empty
 674       else
 675         exc_located_wrapper
 676           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 677   end
 678
 679 (* vim:set encoding=utf8: *)