helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri uri =
  57   let term = CicUtil.term_of_uri uri in
  58   (uri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   arg: [
 175    [ PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ",";
 176       SYMBOL ":"; ty = term; PAREN ")" -> names,ty
 177    | name = IDENT -> [name],CicAst.Implicit
 178    ]
 179   ];
 180   let_defs:[
 181     [ defs = LIST1 [
 182         name = IDENT;
 183         args = LIST1 [arg = arg -> arg];
 184         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 185         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 186         SYMBOL <:unicode<def>> (* ≝ *);
 187         t1 = term ->
 188           let rec list_of_binder binder ty final_term = function
 189             | [] -> final_term
 190             | name::tl ->
 191                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 192                   list_of_binder binder ty final_term tl)
 193           in
 194           let rec binder_of_arg_list binder final_term = function
 195             | [] -> final_term
 196             | (l,ty)::tl ->
 197                 list_of_binder binder ty
 198                   (binder_of_arg_list binder final_term tl) l
 199           in
 200           let t1' = binder_of_arg_list `Lambda t1 args in
 201           let ty' =
 202             match ty with
 203             | None -> None
 204             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 205           in
 206           let rec get_position_of name n = function
 207             | [] -> (None,n)
 208             | nam::tl ->
 209                 if nam = name then
 210                   (Some n,n)
 211                 else
 212                   (get_position_of name (n+1) tl)
 213           in
 214           let rec find_arg name n = function
 215             | [] -> (fail loc (sprintf "Argument %s not found" name))
 216             | (l,_)::tl ->
 217                 let (got,len) = get_position_of name 0 l in
 218                 (match got with
 219                 | None -> (find_arg name (n+len) tl)
 220                 | Some where -> n + where)
 221           in
 222           let index =
 223             (match index_name with
 224              | None -> 0
 225              | (Some name) -> find_arg name 0 args)
 226           in
 227           ((Cic.Name name,ty'), t1', index)
 228       ] SEP "and" -> defs
 229     ]];
 230   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 231   binder_vars: [
 232       [ vars = LIST1 IDENT SEP SYMBOL ",";
 233         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 234       | PAREN "("; vars = LIST1 IDENT SEP SYMBOL ",";
 235         typ = OPT [ SYMBOL ":"; t = term -> t ]; PAREN ")" -> (vars, typ)
 236       ]
 237   ];
 238   term0: [ [ t = term; EOI -> return_term loc t ] ];
 239   term:
 240     [ "letin" NONA
 241       [ "let"; var = typed_name;
 242         SYMBOL <:unicode<def>> (* ≝ *);
 243         t1 = term; "in"; t2 = term ->
 244           return_term loc (CicAst.LetIn (var, t1, t2))
 245       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 246         defs = let_defs; "in"; body = term ->
 247             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 248       ]
 249     | "binder" RIGHTA
 250       [
 251         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 252           let binder = mk_binder_ast b typ vars body in
 253           return_term loc binder
 254       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 255           let binder = mk_binder_ast b typ vars body in
 256           return_term loc binder
 257       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 258           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 259       ]
 260     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 261     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 262     | "logic_inv" NONA    [ (* nothing here by default *) ]
 263     | "relop" LEFTA
 264       [ t1 = term; SYMBOL "="; t2 = term ->
 265         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 266       ]
 267     | "add" LEFTA     [ (* nothing here by default *) ]
 268     | "mult" LEFTA    [ (* nothing here by default *) ]
 269     | "power" LEFTA   [ (* nothing here by default *) ]
 270     | "inv" NONA      [ (* nothing here by default *) ]
 271     | "apply" LEFTA
 272       [ t1 = term; t2 = term ->
 273         let rec aux = function
 274           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 275           | term -> [term]
 276         in
 277         CicAst.Appl (aux t1 @ [t2])
 278       ]
 279     | "simple" NONA
 280       [ sort = sort -> CicAst.Sort sort
 281       | n = substituted_name -> return_term loc n
 282       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 283       | IMPLICIT -> return_term loc CicAst.Implicit
 284       | PLACEHOLDER -> return_term loc CicAst.UserInput
 285       | m = META;
 286         substs = [
 287           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 288             substs
 289         ] ->
 290             let index =
 291               try
 292                 int_of_string (String.sub m 1 (String.length m - 1))
 293               with Failure "int_of_string" ->
 294                 fail loc ("Invalid meta variable number: " ^ m)
 295             in
 296             return_term loc (CicAst.Meta (index, substs))
 297       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 298         "match"; t = term;
 299         indty_ident = OPT ["in" ; id = IDENT -> id ];
 300         "with";
 301         PAREN "[";
 302         patterns = LIST0 [
 303           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 304           ->
 305             ((lhs: CicAst.case_pattern), rhs)
 306         ] SEP SYMBOL "|";
 307         PAREN "]" ->
 308           return_term loc
 309             (CicAst.Case (t, indty_ident, outtyp, patterns))
 310       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 311           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 312       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 313       ]
 314     ];
 315   tactic_where: [
 316     [ where = OPT [ "in"; ident = IDENT -> ident ] -> where ]
 317   ];
 318   tactic_term: [ [ t = term -> t ] ];
 319   ident_list0: [
 320     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 321   ];
 322   ident_list1: [
 323     [ PAREN "["; idents = LIST1 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 324   ];
 325   reduction_kind: [
 326     [ [ IDENT "reduce" ] -> `Reduce
 327     | [ IDENT "simplify" ] -> `Simpl
 328     | [ IDENT "whd" ] -> `Whd
 329     | [ IDENT "normalize" ] -> `Normalize ]
 330   ];
 331   tactic: [
 332     [ [ IDENT "absurd" ]; t = tactic_term ->
 333         TacticAst.Absurd (loc, t)
 334     | [ IDENT "apply" ]; t = tactic_term ->
 335         TacticAst.Apply (loc, t)
 336     | [ IDENT "assumption" ] ->
 337         TacticAst.Assumption loc
 338     | [ IDENT "auto" ] ; num = OPT [ i = NUM -> int_of_string i ] ->
 339           TacticAst.Auto (loc,num)
 340     | [ IDENT "change" ];
 341       t1 = tactic_term; "with"; t2 = tactic_term;
 342       where = tactic_where ->
 343         TacticAst.Change (loc, t1, t2, where)
 344     (* TODO Change_pattern *)
 345     | [ IDENT "contradiction" ] ->
 346         TacticAst.Contradiction loc
 347     | [ IDENT "cut" ];
 348       t = tactic_term ->
 349         TacticAst.Cut (loc, t)
 350     | [ IDENT "decompose" ];
 351       principles = ident_list1; where = IDENT ->
 352         TacticAst.Decompose (loc, where, principles)
 353     | [ IDENT "discriminate" ];
 354       hyp = IDENT ->
 355         TacticAst.Discriminate (loc, hyp)
 356     | [ IDENT "elimType" ]; t = tactic_term ->
 357         TacticAst.ElimType (loc, t)
 358     | [ IDENT "elim" ];
 359       t1 = tactic_term;
 360       using = OPT [ "using"; using = tactic_term -> using ] ->
 361         TacticAst.Elim (loc, t1, using)
 362     | [ IDENT "exact" ]; t = tactic_term ->
 363         TacticAst.Exact (loc, t)
 364     | [ IDENT "exists" ] ->
 365         TacticAst.Exists loc
 366     | [ IDENT "fold" ];
 367       kind = reduction_kind; t = tactic_term ->
 368         TacticAst.Fold (loc, kind, t)
 369     | [ IDENT "fourier" ] ->
 370         TacticAst.Fourier loc
 371     | IDENT "goal"; n = NUM -> TacticAst.Goal (loc, int_of_string n)
 372     | [ IDENT "injection" ]; ident = IDENT ->
 373         TacticAst.Injection (loc, ident)
 374     | [ IDENT "intros" ];
 375       num = OPT [ num = int -> num ];
 376       idents = OPT ident_list0 ->
 377         let idents = match idents with None -> [] | Some idents -> idents in
 378         TacticAst.Intros (loc, num, idents)
 379     | [ IDENT "intro" ] ->
 380         TacticAst.Intros (loc, Some 1, [])
 381     | [ IDENT "left" ] -> TacticAst.Left loc
 382     | [ IDENT "letin" ];
 383        where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 384         TacticAst.LetIn (loc, t, where)
 385     | kind = reduction_kind;
 386       pat = OPT [
 387         "in"; pat = [ IDENT "goal" -> `Goal | IDENT "hyp" -> `Everywhere ] ->
 388           pat
 389       ];
 390       terms = LIST0 term SEP SYMBOL "," ->
 391         (match (pat, terms) with
 392         | None, [] -> TacticAst.Reduce (loc, kind, None)
 393         | None, terms -> TacticAst.Reduce (loc, kind, Some (terms, `Goal))
 394         | Some pat, [] -> fail loc "Missing term [list]"
 395         | Some pat, terms -> TacticAst.Reduce (loc, kind, Some (terms, pat)))
 396     | kind = reduction_kind; where = IDENT ; IDENT "at" ; pat = term ->
 397         TacticAst.ReduceAt (loc, kind, where, pat)
 398     | [ IDENT "reflexivity" ] ->
 399         TacticAst.Reflexivity loc
 400     | [ IDENT "replace" ];
 401       t1 = tactic_term; "with"; t2 = tactic_term ->
 402         TacticAst.Replace (loc, t1, t2)
 403     | [ IDENT "rewrite" ; IDENT "left" ] ; t = term ->
 404         TacticAst.Rewrite (loc,`Left, t, None)
 405     | [ IDENT "rewrite" ; IDENT "right" ] ; t = term ->
 406         TacticAst.Rewrite (loc,`Right, t, None)
 407     (* TODO Replace_pattern *)
 408     | [ IDENT "right" ] -> TacticAst.Right loc
 409     | [ IDENT "ring" ] -> TacticAst.Ring loc
 410     | [ IDENT "split" ] -> TacticAst.Split loc
 411     | [ IDENT "symmetry" ] ->
 412         TacticAst.Symmetry loc
 413     | [ IDENT "transitivity" ];
 414       t = tactic_term ->
 415         TacticAst.Transitivity (loc, t)
 416     ]
 417   ];
 418   tactical:
 419     [ "sequence" LEFTA
 420       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 421           TacticAst.Seq (loc, tacticals)
 422       ]
 423     | "then" NONA
 424       [ tac = tactical;
 425         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 426           (TacticAst.Then (loc, tac, tacs))
 427       ]
 428     | "loops" RIGHTA
 429       [ [ IDENT "do" ]; count = int; tac = tactical ->
 430           TacticAst.Do (loc, count, tac)
 431       | [ IDENT "repeat" ]; tac = tactical ->
 432           TacticAst.Repeat (loc, tac)
 433       ]
 434     | "simple" NONA
 435       [ IDENT "tries";
 436         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 437           TacticAst.Tries (loc, tacs)
 438       | IDENT "try"; tac = NEXT ->
 439           TacticAst.Try (loc, tac)
 440       | IDENT "fail" -> TacticAst.Fail loc
 441       | IDENT "id" -> TacticAst.IdTac loc
 442       | PAREN "("; tac = tactical; PAREN ")" -> tac
 443       | tac = tactic -> TacticAst.Tactic (loc, tac)
 444       ]
 445     ];
 446   theorem_flavour: [
 447     [ [ IDENT "definition"  ] -> `Definition
 448     | [ IDENT "fact"        ] -> `Fact
 449     | [ IDENT "lemma"       ] -> `Lemma
 450     | [ IDENT "remark"      ] -> `Remark
 451     | [ IDENT "theorem"     ] -> `Theorem
 452     ]
 453   ];
 454   inductive_spec: [ [
 455     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 456     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 457     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 458     tl = OPT [ "with";
 459       types = LIST1 [
 460         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 461        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 462           (name, true, typ, constructors) ] SEP "with" -> types
 463     ] ->
 464       let params =
 465         List.fold_right
 466           (fun (names, typ) acc ->
 467             (List.map (fun name -> (name, typ)) names) @ acc)
 468           params []
 469       in
 470       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 471       let tl_ind_types = match tl with None -> [] | Some types -> types in
 472       let ind_types = fst_ind_type :: tl_ind_types in
 473       (params, ind_types)
 474   ] ];
 475
 476   record_spec: [ [
 477     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 478      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; PAREN "{" ;
 479      fields = LIST0 [
 480        name = IDENT ; SYMBOL ":" ; ty = term -> (name,ty)
 481      ] SEP SYMBOL ";"; PAREN "}" ->
 482       let params =
 483         List.fold_right
 484           (fun (names, typ) acc ->
 485             (List.map (fun name -> (name, typ)) names) @ acc)
 486           params []
 487       in
 488       (params,name,typ,fields)
 489   ] ];
 490
 491   macro: [
 492     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 493 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 494     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 495 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 496         TacticAst.Undo (loc, int_opt steps)
 497     | [ IDENT "redo"   ]; steps = OPT NUM ->
 498         TacticAst.Redo (loc, int_opt steps) *)
 499     | [ IDENT "check"   ]; t = term ->
 500         TacticAst.Check (loc, t)
 501     | [ IDENT "hint" ] -> TacticAst.Hint loc
 502     | [ IDENT "whelp"; "match" ] ; t = term ->
 503         TacticAst.WMatch (loc,t)
 504     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 505         TacticAst.WInstance (loc,t)
 506     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 507         TacticAst.WLocate (loc,id)
 508     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 509         TacticAst.WElim (loc, t)
 510     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 511         TacticAst.WHint (loc,t)
 512     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 513     ]
 514   ];
 515
 516   alias_spec: [
 517     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 518       let alpha = "[a-zA-Z]" in
 519       let num = "[0-9]+" in
 520       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 521       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 522       let rex = Str.regexp ("^"^ident^"$") in
 523       if Str.string_match rex id 0 then
 524         let rex = Str.regexp
 525           ("^\\(cic:/\\|theory:/\\)"^ident^
 526            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 527            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 528         in
 529         if Str.string_match rex uri 0 then
 530           TacticAst.Ident_alias (id, uri)
 531         else
 532           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 533       else
 534         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 535     | IDENT "symbol"; symbol = QSTRING;
 536       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 537       SYMBOL "="; dsc = QSTRING ->
 538         let instance =
 539           match instance with Some i -> int_of_string i | None -> 0
 540         in
 541         TacticAst.Symbol_alias (symbol, instance, dsc)
 542     | IDENT "num";
 543       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 544       SYMBOL "="; dsc = QSTRING ->
 545         let instance =
 546           match instance with Some i -> int_of_string i | None -> 0
 547         in
 548         TacticAst.Number_alias (instance, dsc)
 549     ]
 550   ];
 551
 552   command: [[
 553       [ IDENT "set"    ]; n = QSTRING; v = QSTRING ->
 554         TacticAst.Set (loc, n, v)
 555     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 556     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 557       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 558         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, typ, body))
 559     | flavour = theorem_flavour; name = IDENT;
 560       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 561         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, CicAst.Implicit, body))
 562     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 563         defs = let_defs ->
 564           let name,ty =
 565             match defs with
 566             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 567             | ((Cic.Name name,None),_,_) :: _ -> name,CicAst.Implicit
 568             | _ -> assert false
 569           in
 570           let body = CicAst.Ident (name,None) in
 571           TacticAst.Obj (loc,TacticAst.Theorem(`Definition, name, ty,
 572             Some (CicAst.LetRec (ind_kind, defs, body))))
 573
 574     | [ IDENT "inductive" ]; spec = inductive_spec ->
 575         let (params, ind_types) = spec in
 576         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 577     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 578         let (params, ind_types) = spec in
 579         let ind_types = (* set inductive flags to false (coinductive) *)
 580           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 581             ind_types
 582         in
 583         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 584     | [ IDENT "coercion" ] ; name = IDENT ->
 585         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 586     | [ IDENT "coercion" ] ; name = URI ->
 587         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 588     | [ IDENT "alias"   ]; spec = alias_spec ->
 589         TacticAst.Alias (loc, spec)
 590     | [ IDENT "record" ]; (params,name,ty,fields) = record_spec ->
 591         TacticAst.Obj (loc,TacticAst.Record (params,name,ty,fields))
 592   ]];
 593
 594   executable: [
 595     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 596     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 597     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 598     ]
 599   ];
 600
 601   comment: [
 602     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 603        TacticAst.Code (loc, ex)
 604     | str = NOTE ->
 605        TacticAst.Note (loc, str)
 606     ]
 607   ];
 608
 609   statement: [
 610     [ ex = executable -> TacticAst.Executable (loc,ex)
 611     | com = comment -> TacticAst.Comment (loc, com)
 612     ]
 613   ];
 614   statements: [
 615     [ l = LIST0 [ statement ] -> l
 616     ]
 617   ];
 618 END
 619
 620 let exc_located_wrapper f =
 621   try
 622     f ()
 623   with
 624   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 625       raise (Parse_error (floc, msg))
 626   | Stdpp.Exc_located (floc, exn) ->
 627       raise (Parse_error (floc, (Printexc.to_string exn)))
 628
 629 let parse_term stream =
 630   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 631 let parse_statement stream =
 632   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 633 let parse_statements stream =
 634   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 635
 636
 637 (**/**)
 638
 639 (** {2 Interface for gTopLevel} *)
 640
 641 module EnvironmentP3 =
 642   struct
 643     type t = environment
 644
 645     let empty = ""
 646
 647     let aliases_grammar = Grammar.gcreate cic_lexer
 648     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 649
 650     let to_string env =
 651       let aliases =
 652         Environment.fold
 653           (fun domain_item (dsc, _) acc ->
 654             let s =
 655               match domain_item with
 656               | Id id ->
 657                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 658               | Symbol (symb, i) ->
 659                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 660                   ^ "."
 661               | Num i ->
 662                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 663             in
 664             s :: acc)
 665           env []
 666       in
 667       String.concat "\n" (List.sort compare aliases)
 668
 669     EXTEND
 670       GLOBAL: aliases;
 671       aliases: [  (* build an environment from an aliases list *)
 672         [ aliases = LIST0 alias; EOI ->
 673             List.fold_left
 674               (fun env (domain_item, codomain_item) ->
 675                 Environment.add domain_item codomain_item env)
 676               Environment.empty aliases
 677         ]
 678       ];
 679       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 680         [ IDENT "alias";
 681           choice =
 682             [ IDENT "id"; id = IDENT; SYMBOL "="; uri = URI ->
 683                 (Id id, choice_of_uri uri)
 684             | IDENT "symbol"; symbol = QSTRING;
 685               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 686               SYMBOL "="; dsc = QSTRING ->
 687                 (Symbol (symbol, int_of_string instance),
 688                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 689             | IDENT "num";
 690               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 691               SYMBOL "="; dsc = QSTRING ->
 692                 (Num (int_of_string instance),
 693                  DisambiguateChoices.lookup_num_by_dsc dsc)
 694             ] -> choice ]
 695       ];
 696     END
 697
 698     let of_string s =
 699       if s = empty then
 700         Environment.empty
 701       else
 702         exc_located_wrapper
 703           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 704   end
 705
 706 (* vim:set encoding=utf8: *)