helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri suri =
  57   let term = CicUtil.term_of_uri (UriManager.uri_of_string suri) in
  58   (suri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   arg: [
 175    [ PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ",";
 176       SYMBOL ":"; ty = term; PAREN ")" -> names,ty
 177    | name = IDENT -> [name],CicAst.Implicit
 178    ]
 179   ];
 180   let_defs:[
 181     [ defs = LIST1 [
 182         name = IDENT;
 183         args = LIST1 [arg = arg -> arg];
 184         index_name = OPT [ "on"; idx = IDENT -> idx ];
 185         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 186         SYMBOL <:unicode<def>> (* ≝ *);
 187         t1 = term ->
 188           let rec list_of_binder binder ty final_term = function
 189             | [] -> final_term
 190             | name::tl ->
 191                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 192                   list_of_binder binder ty final_term tl)
 193           in
 194           let rec binder_of_arg_list binder final_term = function
 195             | [] -> final_term
 196             | (l,ty)::tl ->
 197                 list_of_binder binder ty
 198                   (binder_of_arg_list binder final_term tl) l
 199           in
 200           let t1' = binder_of_arg_list `Lambda t1 args in
 201           let ty' =
 202             match ty with
 203             | None -> None
 204             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 205           in
 206           let rec get_position_of name n = function
 207             | [] -> (None,n)
 208             | nam::tl ->
 209                 if nam = name then
 210                   (Some n,n)
 211                 else
 212                   (get_position_of name (n+1) tl)
 213           in
 214           let rec find_arg name n = function
 215             | [] -> (fail loc (sprintf "Argument %s not found" name))
 216             | (l,_)::tl ->
 217                 let (got,len) = get_position_of name 0 l in
 218                 (match got with
 219                 | None -> (find_arg name (n+len) tl)
 220                 | Some where -> n + where)
 221           in
 222           let index =
 223             (match index_name with
 224              | None -> 0
 225              | (Some name) -> find_arg name 0 args)
 226           in
 227           ((Cic.Name name,ty'), t1', index)
 228       ] SEP "and" -> defs
 229     ]];
 230   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 231   binder_vars: [
 232       [ vars = [ l = LIST1 IDENT SEP SYMBOL "," -> l | SYMBOL "_" -> ["_"]];
 233         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 234       | PAREN "(";
 235           vars = [ l =  LIST1 IDENT SEP SYMBOL "," -> l | SYMBOL "_" -> ["_"]];
 236           typ = OPT [ SYMBOL ":"; t = term -> t ];
 237         PAREN ")" -> (vars, typ)
 238       ]
 239   ];
 240   term0: [ [ t = term; EOI -> return_term loc t ] ];
 241   term:
 242     [ "letin" NONA
 243       [ "let"; var = typed_name;
 244         SYMBOL <:unicode<def>> (* ≝ *);
 245         t1 = term; "in"; t2 = term ->
 246           return_term loc (CicAst.LetIn (var, t1, t2))
 247       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 248         defs = let_defs; "in"; body = term ->
 249             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 250       ]
 251     | "binder" RIGHTA
 252       [
 253         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 254           let binder = mk_binder_ast b typ vars body in
 255           return_term loc binder
 256       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 257           let binder = mk_binder_ast b typ vars body in
 258           return_term loc binder
 259       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 260           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 261       ]
 262     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 263     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 264     | "logic_inv" NONA    [ (* nothing here by default *) ]
 265     | "relop" LEFTA
 266       [ t1 = term; SYMBOL "="; t2 = term ->
 267         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 268       ]
 269     | "add" LEFTA     [ (* nothing here by default *) ]
 270     | "mult" LEFTA    [ (* nothing here by default *) ]
 271     | "power" LEFTA   [ (* nothing here by default *) ]
 272     | "inv" NONA      [ (* nothing here by default *) ]
 273     | "apply" LEFTA
 274       [ t1 = term; t2 = term ->
 275         let rec aux = function
 276           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 277           | term -> [term]
 278         in
 279         CicAst.Appl (aux t1 @ [t2])
 280       ]
 281     | "simple" NONA
 282       [ sort = sort -> CicAst.Sort sort
 283       | n = substituted_name -> return_term loc n
 284       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 285       | IMPLICIT -> return_term loc CicAst.Implicit
 286       | PLACEHOLDER -> return_term loc CicAst.UserInput
 287       | m = META;
 288         substs = [
 289           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 290             substs
 291         ] ->
 292             let index =
 293               try
 294                 int_of_string (String.sub m 1 (String.length m - 1))
 295               with Failure "int_of_string" ->
 296                 fail loc ("Invalid meta variable number: " ^ m)
 297             in
 298             return_term loc (CicAst.Meta (index, substs))
 299       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 300         "match"; t = term;
 301         indty_ident = OPT ["in" ; id = IDENT -> id ];
 302         "with";
 303         PAREN "[";
 304         patterns = LIST0 [
 305           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 306           ->
 307             ((lhs: CicAst.case_pattern), rhs)
 308         ] SEP SYMBOL "|";
 309         PAREN "]" ->
 310           return_term loc
 311             (CicAst.Case (t, indty_ident, outtyp, patterns))
 312       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 313           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 314       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 315       ]
 316     ];
 317   tactic_term: [ [ t = term -> t ] ];
 318   ident_list0: [
 319     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 320   ];
 321   tactic_term_list1: [
 322     [ tactic_terms = LIST1 tactic_term SEP SYMBOL "," -> tactic_terms ]
 323   ];
 324   reduction_kind: [
 325     [ [ IDENT "reduce" ] -> `Reduce
 326     | [ IDENT "simplify" ] -> `Simpl
 327     | [ IDENT "whd" ] -> `Whd
 328     | [ IDENT "normalize" ] -> `Normalize ]
 329   ];
 330   sequent_pattern_spec : [
 331    [ hyp_paths =
 332       LIST0
 333        [ id = IDENT ;
 334          path = OPT [SYMBOL ":" ; path = term -> path ] ->
 335          (id,match path with Some p -> p | None -> CicAst.UserInput) ]
 336        SEP SYMBOL ";";
 337      goal_path = OPT [ SYMBOL <:unicode<vdash>>; term = term -> term ] ->
 338       let goal_path =
 339        match goal_path with
 340           None -> CicAst.UserInput
 341         | Some goal_path -> goal_path
 342       in
 343        hyp_paths,goal_path
 344    ]
 345   ];
 346   pattern_spec: [
 347     [ res = OPT [
 348        "in";
 349        wanted_and_sps =
 350         [ "match" ; wanted = term ;
 351           sps = OPT [ "in"; sps = sequent_pattern_spec -> sps ] ->
 352            Some wanted,sps
 353         | sps = sequent_pattern_spec ->
 354            None,Some sps
 355         ] ->
 356          let wanted,hyp_paths,goal_path =
 357           match wanted_and_sps with
 358              wanted,None -> wanted, [], CicAst.UserInput
 359            | wanted,Some (hyp_paths,goal_path) -> wanted,hyp_paths,goal_path
 360          in
 361           wanted, hyp_paths, goal_path ] ->
 362       match res with
 363          None -> None,[],CicAst.UserInput
 364        | Some ps -> ps]
 365   ];
 366   direction: [
 367     [ SYMBOL ">" -> `LeftToRight
 368     | SYMBOL "<" -> `RightToLeft ]
 369   ];
 370   tactic: [
 371     [ IDENT "absurd"; t = tactic_term ->
 372         TacticAst.Absurd (loc, t)
 373     | IDENT "apply"; t = tactic_term ->
 374         TacticAst.Apply (loc, t)
 375     | IDENT "assumption" ->
 376         TacticAst.Assumption loc
 377     | IDENT "auto";
 378       depth = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ];
 379       width = OPT [ IDENT "width"; SYMBOL "="; i = NUM -> int_of_string i ] ->
 380           TacticAst.Auto (loc,depth,width)
 381     | IDENT "clear"; id = IDENT ->
 382         TacticAst.Clear (loc,id)
 383     | IDENT "clearbody"; id = IDENT ->
 384         TacticAst.ClearBody (loc,id)
 385     | IDENT "change"; what = pattern_spec; "with"; t = tactic_term ->
 386         TacticAst.Change (loc, what, t)
 387     | IDENT "compare"; t = tactic_term ->
 388         TacticAst.Compare (loc,t)
 389     | IDENT "constructor"; n = NUM ->
 390         TacticAst.Constructor (loc,int_of_string n)
 391     | IDENT "contradiction" ->
 392         TacticAst.Contradiction loc
 393     | IDENT "cut"; t = tactic_term; ident = OPT [ "as"; id = IDENT -> id] ->
 394         TacticAst.Cut (loc, ident, t)
 395     | IDENT "decide"; IDENT "equality" ->
 396         TacticAst.DecideEquality loc
 397     | IDENT "decompose"; where = tactic_term ->
 398         TacticAst.Decompose (loc, where)
 399     | IDENT "discriminate"; t = tactic_term ->
 400         TacticAst.Discriminate (loc, t)
 401     | IDENT "elim"; t1 = tactic_term;
 402       using = OPT [ "using"; using = tactic_term -> using ] ->
 403         TacticAst.Elim (loc, t1, using)
 404     | IDENT "elimType"; t = tactic_term ->
 405         TacticAst.ElimType (loc, t)
 406     | IDENT "exact"; t = tactic_term ->
 407         TacticAst.Exact (loc, t)
 408     | IDENT "exists" ->
 409         TacticAst.Exists loc
 410     | IDENT "fail" -> TacticAst.Fail loc
 411     | IDENT "fold"; kind = reduction_kind; t = tactic_term; p = pattern_spec ->
 412        let (pt,_,_) = p in
 413         if pt <> None then
 414          raise
 415           (Parse_error
 416             (loc,"the pattern cannot specify the term to replace, only its paths in the hypotheses and in the conclusion"))
 417         else
 418          TacticAst.Fold (loc, kind, t, p)
 419     | IDENT "fourier" ->
 420         TacticAst.Fourier loc
 421     | IDENT "fwd"; hyp = IDENT; idents = OPT ident_list0 ->
 422         let idents = match idents with None -> [] | Some idents -> idents in
 423         TacticAst.FwdSimpl (loc, hyp, idents)
 424     | IDENT "generalize"; p=pattern_spec; id = OPT ["as" ; id = IDENT -> id] ->
 425        TacticAst.Generalize (loc,p,id)
 426     | IDENT "goal"; n = NUM ->
 427         TacticAst.Goal (loc, int_of_string n)
 428     | IDENT "id" -> TacticAst.IdTac loc
 429     | IDENT "injection"; t = tactic_term ->
 430         TacticAst.Injection (loc, t)
 431     | IDENT "intro"; ident = OPT IDENT ->
 432         let idents = match ident with None -> [] | Some id -> [id] in
 433         TacticAst.Intros (loc, Some 1, idents)
 434     | IDENT "intros"; num = OPT [num = int -> num]; idents = OPT ident_list0 ->
 435         let idents = match idents with None -> [] | Some idents -> idents in
 436         TacticAst.Intros (loc, num, idents)
 437     | IDENT "lapply";
 438       depth = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ];
 439       what = tactic_term;
 440       to_what = OPT [ "to" ; t = tactic_term_list1 -> t ];
 441       ident = OPT [ "using" ; ident = IDENT -> ident ] ->
 442         let to_what = match to_what with None -> [] | Some to_what -> to_what in
 443         TacticAst.LApply (loc, depth, to_what, what, ident)
 444     | IDENT "left" -> TacticAst.Left loc
 445     | IDENT "letin"; where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 446         TacticAst.LetIn (loc, t, where)
 447     | kind = reduction_kind; p = pattern_spec ->
 448         TacticAst.Reduce (loc, kind, p)
 449     | IDENT "reflexivity" ->
 450         TacticAst.Reflexivity loc
 451     | IDENT "replace"; p = pattern_spec; "with"; t = tactic_term ->
 452         TacticAst.Replace (loc, p, t)
 453     | IDENT "rewrite" ; d = direction; t = tactic_term ; p = pattern_spec ->
 454        let (pt,_,_) = p in
 455         if pt <> None then
 456          raise
 457           (Parse_error
 458             (loc,"the pattern cannot specify the term to rewrite, only its paths in the hypotheses and in the conclusion"))
 459         else
 460          TacticAst.Rewrite (loc, d, t, p)
 461     | IDENT "right" ->
 462         TacticAst.Right loc
 463     | IDENT "ring" ->
 464         TacticAst.Ring loc
 465     | IDENT "split" ->
 466         TacticAst.Split loc
 467     | IDENT "symmetry" ->
 468         TacticAst.Symmetry loc
 469     | IDENT "transitivity"; t = tactic_term ->
 470         TacticAst.Transitivity (loc, t)
 471     ]
 472   ];
 473   tactical:
 474     [ "sequence" LEFTA
 475       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 476           TacticAst.Seq (loc, tacticals)
 477       ]
 478     | "then" NONA
 479       [ tac = tactical;
 480         PAREN "["; tacs = LIST0 tactical SEP SYMBOL "|"; PAREN "]" ->
 481           (TacticAst.Then (loc, tac, tacs))
 482       ]
 483     | "loops" RIGHTA
 484       [ [ IDENT "do" ]; count = int; tac = tactical ->
 485           TacticAst.Do (loc, count, tac)
 486       | [ IDENT "repeat" ]; tac = tactical ->
 487           TacticAst.Repeat (loc, tac)
 488       ]
 489     | "simple" NONA
 490       [ IDENT "tries";
 491         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 492           TacticAst.Tries (loc, tacs)
 493       | IDENT "try"; tac = NEXT ->
 494           TacticAst.Try (loc, tac)
 495       | PAREN "("; tac = tactical; PAREN ")" -> tac
 496       | tac = tactic -> TacticAst.Tactic (loc, tac)
 497       ]
 498     ];
 499   theorem_flavour: [
 500     [ [ IDENT "definition"  ] -> `Definition
 501     | [ IDENT "fact"        ] -> `Fact
 502     | [ IDENT "lemma"       ] -> `Lemma
 503     | [ IDENT "remark"      ] -> `Remark
 504     | [ IDENT "theorem"     ] -> `Theorem
 505     ]
 506   ];
 507   inductive_spec: [ [
 508     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 509     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 510     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 511     tl = OPT [ "with";
 512       types = LIST1 [
 513         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 514        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 515           (name, true, typ, constructors) ] SEP "with" -> types
 516     ] ->
 517       let params =
 518         List.fold_right
 519           (fun (names, typ) acc ->
 520             (List.map (fun name -> (name, typ)) names) @ acc)
 521           params []
 522       in
 523       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 524       let tl_ind_types = match tl with None -> [] | Some types -> types in
 525       let ind_types = fst_ind_type :: tl_ind_types in
 526       (params, ind_types)
 527   ] ];
 528
 529   record_spec: [ [
 530     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 531      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; PAREN "{" ;
 532      fields = LIST0 [
 533        name = IDENT ; SYMBOL ":" ; ty = term -> (name,ty)
 534      ] SEP SYMBOL ";"; PAREN "}" ->
 535       let params =
 536         List.fold_right
 537           (fun (names, typ) acc ->
 538             (List.map (fun name -> (name, typ)) names) @ acc)
 539           params []
 540       in
 541       (params,name,typ,fields)
 542   ] ];
 543
 544   macro: [
 545     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 546 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 547     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 548 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 549         TacticAst.Undo (loc, int_opt steps)
 550     | [ IDENT "redo"   ]; steps = OPT NUM ->
 551         TacticAst.Redo (loc, int_opt steps) *)
 552     | [ IDENT "check"   ]; t = term ->
 553         TacticAst.Check (loc, t)
 554     | [ IDENT "hint" ] -> TacticAst.Hint loc
 555     | [ IDENT "whelp"; "match" ] ; t = term ->
 556         TacticAst.WMatch (loc,t)
 557     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 558         TacticAst.WInstance (loc,t)
 559     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 560         TacticAst.WLocate (loc,id)
 561     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 562         TacticAst.WElim (loc, t)
 563     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 564         TacticAst.WHint (loc,t)
 565     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 566     ]
 567   ];
 568
 569   alias_spec: [
 570     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 571       let alpha = "[a-zA-Z]" in
 572       let num = "[0-9]+" in
 573       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 574       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 575       let rex = Str.regexp ("^"^ident^"$") in
 576       if Str.string_match rex id 0 then
 577         let rex = Str.regexp
 578           ("^\\(cic:/\\|theory:/\\)"^ident^
 579            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 580            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 581         in
 582         if Str.string_match rex uri 0 then
 583           TacticAst.Ident_alias (id, uri)
 584         else
 585           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 586       else
 587         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 588     | IDENT "symbol"; symbol = QSTRING;
 589       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 590       SYMBOL "="; dsc = QSTRING ->
 591         let instance =
 592           match instance with Some i -> int_of_string i | None -> 0
 593         in
 594         TacticAst.Symbol_alias (symbol, instance, dsc)
 595     | IDENT "num";
 596       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 597       SYMBOL "="; dsc = QSTRING ->
 598         let instance =
 599           match instance with Some i -> int_of_string i | None -> 0
 600         in
 601         TacticAst.Number_alias (instance, dsc)
 602     ]
 603   ];
 604
 605   command: [[
 606        [ IDENT "set" ]; n = QSTRING; v = QSTRING ->
 607         TacticAst.Set (loc, n, v)
 608     |  [ IDENT "drop" ] -> TacticAst.Drop loc
 609     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 610     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 611       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 612         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, typ, body))
 613     | flavour = theorem_flavour; name = IDENT;
 614       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 615         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, CicAst.Implicit, body))
 616     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 617         defs = let_defs ->
 618           let name,ty =
 619             match defs with
 620             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 621             | ((Cic.Name name,None),_,_) :: _ -> name,CicAst.Implicit
 622             | _ -> assert false
 623           in
 624           let body = CicAst.Ident (name,None) in
 625           TacticAst.Obj (loc,TacticAst.Theorem(`Definition, name, ty,
 626             Some (CicAst.LetRec (ind_kind, defs, body))))
 627
 628     | [ IDENT "inductive" ]; spec = inductive_spec ->
 629         let (params, ind_types) = spec in
 630         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 631     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 632         let (params, ind_types) = spec in
 633         let ind_types = (* set inductive flags to false (coinductive) *)
 634           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 635             ind_types
 636         in
 637         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 638     | IDENT "coercion" ; name = IDENT ->
 639         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 640     | IDENT "coercion" ; name = URI ->
 641         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 642     | IDENT "alias" ; spec = alias_spec ->
 643         TacticAst.Alias (loc, spec)
 644     | IDENT "record" ; (params,name,ty,fields) = record_spec ->
 645         TacticAst.Obj (loc,TacticAst.Record (params,name,ty,fields))
 646     | IDENT "include" ; path = QSTRING ->
 647         TacticAst.Include (loc,path)
 648     | IDENT "default" ; what = QSTRING ; uris = LIST1 URI ->
 649        let uris = List.map UriManager.uri_of_string uris in
 650         TacticAst.Default (loc,what,uris)
 651   ]];
 652
 653   executable: [
 654     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 655     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 656     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 657     ]
 658   ];
 659
 660   comment: [
 661     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 662        TacticAst.Code (loc, ex)
 663     | str = NOTE ->
 664        TacticAst.Note (loc, str)
 665     ]
 666   ];
 667
 668   statement: [
 669     [ ex = executable -> TacticAst.Executable (loc,ex)
 670     | com = comment -> TacticAst.Comment (loc, com)
 671     ]
 672   ];
 673   statements: [
 674     [ l = LIST0 statement ; EOI -> l
 675     ]
 676   ];
 677 END
 678
 679 let exc_located_wrapper f =
 680   try
 681     f ()
 682   with
 683   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 684       raise (Parse_error (floc, msg))
 685   | Stdpp.Exc_located (floc, exn) ->
 686       raise (Parse_error (floc, (Printexc.to_string exn)))
 687
 688 let parse_term stream =
 689   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 690 let parse_statement stream =
 691   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 692 let parse_statements stream =
 693   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 694
 695
 696 (**/**)
 697
 698 (** {2 Interface for gTopLevel} *)
 699
 700 module EnvironmentP3 =
 701   struct
 702     type t = environment
 703
 704     let empty = ""
 705
 706     let aliases_grammar = Grammar.gcreate cic_lexer
 707     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 708
 709     let to_string env =
 710       let aliases =
 711         Environment.fold
 712           (fun domain_item (dsc, _) acc ->
 713             let s =
 714               match domain_item with
 715               | Id id ->
 716                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 717               | Symbol (symb, i) ->
 718                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 719                   ^ "."
 720               | Num i ->
 721                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 722             in
 723             s :: acc)
 724           env []
 725       in
 726       String.concat "\n" (List.sort compare aliases) ^
 727        (if aliases = [] then "" else "\n")
 728
 729     EXTEND
 730       GLOBAL: aliases;
 731       aliases: [  (* build an environment from an aliases list *)
 732         [ aliases = LIST0 alias; EOI ->
 733             List.fold_left
 734               (fun env (domain_item, codomain_item) ->
 735                 Environment.add domain_item codomain_item env)
 736               Environment.empty aliases
 737         ]
 738       ];
 739       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 740         [ IDENT "alias";
 741           choice =
 742             [ IDENT "id"; id = IDENT; SYMBOL "="; suri = URI ->
 743                 (Id id, choice_of_uri suri)
 744             | IDENT "symbol"; symbol = QSTRING;
 745               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 746               SYMBOL "="; dsc = QSTRING ->
 747                 (Symbol (symbol, int_of_string instance),
 748                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 749             | IDENT "num";
 750               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 751               SYMBOL "="; dsc = QSTRING ->
 752                 (Num (int_of_string instance),
 753                  DisambiguateChoices.lookup_num_by_dsc dsc)
 754             ] -> choice ]
 755       ];
 756     END
 757
 758     let of_string s =
 759       if s = empty then
 760         Environment.empty
 761       else
 762         exc_located_wrapper
 763           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 764   end
 765
 766 (* vim:set encoding=utf8: *)