helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri suri =
  57   let term = CicUtil.term_of_uri (UriManager.uri_of_string suri) in
  58   (suri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   arg: [
 175    [ PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ",";
 176       SYMBOL ":"; ty = term; PAREN ")" -> names,ty
 177    | name = IDENT -> [name],CicAst.Implicit
 178    ]
 179   ];
 180   let_defs:[
 181     [ defs = LIST1 [
 182         name = IDENT;
 183         args = LIST1 [arg = arg -> arg];
 184         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 185         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 186         SYMBOL <:unicode<def>> (* ≝ *);
 187         t1 = term ->
 188           let rec list_of_binder binder ty final_term = function
 189             | [] -> final_term
 190             | name::tl ->
 191                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 192                   list_of_binder binder ty final_term tl)
 193           in
 194           let rec binder_of_arg_list binder final_term = function
 195             | [] -> final_term
 196             | (l,ty)::tl ->
 197                 list_of_binder binder ty
 198                   (binder_of_arg_list binder final_term tl) l
 199           in
 200           let t1' = binder_of_arg_list `Lambda t1 args in
 201           let ty' =
 202             match ty with
 203             | None -> None
 204             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 205           in
 206           let rec get_position_of name n = function
 207             | [] -> (None,n)
 208             | nam::tl ->
 209                 if nam = name then
 210                   (Some n,n)
 211                 else
 212                   (get_position_of name (n+1) tl)
 213           in
 214           let rec find_arg name n = function
 215             | [] -> (fail loc (sprintf "Argument %s not found" name))
 216             | (l,_)::tl ->
 217                 let (got,len) = get_position_of name 0 l in
 218                 (match got with
 219                 | None -> (find_arg name (n+len) tl)
 220                 | Some where -> n + where)
 221           in
 222           let index =
 223             (match index_name with
 224              | None -> 0
 225              | (Some name) -> find_arg name 0 args)
 226           in
 227           ((Cic.Name name,ty'), t1', index)
 228       ] SEP "and" -> defs
 229     ]];
 230   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 231   binder_vars: [
 232       [ vars = LIST1 IDENT SEP SYMBOL ",";
 233         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 234       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 235         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 236       ]
 237   ];
 238   term0: [ [ t = term; EOI -> return_term loc t ] ];
 239   term:
 240     [ "letin" NONA
 241       [ "let"; var = typed_name;
 242         SYMBOL <:unicode<def>> (* ≝ *);
 243         t1 = term; "in"; t2 = term ->
 244           return_term loc (CicAst.LetIn (var, t1, t2))
 245       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 246         defs = let_defs; "in"; body = term ->
 247             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 248       ]
 249     | "binder" RIGHTA
 250       [
 251         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 252           let binder = mk_binder_ast b typ vars body in
 253           return_term loc binder
 254       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 255           let binder = mk_binder_ast b typ vars body in
 256           return_term loc binder
 257       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 258           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 259       ]
 260     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 261     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 262     | "logic_inv" NONA    [ (* nothing here by default *) ]
 263     | "relop" LEFTA
 264       [ t1 = term; SYMBOL "="; t2 = term ->
 265         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 266       ]
 267     | "add" LEFTA     [ (* nothing here by default *) ]
 268     | "mult" LEFTA    [ (* nothing here by default *) ]
 269     | "power" LEFTA   [ (* nothing here by default *) ]
 270     | "inv" NONA      [ (* nothing here by default *) ]
 271     | "apply" LEFTA
 272       [ t1 = term; t2 = term ->
 273         let rec aux = function
 274           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 275           | term -> [term]
 276         in
 277         CicAst.Appl (aux t1 @ [t2])
 278       ]
 279     | "simple" NONA
 280       [ sort = sort -> CicAst.Sort sort
 281       | n = substituted_name -> return_term loc n
 282       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 283       | IMPLICIT -> return_term loc CicAst.Implicit
 284       | PLACEHOLDER -> return_term loc CicAst.UserInput
 285       | m = META;
 286         substs = [
 287           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 288             substs
 289         ] ->
 290             let index =
 291               try
 292                 int_of_string (String.sub m 1 (String.length m - 1))
 293               with Failure "int_of_string" ->
 294                 fail loc ("Invalid meta variable number: " ^ m)
 295             in
 296             return_term loc (CicAst.Meta (index, substs))
 297       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 298         "match"; t = term;
 299         indty_ident = OPT ["in" ; id = IDENT -> id ];
 300         "with";
 301         PAREN "[";
 302         patterns = LIST0 [
 303           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 304           ->
 305             ((lhs: CicAst.case_pattern), rhs)
 306         ] SEP SYMBOL "|";
 307         PAREN "]" ->
 308           return_term loc
 309             (CicAst.Case (t, indty_ident, outtyp, patterns))
 310       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 311           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 312       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 313       ]
 314     ];
 315   tactic_term: [ [ t = term -> t ] ];
 316   ident_list0: [
 317     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 318   ];
 319   reduction_kind: [
 320     [ [ IDENT "reduce" ] -> `Reduce
 321     | [ IDENT "simplify" ] -> `Simpl
 322     | [ IDENT "whd" ] -> `Whd
 323     | [ IDENT "normalize" ] -> `Normalize ]
 324   ];
 325   pattern_spec: [
 326     [ "in";
 327       hyp_paths =
 328        LIST0
 329         [ id = IDENT ;
 330           path = OPT [SYMBOL ":" ; path = term -> path ] ->
 331           (id,match path with Some p -> p | None -> CicAst.UserInput) ]
 332         SEP SYMBOL ";";
 333       goal_path = OPT [ SYMBOL <:unicode<vdash>>; term = term -> term ] ->
 334         (hyp_paths, goal_path) ]
 335   ];
 336   direction: [
 337     [ IDENT "left" -> `Left
 338     | SYMBOL ">" -> `Left
 339     | IDENT "right" -> `Right
 340     | SYMBOL "<" -> `Right ]
 341   ];
 342   tactic: [
 343     [ IDENT "absurd"; t = tactic_term ->
 344         TacticAst.Absurd (loc, t)
 345     | IDENT "apply"; t = tactic_term ->
 346         TacticAst.Apply (loc, t)
 347     | IDENT "assumption" ->
 348         TacticAst.Assumption loc
 349     | IDENT "auto";
 350       depth = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ];
 351       width = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ] ->
 352           TacticAst.Auto (loc,depth,width)
 353     | IDENT "change"; t1 = tactic_term; "with"; t2 = tactic_term; "in";
 354       where = pattern_spec ->
 355         TacticAst.Change (loc, t1, t2, where)
 356     | IDENT "compare"; t = tactic_term ->
 357         TacticAst.Compare (loc,t)
 358     | IDENT "constructor"; n = NUM ->
 359         TacticAst.Constructor (loc,int_of_string n)
 360     | IDENT "contradiction" ->
 361         TacticAst.Contradiction loc
 362     | IDENT "cut"; t = tactic_term ->
 363         TacticAst.Cut (loc, t)
 364     | IDENT "decide"; IDENT "equality" ->
 365         TacticAst.DecideEquality loc
 366     | IDENT "decompose"; where = term ->
 367         TacticAst.Decompose (loc, where)
 368     | IDENT "discriminate"; t = tactic_term ->
 369         TacticAst.Discriminate (loc, t)
 370     | IDENT "elim"; t1 = tactic_term;
 371       using = OPT [ "using"; using = tactic_term -> using ] ->
 372         TacticAst.Elim (loc, t1, using)
 373     | IDENT "elimType"; t = tactic_term ->
 374         TacticAst.ElimType (loc, t)
 375     | IDENT "exact"; t = tactic_term ->
 376         TacticAst.Exact (loc, t)
 377     | IDENT "exists" ->
 378         TacticAst.Exists loc
 379     | IDENT "fold"; kind = reduction_kind; t = tactic_term ->
 380         TacticAst.Fold (loc, kind, t)
 381     | IDENT "fourier" ->
 382         TacticAst.Fourier loc
 383     | IDENT "fwd"; t = term ->
 384         TacticAst.FwdSimpl (loc, t)
 385     | IDENT "generalize"; t = tactic_term; p = OPT [ pattern_spec ] ->
 386        let p = match p with None -> [], None | Some p -> p in
 387        TacticAst.Generalize (loc,t,p)
 388     | IDENT "goal"; n = NUM ->
 389         TacticAst.Goal (loc, int_of_string n)
 390     | IDENT "injection"; t = term ->
 391         TacticAst.Injection (loc, t)
 392     | IDENT "intros"; num = OPT [num = int -> num]; idents = OPT ident_list0 ->
 393         let idents = match idents with None -> [] | Some idents -> idents in
 394         TacticAst.Intros (loc, num, idents)
 395     | IDENT "intro"; ident = OPT IDENT ->
 396         let idents = match ident with None -> [] | Some id -> [id] in
 397         TacticAst.Intros (loc, Some 1, idents)
 398     | IDENT "lapply"; what = tactic_term;
 399       to_what = OPT [ "to" ; t = tactic_term -> t ] ->
 400         TacticAst.LApply (loc, to_what, what)
 401     | IDENT "left" -> TacticAst.Left loc
 402     | IDENT "letin"; where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 403         TacticAst.LetIn (loc, t, where)
 404     | kind = reduction_kind; p = OPT [ pattern_spec ] ->
 405         let p = match p with None -> [], None | Some p -> p in
 406         TacticAst.Reduce (loc, kind, p)
 407     | IDENT "reflexivity" ->
 408         TacticAst.Reflexivity loc
 409     | IDENT "replace"; t1 = tactic_term; "with"; t2 = tactic_term ->
 410         TacticAst.Replace (loc, t1, t2)
 411     | IDENT "rewrite" ; d = direction; t = term ; p = OPT [ pattern_spec ] ->
 412         let p = match p with None -> [], None | Some p -> p in
 413         TacticAst.Rewrite (loc, d, t, p)
 414     | IDENT "right" ->
 415         TacticAst.Right loc
 416     | IDENT "ring" ->
 417         TacticAst.Ring loc
 418     | IDENT "split" ->
 419         TacticAst.Split loc
 420     | IDENT "symmetry" ->
 421         TacticAst.Symmetry loc
 422     | IDENT "transitivity"; t = tactic_term ->
 423         TacticAst.Transitivity (loc, t)
 424     ]
 425   ];
 426   tactical:
 427     [ "sequence" LEFTA
 428       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 429           TacticAst.Seq (loc, tacticals)
 430       ]
 431     | "then" NONA
 432       [ tac = tactical;
 433         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 434           (TacticAst.Then (loc, tac, tacs))
 435       ]
 436     | "loops" RIGHTA
 437       [ [ IDENT "do" ]; count = int; tac = tactical ->
 438           TacticAst.Do (loc, count, tac)
 439       | [ IDENT "repeat" ]; tac = tactical ->
 440           TacticAst.Repeat (loc, tac)
 441       ]
 442     | "simple" NONA
 443       [ IDENT "tries";
 444         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 445           TacticAst.Tries (loc, tacs)
 446       | IDENT "try"; tac = NEXT ->
 447           TacticAst.Try (loc, tac)
 448       | IDENT "fail" -> TacticAst.Fail loc
 449       | IDENT "id" -> TacticAst.IdTac loc
 450       | PAREN "("; tac = tactical; PAREN ")" -> tac
 451       | tac = tactic -> TacticAst.Tactic (loc, tac)
 452       ]
 453     ];
 454   theorem_flavour: [
 455     [ [ IDENT "definition"  ] -> `Definition
 456     | [ IDENT "fact"        ] -> `Fact
 457     | [ IDENT "lemma"       ] -> `Lemma
 458     | [ IDENT "remark"      ] -> `Remark
 459     | [ IDENT "theorem"     ] -> `Theorem
 460     ]
 461   ];
 462   inductive_spec: [ [
 463     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 464     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 465     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 466     tl = OPT [ "with";
 467       types = LIST1 [
 468         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 469        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 470           (name, true, typ, constructors) ] SEP "with" -> types
 471     ] ->
 472       let params =
 473         List.fold_right
 474           (fun (names, typ) acc ->
 475             (List.map (fun name -> (name, typ)) names) @ acc)
 476           params []
 477       in
 478       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 479       let tl_ind_types = match tl with None -> [] | Some types -> types in
 480       let ind_types = fst_ind_type :: tl_ind_types in
 481       (params, ind_types)
 482   ] ];
 483
 484   record_spec: [ [
 485     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 486      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; PAREN "{" ;
 487      fields = LIST0 [
 488        name = IDENT ; SYMBOL ":" ; ty = term -> (name,ty)
 489      ] SEP SYMBOL ";"; PAREN "}" ->
 490       let params =
 491         List.fold_right
 492           (fun (names, typ) acc ->
 493             (List.map (fun name -> (name, typ)) names) @ acc)
 494           params []
 495       in
 496       (params,name,typ,fields)
 497   ] ];
 498
 499   macro: [
 500     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 501 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 502     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 503 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 504         TacticAst.Undo (loc, int_opt steps)
 505     | [ IDENT "redo"   ]; steps = OPT NUM ->
 506         TacticAst.Redo (loc, int_opt steps) *)
 507     | [ IDENT "check"   ]; t = term ->
 508         TacticAst.Check (loc, t)
 509     | [ IDENT "hint" ] -> TacticAst.Hint loc
 510     | [ IDENT "whelp"; "match" ] ; t = term ->
 511         TacticAst.WMatch (loc,t)
 512     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 513         TacticAst.WInstance (loc,t)
 514     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 515         TacticAst.WLocate (loc,id)
 516     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 517         TacticAst.WElim (loc, t)
 518     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 519         TacticAst.WHint (loc,t)
 520     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 521     ]
 522   ];
 523
 524   alias_spec: [
 525     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 526       let alpha = "[a-zA-Z]" in
 527       let num = "[0-9]+" in
 528       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 529       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 530       let rex = Str.regexp ("^"^ident^"$") in
 531       if Str.string_match rex id 0 then
 532         let rex = Str.regexp
 533           ("^\\(cic:/\\|theory:/\\)"^ident^
 534            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 535            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 536         in
 537         if Str.string_match rex uri 0 then
 538           TacticAst.Ident_alias (id, uri)
 539         else
 540           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 541       else
 542         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 543     | IDENT "symbol"; symbol = QSTRING;
 544       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 545       SYMBOL "="; dsc = QSTRING ->
 546         let instance =
 547           match instance with Some i -> int_of_string i | None -> 0
 548         in
 549         TacticAst.Symbol_alias (symbol, instance, dsc)
 550     | IDENT "num";
 551       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 552       SYMBOL "="; dsc = QSTRING ->
 553         let instance =
 554           match instance with Some i -> int_of_string i | None -> 0
 555         in
 556         TacticAst.Number_alias (instance, dsc)
 557     ]
 558   ];
 559
 560   command: [[
 561       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 562         TacticAst.Set (loc, n, v)
 563     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 564     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 565       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 566         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, typ, body))
 567     | flavour = theorem_flavour; name = IDENT;
 568       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 569         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, CicAst.Implicit, body))
 570     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 571         defs = let_defs ->
 572           let name,ty =
 573             match defs with
 574             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 575             | ((Cic.Name name,None),_,_) :: _ -> name,CicAst.Implicit
 576             | _ -> assert false
 577           in
 578           let body = CicAst.Ident (name,None) in
 579           TacticAst.Obj (loc,TacticAst.Theorem(`Definition, name, ty,
 580             Some (CicAst.LetRec (ind_kind, defs, body))))
 581
 582     | [ IDENT "inductive" ]; spec = inductive_spec ->
 583         let (params, ind_types) = spec in
 584         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 585     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 586         let (params, ind_types) = spec in
 587         let ind_types = (* set inductive flags to false (coinductive) *)
 588           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 589             ind_types
 590         in
 591         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 592     | [ IDENT "coercion" ] ; name = IDENT ->
 593         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 594     | [ IDENT "coercion" ] ; name = URI ->
 595         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 596     | [ IDENT "alias"   ]; spec = alias_spec ->
 597         TacticAst.Alias (loc, spec)
 598     | [ IDENT "record" ]; (params,name,ty,fields) = record_spec ->
 599         TacticAst.Obj (loc,TacticAst.Record (params,name,ty,fields))
 600   ]];
 601
 602   executable: [
 603     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 604     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 605     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 606     ]
 607   ];
 608
 609   comment: [
 610     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 611        TacticAst.Code (loc, ex)
 612     | str = NOTE ->
 613        TacticAst.Note (loc, str)
 614     ]
 615   ];
 616
 617   statement: [
 618     [ ex = executable -> TacticAst.Executable (loc,ex)
 619     | com = comment -> TacticAst.Comment (loc, com)
 620     ]
 621   ];
 622   statements: [
 623     [ l = LIST0 statement ; EOI -> l
 624     ]
 625   ];
 626 END
 627
 628 let exc_located_wrapper f =
 629   try
 630     f ()
 631   with
 632   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 633       raise (Parse_error (floc, msg))
 634   | Stdpp.Exc_located (floc, exn) ->
 635       raise (Parse_error (floc, (Printexc.to_string exn)))
 636
 637 let parse_term stream =
 638   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 639 let parse_statement stream =
 640   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 641 let parse_statements stream =
 642   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 643
 644
 645 (**/**)
 646
 647 (** {2 Interface for gTopLevel} *)
 648
 649 module EnvironmentP3 =
 650   struct
 651     type t = environment
 652
 653     let empty = ""
 654
 655     let aliases_grammar = Grammar.gcreate cic_lexer
 656     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 657
 658     let to_string env =
 659       let aliases =
 660         Environment.fold
 661           (fun domain_item (dsc, _) acc ->
 662             let s =
 663               match domain_item with
 664               | Id id ->
 665                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 666               | Symbol (symb, i) ->
 667                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 668                   ^ "."
 669               | Num i ->
 670                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 671             in
 672             s :: acc)
 673           env []
 674       in
 675       String.concat "\n" (List.sort compare aliases)
 676
 677     EXTEND
 678       GLOBAL: aliases;
 679       aliases: [  (* build an environment from an aliases list *)
 680         [ aliases = LIST0 alias; EOI ->
 681             List.fold_left
 682               (fun env (domain_item, codomain_item) ->
 683                 Environment.add domain_item codomain_item env)
 684               Environment.empty aliases
 685         ]
 686       ];
 687       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 688         [ IDENT "alias";
 689           choice =
 690             [ IDENT "id"; id = IDENT; SYMBOL "="; suri = URI ->
 691                 (Id id, choice_of_uri suri)
 692             | IDENT "symbol"; symbol = QSTRING;
 693               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 694               SYMBOL "="; dsc = QSTRING ->
 695                 (Symbol (symbol, int_of_string instance),
 696                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 697             | IDENT "num";
 698               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 699               SYMBOL "="; dsc = QSTRING ->
 700                 (Num (int_of_string instance),
 701                  DisambiguateChoices.lookup_num_by_dsc dsc)
 702             ] -> choice ]
 703       ];
 704     END
 705
 706     let of_string s =
 707       if s = empty then
 708         Environment.empty
 709       else
 710         exc_located_wrapper
 711           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 712   end
 713
 714 (* vim:set encoding=utf8: *)