helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri uri =
  57   let term = CicUtil.term_of_uri uri in
  58   (uri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72
  73 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  74
  75 let fail floc msg =
  76   let (x, y) = CicAst.loc_of_floc floc in
  77   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  78
  79 let name_of_string = function
  80   | "_" -> Cic.Anonymous
  81   | s -> Cic.Name s
  82
  83 let string_of_name = function
  84   | Cic.Anonymous -> "_"
  85   | Cic.Name s -> s
  86
  87 let int_opt = function
  88   | None -> None
  89   | Some lexeme -> Some (int_of_string lexeme)
  90
  91 let int_of_string s =
  92   try
  93     Pervasives.int_of_string s
  94   with Failure _ ->
  95     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  96
  97   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  98   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
  99   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 100   * type in a block of mutual inductive types.
 101   *
 102   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 103   *)
 104 let ind_expansion uri =
 105   let len = String.length uri in
 106   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 107     uri ^ "#xpointer(1/1)"
 108   else
 109     uri
 110
 111 let mk_binder_ast binder typ vars body =
 112   List.fold_right
 113     (fun var body ->
 114        let name = name_of_string var in
 115        CicAst.Binder (binder, (name, typ), body))
 116     vars body
 117
 118 EXTEND
 119   GLOBAL: term term0 statement;
 120   int: [
 121     [ num = NUM ->
 122         try
 123           int_of_string num
 124         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 125     ]
 126   ];
 127   meta_subst: [
 128     [ s = SYMBOL "_" -> None
 129     | t = term -> Some t ]
 130   ];
 131   binder_low: [
 132     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 133     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 134     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 135   ];
 136   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 137   sort: [
 138     [ "Prop" -> `Prop
 139     | "Set" -> `Set
 140     | "Type" -> `Type
 141     | "CProp" -> `CProp ]
 142   ];
 143   typed_name: [
 144     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 145         (Cic.Name i, Some typ)
 146     | i = IDENT -> (Cic.Name i, None)
 147     ]
 148   ];
 149   subst: [
 150     [ subst = OPT [
 151         SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152         PAREN "[";
 153         substs = LIST1 [
 154           i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155         ] SEP SYMBOL ";";
 156         PAREN "]" ->
 157           substs
 158       ] -> subst
 159     ]
 160   ];
 161   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 162     [ s = IDENT; subst = subst -> CicAst.Ident (s, subst)
 163     | s = URI; subst = subst -> CicAst.Uri (ind_expansion s, subst)
 164     ]
 165   ];
 166   name: [ (* as substituted_name with no explicit substitution *)
 167     [ s = [ IDENT | SYMBOL ] -> s ]
 168   ];
 169   pattern: [
 170     [ n = name -> (n, [])
 171     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 172         (head, vars)
 173     ]
 174   ];
 175   let_defs:[
 176     [ defs = LIST1 [
 177         name = IDENT;
 178         args = LIST1 [
 179           PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 180           ty = term; PAREN ")" ->
 181             (names, ty)
 182         ];
 183         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 184         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 185         SYMBOL <:unicode<def>> (* ≝ *);
 186         t1 = term ->
 187           let rec list_of_binder binder ty final_term = function
 188             | [] -> final_term
 189             | name::tl ->
 190                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 191                   list_of_binder binder ty final_term tl)
 192           in
 193           let rec binder_of_arg_list binder final_term = function
 194             | [] -> final_term
 195             | (l,ty)::tl ->
 196                 list_of_binder binder ty
 197                   (binder_of_arg_list binder final_term tl) l
 198           in
 199           let t1' = binder_of_arg_list `Lambda t1 args in
 200           let ty' =
 201             match ty with
 202             | None -> None
 203             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 204           in
 205           let rec get_position_of name n = function
 206             | [] -> (None,n)
 207             | nam::tl ->
 208                 if nam = name then
 209                   (Some n,n)
 210                 else
 211                   (get_position_of name (n+1) tl)
 212           in
 213           let rec find_arg name n = function
 214             | [] -> (fail loc (sprintf "Argument %s not found" name))
 215             | (l,_)::tl ->
 216                 let (got,len) = get_position_of name 0 l in
 217                 (match got with
 218                 | None -> (find_arg name (n+len) tl)
 219                 | Some where -> n + where)
 220           in
 221           let index =
 222             (match index_name with
 223              | None -> 0
 224              | (Some name) -> find_arg name 0 args)
 225           in
 226           ((Cic.Name name,ty'), t1', index)
 227       ] SEP "and" -> defs
 228     ]];
 229   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 230   binder_vars: [
 231       [ vars = LIST1 IDENT SEP SYMBOL ",";
 232         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 233       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 234         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 235       ]
 236   ];
 237   term0: [ [ t = term; EOI -> return_term loc t ] ];
 238   term:
 239     [ "letin" NONA
 240       [ "let"; var = typed_name;
 241         SYMBOL <:unicode<def>> (* ≝ *);
 242         t1 = term; "in"; t2 = term ->
 243           return_term loc (CicAst.LetIn (var, t1, t2))
 244       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 245         defs = let_defs; "in"; body = term ->
 246             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 247       ]
 248     | "binder" RIGHTA
 249       [
 250         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 251           let binder = mk_binder_ast b typ vars body in
 252           return_term loc binder
 253       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 254           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 255       ]
 256     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 257     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 258     | "logic_inv" NONA    [ (* nothing here by default *) ]
 259     | "relop" LEFTA
 260       [ t1 = term; SYMBOL "="; t2 = term ->
 261         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 262       ]
 263     | "add" LEFTA     [ (* nothing here by default *) ]
 264     | "mult" LEFTA    [ (* nothing here by default *) ]
 265     | "power" LEFTA   [ (* nothing here by default *) ]
 266     | "inv" NONA      [ (* nothing here by default *) ]
 267     | "apply" LEFTA
 268       [ t1 = term; t2 = term ->
 269         let rec aux = function
 270           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 271           | term -> [term]
 272         in
 273         CicAst.Appl (aux t1 @ [t2])
 274       ]
 275     | "binder" RIGHTA
 276       [
 277         b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 278           let binder = mk_binder_ast b typ vars body in
 279           return_term loc binder
 280       ]
 281     | "simple" NONA
 282       [ sort = sort -> CicAst.Sort sort
 283       | n = substituted_name -> return_term loc n
 284       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 285       | IMPLICIT -> return_term loc CicAst.Implicit
 286       | m = META;
 287         substs = [
 288           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 289             substs
 290         ] ->
 291             let index =
 292               try
 293                 int_of_string (String.sub m 1 (String.length m - 1))
 294               with Failure "int_of_string" ->
 295                 fail loc ("Invalid meta variable number: " ^ m)
 296             in
 297             return_term loc (CicAst.Meta (index, substs))
 298       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 299         "match"; t = term;
 300         indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
 301         "with";
 302         PAREN "[";
 303         patterns = LIST0 [
 304           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 305           ->
 306             ((lhs: CicAst.case_pattern), rhs)
 307         ] SEP SYMBOL "|";
 308         PAREN "]" ->
 309           return_term loc
 310             (CicAst.Case (t, indty_ident, outtyp, patterns))
 311       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 312           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 313       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 314       ]
 315     ];
 316   tactic_where: [
 317     [ where = OPT [ "in"; ident = IDENT -> ident ] -> where ]
 318   ];
 319   tactic_term: [ [ t = term -> t ] ];
 320   ident_list0: [
 321     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 322   ];
 323   ident_list1: [
 324     [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 325   ];
 326   reduction_kind: [
 327     [ [ IDENT "reduce" ] -> `Reduce
 328     | [ IDENT "simplify" ] -> `Simpl
 329     | [ IDENT "whd" ] -> `Whd ]
 330   ];
 331   tactic: [
 332     [ [ IDENT "absurd" ]; t = tactic_term ->
 333         TacticAst.Absurd (loc, t)
 334     | [ IDENT "apply" ]; t = tactic_term ->
 335         TacticAst.Apply (loc, t)
 336     | [ IDENT "assumption" ] ->
 337         TacticAst.Assumption loc
 338     | [ IDENT "auto" ] -> TacticAst.Auto loc
 339     | [ IDENT "change" ];
 340       t1 = tactic_term; "with"; t2 = tactic_term;
 341       where = tactic_where ->
 342         TacticAst.Change (loc, t1, t2, where)
 343     (* TODO Change_pattern *)
 344     | [ IDENT "contradiction" ] ->
 345         TacticAst.Contradiction loc
 346     | [ IDENT "cut" ];
 347       t = tactic_term ->
 348         TacticAst.Cut (loc, t)
 349     | [ IDENT "decompose" ];
 350       principles = ident_list1; where = IDENT ->
 351         TacticAst.Decompose (loc, where, principles)
 352     | [ IDENT "discriminate" ];
 353       hyp = IDENT ->
 354         TacticAst.Discriminate (loc, hyp)
 355     | [ IDENT "elimType" ]; t = tactic_term ->
 356         TacticAst.ElimType (loc, t)
 357     | [ IDENT "elim" ];
 358       t1 = tactic_term;
 359       using = OPT [ "using"; using = tactic_term -> using ] ->
 360         TacticAst.Elim (loc, t1, using)
 361     | [ IDENT "exact" ]; t = tactic_term ->
 362         TacticAst.Exact (loc, t)
 363     | [ IDENT "exists" ] ->
 364         TacticAst.Exists loc
 365     | [ IDENT "fold" ];
 366       kind = reduction_kind; t = tactic_term ->
 367         TacticAst.Fold (loc, kind, t)
 368     | [ IDENT "fourier" ] ->
 369         TacticAst.Fourier loc
 370     | IDENT "goal"; n = NUM -> TacticAst.Goal (loc, int_of_string n)
 371     | [ IDENT "injection" ]; ident = IDENT ->
 372         TacticAst.Injection (loc, ident)
 373     | [ IDENT "intros" ];
 374       num = OPT [ num = int -> num ];
 375       idents = OPT ident_list0 ->
 376         let idents = match idents with None -> [] | Some idents -> idents in
 377         TacticAst.Intros (loc, num, idents)
 378     | [ IDENT "intro" ] ->
 379         TacticAst.Intros (loc, None, [])
 380     | [ IDENT "left" ] -> TacticAst.Left loc
 381     | [ "let" | "Let" ];
 382       t = tactic_term; "in"; where = IDENT ->
 383         TacticAst.LetIn (loc, t, where)
 384     | kind = reduction_kind;
 385       pat = OPT [
 386         "in"; pat = [ IDENT "goal" -> `Goal | IDENT "hyp" -> `Everywhere ] ->
 387           pat
 388       ];
 389       terms = LIST0 term SEP SYMBOL "," ->
 390         (match (pat, terms) with
 391         | None, [] -> TacticAst.Reduce (loc, kind, None)
 392         | None, terms -> TacticAst.Reduce (loc, kind, Some (terms, `Goal))
 393         | Some pat, [] -> TacticAst.Reduce (loc, kind, Some ([], pat))
 394         | Some pat, terms -> TacticAst.Reduce (loc, kind, Some (terms, pat)))
 395     | [ IDENT "reflexivity" ] ->
 396         TacticAst.Reflexivity loc
 397     | [ IDENT "replace" ];
 398       t1 = tactic_term; "with"; t2 = tactic_term ->
 399         TacticAst.Replace (loc, t1, t2)
 400     (* TODO Rewrite *)
 401     (* TODO Replace_pattern *)
 402     | [ IDENT "right" ] -> TacticAst.Right loc
 403     | [ IDENT "ring" ] -> TacticAst.Ring loc
 404     | [ IDENT "split" ] -> TacticAst.Split loc
 405     | [ IDENT "symmetry" ] ->
 406         TacticAst.Symmetry loc
 407     | [ IDENT "transitivity" ];
 408       t = tactic_term ->
 409         TacticAst.Transitivity (loc, t)
 410     ]
 411   ];
 412   tactical:
 413     [ "sequence" LEFTA
 414       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 415           TacticAst.Seq (loc, tacticals)
 416       ]
 417     | "then" NONA
 418       [ tac = tactical;
 419         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 420           (TacticAst.Then (loc, tac, tacs))
 421       ]
 422     | "loops" RIGHTA
 423       [ [ IDENT "do" ]; count = int; tac = tactical ->
 424           TacticAst.Do (loc, count, tac)
 425       | [ IDENT "repeat" ]; tac = tactical ->
 426           TacticAst.Repeat (loc, tac)
 427       ]
 428     | "simple" NONA
 429       [ IDENT "tries";
 430         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 431           TacticAst.Tries (loc, tacs)
 432       | IDENT "try"; tac = NEXT ->
 433           TacticAst.Try (loc, tac)
 434       | IDENT "fail" -> TacticAst.Fail loc
 435       | IDENT "id" -> TacticAst.IdTac loc
 436       | PAREN "("; tac = tactical; PAREN ")" -> tac
 437       | tac = tactic -> TacticAst.Tactic (loc, tac)
 438       ]
 439     ];
 440   theorem_flavour: [
 441     [ [ IDENT "definition"  ] -> `Definition
 442     | [ IDENT "fact"        ] -> `Fact
 443     | [ IDENT "lemma"       ] -> `Lemma
 444     | [ IDENT "remark"      ] -> `Remark
 445     | [ IDENT "theorem"     ] -> `Theorem
 446     ]
 447   ];
 448   inductive_spec: [ [
 449     fst_name = IDENT; params = LIST0 [
 450       PAREN "("; names = LIST1 IDENT SEP SYMBOL ","; SYMBOL ":";
 451       typ = term; PAREN ")" -> (names, typ) ];
 452     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 453     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 454     tl = OPT [ "with";
 455       types = LIST1 [
 456         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 457        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 458           (name, true, typ, constructors) ] SEP "with" -> types
 459     ] ->
 460       let params =
 461         List.fold_right
 462           (fun (names, typ) acc ->
 463             (List.map (fun name -> (name, typ)) names) @ acc)
 464           params []
 465       in
 466       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 467       let tl_ind_types = match tl with None -> [] | Some types -> types in
 468       let ind_types = fst_ind_type :: tl_ind_types in
 469       (params, ind_types)
 470   ] ];
 471
 472   macro: [[
 473       [ IDENT "abort" ] -> TacticAst.Abort loc
 474     | [ IDENT "quit"  ] -> TacticAst.Quit loc
 475     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 476     | [ IDENT "undo"   ]; steps = OPT NUM ->
 477         TacticAst.Undo (loc, int_opt steps)
 478     | [ IDENT "redo"   ]; steps = OPT NUM ->
 479         TacticAst.Redo (loc, int_opt steps)
 480     | [ IDENT "check"   ]; t = term ->
 481         TacticAst.Check (loc, t)
 482     | [ IDENT "hint" ] -> TacticAst.Hint loc
 483     | [ IDENT "pmatch" ] ; t = term -> TacticAst.Match (loc,t)
 484     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 485   ]];
 486
 487   alias_spec: [
 488     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 489       let alpha = "[a-zA-Z]" in
 490       let num = "[0-9]+" in
 491       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 492       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 493       let rex = Str.regexp ("^"^ident^"$") in
 494       if Str.string_match rex id 0 then
 495         let rex = Str.regexp
 496           ("^\\(cic:/\\|theory:/\\)"^ident^
 497            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 498            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 499         in
 500         if Str.string_match rex uri 0 then
 501           TacticAst.Ident_alias (id, uri)
 502         else
 503           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 504       else
 505         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 506     | IDENT "symbol"; symbol = QSTRING;
 507       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 508       SYMBOL "="; dsc = QSTRING ->
 509         let instance =
 510           match instance with Some i -> int_of_string i | None -> 0
 511         in
 512         TacticAst.Symbol_alias (symbol, instance, dsc)
 513     | IDENT "num";
 514       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 515       SYMBOL "="; dsc = QSTRING ->
 516         let instance =
 517           match instance with Some i -> int_of_string i | None -> 0
 518         in
 519         TacticAst.Number_alias (instance, dsc)
 520     ]
 521   ];
 522
 523   command: [[
 524       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 525         TacticAst.Set (loc, n, v)
 526     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 527     | flavour = theorem_flavour; name = OPT IDENT; SYMBOL ":"; typ = term;
 528       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 529         TacticAst.Theorem (loc, flavour, name, typ, body)
 530     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 531         defs = let_defs ->
 532           let name,ty =
 533             match defs with
 534             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 535             | ((Cic.Name name,None),_,_) :: _ ->
 536                 fail loc ("No type given for " ^ name)
 537             | _ -> assert false
 538           in
 539           let body = CicAst.Ident (name,None) in
 540           TacticAst.Theorem(loc, `Definition, Some name, ty,
 541             Some (CicAst.LetRec (ind_kind, defs, body)))
 542
 543     | [ IDENT "inductive" ]; spec = inductive_spec ->
 544         let (params, ind_types) = spec in
 545         TacticAst.Inductive (loc, params, ind_types)
 546     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 547         let (params, ind_types) = spec in
 548         let ind_types = (* set inductive flags to false (coinductive) *)
 549           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 550             ind_types
 551         in
 552         TacticAst.Inductive (loc, params, ind_types)
 553     | [ IDENT "coercion" ] ; name = IDENT ->
 554         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 555     | [ IDENT "coercion" ] ; name = URI ->
 556         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 557     | [ IDENT "alias"   ]; spec = alias_spec ->
 558         TacticAst.Alias (loc, spec)
 559   ]];
 560
 561   statement: [
 562     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 563     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 564     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 565     ]
 566   ];
 567 END
 568
 569 let exc_located_wrapper f =
 570   try
 571     f ()
 572   with
 573   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 574       raise (Parse_error (floc, msg))
 575   | Stdpp.Exc_located (floc, exn) ->
 576       raise (Parse_error (floc, (Printexc.to_string exn)))
 577
 578 let parse_term stream =
 579   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 580 let parse_statement stream =
 581   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 582
 583 (**/**)
 584
 585 (** {2 Interface for gTopLevel} *)
 586
 587 module EnvironmentP3 =
 588   struct
 589     type t = environment
 590
 591     let empty = ""
 592
 593     let aliases_grammar = Grammar.gcreate cic_lexer
 594     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 595
 596     let to_string env =
 597       let aliases =
 598         Environment.fold
 599           (fun domain_item (dsc, _) acc ->
 600             let s =
 601               match domain_item with
 602               | Id id ->
 603                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 604               | Symbol (symb, i) ->
 605                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 606                   ^ "."
 607               | Num i ->
 608                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 609             in
 610             s :: acc)
 611           env []
 612       in
 613       String.concat "\n" (List.sort compare aliases)
 614
 615     EXTEND
 616       GLOBAL: aliases;
 617       aliases: [  (* build an environment from an aliases list *)
 618         [ aliases = LIST0 alias; EOI ->
 619             List.fold_left
 620               (fun env (domain_item, codomain_item) ->
 621                 Environment.add domain_item codomain_item env)
 622               Environment.empty aliases
 623         ]
 624       ];
 625       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 626         [ IDENT "alias";
 627           choice =
 628             [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
 629                 (Id id, choice_of_uri uri)
 630             | IDENT "symbol"; symbol = QSTRING;
 631               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 632               SYMBOL "="; dsc = QSTRING ->
 633                 (Symbol (symbol, int_of_string instance),
 634                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 635             | IDENT "num";
 636               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 637               SYMBOL "="; dsc = QSTRING ->
 638                 (Num (int_of_string instance),
 639                  DisambiguateChoices.lookup_num_by_dsc dsc)
 640             ] -> choice ]
 641       ];
 642     END
 643
 644     let of_string s =
 645       if s = empty then
 646         Environment.empty
 647       else
 648         exc_located_wrapper
 649           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 650   end
 651
 652 (* vim:set encoding=utf8: *)